1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
34
35
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
38
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
45
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
52
53 # Setup a number of variables describing how native output files are
54 # named on this platform/toolchain.
55 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
56 [
57 # Define filename patterns
58 if test "x$OPENJDK_TARGET_OS" = xwindows; then
59 LIBRARY_PREFIX=
60 SHARED_LIBRARY_SUFFIX='.dll'
61 STATIC_LIBRARY_SUFFIX='.lib'
62 SHARED_LIBRARY='[$]1.dll'
63 STATIC_LIBRARY='[$]1.lib'
64 OBJ_SUFFIX='.obj'
65 EXE_SUFFIX='.exe'
66 else
67 LIBRARY_PREFIX=lib
68 SHARED_LIBRARY_SUFFIX='.so'
69 STATIC_LIBRARY_SUFFIX='.a'
70 SHARED_LIBRARY='lib[$]1.so'
71 STATIC_LIBRARY='lib[$]1.a'
72 OBJ_SUFFIX='.o'
73 EXE_SUFFIX=''
74 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
75 SHARED_LIBRARY='lib[$]1.dylib'
76 SHARED_LIBRARY_SUFFIX='.dylib'
77 fi
78 fi
79
80 AC_SUBST(LIBRARY_PREFIX)
81 AC_SUBST(SHARED_LIBRARY_SUFFIX)
82 AC_SUBST(STATIC_LIBRARY_SUFFIX)
83 AC_SUBST(SHARED_LIBRARY)
84 AC_SUBST(STATIC_LIBRARY)
85 AC_SUBST(OBJ_SUFFIX)
86 AC_SUBST(EXE_SUFFIX)
87 ])
88
89 # Determine which toolchain type to use, and make sure it is valid for this
90 # platform. Setup various information about the selected toolchain.
91 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
92 [
93 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
94 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
95
96 # Use indirect variable referencing
97 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
98 VALID_TOOLCHAINS=${!toolchain_var_name}
99
100 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
101 if test -n "$XCODEBUILD"; then
102 # On Mac OS X, default toolchain to clang after Xcode 5
103 XCODE_VERSION_OUTPUT=`"$XCODEBUILD" -version 2>&1 | $HEAD -n 1`
104 $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
105 if test $? -ne 0; then
106 AC_MSG_ERROR([Failed to determine Xcode version.])
107 fi
108 XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
109 $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
110 $CUT -f 1 -d .`
111 AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
112 if test $XCODE_MAJOR_VERSION -ge 5; then
113 DEFAULT_TOOLCHAIN="clang"
114 else
115 DEFAULT_TOOLCHAIN="gcc"
116 fi
117 else
118 # If Xcode is not installed, but the command line tools are
119 # then we can't run xcodebuild. On these systems we should
120 # default to clang
121 DEFAULT_TOOLCHAIN="clang"
122 fi
123 else
124 # First toolchain type in the list is the default
125 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
126 fi
127
128 if test "x$with_toolchain_type" = xlist; then
129 # List all toolchains
130 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
131 for toolchain in $VALID_TOOLCHAINS; do
132 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
133 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
134 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
135 done
136
137 exit 0
138 elif test "x$with_toolchain_type" != x; then
139 # User override; check that it is valid
140 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
141 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
142 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
143 AC_MSG_ERROR([Cannot continue.])
144 fi
145 TOOLCHAIN_TYPE=$with_toolchain_type
146 else
147 # No flag given, use default
148 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
149 fi
150 AC_SUBST(TOOLCHAIN_TYPE)
151
152 TOOLCHAIN_CC_BINARY_clang="clang"
153 TOOLCHAIN_CC_BINARY_gcc="gcc"
154 TOOLCHAIN_CC_BINARY_microsoft="cl"
155 TOOLCHAIN_CC_BINARY_solstudio="cc"
156 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
157
158 TOOLCHAIN_CXX_BINARY_clang="clang++"
159 TOOLCHAIN_CXX_BINARY_gcc="g++"
160 TOOLCHAIN_CXX_BINARY_microsoft="cl"
161 TOOLCHAIN_CXX_BINARY_solstudio="CC"
162 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
163
164 # Use indirect variable referencing
165 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
166 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
167 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
168 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
169 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
170 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
171
172 TOOLCHAIN_SETUP_FILENAME_PATTERNS
173
174 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
175 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
176 else
177 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
178 fi
179 ])
180
181 # Before we start detecting the toolchain executables, we might need some
182 # special setup, e.g. additional paths etc.
183 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
184 [
185 # FIXME: Is this needed?
186 AC_LANG(C++)
187
188 # Store the CFLAGS etc passed to the configure script.
189 ORG_CFLAGS="$CFLAGS"
190 ORG_CXXFLAGS="$CXXFLAGS"
191
192 # autoconf magic only relies on PATH, so update it if tools dir is specified
193 OLD_PATH="$PATH"
194
195 # On Windows, we need to detect the visual studio installation first.
196 # This will change the PATH, but we need to keep that new PATH even
197 # after toolchain detection is done, since the compiler (on x86) uses
198 # it for DLL resolution in runtime.
199 if test "x$OPENJDK_BUILD_OS" = "xwindows" \
200 && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
201 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
202 # Reset path to VS_PATH. It will include everything that was on PATH at the time we
203 # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
204 PATH="$VS_PATH"
205 # The microsoft toolchain also requires INCLUDE and LIB to be set.
206 export INCLUDE="$VS_INCLUDE"
207 export LIB="$VS_LIB"
208 fi
209
210 # For solaris we really need solaris tools, and not the GNU equivalent.
211 # The build tools on Solaris reside in /usr/ccs (C Compilation System),
212 # so add that to path before starting to probe.
213 # FIXME: This was originally only done for AS,NM,GNM,STRIP,OBJCOPY,OBJDUMP.
214 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
215 PATH="/usr/ccs/bin:$PATH"
216 fi
217
218 # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
219 # override all other locations.
220 if test "x$TOOLCHAIN_PATH" != x; then
221 PATH=$TOOLCHAIN_PATH:$PATH
222 fi
223 ])
224
225 # Restore path, etc
226 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
227 [
228 # Restore old path.
229 PATH="$OLD_PATH"
230
231 # Restore the flags to the user specified values.
232 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
233 CFLAGS="$ORG_CFLAGS"
234 CXXFLAGS="$ORG_CXXFLAGS"
235 ])
236
237 # Check if a compiler is of the toolchain type we expect, and save the version
238 # information from it. If the compiler does not match the expected type,
239 # this function will abort using AC_MSG_ERROR. If it matches, the version will
240 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
241 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
242 #
243 # $1 = compiler to test (CC or CXX)
244 # $2 = human readable name of compiler (C or C++)
245 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
246 [
247 COMPILER=[$]$1
248 COMPILER_NAME=$2
249
250 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
251 # cc -V output typically looks like
252 # cc: Sun C 5.12 Linux_i386 2011/11/16
253 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
254 # Check that this is likely to be the Solaris Studio cc.
255 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
256 if test $? -ne 0; then
257 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
258 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
259 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
260 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
261 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
262 fi
263 # Remove usage instructions (if present), and
264 # collapse compiler output into a single line
265 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
266 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
267 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
268 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
269 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
270 # xlc -qversion output typically looks like
271 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
272 # Version: 11.01.0000.0015
273 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
274 # Check that this is likely to be the IBM XL C compiler.
275 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
276 if test $? -ne 0; then
277 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
278 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
279 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
280 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
281 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
282 fi
283 # Collapse compiler output into a single line
284 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
285 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
286 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
287 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
288 # There is no specific version flag, but all output starts with a version string.
289 # First line typically looks something like:
290 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
291 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
292 # Check that this is likely to be Microsoft CL.EXE.
293 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
294 if test $? -ne 0; then
295 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
296 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
297 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
298 fi
299 # Collapse compiler output into a single line
300 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
301 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
302 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
303 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
304 # gcc --version output typically looks like
305 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
306 # Copyright (C) 2013 Free Software Foundation, Inc.
307 # This is free software; see the source for copying conditions. There is NO
308 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
309 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
310 # Check that this is likely to be GCC.
311 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
312 if test $? -ne 0; then
313 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
314 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
315 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
316 fi
317 # Remove Copyright and legalese from version string, and
318 # collapse into a single line
319 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
320 $SED -e 's/ *Copyright .*//'`
321 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
322 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
323 elif test "x$TOOLCHAIN_TYPE" = xclang; then
324 # clang --version output typically looks like
325 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
326 # clang version 3.3 (tags/RELEASE_33/final)
327 # or
328 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
329 # Target: x86_64-pc-linux-gnu
330 # Thread model: posix
331 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
332 # Check that this is likely to be clang
333 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
334 if test $? -ne 0; then
335 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
336 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
337 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
338 fi
339 # Collapse compiler output into a single line
340 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
341 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
342 $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
343 else
344 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
345 fi
346 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
347 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
348 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
349 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
350
351 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
352 ])
353
354 # Try to locate the given C or C++ compiler in the path, or otherwise.
355 #
356 # $1 = compiler to test (CC or CXX)
357 # $2 = human readable name of compiler (C or C++)
358 # $3 = list of compiler names to search for
359 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
360 [
361 COMPILER_NAME=$2
362 SEARCH_LIST="$3"
363
364 if test "x[$]$1" != x; then
365 # User has supplied compiler name already, always let that override.
366 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
367 if test "x`basename [$]$1`" = "x[$]$1"; then
368 # A command without a complete path is provided, search $PATH.
369
370 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
371 if test "x$POTENTIAL_$1" != x; then
372 $1=$POTENTIAL_$1
373 else
374 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
375 fi
376 else
377 # Otherwise it might already be a complete path
378 if test ! -x "[$]$1"; then
379 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
380 fi
381 fi
382 else
383 # No user supplied value. Locate compiler ourselves.
384
385 # If we are cross compiling, assume cross compilation tools follows the
386 # cross compilation standard where they are prefixed with the autoconf
387 # standard name for the target. For example the binary
388 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
389 # If we are not cross compiling, then the default compiler name will be
390 # used.
391
392 $1=
393 # If TOOLCHAIN_PATH is set, check for all compiler names in there first
394 # before checking the rest of the PATH.
395 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
396 # step, this should not be necessary.
397 if test -n "$TOOLCHAIN_PATH"; then
398 PATH_save="$PATH"
399 PATH="$TOOLCHAIN_PATH"
400 AC_PATH_PROGS(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
401 $1=$TOOLCHAIN_PATH_$1
402 PATH="$PATH_save"
403 fi
404
405 # AC_PATH_PROGS can't be run multiple times with the same variable,
406 # so create a new name for this run.
407 if test "x[$]$1" = x; then
408 AC_PATH_PROGS(POTENTIAL_$1, $SEARCH_LIST)
409 $1=$POTENTIAL_$1
410 fi
411
412 if test "x[$]$1" = x; then
413 HELP_MSG_MISSING_DEPENDENCY([devkit])
414 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
415 fi
416 fi
417
418 # Now we have a compiler binary in $1. Make sure it's okay.
419 BASIC_FIXUP_EXECUTABLE($1)
420 TEST_COMPILER="[$]$1"
421 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
422 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
423 if test "x$OPENJDK_BUILD_OS" != xaix; then
424 # FIXME: This test should not be needed anymore; we don't do that for any platform.
425 AC_MSG_CHECKING([resolved symbolic links for $1])
426 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
427 AC_MSG_RESULT([$TEST_COMPILER])
428 fi
429 AC_MSG_CHECKING([if $1 is disguised ccache])
430
431 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
432 if test "x$COMPILER_BASENAME" = "xccache"; then
433 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
434 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
435 # We want to control ccache invocation ourselves, so ignore this cc and try
436 # searching again.
437
438 # Remove the path to the fake ccache cc from the PATH
439 RETRY_COMPILER_SAVED_PATH="$PATH"
440 COMPILER_DIRNAME=`$DIRNAME [$]$1`
441 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
442
443 # Try again looking for our compiler
444 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
445 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
446 PATH="$RETRY_COMPILER_SAVED_PATH"
447
448 AC_MSG_CHECKING([for resolved symbolic links for $1])
449 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
450 AC_MSG_RESULT([$PROPER_COMPILER_$1])
451 $1="$PROPER_COMPILER_$1"
452 else
453 AC_MSG_RESULT([no, keeping $1])
454 fi
455
456 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
457 ])
458
459 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
460 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
461 # archiver (AR). Verify that the compilers are correct according to the
462 # toolchain type.
463 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
464 [
465 #
466 # Setup the compilers (CC and CXX)
467 #
468 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
469 # Now that we have resolved CC ourself, let autoconf have its go at it
470 AC_PROG_CC([$CC])
471
472 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
473 # Now that we have resolved CXX ourself, let autoconf have its go at it
474 AC_PROG_CXX([$CXX])
475
476 #
477 # Setup the preprocessor (CPP and CXXCPP)
478 #
479 AC_PROG_CPP
480 BASIC_FIXUP_EXECUTABLE(CPP)
481 AC_PROG_CXXCPP
482 BASIC_FIXUP_EXECUTABLE(CXXCPP)
483
484 #
485 # Setup the linker (LD)
486 #
487 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
488 # In the Microsoft toolchain we have a separate LD command "link".
489 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
490 # a cygwin program for something completely different.
491 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
492 BASIC_FIXUP_EXECUTABLE(LD)
493 # Verify that we indeed succeeded with this trick.
494 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
495 "$LD" --version > /dev/null
496 if test $? -eq 0 ; then
497 AC_MSG_RESULT([no])
498 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
499 else
500 AC_MSG_RESULT([yes])
501 fi
502 LDCXX="$LD"
503 else
504 # All other toolchains use the compiler to link.
505 LD="$CC"
506 LDCXX="$CXX"
507 fi
508 AC_SUBST(LD)
509 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
510 AC_SUBST(LDCXX)
511
512 #
513 # Setup the assembler (AS)
514 #
515 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
516 # FIXME: should this really be solaris, or solstudio?
517 BASIC_PATH_PROGS(AS, as)
518 BASIC_FIXUP_EXECUTABLE(AS)
519 else
520 # FIXME: is this correct for microsoft?
521 AS="$CC -c"
522 fi
523 AC_SUBST(AS)
524
525 #
526 # Setup the archiver (AR)
527 #
528 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
529 # The corresponding ar tool is lib.exe (used to create static libraries)
530 AC_CHECK_PROG([AR], [lib],[lib],,,)
531 else
532 BASIC_CHECK_TOOLS(AR, ar)
533 fi
534 BASIC_FIXUP_EXECUTABLE(AR)
535 ])
536
537 # Setup additional tools that is considered a part of the toolchain, but not the
538 # core part. Many of these are highly platform-specific and do not exist,
539 # and/or are not needed on all platforms.
540 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
541 [
542 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
543 BASIC_PATH_PROGS(LIPO, lipo)
544 BASIC_FIXUP_EXECUTABLE(LIPO)
545 fi
546
547 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
548 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
549 BASIC_FIXUP_EXECUTABLE(MT)
550 # Setup the resource compiler (RC)
551 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
552 BASIC_FIXUP_EXECUTABLE(RC)
553 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
554 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
555 # We need to check for 'msbuild.exe' because at the place where we expect to
556 # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
557 # won't find the 'msbuild.exe' executable in that case (and the
558 # 'ac_executable_extensions' is unusable due to performance reasons).
559 # Notice that we intentionally don't fix up the path to MSBUILD because we
560 # will call it in a DOS shell during freetype detection on Windows (see
561 # 'LIB_SETUP_FREETYPE' in "libraries.m4"
562 AC_CHECK_PROG([MSBUILD], [msbuild.exe], [msbuild.exe],,,)
563 fi
564
565 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
566 BASIC_PATH_PROGS(STRIP, strip)
567 BASIC_FIXUP_EXECUTABLE(STRIP)
568 BASIC_PATH_PROGS(NM, nm)
569 BASIC_FIXUP_EXECUTABLE(NM)
570 BASIC_PATH_PROGS(GNM, gnm)
571 BASIC_FIXUP_EXECUTABLE(GNM)
572 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
573 # FIXME: we should unify this with the solaris case above.
574 BASIC_CHECK_TOOLS(STRIP, strip)
575 BASIC_FIXUP_EXECUTABLE(STRIP)
576 BASIC_CHECK_TOOLS(NM, nm)
577 BASIC_FIXUP_EXECUTABLE(NM)
578 GNM="$NM"
579 AC_SUBST(GNM)
580 fi
581
582 # objcopy is used for moving debug symbols to separate files when
583 # full debug symbols are enabled.
584 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
585 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
586 # Only call fixup if objcopy was found.
587 if test -n "$OBJCOPY"; then
588 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
589 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
590 # objcopy prior to 2.21.1 on solaris is broken and is not usable.
591 # Rewrite objcopy version output to VALID_VERSION or BAD_VERSION.
592 # - version number is last blank separate word on first line
593 # - version number formats that have been seen:
594 # - <major>.<minor>
595 # - <major>.<minor>.<micro>
596 OBJCOPY_VERSION=`$OBJCOPY --version | $HEAD -n 1`
597 # The outer [ ] is to prevent m4 from eating the [] in the sed expression.
598 [ OBJCOPY_VERSION_CHECK=`$ECHO $OBJCOPY_VERSION | $SED -n \
599 -e 's/.* //' \
600 -e '/^[01]\./b bad' \
601 -e '/^2\./{' \
602 -e ' s/^2\.//' \
603 -e ' /^[0-9]$/b bad' \
604 -e ' /^[0-9]\./b bad' \
605 -e ' /^1[0-9]$/b bad' \
606 -e ' /^1[0-9]\./b bad' \
607 -e ' /^20\./b bad' \
608 -e ' /^21\.0$/b bad' \
609 -e ' /^21\.0\./b bad' \
610 -e '}' \
611 -e ':good' \
612 -e 's/.*/VALID_VERSION/p' \
613 -e 'q' \
614 -e ':bad' \
615 -e 's/.*/BAD_VERSION/p' \
616 -e 'q'` ]
617 if test "x$OBJCOPY_VERSION_CHECK" = xBAD_VERSION; then
618 OBJCOPY=
619 AC_MSG_WARN([Ignoring found objcopy since it is broken (prior to 2.21.1). No debug symbols will be generated.])
620 AC_MSG_NOTICE([objcopy reports version $OBJCOPY_VERSION])
621 AC_MSG_NOTICE([Note: patch 149063-01 or newer contains the correct Solaris 10 SPARC version])
622 AC_MSG_NOTICE([Note: patch 149064-01 or newer contains the correct Solaris 10 X86 version])
623 AC_MSG_NOTICE([Note: Solaris 11 Update 1 contains the correct version])
624 fi
625 fi
626 fi
627 fi
628
629 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
630 if test "x$OBJDUMP" != x; then
631 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
632 # bails if argument is missing.
633 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
634 fi
635 ])
636
637 # Setup the build tools (i.e, the compiler and linker used to build programs
638 # that should be run on the build platform, not the target platform, as a build
639 # helper). Since the non-cross-compile case uses the normal, target compilers
640 # for this, we can only do this after these have been setup.
641 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
642 [
643 if test "x$COMPILE_TYPE" = "xcross"; then
644 # Now we need to find a C/C++ compiler that can build executables for the
645 # build platform. We can't use the AC_PROG_CC macro, since it can only be
646 # used once. Also, we need to do this without adding a tools dir to the
647 # path, otherwise we might pick up cross-compilers which don't use standard
648 # naming.
649
650 # FIXME: we should list the discovered compilers as an exclude pattern!
651 # If we do that, we can do this detection before POST_DETECTION, and still
652 # find the build compilers in the tools dir, if needed.
653 BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
654 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
655 BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
656 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
657 BASIC_PATH_PROGS(BUILD_LD, ld)
658 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
659 BUILD_SYSROOT_CFLAGS=""
660 BUILD_SYSROOT_LDFLAGS=""
661 else
662 # If we are not cross compiling, use the normal target compilers for
663 # building the build platform executables.
664 BUILD_CC="$CC"
665 BUILD_CXX="$CXX"
666 BUILD_LD="$LD"
667 BUILD_SYSROOT_CFLAGS="$SYSROOT_CFLAGS"
668 BUILD_SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS"
669 fi
670
671 AC_SUBST(BUILD_CC)
672 AC_SUBST(BUILD_CXX)
673 AC_SUBST(BUILD_LD)
674 AC_SUBST(BUILD_SYSROOT_CFLAGS)
675 AC_SUBST(BUILD_SYSROOT_LDFLAGS)
676 ])
677
678 # Setup legacy variables that are still needed as alternative ways to refer to
679 # parts of the toolchain.
680 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
681 [
682 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
683 # For hotspot, we need these in Windows mixed path,
684 # so rewrite them all. Need added .exe suffix.
685 HOTSPOT_CXX="$CXX.exe"
686 HOTSPOT_LD="$LD.exe"
687 HOTSPOT_MT="$MT.exe"
688 HOTSPOT_RC="$RC.exe"
689 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
690 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
691 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
692 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
693 AC_SUBST(HOTSPOT_MT)
694 AC_SUBST(HOTSPOT_RC)
695 else
696 HOTSPOT_CXX="$CXX"
697 HOTSPOT_LD="$LD"
698 fi
699 AC_SUBST(HOTSPOT_CXX)
700 AC_SUBST(HOTSPOT_LD)
701
702 if test "x$TOOLCHAIN_TYPE" = xclang; then
703 USE_CLANG=true
704 fi
705 AC_SUBST(USE_CLANG)
706 ])
707
708 # Do some additional checks on the detected tools.
709 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
710 [
711 # The package path is used only on macosx?
712 # FIXME: clean this up, and/or move it elsewhere.
713 PACKAGE_PATH=/opt/local
714 AC_SUBST(PACKAGE_PATH)
715
716 # Check for extra potential brokenness.
717 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
718 # On Windows, double-check that we got the right compiler.
719 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
720 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
721 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
722 if test "x$COMPILER_CPU_TEST" != "x80x86" -a "x$COMPILER_CPU_TEST" != "xx86"; then
723 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86" or "x86".])
724 fi
725 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
726 if test "x$COMPILER_CPU_TEST" != "xx64"; then
727 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
728 fi
729 fi
730 fi
731
732 if test "x$TOOLCHAIN_TYPE" = xgcc; then
733 # If this is a --hash-style=gnu system, use --hash-style=both, why?
734 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
735 # This is later checked when setting flags.
736
737 # "-Og" suppported for GCC 4.8 and later
738 CFLAG_OPTIMIZE_DEBUG_FLAG="-Og"
739 FLAGS_COMPILER_CHECK_ARGUMENTS([$CFLAG_OPTIMIZE_DEBUG_FLAG],
740 [HAS_CFLAG_OPTIMIZE_DEBUG=true],
741 [HAS_CFLAG_OPTIMIZE_DEBUG=false])
742
743 # "-z relro" supported in GNU binutils 2.17 and later
744 LINKER_RELRO_FLAG="-Xlinker -z -Xlinker relro"
745 FLAGS_LINKER_CHECK_ARGUMENTS([$LINKER_RELRO_FLAG],
746 [HAS_LINKER_RELRO=true],
747 [HAS_LINKER_RELRO=false])
748
749 # "-z now" supported in GNU binutils 2.11 and later
750 LINKER_NOW_FLAG="-Xlinker -z -Xlinker now"
751 FLAGS_LINKER_CHECK_ARGUMENTS([$LINKER_NOW_FLAG],
752 [HAS_LINKER_NOW=true],
753 [HAS_LINKER_NOW=false])
754 fi
755
756 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
757 # in executable.'
758 USING_BROKEN_SUSE_LD=no
759 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
760 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
761 $ECHO "SUNWprivate_1.1 { local: *; };" > version-script.map
762 $ECHO "int main() { }" > main.c
763 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
764 AC_MSG_RESULT(no)
765 USING_BROKEN_SUSE_LD=no
766 else
767 AC_MSG_RESULT(yes)
768 USING_BROKEN_SUSE_LD=yes
769 fi
770 rm -rf version-script.map main.c a.out
771 fi
772 AC_SUBST(USING_BROKEN_SUSE_LD)
773 ])
774
775 # Setup the JTReg Regression Test Harness.
776 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
777 [
778 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
779 [Regression Test Harness @<:@probed@:>@])],
780 [],
781 [with_jtreg=no])
782
783 if test "x$with_jtreg" = xno; then
784 # jtreg disabled
785 AC_MSG_CHECKING([for jtreg])
786 AC_MSG_RESULT(no)
787 else
788 if test "x$with_jtreg" != xyes; then
789 # with path specified.
790 JT_HOME="$with_jtreg"
791 fi
792
793 if test "x$JT_HOME" != x; then
794 AC_MSG_CHECKING([for jtreg])
795
796 # use JT_HOME enviroment var.
797 BASIC_FIXUP_PATH([JT_HOME])
798
799 # jtreg win32 script works for everybody
800 JTREGEXE="$JT_HOME/bin/jtreg"
801
802 if test ! -f "$JTREGEXE"; then
803 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
804 fi
805
806 AC_MSG_RESULT($JTREGEXE)
807 else
808 # try to find jtreg on path
809 BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
810 JT_HOME="`$DIRNAME $JTREGEXE`"
811 fi
812 fi
813
814 AC_SUBST(JT_HOME)
815 AC_SUBST(JTREGEXE)
816 ])