1 #
2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
31
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 FOUND_CORES=yes
36 elif test -x /usr/sbin/psrinfo; then
37 # Looks like a Solaris system
38 NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39 FOUND_CORES=yes
40 elif test -x /usr/sbin/system_profiler; then
41 # Looks like a MacOSX system
42 NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk '{print [$]5}'`
43 FOUND_CORES=yes
44 elif test "x$OPENJDK_BUILD_OS" = xaix ; then
45 NUM_LCPU=`lparstat -m 2> /dev/null | $GREP -o "lcpu=[[0-9]]*" | $CUT -d "=" -f 2`
46 if test -n "$NUM_LCPU"; then
47 NUM_CORES=$NUM_LCPU
48 FOUND_CORES=yes
49 fi
50 elif test -n "$NUMBER_OF_PROCESSORS"; then
51 # On windows, look in the env
52 NUM_CORES=$NUMBER_OF_PROCESSORS
53 FOUND_CORES=yes
54 fi
55
56 if test "x$FOUND_CORES" = xyes; then
57 AC_MSG_RESULT([$NUM_CORES])
58 else
59 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
60 AC_MSG_WARN([This will disable all parallelism from build!])
61 fi
62 ])
63
64 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
65 [
66 AC_MSG_CHECKING([for memory size])
67 # Default to 1024 MB
68 MEMORY_SIZE=1024
69 FOUND_MEM=no
70
71 if test -f /proc/meminfo; then
72 # Looks like a Linux (or cygwin) system
73 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
74 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
75 FOUND_MEM=yes
76 elif test -x /usr/sbin/prtconf; then
77 # Looks like a Solaris or AIX system
78 MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
79 FOUND_MEM=yes
80 elif test -x /usr/sbin/system_profiler; then
81 # Looks like a MacOSX system
82 MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk '{print [$]2}'`
83 MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
84 FOUND_MEM=yes
85 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
86 # Windows, but without cygwin
87 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
88 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
89 FOUND_MEM=yes
90 fi
91
92 if test "x$FOUND_MEM" = xyes; then
93 AC_MSG_RESULT([$MEMORY_SIZE MB])
94 else
95 AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])
96 AC_MSG_WARN([This might seriously impact build performance!])
97 fi
98 ])
99
100 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
101 [
102 # How many cores do we have on this build system?
103 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
104 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
105 if test "x$with_num_cores" = x; then
106 # The number of cores were not specified, try to probe them.
107 BPERF_CHECK_CORES
108 else
109 NUM_CORES=$with_num_cores
110 fi
111 AC_SUBST(NUM_CORES)
112 ])
113
114 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
115 [
116 # How much memory do we have on this build system?
117 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
118 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
119 if test "x$with_memory_size" = x; then
120 # The memory size was not specified, try to probe it.
121 BPERF_CHECK_MEMORY_SIZE
122 else
123 MEMORY_SIZE=$with_memory_size
124 fi
125 AC_SUBST(MEMORY_SIZE)
126 ])
127
128 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
129 [
130 # Provide a decent default number of parallel jobs for make depending on
131 # number of cores, amount of memory and machine architecture.
132 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
133 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
134 if test "x$with_jobs" = x; then
135 # Number of jobs was not specified, calculate.
136 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
137 # Approximate memory in GB, rounding up a bit.
138 memory_gb=`expr $MEMORY_SIZE / 1100`
139 # Pick the lowest of memory in gb and number of cores.
140 if test "$memory_gb" -lt "$NUM_CORES"; then
141 JOBS="$memory_gb"
142 else
143 JOBS="$NUM_CORES"
144 # On bigger machines, leave some room for other processes to run
145 if test "$JOBS" -gt "4"; then
146 JOBS=`expr $JOBS '*' 90 / 100`
147 fi
148 fi
149 # Cap number of jobs to 16
150 if test "$JOBS" -gt "16"; then
151 JOBS=16
152 fi
153 if test "$JOBS" -eq "0"; then
154 JOBS=1
155 fi
156 AC_MSG_RESULT([$JOBS])
157 else
158 JOBS=$with_jobs
159 fi
160 AC_SUBST(JOBS)
161 ])
162
163 AC_DEFUN([BPERF_SETUP_CCACHE],
164 [
165 AC_ARG_ENABLE([ccache],
166 [AS_HELP_STRING([--enable-ccache],
167 [enable using ccache to speed up recompilations @<:@disabled@:>@])])
168
169 CCACHE=
170 AC_MSG_CHECKING([is ccache enabled])
171 ENABLE_CCACHE=$enable_ccache
172 if test "x$enable_ccache" = xyes; then
173 AC_MSG_RESULT([yes])
174 OLD_PATH="$PATH"
175 if test "x$TOOLCHAIN_PATH" != x; then
176 PATH=$TOOLCHAIN_PATH:$PATH
177 fi
178 BASIC_REQUIRE_PROGS(CCACHE, ccache)
179 CCACHE_STATUS="enabled"
180 PATH="$OLD_PATH"
181 elif test "x$enable_ccache" = xno; then
182 AC_MSG_RESULT([no, explicitly disabled])
183 elif test "x$enable_ccache" = x; then
184 AC_MSG_RESULT([no])
185 else
186 AC_MSG_RESULT([unknown])
187 AC_MSG_ERROR([--enable-ccache does not accept any parameters])
188 fi
189 AC_SUBST(CCACHE)
190
191 AC_ARG_WITH([ccache-dir],
192 [AS_HELP_STRING([--with-ccache-dir],
193 [where to store ccache files @<:@~/.ccache@:>@])])
194
195 if test "x$with_ccache_dir" != x; then
196 # When using a non home ccache directory, assume the use is to share ccache files
197 # with other users. Thus change the umask.
198 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
199 if test "x$CCACHE" = x; then
200 AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
201 fi
202 fi
203
204 if test "x$CCACHE" != x; then
205 BPERF_SETUP_CCACHE_USAGE
206 fi
207 ])
208
209 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
210 [
211 if test "x$CCACHE" != x; then
212 # Only use ccache if it is 3.1.4 or later, which supports
213 # precompiled headers.
214 AC_MSG_CHECKING([if ccache supports precompiled headers])
215 HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`
216 if test "x$HAS_GOOD_CCACHE" = x; then
217 AC_MSG_RESULT([no, disabling ccache])
218 CCACHE=
219 CCACHE_STATUS="disabled"
220 else
221 AC_MSG_RESULT([yes])
222 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
223 PUSHED_FLAGS="$CXXFLAGS"
224 CXXFLAGS="-fpch-preprocess $CXXFLAGS"
225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
226 CXXFLAGS="$PUSHED_FLAGS"
227 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
228 AC_MSG_RESULT([yes])
229 else
230 AC_MSG_RESULT([no, disabling ccaching of precompiled headers])
231 CCACHE=
232 CCACHE_STATUS="disabled"
233 fi
234 fi
235 fi
236
237 if test "x$CCACHE" != x; then
238 CCACHE_SLOPPINESS=time_macros
239 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"
240 CCACHE_FLAGS=-fpch-preprocess
241
242 if test "x$SET_CCACHE_DIR" != x; then
243 mkdir -p $CCACHE_DIR > /dev/null 2>&1
244 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
245 fi
246 fi
247 ])
248
249 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
250 [
251
252 ###############################################################################
253 #
254 # Can the C/C++ compiler use precompiled headers?
255 #
256 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
257 [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
258 [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
259
260 USE_PRECOMPILED_HEADER=1
261 if test "x$ENABLE_PRECOMPH" = xno; then
262 USE_PRECOMPILED_HEADER=0
263 fi
264
265 if test "x$ENABLE_PRECOMPH" = xyes; then
266 # Check that the compiler actually supports precomp headers.
267 if test "x$TOOLCHAIN_TYPE" = xgcc; then
268 AC_MSG_CHECKING([that precompiled headers work])
269 echo "int alfa();" > conftest.h
270 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
271 if test ! -f conftest.hpp.gch; then
272 USE_PRECOMPILED_HEADER=0
273 AC_MSG_RESULT([no])
274 else
275 AC_MSG_RESULT([yes])
276 fi
277 rm -f conftest.h conftest.hpp.gch
278 fi
279 fi
280
281 AC_SUBST(USE_PRECOMPILED_HEADER)
282 ])
283
284
285 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
286 [
287 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
288 [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
289
290 if test "x$with_sjavac_server_java" != x; then
291 SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
292 FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
293 if test "x$FOUND_VERSION" = x; then
294 AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
295 fi
296 else
297 SJAVAC_SERVER_JAVA=""
298 # Hotspot specific options.
299 ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])
300 # JRockit specific options.
301 ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])
302 SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"
303 fi
304 AC_SUBST(SJAVAC_SERVER_JAVA)
305
306 if test "$MEMORY_SIZE" -gt "2500"; then
307 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
308 if test "$JVM_ARG_OK" = true; then
309 JVM_64BIT=true
310 JVM_ARG_OK=false
311 fi
312 fi
313
314 if test "$JVM_64BIT" = true; then
315 if test "$MEMORY_SIZE" -gt "17000"; then
316 ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
317 fi
318 if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then
319 ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
320 fi
321 if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then
322 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
323 fi
324 if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then
325 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
326 fi
327 fi
328 if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then
329 ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
330 fi
331 if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then
332 ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
333 fi
334 if test "$JVM_ARG_OK" = false; then
335 ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
336 fi
337
338 AC_MSG_CHECKING([whether to use sjavac])
339 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
340 [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
341 [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])
342 AC_MSG_RESULT([$ENABLE_SJAVAC])
343 AC_SUBST(ENABLE_SJAVAC)
344
345 if test "x$ENABLE_SJAVAC" = xyes; then
346 SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"
347 else
348 SJAVAC_SERVER_DIR=
349 fi
350 AC_SUBST(SJAVAC_SERVER_DIR)
351 ])