1 #
   2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64)
  34       VAR_CPU=x86_64
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=64
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     i?86)
  40       VAR_CPU=x86
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=32
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     arm*)
  46       VAR_CPU=arm
  47       VAR_CPU_ARCH=arm
  48       VAR_CPU_BITS=32
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     aarch64)
  52       VAR_CPU=aarch64
  53       VAR_CPU_ARCH=aarch64
  54       VAR_CPU_BITS=64
  55       VAR_CPU_ENDIAN=little
  56       ;;
  57     powerpc)
  58       VAR_CPU=ppc
  59       VAR_CPU_ARCH=ppc
  60       VAR_CPU_BITS=32
  61       VAR_CPU_ENDIAN=big
  62       ;;
  63     powerpc64)
  64       VAR_CPU=ppc64
  65       VAR_CPU_ARCH=ppc
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=big
  68       ;;
  69     powerpc64le)
  70       VAR_CPU=ppc64
  71       VAR_CPU_ARCH=ppc
  72       VAR_CPU_BITS=64
  73       VAR_CPU_ENDIAN=little
  74       ;;
  75     s390)
  76       VAR_CPU=s390
  77       VAR_CPU_ARCH=s390
  78       VAR_CPU_BITS=32
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     s390x)
  82       VAR_CPU=s390x
  83       VAR_CPU_ARCH=s390
  84       VAR_CPU_BITS=64
  85       VAR_CPU_ENDIAN=big
  86       ;;
  87     sparc)
  88       VAR_CPU=sparc
  89       VAR_CPU_ARCH=sparc
  90       VAR_CPU_BITS=32
  91       VAR_CPU_ENDIAN=big
  92       ;;
  93     sparcv9|sparc64)
  94       VAR_CPU=sparcv9
  95       VAR_CPU_ARCH=sparc
  96       VAR_CPU_BITS=64
  97       VAR_CPU_ENDIAN=big
  98       ;;
  99     *)
 100       AC_MSG_ERROR([unsupported cpu $1])
 101       ;;
 102   esac
 103 ])
 104 
 105 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 106 # Converts autoconf style OS name to OpenJDK style, into
 107 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
 108 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 109 [
 110   case "$1" in
 111     *linux*)
 112       VAR_OS=linux
 113       VAR_OS_TYPE=unix
 114       ;;
 115     *solaris*)
 116       VAR_OS=solaris
 117       VAR_OS_TYPE=unix
 118       ;;
 119     *darwin*)
 120       VAR_OS=macosx
 121       VAR_OS_TYPE=unix
 122       ;;
 123     *bsd*)
 124       VAR_OS=bsd
 125       VAR_OS_TYPE=unix
 126       ;;
 127     *cygwin*)
 128       VAR_OS=windows
 129       VAR_OS_ENV=windows.cygwin
 130       ;;
 131     *mingw*)
 132       VAR_OS=windows
 133       VAR_OS_ENV=windows.msys
 134       ;;
 135     *aix*)
 136       VAR_OS=aix
 137       VAR_OS_TYPE=unix
 138       ;;
 139     *)
 140       AC_MSG_ERROR([unsupported operating system $1])
 141       ;;
 142   esac
 143 ])
 144 
 145 # Expects $host_os $host_cpu $build_os and $build_cpu
 146 # and $with_target_bits to have been setup!
 147 #
 148 # Translate the standard triplet(quadruplet) definition
 149 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 150 # OPENJDK_BUILD_OS, etc.
 151 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 152 [
 153   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 154   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 155   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 156   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 157   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 158   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 159   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 160   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 161 
 162   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 163   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 164   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 165   # ..and setup our own variables. (Do this explicitely to facilitate searching)
 166   OPENJDK_BUILD_OS="$VAR_OS"
 167   if test "x$VAR_OS_TYPE" != x; then
 168     OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
 169   else
 170     OPENJDK_BUILD_OS_TYPE="$VAR_OS"
 171   fi
 172   if test "x$VAR_OS_ENV" != x; then
 173     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 174   else
 175     OPENJDK_BUILD_OS_ENV="$VAR_OS"
 176   fi
 177   OPENJDK_BUILD_CPU="$VAR_CPU"
 178   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 179   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 180   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 181   AC_SUBST(OPENJDK_BUILD_OS)
 182   AC_SUBST(OPENJDK_BUILD_OS_TYPE)
 183   AC_SUBST(OPENJDK_BUILD_OS_ENV)
 184   AC_SUBST(OPENJDK_BUILD_CPU)
 185   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 186   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 187   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 188 
 189   AC_MSG_CHECKING([openjdk-build os-cpu])
 190   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 191 
 192   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 193   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 194   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 195   # ... and setup our own variables. (Do this explicitely to facilitate searching)
 196   OPENJDK_TARGET_OS="$VAR_OS"
 197   if test "x$VAR_OS_TYPE" != x; then
 198     OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
 199   else
 200     OPENJDK_TARGET_OS_TYPE="$VAR_OS"
 201   fi
 202   if test "x$VAR_OS_ENV" != x; then
 203     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 204   else
 205     OPENJDK_TARGET_OS_ENV="$VAR_OS"
 206   fi
 207   OPENJDK_TARGET_CPU="$VAR_CPU"
 208   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 209   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 210   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 211   AC_SUBST(OPENJDK_TARGET_OS)
 212   AC_SUBST(OPENJDK_TARGET_OS_TYPE)
 213   AC_SUBST(OPENJDK_TARGET_OS_ENV)
 214   AC_SUBST(OPENJDK_TARGET_CPU)
 215   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 216   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 217   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 218 
 219   AC_MSG_CHECKING([openjdk-target os-cpu])
 220   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 221 ])
 222 
 223 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 224 # accordingly. Must be done after setting up build and target system, but before
 225 # doing anything else with these values.
 226 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 227 [
 228   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 229        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 230 
 231   # We have three types of compiles:
 232   # native  == normal compilation, target system == build system
 233   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 234   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 235   #
 236   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 237     # We're doing a proper cross-compilation
 238     COMPILE_TYPE="cross"
 239   else
 240     COMPILE_TYPE="native"
 241   fi
 242 
 243   if test "x$with_target_bits" != x; then
 244     if test "x$COMPILE_TYPE" = "xcross"; then
 245       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 246     fi
 247 
 248     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 249       # A reduced build is requested
 250       COMPILE_TYPE="reduced"
 251       OPENJDK_TARGET_CPU_BITS=32
 252       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 253         OPENJDK_TARGET_CPU=x86
 254       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 255         OPENJDK_TARGET_CPU=sparc
 256       else
 257         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 258       fi
 259     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 260       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 261     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 262       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 263     else
 264       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 265     fi
 266   fi
 267   AC_SUBST(COMPILE_TYPE)
 268 
 269   AC_MSG_CHECKING([compilation type])
 270   AC_MSG_RESULT([$COMPILE_TYPE])
 271 ])
 272 
 273 # Setup the legacy variables, for controlling the old makefiles.
 274 #
 275 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 276 [
 277   # Also store the legacy naming of the cpu.
 278   # Ie i586 and amd64 instead of x86 and x86_64
 279   OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
 280   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 281     OPENJDK_TARGET_CPU_LEGACY="i586"
 282   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 283     # On all platforms except MacOSX replace x86_64 with amd64.
 284     OPENJDK_TARGET_CPU_LEGACY="amd64"
 285   fi
 286   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
 287 
 288   # And the second legacy naming of the cpu.
 289   # Ie i386 and amd64 instead of x86 and x86_64.
 290   OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
 291   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 292     OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
 293   elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 294     OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
 295   fi
 296   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
 297 
 298   # This is the name of the cpu (but using i386 and amd64 instead of
 299   # x86 and x86_64, respectively), preceeded by a /, to be used when
 300   # locating libraries. On macosx, it's empty, though.
 301   OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
 302   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 303     OPENJDK_TARGET_CPU_LIBDIR=""
 304   fi
 305   AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
 306 
 307   # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 308   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 309   # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
 310   OPENJDK_TARGET_CPU_ISADIR=""
 311   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 312     if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 313       OPENJDK_TARGET_CPU_ISADIR="/amd64"
 314     elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
 315       OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
 316     fi
 317   fi
 318   AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
 319 
 320   # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
 321   OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
 322   if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
 323     # On linux only, we replace x86 with i386.
 324     OPENJDK_TARGET_CPU_OSARCH="i386"
 325   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 326     # On all platforms except macosx, we replace x86_64 with amd64.
 327     OPENJDK_TARGET_CPU_OSARCH="amd64"
 328   fi
 329   AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
 330 
 331   OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
 332   if test "x$OPENJDK_TARGET_CPU" = xx86; then
 333     OPENJDK_TARGET_CPU_JLI="i386"
 334   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 335     # On all platforms except macosx, we replace x86_64 with amd64.
 336     OPENJDK_TARGET_CPU_JLI="amd64"
 337   fi
 338   # Now setup the -D flags for building libjli.
 339   OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
 340   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 341     if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
 342       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
 343     elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
 344       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
 345     fi
 346   fi
 347   AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
 348 
 349   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 350       OPENJDK_TARGET_OS_EXPORT_DIR=macosx
 351   else
 352       OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_TYPE}
 353   fi
 354   AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
 355 
 356   if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 357     A_LP64="LP64:="
 358     # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
 359     # unpack200.exe
 360     if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
 361       ADD_LP64="-D_LP64=1"
 362     fi
 363   fi
 364   AC_SUBST(LP64,$A_LP64)
 365 
 366   if test "x$COMPILE_TYPE" = "xcross"; then
 367     # FIXME: ... or should this include reduced builds..?
 368     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
 369   else
 370     DEFINE_CROSS_COMPILE_ARCH=""
 371   fi
 372   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 373 
 374   # ZERO_ARCHDEF is used to enable architecture-specific code
 375   case "${OPENJDK_TARGET_CPU}" in
 376     ppc)     ZERO_ARCHDEF=PPC32 ;;
 377     ppc64)   ZERO_ARCHDEF=PPC64 ;;
 378     s390*)   ZERO_ARCHDEF=S390  ;;
 379     sparc*)  ZERO_ARCHDEF=SPARC ;;
 380     x86_64*) ZERO_ARCHDEF=AMD64 ;;
 381     x86)     ZERO_ARCHDEF=IA32  ;;
 382     *)      ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
 383   esac
 384   AC_SUBST(ZERO_ARCHDEF)
 385 ])
 386 
 387 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 388 [
 389   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 390     REQUIRED_OS_NAME=SunOS
 391     REQUIRED_OS_VERSION=5.10
 392   fi
 393   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 394     REQUIRED_OS_NAME=Linux
 395     REQUIRED_OS_VERSION=2.6
 396   fi
 397   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 398     REQUIRED_OS_NAME=Windows
 399     if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
 400       REQUIRED_OS_VERSION=5.2
 401     else
 402       REQUIRED_OS_VERSION=5.1
 403     fi
 404   fi
 405   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 406     REQUIRED_OS_NAME=Darwin
 407     REQUIRED_OS_VERSION=11.2
 408   fi
 409 
 410   AC_SUBST(REQUIRED_OS_NAME)
 411   AC_SUBST(REQUIRED_OS_VERSION)
 412 ])
 413 
 414 #%%% Build and target systems %%%
 415 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 416 [
 417   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 418   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 419   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 420   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 421   # to use the configure naming style.
 422   AC_CANONICAL_BUILD
 423   AC_CANONICAL_HOST
 424   AC_CANONICAL_TARGET
 425 
 426   PLATFORM_EXTRACT_TARGET_AND_BUILD
 427   PLATFORM_SETUP_TARGET_CPU_BITS
 428   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 429   PLATFORM_SETUP_LEGACY_VARS
 430 ])
 431 
 432 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 433 [
 434   ###############################################################################
 435 
 436   # Note that this is the build platform OS version!
 437 
 438   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 439   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 440   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 441   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 442   AC_SUBST(OS_VERSION_MAJOR)
 443   AC_SUBST(OS_VERSION_MINOR)
 444   AC_SUBST(OS_VERSION_MICRO)
 445 ])
 446 
 447 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
 448 # Add -mX to various FLAGS variables.
 449 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
 450 [
 451   # When we add flags to the "official" CFLAGS etc, we need to
 452   # keep track of these additions in ADDED_CFLAGS etc. These
 453   # will later be checked to make sure only controlled additions
 454   # have been made to CFLAGS etc.
 455   ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 456   ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 457   ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
 458 
 459   CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
 460   CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
 461   LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
 462 
 463   CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
 464   CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
 465   LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
 466 ])
 467 
 468 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 469 [
 470   ###############################################################################
 471   #
 472   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 473   # (The JVM can use 32 or 64 bit Java pointers but that decision
 474   # is made at runtime.)
 475   #
 476 
 477   if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
 478     # Always specify -m flag on Solaris
 479     # And -q on AIX because otherwise the compiler produces 32-bit objects by default
 480     PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 481   elif test "x$COMPILE_TYPE" = xreduced; then
 482     if test "x$OPENJDK_TARGET_OS_TYPE" = xunix; then
 483       # Specify -m if running reduced on unix platforms
 484       PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 485     fi
 486   fi
 487 
 488   # Make compilation sanity check
 489   AC_CHECK_HEADERS([stdio.h], , [
 490     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 491     if test "x$COMPILE_TYPE" = xreduced; then
 492       HELP_MSG_MISSING_DEPENDENCY([reduced])
 493       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 494     elif test "x$COMPILE_TYPE" = xcross; then
 495       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 496     fi
 497     AC_MSG_ERROR([Cannot continue.])
 498   ])
 499 
 500   AC_CHECK_SIZEOF([int *], [1111])
 501 
 502   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 503   if test "x$ac_cv_sizeof_int_p" = x; then
 504     # The test failed, lets stick to the assumed value.
 505     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 506   else
 507     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 508 
 509     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 510       # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
 511       # Let's try to implicitely set the compilers target architecture and retry the test
 512       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
 513       AC_MSG_NOTICE([Retrying with platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
 514       PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
 515 
 516       # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
 517       unset ac_cv_sizeof_int_p
 518       # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
 519       cat >>confdefs.h <<_ACEOF
 520 #undef SIZEOF_INT_P
 521 _ACEOF
 522 
 523       AC_CHECK_SIZEOF([int *], [1111])
 524 
 525       TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 526 
 527       if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 528         AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 529         if test "x$COMPILE_TYPE" = xreduced; then
 530           HELP_MSG_MISSING_DEPENDENCY([reduced])
 531           AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 532         elif test "x$COMPILE_TYPE" = xcross; then
 533           AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 534         fi
 535         AC_MSG_ERROR([Cannot continue.])
 536       fi
 537     fi
 538   fi
 539 
 540   AC_MSG_CHECKING([for target address size])
 541   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 542 ])
 543 
 544 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 545 [
 546   ###############################################################################
 547   #
 548   # Is the target little of big endian?
 549   #
 550   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 551 
 552   if test "x$ENDIAN" = xuniversal_endianness; then
 553     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 554   fi
 555   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 556     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 557   fi
 558 ])