1 #
   2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 # Setup X11 Windows system
  28 ################################################################################
  29 AC_DEFUN_ONCE([LIB_SETUP_X11],
  30 [
  31   if test "x$NEEDS_LIB_X11" = xfalse; then
  32     if (test "x${with_x}" != x && test "x${with_x}" != xno); then
  33       AC_MSG_WARN([X11 is not used, so --with-x is ignored])
  34     fi
  35     X_CFLAGS=
  36     X_LIBS=
  37   else
  38 
  39     if test "x${with_x}" = xno; then
  40       AC_MSG_ERROR([It is not possible to disable the use of X11. Remove the --without-x option.])
  41     fi
  42 
  43     if test "x${with_x}" != x &&  test "x${with_x}" != xyes; then
  44       # The user has specified a X11 base directory. Use it for includes and
  45       # libraries, unless explicitely overridden.
  46       if test "x$x_includes" = xNONE; then
  47         x_includes="${with_x}/include"
  48       fi
  49       if test "x$x_libraries" = xNONE; then
  50         x_libraries="${with_x}/lib"
  51       fi
  52     else
  53       # Check if the user has specified sysroot, but not --with-x, --x-includes or --x-libraries.
  54       # Make a simple check for the libraries at the sysroot, and setup --x-includes and
  55       # --x-libraries for the sysroot, if that seems to be correct.
  56       if test "x$SYSROOT" != "x"; then
  57         if test "x$x_includes" = xNONE; then
  58           if test -f "$SYSROOT/usr/X11R6/include/X11/Xlib.h"; then
  59             x_includes="$SYSROOT/usr/X11R6/include"
  60           elif test -f "$SYSROOT/usr/include/X11/Xlib.h"; then
  61             x_includes="$SYSROOT/usr/include"
  62           fi
  63         fi
  64         if test "x$x_libraries" = xNONE; then
  65           if test -f "$SYSROOT/usr/X11R6/lib/libX11.so"; then
  66             x_libraries="$SYSROOT/usr/X11R6/lib"
  67           elif test -f "$SYSROOT/usr/lib64/libX11.so" && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
  68             x_libraries="$SYSROOT/usr/lib64"
  69           elif test -f "$SYSROOT/usr/lib/libX11.so"; then
  70             x_libraries="$SYSROOT/usr/lib"
  71           fi
  72         fi
  73       fi
  74     fi
  75 
  76     # Now let autoconf do it's magic
  77     AC_PATH_X
  78     AC_PATH_XTRA
  79 
  80     # AC_PATH_XTRA creates X_LIBS and sometimes adds -R flags. When cross compiling
  81     # this doesn't make sense so we remove it.
  82     if test "x$COMPILE_TYPE" = xcross; then
  83       X_LIBS=`$ECHO $X_LIBS | $SED 's/-R \{0,1\}[[^ ]]*//g'`
  84     fi
  85 
  86     if test "x$no_x" = xyes; then
  87       HELP_MSG_MISSING_DEPENDENCY([x11])
  88       AC_MSG_ERROR([Could not find X11 libraries. $HELP_MSG])
  89     fi
  90 
  91     if test "x$OPENJDK_TARGET_OS" = xsolaris; then
  92       OPENWIN_HOME="/usr/openwin"
  93       X_CFLAGS="-I$SYSROOT$OPENWIN_HOME/include -I$SYSROOT$OPENWIN_HOME/include/X11/extensions"
  94       X_LIBS="-L$SYSROOT$OPENWIN_HOME/sfw/lib$OPENJDK_TARGET_CPU_ISADIR \
  95           -L$SYSROOT$OPENWIN_HOME/lib$OPENJDK_TARGET_CPU_ISADIR \
  96           -R$OPENWIN_HOME/sfw/lib$OPENJDK_TARGET_CPU_ISADIR \
  97           -R$OPENWIN_HOME/lib$OPENJDK_TARGET_CPU_ISADIR"
  98     fi
  99 
 100     AC_LANG_PUSH(C)
 101     OLD_CFLAGS="$CFLAGS"
 102     CFLAGS="$CFLAGS $SYSROOT_CFLAGS $X_CFLAGS"
 103 
 104     # Need to include Xlib.h and Xutil.h to avoid "present but cannot be compiled" warnings on Solaris 10
 105     AC_CHECK_HEADERS([X11/extensions/shape.h X11/extensions/Xrender.h X11/extensions/XTest.h X11/Intrinsic.h],
 106         [X11_HEADERS_OK=yes],
 107         [X11_HEADERS_OK=no; break],
 108         [
 109           # include <X11/Xlib.h>
 110           # include <X11/Xutil.h>
 111         ]
 112     )
 113 
 114     if test "x$X11_HEADERS_OK" = xno; then
 115       HELP_MSG_MISSING_DEPENDENCY([x11])
 116       AC_MSG_ERROR([Could not find all X11 headers (shape.h Xrender.h XTest.h Intrinsic.h). $HELP_MSG])
 117     fi
 118 
 119     # If XLinearGradient isn't available in Xrender.h, signal that it needs to be
 120     # defined in libawt_xawt.
 121     AC_MSG_CHECKING([if XlinearGradient is defined in Xrender.h])
 122     AC_COMPILE_IFELSE(
 123         [AC_LANG_PROGRAM([[#include <X11/extensions/Xrender.h>]],
 124             [[XLinearGradient x;]])],
 125         [AC_MSG_RESULT([yes])],
 126         [AC_MSG_RESULT([no])
 127          X_CFLAGS="$X_CFLAGS -DSOLARIS10_NO_XRENDER_STRUCTS"])
 128 
 129     CFLAGS="$OLD_CFLAGS"
 130     AC_LANG_POP(C)
 131   fi # NEEDS_LIB_X11
 132 
 133   AC_SUBST(X_CFLAGS)
 134   AC_SUBST(X_LIBS)
 135 ])