1 #
   2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64)
  34       VAR_CPU=x86_64
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=64
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     i?86)
  40       VAR_CPU=x86
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=32
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     arm*)
  46       VAR_CPU=arm
  47       VAR_CPU_ARCH=arm
  48       VAR_CPU_BITS=32
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     powerpc)
  52       VAR_CPU=ppc
  53       VAR_CPU_ARCH=ppc
  54       VAR_CPU_BITS=32
  55       VAR_CPU_ENDIAN=big
  56       ;;
  57     powerpc64)
  58       VAR_CPU=ppc64
  59       VAR_CPU_ARCH=ppc
  60       VAR_CPU_BITS=64
  61       VAR_CPU_ENDIAN=big
  62       ;;
  63     powerpc64le)
  64       VAR_CPU=ppc64le
  65       VAR_CPU_ARCH=ppc
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=little
  68       ;;
  69     s390)
  70       VAR_CPU=s390
  71       VAR_CPU_ARCH=s390
  72       VAR_CPU_BITS=32
  73       VAR_CPU_ENDIAN=big
  74       ;;
  75     s390x)
  76       VAR_CPU=s390x
  77       VAR_CPU_ARCH=s390
  78       VAR_CPU_BITS=64
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     sparc)
  82       VAR_CPU=sparc
  83       VAR_CPU_ARCH=sparc
  84       VAR_CPU_BITS=32
  85       VAR_CPU_ENDIAN=big
  86       ;;
  87     sparcv9)
  88       VAR_CPU=sparcv9
  89       VAR_CPU_ARCH=sparc
  90       VAR_CPU_BITS=64
  91       VAR_CPU_ENDIAN=big
  92       ;;
  93     *)
  94       AC_MSG_ERROR([unsupported cpu $1])
  95       ;;
  96   esac
  97 ])
  98 
  99 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 100 # Converts autoconf style OS name to OpenJDK style, into
 101 # VAR_OS and VAR_OS_API.
 102 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 103 [
 104   case "$1" in
 105     *linux*)
 106       VAR_OS=linux
 107       VAR_OS_API=posix
 108       VAR_OS_ENV=linux
 109       ;;
 110     *solaris*)
 111       VAR_OS=solaris
 112       VAR_OS_API=posix
 113       VAR_OS_ENV=solaris
 114       ;;
 115     *darwin*)
 116       VAR_OS=macosx
 117       VAR_OS_API=posix
 118       VAR_OS_ENV=macosx
 119       ;;
 120     *bsd*)
 121       VAR_OS=bsd
 122       VAR_OS_API=posix
 123       VAR_OS_ENV=bsd
 124       ;;
 125     *cygwin*)
 126       VAR_OS=windows
 127       VAR_OS_API=winapi
 128       VAR_OS_ENV=windows.cygwin
 129       ;;
 130     *mingw*)
 131       VAR_OS=windows
 132       VAR_OS_API=winapi
 133       VAR_OS_ENV=windows.msys
 134       ;;
 135     *aix*)
 136       VAR_OS=aix
 137       VAR_OS_API=posix
 138       VAR_OS_ENV=aix
 139       ;;
 140     *)
 141       AC_MSG_ERROR([unsupported operating system $1])
 142       ;;
 143   esac
 144 ])
 145 
 146 # Expects $host_os $host_cpu $build_os and $build_cpu
 147 # and $with_target_bits to have been setup!
 148 #
 149 # Translate the standard triplet(quadruplet) definition
 150 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 151 # OPENJDK_BUILD_OS, etc.
 152 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 153 [
 154   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 155   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 156   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 157   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 158   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 159   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 160   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 161   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 162 
 163   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 164   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 165   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 166   # ..and setup our own variables. (Do this explicitely to facilitate searching)
 167   OPENJDK_BUILD_OS="$VAR_OS"
 168   OPENJDK_BUILD_OS_API="$VAR_OS_API"
 169   OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 170   OPENJDK_BUILD_CPU="$VAR_CPU"
 171   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 172   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 173   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 174   AC_SUBST(OPENJDK_BUILD_OS)
 175   AC_SUBST(OPENJDK_BUILD_OS_API)
 176   AC_SUBST(OPENJDK_BUILD_CPU)
 177   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 178   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 179   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 180 
 181   AC_MSG_CHECKING([openjdk-build os-cpu])
 182   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 183 
 184   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 185   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 186   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 187   # ... and setup our own variables. (Do this explicitely to facilitate searching)
 188   OPENJDK_TARGET_OS="$VAR_OS"
 189   OPENJDK_TARGET_OS_API="$VAR_OS_API"
 190   OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 191   OPENJDK_TARGET_CPU="$VAR_CPU"
 192   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 193   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 194   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 195   AC_SUBST(OPENJDK_TARGET_OS)
 196   AC_SUBST(OPENJDK_TARGET_OS_API)
 197   AC_SUBST(OPENJDK_TARGET_CPU)
 198   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 199   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 200   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 201 
 202   AC_MSG_CHECKING([openjdk-target os-cpu])
 203   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 204 ])
 205 
 206 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 207 # accordingly. Must be done after setting up build and target system, but before
 208 # doing anything else with these values.
 209 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 210 [
 211   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 212        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 213 
 214   # We have three types of compiles:
 215   # native  == normal compilation, target system == build system
 216   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 217   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 218   #
 219   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 220     # We're doing a proper cross-compilation
 221     COMPILE_TYPE="cross"
 222   else
 223     COMPILE_TYPE="native"
 224   fi
 225 
 226   if test "x$with_target_bits" != x; then
 227     if test "x$COMPILE_TYPE" = "xcross"; then
 228       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 229     fi
 230 
 231     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 232       # A reduced build is requested
 233       COMPILE_TYPE="reduced"
 234       OPENJDK_TARGET_CPU_BITS=32
 235       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 236         OPENJDK_TARGET_CPU=x86
 237       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 238         OPENJDK_TARGET_CPU=sparc
 239       else
 240         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 241       fi
 242     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 243       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 244     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 245       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 246     else
 247       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 248     fi
 249   fi
 250   AC_SUBST(COMPILE_TYPE)
 251 
 252   AC_MSG_CHECKING([compilation type])
 253   AC_MSG_RESULT([$COMPILE_TYPE])
 254 ])
 255 
 256 # Setup the legacy variables, for controlling the old makefiles.
 257 #
 258 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 259 [
 260   # Also store the legacy naming of the cpu.
 261   # Ie i586 and amd64 instead of x86 and x86_64
 262   OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
 263   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 264     OPENJDK_TARGET_CPU_LEGACY="i586"
 265   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 266     # On all platforms except MacOSX replace x86_64 with amd64.
 267     OPENJDK_TARGET_CPU_LEGACY="amd64"
 268   fi
 269   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
 270 
 271   # And the second legacy naming of the cpu.
 272   # Ie i386 and amd64 instead of x86 and x86_64.
 273   OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
 274   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 275     OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
 276   elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 277     OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
 278   fi
 279   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
 280 
 281   # This is the name of the cpu (but using i386 and amd64 instead of
 282   # x86 and x86_64, respectively), preceeded by a /, to be used when
 283   # locating libraries. On macosx, it's empty, though.
 284   OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
 285   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 286     OPENJDK_TARGET_CPU_LIBDIR=""
 287   fi
 288   AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
 289 
 290   # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 291   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 292   # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
 293   OPENJDK_TARGET_CPU_ISADIR=""
 294   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 295     if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 296       OPENJDK_TARGET_CPU_ISADIR="/amd64"
 297     elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
 298       OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
 299     fi
 300   fi
 301   AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
 302 
 303   # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
 304   OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
 305   if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
 306     # On linux only, we replace x86 with i386.
 307     OPENJDK_TARGET_CPU_OSARCH="i386"
 308   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 309     # On all platforms except macosx, we replace x86_64 with amd64.
 310     OPENJDK_TARGET_CPU_OSARCH="amd64"
 311   fi
 312   AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
 313 
 314   OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
 315   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 316     OPENJDK_TARGET_CPU_JLI="i386"
 317   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 318     # On all platforms except macosx, we replace x86_64 with amd64.
 319     OPENJDK_TARGET_CPU_JLI="amd64"
 320   fi
 321   # Now setup the -D flags for building libjli.
 322   OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
 323   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 324     if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
 325       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
 326     elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
 327       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
 328     fi
 329   fi
 330   AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
 331 
 332   # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.
 333   if test "x$OPENJDK_TARGET_OS_API" = xposix; then
 334     OPENJDK_TARGET_OS_API_DIR="solaris"
 335   fi
 336   if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then
 337     OPENJDK_TARGET_OS_API_DIR="windows"
 338   fi
 339   AC_SUBST(OPENJDK_TARGET_OS_API_DIR)
 340 
 341   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 342       OPENJDK_TARGET_OS_EXPORT_DIR=macosx
 343   else
 344       OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_API_DIR}
 345   fi
 346   AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
 347 
 348   if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 349     A_LP64="LP64:="
 350     # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
 351     # unpack200.exe
 352     if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
 353       ADD_LP64="-D_LP64=1"
 354     fi
 355   fi
 356   AC_SUBST(LP64,$A_LP64)
 357 
 358   if test "x$COMPILE_TYPE" = "xcross"; then
 359     # FIXME: ... or should this include reduced builds..?
 360     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
 361   else
 362     DEFINE_CROSS_COMPILE_ARCH=""
 363   fi
 364   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 365 
 366   # ZERO_ARCHDEF is used to enable architecture-specific code
 367   case "${OPENJDK_TARGET_CPU}" in
 368     ppc*)    ZERO_ARCHDEF=PPC   ;;
 369     s390*)   ZERO_ARCHDEF=S390  ;;
 370     sparc*)  ZERO_ARCHDEF=SPARC ;;
 371     x86_64*) ZERO_ARCHDEF=AMD64 ;;
 372     x86)     ZERO_ARCHDEF=IA32  ;;
 373     *)      ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
 374   esac
 375   AC_SUBST(ZERO_ARCHDEF)
 376 ])
 377 
 378 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 379 [
 380   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 381     REQUIRED_OS_NAME=SunOS
 382     REQUIRED_OS_VERSION=5.10
 383   fi
 384   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 385     REQUIRED_OS_NAME=Linux
 386     REQUIRED_OS_VERSION=2.6
 387   fi
 388   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 389     REQUIRED_OS_NAME=Windows
 390     if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
 391       REQUIRED_OS_VERSION=5.2
 392     else
 393       REQUIRED_OS_VERSION=5.1
 394     fi
 395   fi
 396   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 397     REQUIRED_OS_NAME=Darwin
 398     REQUIRED_OS_VERSION=11.2
 399   fi
 400 
 401   AC_SUBST(REQUIRED_OS_NAME)
 402   AC_SUBST(REQUIRED_OS_VERSION)
 403 ])
 404 
 405 #%%% Build and target systems %%%
 406 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 407 [
 408   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 409   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 410   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 411   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 412   # to use the configure naming style.
 413   AC_CANONICAL_BUILD
 414   AC_CANONICAL_HOST
 415   AC_CANONICAL_TARGET
 416 
 417   PLATFORM_EXTRACT_TARGET_AND_BUILD
 418   PLATFORM_SETUP_TARGET_CPU_BITS
 419   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 420   PLATFORM_SETUP_LEGACY_VARS
 421 ])
 422 
 423 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 424 [
 425   ###############################################################################
 426 
 427   # Note that this is the build platform OS version!
 428 
 429   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 430   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 431   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 432   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 433   AC_SUBST(OS_VERSION_MAJOR)
 434   AC_SUBST(OS_VERSION_MINOR)
 435   AC_SUBST(OS_VERSION_MICRO)
 436 ])
 437 
 438 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
 439 # Add -mX to various FLAGS variables.
 440 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
 441 [
 442   # When we add flags to the "official" CFLAGS etc, we need to
 443   # keep track of these additions in ADDED_CFLAGS etc. These
 444   # will later be checked to make sure only controlled additions
 445   # have been made to CFLAGS etc.
 446   ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 447   ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 448   ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 449 
 450   CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
 451   CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
 452   LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
 453 
 454   CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
 455   CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
 456   LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
 457 ])
 458 
 459 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 460 [
 461   ###############################################################################
 462   #
 463   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 464   # (The JVM can use 32 or 64 bit Java pointers but that decision
 465   # is made at runtime.)
 466   #
 467 
 468   if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
 469     # Always specify -m flag on Solaris
 470     # And -q on AIX because otherwise the compiler produces 32-bit objects by default
 471     PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 472   elif test "x$COMPILE_TYPE" = xreduced; then
 473     if test "x$OPENJDK_TARGET_OS" != xwindows; then
 474       # Specify -m if running reduced on other Posix platforms
 475       PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 476     fi
 477   fi
 478 
 479   # Make compilation sanity check
 480   AC_CHECK_HEADERS([stdio.h], , [
 481     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 482     if test "x$COMPILE_TYPE" = xreduced; then
 483       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])
 484     elif test "x$COMPILE_TYPE" = xcross; then
 485       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 486     fi
 487     AC_MSG_ERROR([Cannot continue.])
 488   ])
 489 
 490   AC_CHECK_SIZEOF([int *], [1111])
 491 
 492   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 493   if test "x$ac_cv_sizeof_int_p" = x; then
 494     # The test failed, lets stick to the assumed value.
 495     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 496   else
 497     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 498 
 499     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 500       # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
 501       # Let's try to implicitely set the compilers target architecture and retry the test
 502       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
 503       AC_MSG_NOTICE([I'll retry after setting the platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
 504       PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 505 
 506       # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
 507       unset ac_cv_sizeof_int_p
 508       # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
 509       cat >>confdefs.h <<_ACEOF
 510 #undef SIZEOF_INT_P
 511 _ACEOF
 512 
 513       AC_CHECK_SIZEOF([int *], [1111])
 514 
 515       TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 516 
 517       if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 518         AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 519       fi
 520     fi
 521   fi
 522 
 523   AC_MSG_CHECKING([for target address size])
 524   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 525 ])
 526 
 527 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 528 [
 529   ###############################################################################
 530   #
 531   # Is the target little of big endian?
 532   #
 533   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 534 
 535   if test "x$ENDIAN" = xuniversal_endianness; then
 536     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 537   fi
 538   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 539     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 540   fi
 541 ])