1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64)
  34       VAR_CPU=x86_64
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=64
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     i?86)
  40       VAR_CPU=x86
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=32
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     alpha*)
  46       VAR_CPU=alpha
  47       VAR_CPU_ARCH=alpha
  48       VAR_CPU_BITS=64
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     arm*)
  52       VAR_CPU=arm
  53       VAR_CPU_ARCH=arm
  54       VAR_CPU_BITS=32
  55       VAR_CPU_ENDIAN=little
  56       ;;
  57     aarch64)
  58       VAR_CPU=aarch64
  59       VAR_CPU_ARCH=aarch64
  60       VAR_CPU_BITS=64
  61       VAR_CPU_ENDIAN=little
  62       ;;
  63     ia64)
  64       VAR_CPU=ia64
  65       VAR_CPU_ARCH=ia64
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=little
  68       ;;
  69     m68k)
  70       VAR_CPU=m68k
  71       VAR_CPU_ARCH=m68k
  72       VAR_CPU_BITS=32
  73       VAR_CPU_ENDIAN=big
  74       ;;
  75     mips)
  76       VAR_CPU=mips
  77       VAR_CPU_ARCH=mips
  78       VAR_CPU_BITS=32
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     mipsel)
  82       VAR_CPU=mipsel
  83       VAR_CPU_ARCH=mipsel
  84       VAR_CPU_BITS=32
  85       VAR_CPU_ENDIAN=little
  86       ;;
  87     mips64)
  88       VAR_CPU=mips64
  89       VAR_CPU_ARCH=mips64
  90       VAR_CPU_BITS=64
  91       VAR_CPU_ENDIAN=big
  92       ;;
  93     mips64el)
  94       VAR_CPU=mips64el
  95       VAR_CPU_ARCH=mips64el
  96       VAR_CPU_BITS=64
  97       VAR_CPU_ENDIAN=little
  98       ;;
  99     powerpc)
 100       VAR_CPU=ppc
 101       VAR_CPU_ARCH=ppc
 102       VAR_CPU_BITS=32
 103       VAR_CPU_ENDIAN=big
 104       ;;
 105     powerpc64)
 106       VAR_CPU=ppc64
 107       VAR_CPU_ARCH=ppc
 108       VAR_CPU_BITS=64
 109       VAR_CPU_ENDIAN=big
 110       ;;
 111     powerpc64le)
 112       VAR_CPU=ppc64le
 113       VAR_CPU_ARCH=ppc
 114       VAR_CPU_BITS=64
 115       VAR_CPU_ENDIAN=little
 116       ;;
 117     s390)
 118       VAR_CPU=s390
 119       VAR_CPU_ARCH=s390
 120       VAR_CPU_BITS=32
 121       VAR_CPU_ENDIAN=big
 122       ;;
 123     s390x)
 124       VAR_CPU=s390x
 125       VAR_CPU_ARCH=s390
 126       VAR_CPU_BITS=64
 127       VAR_CPU_ENDIAN=big
 128       ;;
 129     sh*eb)
 130       VAR_CPU=sh
 131       VAR_CPU_ARCH=sh
 132       VAR_CPU_BITS=32
 133       VAR_CPU_ENDIAN=big
 134       ;;
 135     sh*)
 136       VAR_CPU=sh
 137       VAR_CPU_ARCH=sh
 138       VAR_CPU_BITS=32
 139       VAR_CPU_ENDIAN=little
 140       ;;
 141     sparc)
 142       VAR_CPU=sparc
 143       VAR_CPU_ARCH=sparc
 144       VAR_CPU_BITS=32
 145       VAR_CPU_ENDIAN=big
 146       ;;
 147     sparcv9|sparc64)
 148       VAR_CPU=sparcv9
 149       VAR_CPU_ARCH=sparc
 150       VAR_CPU_BITS=64
 151       VAR_CPU_ENDIAN=big
 152       ;;
 153     *)
 154       AC_MSG_ERROR([unsupported cpu $1])
 155       ;;
 156   esac
 157 ])
 158 
 159 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 160 # Converts autoconf style OS name to OpenJDK style, into
 161 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
 162 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 163 [
 164   case "$1" in
 165     *linux*)
 166       VAR_OS=linux
 167       VAR_OS_TYPE=unix
 168       ;;
 169     *solaris*)
 170       VAR_OS=solaris
 171       VAR_OS_TYPE=unix
 172       ;;
 173     *darwin*)
 174       VAR_OS=macosx
 175       VAR_OS_TYPE=unix
 176       ;;
 177     *bsd*)
 178       VAR_OS=bsd
 179       VAR_OS_TYPE=unix
 180       ;;
 181     *cygwin*)
 182       VAR_OS=windows
 183       VAR_OS_ENV=windows.cygwin
 184       ;;
 185     *mingw*)
 186       VAR_OS=windows
 187       VAR_OS_ENV=windows.msys
 188       ;;
 189     *aix*)
 190       VAR_OS=aix
 191       VAR_OS_TYPE=unix
 192       ;;
 193     *)
 194       AC_MSG_ERROR([unsupported operating system $1])
 195       ;;
 196   esac
 197 ])
 198 
 199 # Expects $host_os $host_cpu $build_os and $build_cpu
 200 # and $with_target_bits to have been setup!
 201 #
 202 # Translate the standard triplet(quadruplet) definition
 203 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 204 # OPENJDK_BUILD_OS, etc.
 205 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 206 [
 207   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 208   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 209   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 210   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 211   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 212   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 213   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 214   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 215 
 216   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 217   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 218   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 219   # ..and setup our own variables. (Do this explicitly to facilitate searching)
 220   OPENJDK_BUILD_OS="$VAR_OS"
 221   if test "x$VAR_OS_TYPE" != x; then
 222     OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
 223   else
 224     OPENJDK_BUILD_OS_TYPE="$VAR_OS"
 225   fi
 226   if test "x$VAR_OS_ENV" != x; then
 227     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 228   else
 229     OPENJDK_BUILD_OS_ENV="$VAR_OS"
 230   fi
 231   OPENJDK_BUILD_CPU="$VAR_CPU"
 232   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 233   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 234   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 235   AC_SUBST(OPENJDK_BUILD_OS)
 236   AC_SUBST(OPENJDK_BUILD_OS_TYPE)
 237   AC_SUBST(OPENJDK_BUILD_OS_ENV)
 238   AC_SUBST(OPENJDK_BUILD_CPU)
 239   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 240   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 241   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 242 
 243   AC_MSG_CHECKING([openjdk-build os-cpu])
 244   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 245 
 246   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 247   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 248   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 249   # ... and setup our own variables. (Do this explicitly to facilitate searching)
 250   OPENJDK_TARGET_OS="$VAR_OS"
 251   if test "x$VAR_OS_TYPE" != x; then
 252     OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
 253   else
 254     OPENJDK_TARGET_OS_TYPE="$VAR_OS"
 255   fi
 256   if test "x$VAR_OS_ENV" != x; then
 257     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 258   else
 259     OPENJDK_TARGET_OS_ENV="$VAR_OS"
 260   fi
 261   OPENJDK_TARGET_CPU="$VAR_CPU"
 262   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 263   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 264   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 265   OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 266 
 267   AC_SUBST(OPENJDK_TARGET_OS)
 268   AC_SUBST(OPENJDK_TARGET_OS_TYPE)
 269   AC_SUBST(OPENJDK_TARGET_OS_ENV)
 270   AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
 271   AC_SUBST(OPENJDK_TARGET_CPU)
 272   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 273   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 274   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 275 
 276   AC_MSG_CHECKING([openjdk-target os-cpu])
 277   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 278 ])
 279 
 280 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 281 # accordingly. Must be done after setting up build and target system, but before
 282 # doing anything else with these values.
 283 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 284 [
 285   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 286        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 287 
 288   # We have three types of compiles:
 289   # native  == normal compilation, target system == build system
 290   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 291   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 292   #
 293   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 294     # We're doing a proper cross-compilation
 295     COMPILE_TYPE="cross"
 296   else
 297     COMPILE_TYPE="native"
 298   fi
 299 
 300   if test "x$with_target_bits" != x; then
 301     if test "x$COMPILE_TYPE" = "xcross"; then
 302       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 303     fi
 304 
 305     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 306       # A reduced build is requested
 307       COMPILE_TYPE="reduced"
 308       OPENJDK_TARGET_CPU_BITS=32
 309       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 310         OPENJDK_TARGET_CPU=x86
 311       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 312         OPENJDK_TARGET_CPU=sparc
 313       else
 314         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 315       fi
 316     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 317       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 318     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 319       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 320     else
 321       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 322     fi
 323   fi
 324   AC_SUBST(COMPILE_TYPE)
 325 
 326   AC_MSG_CHECKING([compilation type])
 327   AC_MSG_RESULT([$COMPILE_TYPE])
 328 ])
 329 
 330 # Setup the legacy variables, for controlling the old makefiles.
 331 #
 332 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 333 [
 334   PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
 335   PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
 336 ])
 337 
 338 # $1 - Either TARGET or BUILD to setup the variables for.
 339 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
 340 [
 341   # Also store the legacy naming of the cpu.
 342   # Ie i586 and amd64 instead of x86 and x86_64
 343   OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
 344   if test "x$OPENJDK_$1_CPU" = xx86; then
 345     OPENJDK_$1_CPU_LEGACY="i586"
 346   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 347     # On all platforms except MacOSX replace x86_64 with amd64.
 348     OPENJDK_$1_CPU_LEGACY="amd64"
 349   elif test "x$OPENJDK_$1_CPU" = xalpha; then
 350     # Avoid name collisions with variables named alpha
 351     OPENJDK_$1_CPU_LEGACY="_alpha_"
 352   elif test "x$OPENJDK_$1_CPU" = xsh; then
 353     # Avoid name collisions with variables named sh
 354     OPENJDK_$1_CPU_LEGACY="_sh_"
 355   fi
 356   AC_SUBST(OPENJDK_$1_CPU_LEGACY)
 357 
 358   # And the second legacy naming of the cpu.
 359   # Ie i386 and amd64 instead of x86 and x86_64.
 360   OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
 361   if test "x$OPENJDK_$1_CPU" = xx86; then
 362     OPENJDK_$1_CPU_LEGACY_LIB="i386"
 363   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 364     OPENJDK_$1_CPU_LEGACY_LIB="amd64"
 365   fi
 366   AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
 367 
 368   # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 369   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 370   # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
 371   OPENJDK_$1_CPU_ISADIR=""
 372   if test "x$OPENJDK_$1_OS" = xsolaris; then
 373     if test "x$OPENJDK_$1_CPU" = xx86_64; then
 374       OPENJDK_$1_CPU_ISADIR="/amd64"
 375     elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 376       OPENJDK_$1_CPU_ISADIR="/sparcv9"
 377     fi
 378   fi
 379   AC_SUBST(OPENJDK_$1_CPU_ISADIR)
 380 
 381   # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
 382   OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
 383   if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
 384     # On linux only, we replace x86 with i386.
 385     OPENJDK_$1_CPU_OSARCH="i386"
 386   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 387     # On all platforms except macosx, we replace x86_64 with amd64.
 388     OPENJDK_$1_CPU_OSARCH="amd64"
 389   fi
 390   AC_SUBST(OPENJDK_$1_CPU_OSARCH)
 391 
 392   OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
 393   if test "x$OPENJDK_$1_CPU" = xx86; then
 394     OPENJDK_$1_CPU_JLI="i386"
 395   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 396     # On all platforms except macosx, we replace x86_64 with amd64.
 397     OPENJDK_$1_CPU_JLI="amd64"
 398   fi
 399 
 400   # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
 401   # Macosx is osx and x86_64 is x64
 402   if test "x$OPENJDK_$1_OS" = xmacosx; then
 403     OPENJDK_$1_OS_BUNDLE="osx"
 404   else
 405     OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
 406   fi
 407   if test "x$OPENJDK_$1_CPU" = xx86_64; then
 408     OPENJDK_$1_CPU_BUNDLE="x64"
 409   else
 410     OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
 411   fi
 412   OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
 413   AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
 414 
 415   if test "x$COMPILE_TYPE" = "xcross"; then
 416     # FIXME: ... or should this include reduced builds..?
 417     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
 418   else
 419     DEFINE_CROSS_COMPILE_ARCH=""
 420   fi
 421   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 422 
 423   # Convert openjdk platform names to hotspot names
 424 
 425   HOTSPOT_$1_OS=${OPENJDK_$1_OS}
 426   if test "x$OPENJDK_$1_OS" = xmacosx; then
 427     HOTSPOT_$1_OS=bsd
 428   fi
 429   AC_SUBST(HOTSPOT_$1_OS)
 430 
 431   HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
 432   if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
 433     HOTSPOT_$1_OS_TYPE=posix
 434   fi
 435   AC_SUBST(HOTSPOT_$1_OS_TYPE)
 436 
 437   HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
 438   if test "x$OPENJDK_$1_CPU" = xx86; then
 439     HOTSPOT_$1_CPU=x86_32
 440   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 441     HOTSPOT_$1_CPU=sparc
 442   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 443     HOTSPOT_$1_CPU=ppc_64
 444   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 445     HOTSPOT_$1_CPU=ppc_64
 446   fi
 447   AC_SUBST(HOTSPOT_$1_CPU)
 448 
 449   # This is identical with OPENJDK_*, but define anyway for consistency.
 450   HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
 451   AC_SUBST(HOTSPOT_$1_CPU_ARCH)
 452 
 453   # Setup HOTSPOT_$1_CPU_DEFINE
 454   if test "x$OPENJDK_$1_CPU" = xx86; then
 455     HOTSPOT_$1_CPU_DEFINE=IA32
 456   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 457     HOTSPOT_$1_CPU_DEFINE=AMD64
 458   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 459     HOTSPOT_$1_CPU_DEFINE=SPARC
 460   elif test "x$OPENJDK_$1_CPU" = xaarch64; then
 461     HOTSPOT_$1_CPU_DEFINE=AARCH64
 462   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 463     HOTSPOT_$1_CPU_DEFINE=PPC64
 464   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 465     HOTSPOT_$1_CPU_DEFINE=PPC64
 466 
 467   # The cpu defines below are for zero, we don't support them directly.
 468   elif test "x$OPENJDK_$1_CPU" = xsparc; then
 469     HOTSPOT_$1_CPU_DEFINE=SPARC
 470   elif test "x$OPENJDK_$1_CPU" = xppc; then
 471     HOTSPOT_$1_CPU_DEFINE=PPC32
 472   elif test "x$OPENJDK_$1_CPU" = xs390; then
 473     HOTSPOT_$1_CPU_DEFINE=S390
 474   elif test "x$OPENJDK_$1_CPU" = xs390x; then
 475     HOTSPOT_$1_CPU_DEFINE=S390
 476   elif test "x$OPENJDK_$1_CPU" != x; then
 477     HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
 478   fi
 479   AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
 480 
 481   # For historical reasons, the OS include directories have odd names.
 482   OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
 483   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 484     OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
 485   elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 486     OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
 487   fi
 488   AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
 489 ])
 490 
 491 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 492 [
 493   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 494     RELEASE_FILE_OS_NAME=SunOS
 495   fi
 496   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 497     RELEASE_FILE_OS_NAME=Linux
 498   fi
 499   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 500     RELEASE_FILE_OS_NAME=Windows
 501   fi
 502   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 503     RELEASE_FILE_OS_NAME="Darwin"
 504   fi
 505   if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 506     RELEASE_FILE_OS_NAME="AIX"
 507   fi
 508   RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
 509 
 510   AC_SUBST(RELEASE_FILE_OS_NAME)
 511   AC_SUBST(RELEASE_FILE_OS_ARCH)
 512 ])
 513 
 514 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
 515 [
 516   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 517     OPENJDK_MODULE_TARGET_OS_NAME="macos"
 518   else
 519     OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
 520   fi
 521 
 522   if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 523     OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
 524   else
 525     OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
 526   fi
 527 
 528   OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
 529   AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
 530 ])
 531 
 532 #%%% Build and target systems %%%
 533 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 534 [
 535   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 536   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 537   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 538   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 539   # to use the configure naming style.
 540   AC_CANONICAL_BUILD
 541   AC_CANONICAL_HOST
 542   AC_CANONICAL_TARGET
 543 
 544   PLATFORM_EXTRACT_TARGET_AND_BUILD
 545   PLATFORM_SETUP_TARGET_CPU_BITS
 546   PLATFORM_SET_MODULE_TARGET_OS_VALUES
 547   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 548   PLATFORM_SETUP_LEGACY_VARS
 549 ])
 550 
 551 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 552 [
 553   ###############################################################################
 554 
 555   # Note that this is the build platform OS version!
 556 
 557   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 558   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 559   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 560   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 561   AC_SUBST(OS_VERSION_MAJOR)
 562   AC_SUBST(OS_VERSION_MINOR)
 563   AC_SUBST(OS_VERSION_MICRO)
 564 ])
 565 
 566 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 567 [
 568   ###############################################################################
 569   #
 570   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 571   # (The JVM can use 32 or 64 bit Java pointers but that decision
 572   # is made at runtime.)
 573   #
 574 
 575   # Make compilation sanity check
 576   AC_CHECK_HEADERS([stdio.h], , [
 577     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 578     if test "x$COMPILE_TYPE" = xreduced; then
 579       HELP_MSG_MISSING_DEPENDENCY([reduced])
 580       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 581     elif test "x$COMPILE_TYPE" = xcross; then
 582       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 583     fi
 584     AC_MSG_ERROR([Cannot continue.])
 585   ])
 586 
 587   AC_CHECK_SIZEOF([int *], [1111])
 588 
 589   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 590   if test "x$ac_cv_sizeof_int_p" = x; then
 591     # The test failed, lets stick to the assumed value.
 592     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 593   else
 594     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 595 
 596     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 597       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 598       if test "x$COMPILE_TYPE" = xreduced; then
 599         HELP_MSG_MISSING_DEPENDENCY([reduced])
 600         AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 601       elif test "x$COMPILE_TYPE" = xcross; then
 602         AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 603       fi
 604       AC_MSG_ERROR([Cannot continue.])
 605     fi
 606   fi
 607 
 608   AC_MSG_CHECKING([for target address size])
 609   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 610 ])
 611 
 612 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 613 [
 614   ###############################################################################
 615   #
 616   # Is the target little of big endian?
 617   #
 618   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 619 
 620   if test "x$ENDIAN" = xuniversal_endianness; then
 621     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 622   fi
 623   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 624     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 625   fi
 626 ])