1 #
2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup ABI profile (for arm)
29 #
30 AC_DEFUN([FLAGS_SETUP_ABI_PROFILE],
31 [
32 AC_ARG_WITH(abi-profile, [AS_HELP_STRING([--with-abi-profile],
33 [specify ABI profile for ARM builds (arm-vfp-sflt,arm-vfp-hflt,arm-sflt, armv5-vfp-sflt,armv6-vfp-hflt,arm64,aarch64) @<:@toolchain dependent@:>@ ])])
34
35 if test "x$with_abi_profile" != x; then
36 if test "x$OPENJDK_TARGET_CPU" != xarm && \
37 test "x$OPENJDK_TARGET_CPU" != xaarch64; then
38 AC_MSG_ERROR([--with-abi-profile only available on arm/aarch64])
39 fi
40
41 OPENJDK_TARGET_ABI_PROFILE=$with_abi_profile
42 AC_MSG_CHECKING([for ABI profle])
43 AC_MSG_RESULT([$OPENJDK_TARGET_ABI_PROFILE])
44
45 if test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-sflt; then
46 ARM_FLOAT_TYPE=vfp-sflt
47 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
48 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-hflt; then
49 ARM_FLOAT_TYPE=vfp-hflt
50 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
51 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-sflt; then
52 ARM_FLOAT_TYPE=sflt
53 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
54 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv5-vfp-sflt; then
55 ARM_FLOAT_TYPE=vfp-sflt
56 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
57 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv6-vfp-hflt; then
58 ARM_FLOAT_TYPE=vfp-hflt
59 ARM_ARCH_TYPE_FLAGS='-march=armv6 -marm'
60 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm64; then
61 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
62 ARM_FLOAT_TYPE=
63 ARM_ARCH_TYPE_FLAGS=
64 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xaarch64; then
65 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
66 ARM_FLOAT_TYPE=
67 ARM_ARCH_TYPE_FLAGS=
68 else
69 AC_MSG_ERROR([Invalid ABI profile: "$OPENJDK_TARGET_ABI_PROFILE"])
70 fi
71
72 if test "x$ARM_FLOAT_TYPE" = xvfp-sflt; then
73 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=softfp -mfpu=vfp -DFLOAT_ARCH=-vfp-sflt'
74 elif test "x$ARM_FLOAT_TYPE" = xvfp-hflt; then
75 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=hard -mfpu=vfp -DFLOAT_ARCH=-vfp-hflt'
76 elif test "x$ARM_FLOAT_TYPE" = xsflt; then
77 ARM_FLOAT_TYPE_FLAGS='-msoft-float -mfpu=vfp'
78 fi
79 AC_MSG_CHECKING([for $ARM_FLOAT_TYPE floating point flags])
80 AC_MSG_RESULT([$ARM_FLOAT_TYPE_FLAGS])
81
82 AC_MSG_CHECKING([for arch type flags])
83 AC_MSG_RESULT([$ARM_ARCH_TYPE_FLAGS])
84
85 # Now set JDK_ARCH_ABI_PROP_NAME. This is equivalent to the last part of the
86 # autoconf target triplet.
87 [ JDK_ARCH_ABI_PROP_NAME=`$ECHO $OPENJDK_TARGET_AUTOCONF_NAME | $SED -e 's/.*-\([^-]*\)$/\1/'` ]
88 # Sanity check that it is a known ABI.
89 if test "x$JDK_ARCH_ABI_PROP_NAME" != xgnu && \
90 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabi && \
91 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabihf; then
92 AC_MSG_WARN([Unknown autoconf target triplet ABI: "$JDK_ARCH_ABI_PROP_NAME"])
93 fi
94 AC_MSG_CHECKING([for ABI property name])
95 AC_MSG_RESULT([$JDK_ARCH_ABI_PROP_NAME])
96 AC_SUBST(JDK_ARCH_ABI_PROP_NAME)
97
98 # Pass these on to the open part of configure as if they were set using
99 # --with-extra-c[xx]flags.
100 EXTRA_CFLAGS="$EXTRA_CFLAGS $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
101 EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
102 # Get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
103 # FIXME: This should not really be set using extra_cflags.
104 if test "x$OPENJDK_TARGET_CPU" = xarm; then
105 EXTRA_CFLAGS="$EXTRA_CFLAGS -Wno-psabi"
106 EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -Wno-psabi"
107 fi
108 # Also add JDK_ARCH_ABI_PROP_NAME define, but only to CFLAGS.
109 EXTRA_CFLAGS="$EXTRA_CFLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
110 # And pass the architecture flags to the linker as well
111 EXTRA_LDFLAGS="$EXTRA_LDFLAGS $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
112 fi
113
114 # When building with an abi profile, the name of that profile is appended on the
115 # bundle platform, which is used in bundle names.
116 if test "x$OPENJDK_TARGET_ABI_PROFILE" != x; then
117 OPENJDK_TARGET_BUNDLE_PLATFORM="$OPENJDK_TARGET_OS_BUNDLE-$OPENJDK_TARGET_ABI_PROFILE"
118 fi
119 ])
120
121 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
122 # corresponding configure arguments instead
123 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
124 [
125 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
126 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
127 fi
128
129 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
130 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
131 fi
132
133 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
134 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
135 fi
136
137 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
138 [extra flags to be used when compiling jdk c-files])])
139
140 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
141 [extra flags to be used when compiling jdk c++-files])])
142
143 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
144 [extra flags to be used when linking jdk])])
145
146 EXTRA_CFLAGS="$with_extra_cflags"
147 EXTRA_CXXFLAGS="$with_extra_cxxflags"
148 EXTRA_LDFLAGS="$with_extra_ldflags"
149
150 # Hotspot needs these set in their legacy form
151 LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $EXTRA_CFLAGS"
152 LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $EXTRA_CXXFLAGS"
153 LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $EXTRA_LDFLAGS"
154
155 AC_SUBST(LEGACY_EXTRA_CFLAGS)
156 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
157 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
158
159 AC_SUBST(EXTRA_CFLAGS)
160 AC_SUBST(EXTRA_CXXFLAGS)
161 AC_SUBST(EXTRA_LDFLAGS)
162
163 # The global CFLAGS and LDLAGS variables are used by configure tests and
164 # should include the extra parameters
165 CFLAGS="$EXTRA_CFLAGS"
166 CXXFLAGS="$EXTRA_CXXFLAGS"
167 LDFLAGS="$EXTRA_LDFLAGS"
168 CPPFLAGS=""
169 ])
170
171 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
172 # that configure can use them while detecting compilers.
173 # TOOLCHAIN_TYPE is available here.
174 # Param 1 - Optional prefix to all variables. (e.g BUILD_)
175 AC_DEFUN([FLAGS_SETUP_SYSROOT_FLAGS],
176 [
177 if test "x[$]$1SYSROOT" != "x"; then
178 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
179 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
180 # Solaris Studio does not have a concept of sysroot. Instead we must
181 # make sure the default include and lib dirs are appended to each
182 # compile and link command line. Must also add -I-xbuiltin to enable
183 # inlining of system functions and intrinsics.
184 $1SYSROOT_CFLAGS="-I-xbuiltin -I[$]$1SYSROOT/usr/include"
185 $1SYSROOT_LDFLAGS="-L[$]$1SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
186 -L[$]$1SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR"
187 fi
188 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
189 $1SYSROOT_CFLAGS="--sysroot=[$]$1SYSROOT"
190 $1SYSROOT_LDFLAGS="--sysroot=[$]$1SYSROOT"
191 elif test "x$TOOLCHAIN_TYPE" = xclang; then
192 $1SYSROOT_CFLAGS="-isysroot [$]$1SYSROOT"
193 $1SYSROOT_LDFLAGS="-isysroot [$]$1SYSROOT"
194 fi
195 # Propagate the sysroot args to hotspot
196 $1LEGACY_EXTRA_CFLAGS="[$]$1LEGACY_EXTRA_CFLAGS [$]$1SYSROOT_CFLAGS"
197 $1LEGACY_EXTRA_CXXFLAGS="[$]$1LEGACY_EXTRA_CXXFLAGS [$]$1SYSROOT_CFLAGS"
198 $1LEGACY_EXTRA_LDFLAGS="[$]$1LEGACY_EXTRA_LDFLAGS [$]$1SYSROOT_LDFLAGS"
199 # The global CFLAGS and LDFLAGS variables need these for configure to function
200 $1CFLAGS="[$]$1CFLAGS [$]$1SYSROOT_CFLAGS"
201 $1CPPFLAGS="[$]$1CPPFLAGS [$]$1SYSROOT_CFLAGS"
202 $1CXXFLAGS="[$]$1CXXFLAGS [$]$1SYSROOT_CFLAGS"
203 $1LDFLAGS="[$]$1LDFLAGS [$]$1SYSROOT_LDFLAGS"
204 fi
205
206 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
207 # We also need -iframework<path>/System/Library/Frameworks
208 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
209 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
210 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
211 # set this here so it doesn't have to be peppered throughout the forest
212 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
213 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
214 fi
215
216 AC_SUBST($1SYSROOT_CFLAGS)
217 AC_SUBST($1SYSROOT_LDFLAGS)
218 ])
219
220 AC_DEFUN_ONCE([FLAGS_SETUP_INIT_FLAGS],
221 [
222 # COMPILER_TARGET_BITS_FLAG : option for selecting 32- or 64-bit output
223 # COMPILER_COMMAND_FILE_FLAG : option for passing a command file to the compiler
224 # COMPILER_BINDCMD_FILE_FLAG : option for specifying a file which saves the binder
225 # commands produced by the link step (currently AIX only)
226 if test "x$TOOLCHAIN_TYPE" = xxlc; then
227 COMPILER_TARGET_BITS_FLAG="-q"
228 COMPILER_COMMAND_FILE_FLAG="-f"
229 COMPILER_BINDCMD_FILE_FLAG="-bloadmap:"
230 else
231 COMPILER_TARGET_BITS_FLAG="-m"
232 COMPILER_COMMAND_FILE_FLAG="@"
233 COMPILER_BINDCMD_FILE_FLAG=""
234
235 # The solstudio linker does not support @-files.
236 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
237 COMPILER_COMMAND_FILE_FLAG=
238 fi
239
240 # Check if @file is supported by gcc
241 if test "x$TOOLCHAIN_TYPE" = xgcc; then
242 AC_MSG_CHECKING([if @file is supported by gcc])
243 # Extra emtpy "" to prevent ECHO from interpreting '--version' as argument
244 $ECHO "" "--version" > command.file
245 if $CXX @command.file 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
246 AC_MSG_RESULT(yes)
247 COMPILER_COMMAND_FILE_FLAG="@"
248 else
249 AC_MSG_RESULT(no)
250 COMPILER_COMMAND_FILE_FLAG=
251 fi
252 $RM command.file
253 fi
254 fi
255 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
256 AC_SUBST(COMPILER_COMMAND_FILE_FLAG)
257 AC_SUBST(COMPILER_BINDCMD_FILE_FLAG)
258
259 # FIXME: figure out if we should select AR flags depending on OS or toolchain.
260 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
261 ARFLAGS="-r"
262 elif test "x$OPENJDK_TARGET_OS" = xaix; then
263 ARFLAGS="-X64"
264 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
265 # lib.exe is used as AR to create static libraries.
266 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
267 else
268 ARFLAGS=""
269 fi
270 AC_SUBST(ARFLAGS)
271
272 ## Setup strip.
273 # FIXME: should this really be per platform, or should it be per toolchain type?
274 # strip is not provided by clang or solstudio; so guessing platform makes most sense.
275 # FIXME: we should really only export STRIPFLAGS from here, not POST_STRIP_CMD.
276 if test "x$OPENJDK_TARGET_OS" = xlinux; then
277 STRIPFLAGS="-g"
278 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
279 STRIPFLAGS="-x"
280 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
281 STRIPFLAGS="-S"
282 elif test "x$OPENJDK_TARGET_OS" = xaix; then
283 STRIPFLAGS="-X32_64"
284 fi
285
286 AC_SUBST(STRIPFLAGS)
287
288 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
289 CC_OUT_OPTION=-Fo
290 EXE_OUT_OPTION=-out:
291 LD_OUT_OPTION=-out:
292 AR_OUT_OPTION=-out:
293 else
294 # The option used to specify the target .o,.a or .so file.
295 # When compiling, how to specify the to be created object file.
296 CC_OUT_OPTION='-o$(SPACE)'
297 # When linking, how to specify the to be created executable.
298 EXE_OUT_OPTION='-o$(SPACE)'
299 # When linking, how to specify the to be created dynamically linkable library.
300 LD_OUT_OPTION='-o$(SPACE)'
301 # When archiving, how to specify the to be create static archive for object files.
302 AR_OUT_OPTION='rcs$(SPACE)'
303 fi
304 AC_SUBST(CC_OUT_OPTION)
305 AC_SUBST(EXE_OUT_OPTION)
306 AC_SUBST(LD_OUT_OPTION)
307 AC_SUBST(AR_OUT_OPTION)
308
309 # On Windows, we need to set RC flags.
310 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
311 RC_FLAGS="-nologo -l0x409"
312 JVM_RCFLAGS="-nologo"
313 if test "x$DEBUG_LEVEL" = xrelease; then
314 RC_FLAGS="$RC_FLAGS -DNDEBUG"
315 JVM_RCFLAGS="$JVM_RCFLAGS -DNDEBUG"
316 fi
317
318 # The version variables used to create RC_FLAGS may be overridden
319 # in a custom configure script, or possibly the command line.
320 # Let those variables be expanded at make time in spec.gmk.
321 # The \$ are escaped to the shell, and the $(...) variables
322 # are evaluated by make.
323 RC_FLAGS="$RC_FLAGS \
324 -D\"JDK_VERSION_STRING=\$(VERSION_STRING)\" \
325 -D\"JDK_COMPANY=\$(COMPANY_NAME)\" \
326 -D\"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
327 -D\"JDK_VER=\$(VERSION_NUMBER)\" \
328 -D\"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
329 -D\"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(VERSION_MAJOR)\" \
330 -D\"JDK_FVER=\$(subst .,\$(COMMA),\$(VERSION_NUMBER_FOUR_POSITIONS))\""
331
332 JVM_RCFLAGS="$JVM_RCFLAGS \
333 -D\"HS_BUILD_ID=\$(VERSION_STRING)\" \
334 -D\"HS_COMPANY=\$(COMPANY_NAME)\" \
335 -D\"JDK_DOTVER=\$(VERSION_NUMBER_FOUR_POSITIONS)\" \
336 -D\"HS_COPYRIGHT=Copyright $COPYRIGHT_YEAR\" \
337 -D\"HS_NAME=\$(PRODUCT_NAME) \$(VERSION_SHORT)\" \
338 -D\"JDK_VER=\$(subst .,\$(COMMA),\$(VERSION_NUMBER_FOUR_POSITIONS))\" \
339 -D\"HS_FNAME=jvm.dll\" \
340 -D\"HS_INTERNAL_NAME=jvm\""
341 fi
342 AC_SUBST(RC_FLAGS)
343 AC_SUBST(JVM_RCFLAGS)
344
345 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
346 # silence copyright notice and other headers.
347 COMMON_CCXXFLAGS="$COMMON_CCXXFLAGS -nologo"
348 fi
349 ])
350
351 AC_DEFUN([FLAGS_SETUP_COMPILER_FLAGS_FOR_LIBS],
352 [
353 ###############################################################################
354 #
355 # How to compile shared libraries.
356 #
357
358 if test "x$TOOLCHAIN_TYPE" = xgcc; then
359 PICFLAG="-fPIC"
360 C_FLAG_REORDER=''
361 CXX_FLAG_REORDER=''
362
363 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
364 # Linking is different on MacOSX
365 if test "x$STATIC_BUILD" = xtrue; then
366 SHARED_LIBRARY_FLAGS ='-undefined dynamic_lookup'
367 else
368 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
369 JVM_CFLAGS="$JVM_CFLAGS $PICFLAG"
370 fi
371 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path/.'
372 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
373 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
374 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
375 else
376 # Default works for linux, might work on other platforms as well.
377 SHARED_LIBRARY_FLAGS='-shared'
378 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
379 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
380 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
381 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
382 fi
383 elif test "x$TOOLCHAIN_TYPE" = xclang; then
384 C_FLAG_REORDER=''
385 CXX_FLAG_REORDER=''
386
387 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
388 # Linking is different on MacOSX
389 PICFLAG=''
390 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
391 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path/.'
392 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
393 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
394 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
395
396 if test "x$STATIC_BUILD" = xfalse; then
397 JVM_CFLAGS="$JVM_CFLAGS -fPIC"
398 fi
399 else
400 # Default works for linux, might work on other platforms as well.
401 PICFLAG='-fPIC'
402 SHARED_LIBRARY_FLAGS='-shared'
403 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
404 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
405 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
406
407 # arm specific settings
408 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
409 # '-Wl,-z,origin' isn't used on arm.
410 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
411 else
412 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
413 fi
414
415 fi
416 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
417 if test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
418 PICFLAG="-xcode=pic32"
419 else
420 PICFLAG="-KPIC"
421 fi
422 C_FLAG_REORDER='-xF'
423 CXX_FLAG_REORDER='-xF'
424 SHARED_LIBRARY_FLAGS="-G"
425 SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
426 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
427 SET_SHARED_LIBRARY_NAME='-h [$]1'
428 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
429 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
430 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
431 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
432 # will have to patch this single instruction with a call to some out-of-order code which
433 # does the load from the TOC. This is of course slow. But in that case we also would have
434 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
435 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
436 # can be patched directly by the linker and does not require a jump to out-of-order code.
437 # Another alternative instead of using 'qpic=large -bbigtoc' may be to use '-qminimaltoc'
438 # instead. This creates a distinct TOC for every compilation unit (and thus requires two
439 # loads for accessing a global variable). But there are rumors that this may be seen as a
440 # 'performance feature' because of improved code locality of the symbols used in a
441 # compilation unit.
442 PICFLAG="-qpic"
443 JVM_CFLAGS="$JVM_CFLAGS $PICFLAG"
444 C_FLAG_REORDER=''
445 CXX_FLAG_REORDER=''
446 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
447 SET_EXECUTABLE_ORIGIN=""
448 SET_SHARED_LIBRARY_ORIGIN=''
449 SET_SHARED_LIBRARY_NAME=''
450 SET_SHARED_LIBRARY_MAPFILE=''
451 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
452 PICFLAG=""
453 C_FLAG_REORDER=''
454 CXX_FLAG_REORDER=''
455 SHARED_LIBRARY_FLAGS="-dll"
456 SET_EXECUTABLE_ORIGIN=''
457 SET_SHARED_LIBRARY_ORIGIN=''
458 SET_SHARED_LIBRARY_NAME=''
459 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
460 fi
461
462 AC_SUBST(C_FLAG_REORDER)
463 AC_SUBST(CXX_FLAG_REORDER)
464 AC_SUBST(SET_EXECUTABLE_ORIGIN)
465 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
466 AC_SUBST(SET_SHARED_LIBRARY_NAME)
467 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
468 AC_SUBST(SHARED_LIBRARY_FLAGS)
469
470 # The (cross) compiler is now configured, we can now test capabilities
471 # of the target platform.
472 ])
473
474 # Documentation on common flags used for solstudio in HIGHEST.
475 #
476 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
477 # done with care, there are some assumptions below that need to
478 # be understood about the use of pointers, and IEEE behavior.
479 #
480 # -fns: Use non-standard floating point mode (not IEEE 754)
481 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
482 # -fsingle: Use single precision floating point with 'float'
483 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
484 # (Source with excessing pointer casting and data access with mixed
485 # pointer types are not recommended)
486 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
487 # (If you expect perfect errno behavior, do not use this)
488 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
489 # -xrestrict: Pointer parameters to functions do not overlap
490 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
491 # If you pass in multiple pointers to the same data, do not use this)
492 # -xlibmil: Inline some library routines
493 # (If you expect perfect errno behavior, do not use this)
494 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
495 # (If you expect perfect errno behavior, do not use this)
496 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
497
498 # FIXME: this will never happen since sparc != sparcv9, ie 32 bit, which we don't build anymore.
499 # Bug?
500 #if test "x$OPENJDK_TARGET_CPU" = xsparc; then
501 # CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
502 # CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
503 #fi
504
505 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
506 [
507
508 ###############################################################################
509 #
510 # Setup the opt flags for different compilers
511 # and different operating systems.
512 #
513
514 # FIXME: this was indirectly the old default, but just inherited.
515 # if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
516 # C_FLAG_DEPS="-MMD -MF"
517 # fi
518
519 # Generate make dependency files
520 if test "x$TOOLCHAIN_TYPE" = xgcc; then
521 C_FLAG_DEPS="-MMD -MF"
522 elif test "x$TOOLCHAIN_TYPE" = xclang; then
523 C_FLAG_DEPS="-MMD -MF"
524 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
525 C_FLAG_DEPS="-xMMD -xMF"
526 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
527 C_FLAG_DEPS="-qmakedep=gcc -MF"
528 fi
529 CXX_FLAG_DEPS="$C_FLAG_DEPS"
530 AC_SUBST(C_FLAG_DEPS)
531 AC_SUBST(CXX_FLAG_DEPS)
532
533 # Debug symbols
534 if test "x$TOOLCHAIN_TYPE" = xgcc; then
535 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
536 # reduce from default "-g2" option to save space
537 CFLAGS_DEBUG_SYMBOLS="-g1"
538 CXXFLAGS_DEBUG_SYMBOLS="-g1"
539 else
540 CFLAGS_DEBUG_SYMBOLS="-g"
541 CXXFLAGS_DEBUG_SYMBOLS="-g"
542 fi
543 elif test "x$TOOLCHAIN_TYPE" = xclang; then
544 CFLAGS_DEBUG_SYMBOLS="-g"
545 CXXFLAGS_DEBUG_SYMBOLS="-g"
546 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
547 CFLAGS_DEBUG_SYMBOLS="-g -xs"
548 # -g0 enables debug symbols without disabling inlining.
549 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
550 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
551 CFLAGS_DEBUG_SYMBOLS="-g"
552 CXXFLAGS_DEBUG_SYMBOLS="-g"
553 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
554 CFLAGS_DEBUG_SYMBOLS="-Zi"
555 CXXFLAGS_DEBUG_SYMBOLS="-Zi"
556 fi
557 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
558 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
559
560 # Debug symbols for JVM_CFLAGS
561 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
562 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -xs"
563 if test "x$DEBUG_LEVEL" = xslowdebug; then
564 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -g"
565 else
566 # -g0 does not disable inlining, which -g does.
567 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -g0"
568 fi
569 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
570 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -Z7 -d2Zi+"
571 else
572 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -g"
573 fi
574 AC_SUBST(JVM_CFLAGS_SYMBOLS)
575
576 # bounds, memory and behavior checking options
577 if test "x$TOOLCHAIN_TYPE" = xgcc; then
578 case $DEBUG_LEVEL in
579 release )
580 # no adjustment
581 ;;
582 fastdebug )
583 # no adjustment
584 ;;
585 slowdebug )
586 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
587 # get's added conditionally on whether we produce debug symbols or not.
588 # This is most likely not really correct.
589
590 # Add runtime stack smashing and undefined behavior checks.
591 # Not all versions of gcc support -fstack-protector
592 STACK_PROTECTOR_CFLAG="-fstack-protector-all"
593 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$STACK_PROTECTOR_CFLAG -Werror], IF_FALSE: [STACK_PROTECTOR_CFLAG=""])
594
595 CFLAGS_DEBUG_OPTIONS="$STACK_PROTECTOR_CFLAG --param ssp-buffer-size=1"
596 CXXFLAGS_DEBUG_OPTIONS="$STACK_PROTECTOR_CFLAG --param ssp-buffer-size=1"
597 if test "x$STACK_PROTECTOR_CFLAG" != x; then
598 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS $STACK_PROTECTOR_CFLAG --param ssp-buffer-size=1"
599 fi
600 ;;
601 esac
602 fi
603
604 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
605 if test "x$DEBUG_LEVEL" != xrelease; then
606 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
607 JVM_CFLAGS="$JVM_CFLAGS -homeparams"
608 fi
609 fi
610 fi
611
612 # Optimization levels
613 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
614 CC_HIGHEST="$CC_HIGHEST -fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
615
616 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
617 # FIXME: seems we always set -xregs=no%frameptr; put it elsewhere more global?
618 C_O_FLAG_HIGHEST_JVM="-xO4"
619 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xalias_level=basic -xregs=no%frameptr"
620 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
621 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
622 C_O_FLAG_DEBUG="-xregs=no%frameptr"
623 C_O_FLAG_DEBUG_JVM=""
624 C_O_FLAG_NONE="-xregs=no%frameptr"
625 CXX_O_FLAG_HIGHEST_JVM="-xO4"
626 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
627 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
628 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
629 CXX_O_FLAG_DEBUG="-xregs=no%frameptr"
630 CXX_O_FLAG_DEBUG_JVM=""
631 CXX_O_FLAG_NONE="-xregs=no%frameptr"
632 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
633 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
634 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
635 fi
636 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
637 C_O_FLAG_HIGHEST_JVM="-xO4"
638 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xalias_level=basic -xprefetch=auto,explicit -xchip=ultra"
639 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
640 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
641 C_O_FLAG_DEBUG=""
642 C_O_FLAG_DEBUG_JVM=""
643 C_O_FLAG_NONE=""
644 CXX_O_FLAG_HIGHEST_JVM="-xO4"
645 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
646 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
647 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
648 CXX_O_FLAG_DEBUG=""
649 CXX_O_FLAG_DEBUG_JVM=""
650 CXX_O_FLAG_NONE=""
651 fi
652 else
653 # The remaining toolchains share opt flags between CC and CXX;
654 # setup for C and duplicate afterwards.
655 if test "x$TOOLCHAIN_TYPE" = xgcc; then
656 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
657 # On MacOSX we optimize for size, something
658 # we should do for all platforms?
659 C_O_FLAG_HIGHEST_JVM="-Os"
660 C_O_FLAG_HIGHEST="-Os"
661 C_O_FLAG_HI="-Os"
662 C_O_FLAG_NORM="-Os"
663 C_O_FLAG_SIZE="-Os"
664 else
665 C_O_FLAG_HIGHEST_JVM="-O3"
666 C_O_FLAG_HIGHEST="-O3"
667 C_O_FLAG_HI="-O3"
668 C_O_FLAG_NORM="-O2"
669 C_O_FLAG_SIZE="-Os"
670 fi
671 C_O_FLAG_DEBUG="-O0"
672 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
673 C_O_FLAG_DEBUG_JVM=""
674 elif test "x$OPENJDK_TARGET_OS" = xlinux; then
675 C_O_FLAG_DEBUG_JVM="-O0"
676 fi
677 C_O_FLAG_NONE="-O0"
678 elif test "x$TOOLCHAIN_TYPE" = xclang; then
679 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
680 # On MacOSX we optimize for size, something
681 # we should do for all platforms?
682 C_O_FLAG_HIGHEST_JVM="-Os"
683 C_O_FLAG_HIGHEST="-Os"
684 C_O_FLAG_HI="-Os"
685 C_O_FLAG_NORM="-Os"
686 C_O_FLAG_SIZE="-Os"
687 else
688 C_O_FLAG_HIGHEST_JVM="-O3"
689 C_O_FLAG_HIGHEST="-O3"
690 C_O_FLAG_HI="-O3"
691 C_O_FLAG_NORM="-O2"
692 C_O_FLAG_SIZE="-Os"
693 fi
694 C_O_FLAG_DEBUG="-O0"
695 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
696 C_O_FLAG_DEBUG_JVM=""
697 elif test "x$OPENJDK_TARGET_OS" = xlinux; then
698 C_O_FLAG_DEBUG_JVM="-O0"
699 fi
700 C_O_FLAG_NONE="-O0"
701 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
702 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
703 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
704 C_O_FLAG_HI="-O3 -qinline -qinlglue"
705 C_O_FLAG_NORM="-O2"
706 C_O_FLAG_DEBUG="-qnoopt"
707 # FIXME: Value below not verified.
708 C_O_FLAG_DEBUG_JVM=""
709 C_O_FLAG_NONE="-qnoopt"
710 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
711 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
712 C_O_FLAG_HIGHEST="-O2"
713 C_O_FLAG_HI="-O1"
714 C_O_FLAG_NORM="-O1"
715 C_O_FLAG_DEBUG="-Od"
716 C_O_FLAG_DEBUG_JVM=""
717 C_O_FLAG_NONE="-Od"
718 C_O_FLAG_SIZE="-Os"
719 fi
720 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
721 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
722 CXX_O_FLAG_HI="$C_O_FLAG_HI"
723 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
724 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
725 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
726 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
727 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
728 fi
729
730 # Adjust optimization flags according to debug level.
731 case $DEBUG_LEVEL in
732 release )
733 # no adjustment
734 ;;
735 fastdebug )
736 # Not quite so much optimization
737 C_O_FLAG_HI="$C_O_FLAG_NORM"
738 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
739 ;;
740 slowdebug )
741 # Disable optimization
742 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
743 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
744 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
745 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
746 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
747 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
748 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
749 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
750 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
751 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
752 ;;
753 esac
754
755 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
756 AC_SUBST(C_O_FLAG_HIGHEST)
757 AC_SUBST(C_O_FLAG_HI)
758 AC_SUBST(C_O_FLAG_NORM)
759 AC_SUBST(C_O_FLAG_DEBUG)
760 AC_SUBST(C_O_FLAG_NONE)
761 AC_SUBST(C_O_FLAG_SIZE)
762 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
763 AC_SUBST(CXX_O_FLAG_HIGHEST)
764 AC_SUBST(CXX_O_FLAG_HI)
765 AC_SUBST(CXX_O_FLAG_NORM)
766 AC_SUBST(CXX_O_FLAG_DEBUG)
767 AC_SUBST(CXX_O_FLAG_NONE)
768 AC_SUBST(CXX_O_FLAG_SIZE)
769 ])
770
771
772 AC_DEFUN([FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK],
773 [
774
775 FLAGS_SETUP_ABI_PROFILE
776 FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK_HELPER([TARGET])
777 FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK_HELPER([BUILD], [OPENJDK_BUILD_])
778
779 # Tests are only ever compiled for TARGET
780 # Flags for compiling test libraries
781 CFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
782 CXXFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA"
783
784 # Flags for compiling test executables
785 CFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
786 CXXFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
787
788 AC_SUBST(CFLAGS_TESTLIB)
789 AC_SUBST(CFLAGS_TESTEXE)
790 AC_SUBST(CXXFLAGS_TESTLIB)
791 AC_SUBST(CXXFLAGS_TESTEXE)
792
793 LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
794 LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE $JAVA_BASE_LDFLAGS"
795
796 AC_SUBST(LDFLAGS_TESTLIB)
797 AC_SUBST(LDFLAGS_TESTEXE)
798
799 ])
800
801 ################################################################################
802 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
803 # conditionals against.
804 # $2 - Optional prefix for each variable defined.
805 AC_DEFUN([FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK_HELPER],
806 [
807 # Special extras...
808 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
809 if test "x$OPENJDK_$1_CPU_ARCH" = "xsparc"; then
810 $2CFLAGS_JDKLIB_EXTRA="${$2CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
811 $2CXXFLAGS_JDKLIB_EXTRA="${$2CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
812 fi
813 $2CFLAGS_JDKLIB_EXTRA="${$2CFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
814 $2CXXFLAGS_JDKLIB_EXTRA="${$2CXXFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
815 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
816 $2CFLAGS_JDK="${$2CFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
817 $2CXXFLAGS_JDK="${$2CXXFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
818 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
819 $2CXXSTD_CXXFLAG="-std=gnu++98"
820 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [[$]$2CXXSTD_CXXFLAG -Werror],
821 IF_FALSE: [$2CXXSTD_CXXFLAG=""])
822 $2CXXFLAGS_JDK="${$2CXXFLAGS_JDK} ${$2CXXSTD_CXXFLAG}"
823 $2JVM_CFLAGS="${$2JVM_CFLAGS} ${$2CXXSTD_CXXFLAG}"
824 AC_SUBST([$2CXXSTD_CXXFLAG])
825 fi
826 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
827 $2CFLAGS_JDK="${$2CFLAGS_JDK} -D__solaris__"
828 $2CXXFLAGS_JDK="${$2CXXFLAGS_JDK} -D__solaris__"
829 fi
830
831 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
832 $2CFLAGS_JDK="${$2CFLAGS_JDK} -D__solaris__"
833 $2CXXFLAGS_JDK="${$2CXXFLAGS_JDK} -D__solaris__"
834 fi
835
836 $2CFLAGS_JDK="${$2CFLAGS_JDK} ${$2EXTRA_CFLAGS}"
837 $2CXXFLAGS_JDK="${$2CXXFLAGS_JDK} ${$2EXTRA_CXXFLAGS}"
838 $2LDFLAGS_JDK="${$2LDFLAGS_JDK} ${$2EXTRA_LDFLAGS}"
839
840 ###############################################################################
841 #
842 # Now setup the CFLAGS and LDFLAGS for the JDK build.
843 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
844 #
845
846 # Setup compiler/platform specific flags into
847 # $2CFLAGS_JDK - C Compiler flags
848 # $2CXXFLAGS_JDK - C++ Compiler flags
849 # $2COMMON_CCXXFLAGS_JDK - common to C and C++
850 if test "x$TOOLCHAIN_TYPE" = xgcc; then
851 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_GNU_SOURCE"
852 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_REENTRANT"
853 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -fcheck-new"
854 if test "x$OPENJDK_$1_CPU" = xx86; then
855 # Force compatibility with i586 on 32 bit intel platforms.
856 $2COMMON_CCXXFLAGS="${$2COMMON_CCXXFLAGS} -march=i586"
857 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -march=i586"
858 fi
859 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS [$]$2COMMON_CCXXFLAGS_JDK -Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2 \
860 -pipe -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
861 case $OPENJDK_$1_CPU_ARCH in
862 arm )
863 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
864 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
865 $2COMMON_CCXXFLAGS_JDK="${$2COMMON_CCXXFLAGS_JDK} -fsigned-char"
866 ;;
867 ppc )
868 # on ppc we don't prevent gcc to omit frame pointer but do prevent strict aliasing
869 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
870 ;;
871 s390 )
872 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer -mbackchain -march=z10"
873 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
874 ;;
875 * )
876 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer"
877 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
878 ;;
879 esac
880 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: 6, PREFIX: $2, IF_AT_LEAST: FLAGS_SETUP_GCC6_COMPILER_FLAGS($2))
881 elif test "x$TOOLCHAIN_TYPE" = xclang; then
882 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_GNU_SOURCE"
883
884 # Restrict the debug information created by Clang to avoid
885 # too big object files and speed the build up a little bit
886 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
887 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -flimit-debug-info"
888 if test "x$OPENJDK_$1_OS" = xlinux; then
889 if test "x$OPENJDK_$1_CPU" = xx86; then
890 # Force compatibility with i586 on 32 bit intel platforms.
891 $2COMMON_CCXXFLAGS="${$2COMMON_CCXXFLAGS} -march=i586"
892 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -march=i586"
893 fi
894 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wno-sometimes-uninitialized"
895 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS [$]$2COMMON_CCXXFLAGS_JDK -Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2 \
896 -pipe -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
897 case $OPENJDK_$1_CPU_ARCH in
898 ppc )
899 # on ppc we don't prevent gcc to omit frame pointer but do prevent strict aliasing
900 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
901 ;;
902 * )
903 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer"
904 $2CFLAGS_JDK="${$2CFLAGS_JDK} -fno-strict-aliasing"
905 ;;
906 esac
907 fi
908 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
909 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DSPARC_WORKS"
910 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS [$]$2COMMON_CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
911 if test "x$OPENJDK_$1_CPU_ARCH" = xx86; then
912 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_$1_CPU_LEGACY_LIB"
913 fi
914
915 $2CFLAGS_JDK="[$]$2CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
916 $2CXXFLAGS_JDK="[$]$2CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
917 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
918 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_REENTRANT -D__STDC_FORMAT_MACROS"
919 $2CFLAGS_JDK="[$]$2CFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
920 $2CXXFLAGS_JDK="[$]$2CXXFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
921 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
922 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS [$]$2COMMON_CCXXFLAGS_JDK \
923 -MD -Zc:wchar_t- -W3 -wd4800 \
924 -DWIN32_LEAN_AND_MEAN \
925 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
926 -D_WINSOCK_DEPRECATED_NO_WARNINGS \
927 -DWIN32 -DIAL"
928 if test "x$OPENJDK_$1_CPU" = xx86_64; then
929 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_AMD64_ -Damd64"
930 else
931 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_X86_ -Dx86"
932 fi
933 # If building with Visual Studio 2010, we can still use _STATIC_CPPLIB to
934 # avoid bundling msvcpNNN.dll. Doesn't work with newer versions of visual
935 # studio.
936 if test "x$TOOLCHAIN_VERSION" = "x2010"; then
937 STATIC_CPPLIB_FLAGS="-D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB"
938 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK $STATIC_CPPLIB_FLAGS"
939 $2JVM_CFLAGS="[$]$2JVM_CFLAGS $STATIC_CPPLIB_FLAGS"
940 fi
941 fi
942
943 ###############################################################################
944
945 # Adjust flags according to debug level.
946 case $DEBUG_LEVEL in
947 fastdebug | slowdebug )
948 $2CFLAGS_JDK="[$]$2CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS $CFLAGS_DEBUG_OPTIONS"
949 $2CXXFLAGS_JDK="[$]$2CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS $CXXFLAGS_DEBUG_OPTIONS"
950 ;;
951 release )
952 ;;
953 * )
954 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
955 ;;
956 esac
957
958 # Set some common defines. These works for all compilers, but assume
959 # -D is universally accepted.
960
961 # Setup endianness
962 if test "x$OPENJDK_$1_CPU_ENDIAN" = xlittle; then
963 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
964 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
965 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
966 # Note: -Dmacro is the same as #define macro 1
967 # -Dmacro= is the same as #define macro
968 if test "x$OPENJDK_$1_OS" = xsolaris; then
969 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
970 else
971 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
972 fi
973 else
974 # Same goes for _BIG_ENDIAN. Do we really need to set *ENDIAN on Solaris if they
975 # are defined in the system?
976 if test "x$OPENJDK_$1_OS" = xsolaris; then
977 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN="
978 else
979 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN"
980 fi
981 fi
982
983 # Setup target OS define. Use OS target name but in upper case.
984 OPENJDK_$1_OS_UPPERCASE=`$ECHO $OPENJDK_$1_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
985 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D$OPENJDK_$1_OS_UPPERCASE"
986
987 # Setup target CPU
988 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK \
989 $OPENJDK_$1_ADD_LP64 \
990 -DARCH='\"$OPENJDK_$1_CPU_LEGACY\"' -D$OPENJDK_$1_CPU_LEGACY"
991
992 # Setup debug/release defines
993 if test "x$DEBUG_LEVEL" = xrelease; then
994 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -DNDEBUG"
995 if test "x$OPENJDK_$1_OS" = xsolaris; then
996 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -DTRIMMED"
997 fi
998 else
999 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -DDEBUG"
1000 fi
1001
1002 # Set some additional per-OS defines.
1003 if test "x$OPENJDK_$1_OS" = xlinux; then
1004 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DLINUX"
1005 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -pipe $PICFLAG -fno-rtti -fno-exceptions \
1006 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
1007 elif test "x$OPENJDK_$1_OS" = xsolaris; then
1008 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DSOLARIS"
1009 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -template=no%extdef -features=no%split_init \
1010 -D_Crun_inline_placement -library=%none $PICFLAG -mt -features=no%except"
1011 elif test "x$OPENJDK_$1_OS" = xmacosx; then
1012 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
1013 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_ALLBSD_SOURCE"
1014 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
1015 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -fno-rtti -fno-exceptions -fvisibility=hidden \
1016 -mno-omit-leaf-frame-pointer -mstack-alignment=16 -pipe -fno-strict-aliasing \
1017 -DMAC_OS_X_VERSION_MAX_ALLOWED=1070 -mmacosx-version-min=10.7.0 \
1018 -fno-omit-frame-pointer"
1019 elif test "x$OPENJDK_$1_OS" = xaix; then
1020 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DAIX"
1021 # We may need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
1022 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -qtune=balanced \
1023 -qalias=noansi -qstrict -qtls=default -qlanglvl=c99vla \
1024 -qlanglvl=noredefmac -qnortti -qnoeh -qignerrno"
1025 elif test "x$OPENJDK_$1_OS" = xbsd; then
1026 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE"
1027 elif test "x$OPENJDK_$1_OS" = xwindows; then
1028 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
1029 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -nologo -W3 -MD -MP"
1030 fi
1031
1032 # Set some additional per-CPU defines.
1033 if test "x$OPENJDK_$1_OS-$OPENJDK_$1_CPU" = xwindows-x86; then
1034 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -arch:IA32"
1035 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
1036 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -xarch=sparc"
1037 elif test "x$OPENJDK_$1_CPU" = xppc64; then
1038 if test "x$OPENJDK_$1_OS" = xlinux; then
1039 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
1040 # fixes `relocation truncated to fit' error for gcc 4.1.
1041 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -mminimal-toc"
1042 # Use ppc64 instructions, but schedule for power5
1043 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -mcpu=powerpc64 -mtune=power5"
1044 elif test "x$OPENJDK_$1_OS" = xaix; then
1045 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -qarch=ppc64"
1046 fi
1047 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
1048 if test "x$OPENJDK_$1_OS" = xlinux; then
1049 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
1050 # Little endian machine uses ELFv2 ABI.
1051 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DABI_ELFv2"
1052 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
1053 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -mcpu=power8 -mtune=power8"
1054 fi
1055 elif test "x$OPENJDK_$1_CPU" = xs390x; then
1056 if test "x$OPENJDK_$1_OS" = xlinux; then
1057 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -mbackchain -march=z10"
1058 fi
1059 fi
1060
1061 if test "x$OPENJDK_$1_CPU_ENDIAN" = xlittle; then
1062 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -DVM_LITTLE_ENDIAN"
1063 fi
1064
1065 if test "x$OPENJDK_$1_CPU_BITS" = x64; then
1066 if test "x$OPENJDK_$1_OS" != xsolaris && test "x$OPENJDK_$1_OS" != xaix; then
1067 # Solaris does not have _LP64=1 in the old build.
1068 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
1069 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -D_LP64=1"
1070 fi
1071 fi
1072
1073 # Set $2JVM_CFLAGS warning handling
1074 if test "x$OPENJDK_$1_OS" = xlinux; then
1075 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wpointer-arith -Wsign-compare -Wunused-function \
1076 -Wunused-value -Woverloaded-virtual"
1077
1078 if test "x$TOOLCHAIN_TYPE" = xgcc; then
1079 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: [4.8], PREFIX: $2,
1080 IF_AT_LEAST: [
1081 # These flags either do not work or give spurious warnings prior to gcc 4.8.
1082 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wno-format-zero-length -Wtype-limits -Wuninitialized"
1083 ]
1084 )
1085 fi
1086 if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
1087 # Non-zero builds have stricter warnings
1088 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wreturn-type -Wundef -Wformat=2"
1089 else
1090 if test "x$TOOLCHAIN_TYPE" = xclang; then
1091 # Some versions of llvm do not like -Wundef
1092 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wno-undef"
1093 fi
1094 fi
1095 elif test "x$OPENJDK_$1_OS" = xmacosx; then
1096 $2JVM_CFLAGS="[$]$2JVM_CFLAGS -Wno-deprecated -Wpointer-arith \
1097 -Wsign-compare -Wundef -Wunused-function -Wformat=2"
1098 fi
1099
1100 # Additional macosx handling
1101 if test "x$OPENJDK_$1_OS" = xmacosx; then
1102 # Setting these parameters makes it an error to link to macosx APIs that are
1103 # newer than the given OS version and makes the linked binaries compatible
1104 # even if built on a newer version of the OS.
1105 # The expected format is X.Y.Z
1106 MACOSX_VERSION_MIN=10.7.0
1107 AC_SUBST(MACOSX_VERSION_MIN)
1108
1109 # The macro takes the version with no dots, ex: 1070
1110 # Let the flags variables get resolved in make for easier override on make
1111 # command line.
1112 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
1113 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
1114 fi
1115
1116 # Setup some hard coded includes
1117 $2COMMON_CCXXFLAGS_JDK="[$]$2COMMON_CCXXFLAGS_JDK \
1118 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
1119 -I${JDK_TOPDIR}/src/java.base/share/native/include \
1120 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_$1_OS/native/include \
1121 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_$1_OS_TYPE/native/include \
1122 -I${JDK_TOPDIR}/src/java.base/share/native/libjava \
1123 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_$1_OS_TYPE/native/libjava"
1124
1125 # The shared libraries are compiled using the picflag.
1126 $2CFLAGS_JDKLIB="[$]$2COMMON_CCXXFLAGS_JDK \
1127 [$]$2CFLAGS_JDK [$]$2EXTRA_CFLAGS_JDK $PICFLAG [$]$2CFLAGS_JDKLIB_EXTRA"
1128 $2CXXFLAGS_JDKLIB="[$]$2COMMON_CCXXFLAGS_JDK \
1129 [$]$2CXXFLAGS_JDK [$]$2EXTRA_CXXFLAGS_JDK $PICFLAG [$]$2CXXFLAGS_JDKLIB_EXTRA"
1130
1131 # Executable flags
1132 $2CFLAGS_JDKEXE="[$]$2COMMON_CCXXFLAGS_JDK [$]$2CFLAGS_JDK [$]$2EXTRA_CFLAGS_JDK"
1133 $2CXXFLAGS_JDKEXE="[$]$2COMMON_CCXXFLAGS_JDK [$]$2CXXFLAGS_JDK [$]$2EXTRA_CXXFLAGS_JDK"
1134
1135 AC_SUBST($2CFLAGS_JDKLIB)
1136 AC_SUBST($2CFLAGS_JDKEXE)
1137 AC_SUBST($2CXXFLAGS_JDKLIB)
1138 AC_SUBST($2CXXFLAGS_JDKEXE)
1139
1140 # Setup LDFLAGS et al.
1141 #
1142
1143 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1144 LDFLAGS_MICROSOFT="-nologo -opt:ref"
1145 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LDFLAGS_MICROSOFT -incremental:no"
1146 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_MICROSOFT -opt:icf,8 -subsystem:windows -base:0x8000000"
1147 if test "x$OPENJDK_$1_CPU_BITS" = "x32"; then
1148 LDFLAGS_SAFESH="-safeseh"
1149 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LDFLAGS_SAFESH"
1150 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_SAFESH"
1151 # NOTE: Old build added -machine. Probably not needed.
1152 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -machine:I386"
1153 else
1154 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -machine:AMD64"
1155 fi
1156 elif test "x$TOOLCHAIN_TYPE" = xclang; then
1157 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -mno-omit-leaf-frame-pointer -mstack-alignment=16 -stdlib=libstdc++ -fPIC"
1158 if test "x$OPENJDK_$1_OS" = xmacosx; then
1159 # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
1160 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
1161 fi
1162 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
1163 # If this is a --hash-style=gnu system, use --hash-style=both, why?
1164 # We have previously set HAS_GNU_HASH if this is the case
1165 if test -n "$HAS_GNU_HASH"; then
1166 $2LDFLAGS_HASH_STYLE="-Wl,--hash-style=both"
1167 $2LDFLAGS_JDK="${$2LDFLAGS_JDK} [$]$2LDFLAGS_HASH_STYLE"
1168 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS [$]$2LDFLAGS_HASH_STYLE"
1169 fi
1170 if test "x$OPENJDK_$1_OS" = xmacosx; then
1171 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
1172 fi
1173 if test "x$OPENJDK_$1_OS" = xlinux; then
1174 # And since we now know that the linker is gnu, then add -z defs, to forbid
1175 # undefined symbols in object files.
1176 LDFLAGS_NO_UNDEF_SYM="-Wl,-z,defs"
1177 $2LDFLAGS_JDK="${$2LDFLAGS_JDK} $LDFLAGS_NO_UNDEF_SYM"
1178 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_NO_UNDEF_SYM"
1179 LDFLAGS_NO_EXEC_STACK="-Wl,-z,noexecstack"
1180 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_NO_EXEC_STACK"
1181 if test "x$OPENJDK_$1_CPU" = xx86; then
1182 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -march=i586"
1183 fi
1184 case $DEBUG_LEVEL in
1185 release )
1186 # tell linker to optimize libraries.
1187 # Should this be supplied to the OSS linker as well?
1188 LDFLAGS_DEBUGLEVEL_release="-Wl,-O1"
1189 $2LDFLAGS_JDK="${$2LDFLAGS_JDK} $LDFLAGS_DEBUGLEVEL_release"
1190 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_DEBUGLEVEL_release"
1191 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
1192 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LINKER_RELRO_FLAG"
1193 fi
1194 ;;
1195 slowdebug )
1196 # Hotspot always let the linker optimize
1197 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -Wl,-O1"
1198 if test "x$HAS_LINKER_NOW" = "xtrue"; then
1199 # do relocations at load
1200 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LINKER_NOW_FLAG"
1201 $2LDFLAGS_CXX_JDK="[$]$2LDFLAGS_CXX_JDK $LINKER_NOW_FLAG"
1202 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LINKER_NOW_FLAG"
1203 fi
1204 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
1205 # mark relocations read only
1206 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LINKER_RELRO_FLAG"
1207 $2LDFLAGS_CXX_JDK="[$]$2LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
1208 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LINKER_RELRO_FLAG"
1209 fi
1210 ;;
1211 fastdebug )
1212 # Hotspot always let the linker optimize
1213 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -Wl,-O1"
1214 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
1215 # mark relocations read only
1216 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LINKER_RELRO_FLAG"
1217 $2LDFLAGS_CXX_JDK="[$]$2LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
1218 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LINKER_RELRO_FLAG"
1219 fi
1220 ;;
1221 * )
1222 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
1223 ;;
1224 esac
1225 fi
1226 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
1227 LDFLAGS_SOLSTUDIO="-Wl,-z,defs"
1228 $2LDFLAGS_JDK="[$]$2LDFLAGS_JDK $LDFLAGS_SOLSTUDIO -ztext"
1229 LDFLAGS_CXX_SOLSTUDIO="-norunpath"
1230 $2LDFLAGS_CXX_JDK="[$]$2LDFLAGS_CXX_JDK $LDFLAGS_CXX_SOLSTUDIO -xnolib"
1231 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_SOLSTUDIO -library=%none -mt $LDFLAGS_CXX_SOLSTUDIO -z noversion"
1232 if test "x$OPENJDK_$1_CPU_ARCH" = "xsparc"; then
1233 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS -xarch=sparc"
1234 fi
1235 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
1236 LDFLAGS_XLC="-b64 -brtl -bnolibpath -bexpall -bernotok"
1237 $2LDFLAGS_JDK="${$2LDFLAGS_JDK} $LDFLAGS_XLC"
1238 $2JVM_LDFLAGS="[$]$2JVM_LDFLAGS $LDFLAGS_XLC"
1239 fi
1240
1241 # Customize LDFLAGS for executables
1242
1243 $2LDFLAGS_JDKEXE="${$2LDFLAGS_JDK}"
1244
1245 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1246 if test "x$OPENJDK_$1_CPU_BITS" = "x64"; then
1247 LDFLAGS_STACK_SIZE=1048576
1248 else
1249 LDFLAGS_STACK_SIZE=327680
1250 fi
1251 $2LDFLAGS_JDKEXE="${$2LDFLAGS_JDKEXE} /STACK:$LDFLAGS_STACK_SIZE"
1252 elif test "x$OPENJDK_$1_OS" = xlinux; then
1253 $2LDFLAGS_JDKEXE="[$]$2LDFLAGS_JDKEXE -Wl,--allow-shlib-undefined"
1254 fi
1255
1256 $2LDFLAGS_JDKEXE="${$2LDFLAGS_JDKEXE} ${$2EXTRA_LDFLAGS_JDK}"
1257
1258 # Customize LDFLAGS for libs
1259 $2LDFLAGS_JDKLIB="${$2LDFLAGS_JDK}"
1260
1261 $2LDFLAGS_JDKLIB="${$2LDFLAGS_JDKLIB} ${SHARED_LIBRARY_FLAGS}"
1262 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1263 $2JAVA_BASE_LDFLAGS="${$2JAVA_BASE_LDFLAGS} \
1264 -libpath:${OUTPUT_ROOT}/support/modules_libs/java.base"
1265 $2JDKLIB_LIBS=""
1266 else
1267 $2JAVA_BASE_LDFLAGS="${$2JAVA_BASE_LDFLAGS} \
1268 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base"
1269
1270 if test "x$1" = "xTARGET"; then
1271 # On some platforms (mac) the linker warns about non existing -L dirs.
1272 # For any of the variants server, client or minimal, the dir matches the
1273 # variant name. The "main" variant should be used for linking. For the
1274 # rest, the dir is just server.
1275 if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
1276 || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
1277 $2JAVA_BASE_LDFLAGS="${$2JAVA_BASE_LDFLAGS} \
1278 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/$JVM_VARIANT_MAIN"
1279 else
1280 $2JAVA_BASE_LDFLAGS="${$2JAVA_BASE_LDFLAGS} \
1281 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/server"
1282 fi
1283 elif test "x$1" = "xBUILD"; then
1284 # When building a buildjdk, it's always only the server variant
1285 $2JAVA_BASE_LDFLAGS="${$2JAVA_BASE_LDFLAGS} \
1286 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/server"
1287 fi
1288
1289 $2JDKLIB_LIBS="-ljava -ljvm"
1290 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
1291 $2JDKLIB_LIBS="[$]$2JDKLIB_LIBS -lc"
1292 fi
1293
1294 fi
1295
1296 $2LDFLAGS_JDKLIB="${$2LDFLAGS_JDKLIB} ${$2JAVA_BASE_LDFLAGS}"
1297
1298 # Set $2JVM_LIBS (per os)
1299 if test "x$OPENJDK_$1_OS" = xlinux; then
1300 $2JVM_LIBS="[$]$2JVM_LIBS -lm -ldl -lpthread"
1301 elif test "x$OPENJDK_$1_OS" = xsolaris; then
1302 # FIXME: This hard-coded path is not really proper.
1303 if test "x$OPENJDK_$1_CPU" = xx86_64; then
1304 $2SOLARIS_LIBM_LIBS="/usr/lib/amd64/libm.so.1"
1305 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
1306 $2SOLARIS_LIBM_LIBS="/usr/lib/sparcv9/libm.so.1"
1307 fi
1308 $2JVM_LIBS="[$]$2JVM_LIBS -lsocket -lsched -ldl $SOLARIS_LIBM_LIBS -lCrun \
1309 -lthread -ldoor -lc -ldemangle -lnsl -lkstat -lrt"
1310 elif test "x$OPENJDK_$1_OS" = xmacosx; then
1311 $2JVM_LIBS="[$]$2JVM_LIBS -lm"
1312 elif test "x$OPENJDK_$1_OS" = xaix; then
1313 $2JVM_LIBS="[$]$2JVM_LIBS -Wl,-lC_r -lm -ldl -lpthread"
1314 elif test "x$OPENJDK_$1_OS" = xbsd; then
1315 $2JVM_LIBS="[$]$2JVM_LIBS -lm"
1316 elif test "x$OPENJDK_$1_OS" = xwindows; then
1317 $2JVM_LIBS="[$]$2JVM_LIBS kernel32.lib user32.lib gdi32.lib winspool.lib \
1318 comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib \
1319 wsock32.lib winmm.lib version.lib psapi.lib"
1320 fi
1321
1322 # Set $2JVM_ASFLAGS
1323 if test "x$OPENJDK_$1_OS" = xlinux; then
1324 if test "x$OPENJDK_$1_CPU" = xx86; then
1325 $2JVM_ASFLAGS="[$]$2JVM_ASFLAGS -march=i586"
1326 fi
1327 elif test "x$OPENJDK_$1_OS" = xmacosx; then
1328 $2JVM_ASFLAGS="[$]$2JVM_ASFLAGS -x assembler-with-cpp -mno-omit-leaf-frame-pointer -mstack-alignment=16"
1329 fi
1330
1331 $2LDFLAGS_JDKLIB="${$2LDFLAGS_JDKLIB} ${$2EXTRA_LDFLAGS_JDK}"
1332
1333 AC_SUBST($2LDFLAGS_JDKLIB)
1334 AC_SUBST($2LDFLAGS_JDKEXE)
1335 AC_SUBST($2JDKLIB_LIBS)
1336 AC_SUBST($2JDKEXE_LIBS)
1337 AC_SUBST($2LDFLAGS_CXX_JDK)
1338 AC_SUBST($2LDFLAGS_HASH_STYLE)
1339
1340 AC_SUBST($2JVM_CFLAGS)
1341 AC_SUBST($2JVM_LDFLAGS)
1342 AC_SUBST($2JVM_ASFLAGS)
1343 AC_SUBST($2JVM_LIBS)
1344
1345 ])
1346
1347 # FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
1348 # IF_FALSE: [RUN-IF-FALSE])
1349 # ------------------------------------------------------------
1350 # Check that the C compiler supports an argument
1351 BASIC_DEFUN_NAMED([FLAGS_C_COMPILER_CHECK_ARGUMENTS],
1352 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
1353 [
1354 AC_MSG_CHECKING([if the C compiler supports "ARG_ARGUMENT"])
1355 supports=yes
1356
1357 saved_cflags="$CFLAGS"
1358 CFLAGS="$CFLAGS ARG_ARGUMENT"
1359 AC_LANG_PUSH([C])
1360 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
1361 [supports=no])
1362 AC_LANG_POP([C])
1363 CFLAGS="$saved_cflags"
1364
1365 AC_MSG_RESULT([$supports])
1366 if test "x$supports" = "xyes" ; then
1367 :
1368 ARG_IF_TRUE
1369 else
1370 :
1371 ARG_IF_FALSE
1372 fi
1373 ])
1374
1375 # FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
1376 # IF_FALSE: [RUN-IF-FALSE])
1377 # ------------------------------------------------------------
1378 # Check that the C++ compiler supports an argument
1379 BASIC_DEFUN_NAMED([FLAGS_CXX_COMPILER_CHECK_ARGUMENTS],
1380 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
1381 [
1382 AC_MSG_CHECKING([if the C++ compiler supports "ARG_ARGUMENT"])
1383 supports=yes
1384
1385 saved_cxxflags="$CXXFLAGS"
1386 CXXFLAGS="$CXXFLAG ARG_ARGUMENT"
1387 AC_LANG_PUSH([C++])
1388 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
1389 [supports=no])
1390 AC_LANG_POP([C++])
1391 CXXFLAGS="$saved_cxxflags"
1392
1393 AC_MSG_RESULT([$supports])
1394 if test "x$supports" = "xyes" ; then
1395 :
1396 ARG_IF_TRUE
1397 else
1398 :
1399 ARG_IF_FALSE
1400 fi
1401 ])
1402
1403 # FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
1404 # IF_FALSE: [RUN-IF-FALSE])
1405 # ------------------------------------------------------------
1406 # Check that the C and C++ compilers support an argument
1407 BASIC_DEFUN_NAMED([FLAGS_COMPILER_CHECK_ARGUMENTS],
1408 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
1409 [
1410 FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
1411 IF_TRUE: [C_COMP_SUPPORTS="yes"],
1412 IF_FALSE: [C_COMP_SUPPORTS="no"])
1413 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
1414 IF_TRUE: [CXX_COMP_SUPPORTS="yes"],
1415 IF_FALSE: [CXX_COMP_SUPPORTS="no"])
1416
1417 AC_MSG_CHECKING([if both compilers support "ARG_ARGUMENT"])
1418 supports=no
1419 if test "x$C_COMP_SUPPORTS" = "xyes" -a "x$CXX_COMP_SUPPORTS" = "xyes"; then supports=yes; fi
1420
1421 AC_MSG_RESULT([$supports])
1422 if test "x$supports" = "xyes" ; then
1423 :
1424 ARG_IF_TRUE
1425 else
1426 :
1427 ARG_IF_FALSE
1428 fi
1429 ])
1430
1431 # FLAGS_LINKER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
1432 # IF_FALSE: [RUN-IF-FALSE])
1433 # ------------------------------------------------------------
1434 # Check that the linker support an argument
1435 BASIC_DEFUN_NAMED([FLAGS_LINKER_CHECK_ARGUMENTS],
1436 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
1437 [
1438 AC_MSG_CHECKING([if linker supports "ARG_ARGUMENT"])
1439 supports=yes
1440
1441 saved_ldflags="$LDFLAGS"
1442 LDFLAGS="$LDFLAGS ARG_ARGUMENT"
1443 AC_LANG_PUSH([C])
1444 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
1445 [], [supports=no])
1446 AC_LANG_POP([C])
1447 LDFLAGS="$saved_ldflags"
1448
1449 AC_MSG_RESULT([$supports])
1450 if test "x$supports" = "xyes" ; then
1451 :
1452 ARG_IF_TRUE
1453 else
1454 :
1455 ARG_IF_FALSE
1456 fi
1457 ])
1458
1459 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_MISC],
1460 [
1461 # Some Zero and Shark settings.
1462 # ZERO_ARCHFLAG tells the compiler which mode to build for
1463 case "${OPENJDK_TARGET_CPU}" in
1464 s390)
1465 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}31"
1466 ;;
1467 *)
1468 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
1469 esac
1470 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$ZERO_ARCHFLAG], IF_FALSE: [ZERO_ARCHFLAG=""])
1471 AC_SUBST(ZERO_ARCHFLAG)
1472
1473 # Check that the compiler supports -mX (or -qX on AIX) flags
1474 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
1475 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
1476 IF_TRUE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
1477 IF_FALSE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
1478 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
1479
1480 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
1481 [do not consider native warnings to be an error @<:@enabled@:>@])])
1482
1483 AC_MSG_CHECKING([if native warnings are errors])
1484 if test "x$enable_warnings_as_errors" = "xyes"; then
1485 AC_MSG_RESULT([yes (explicitly set)])
1486 WARNINGS_AS_ERRORS=true
1487 elif test "x$enable_warnings_as_errors" = "xno"; then
1488 AC_MSG_RESULT([no])
1489 WARNINGS_AS_ERRORS=false
1490 elif test "x$enable_warnings_as_errors" = "x"; then
1491 AC_MSG_RESULT([yes (default)])
1492 WARNINGS_AS_ERRORS=true
1493 else
1494 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
1495 fi
1496
1497 if test "x$WARNINGS_AS_ERRORS" = "xfalse"; then
1498 # Set legacy hotspot variable
1499 HOTSPOT_SET_WARNINGS_AS_ERRORS="WARNINGS_ARE_ERRORS="
1500 else
1501 HOTSPOT_SET_WARNINGS_AS_ERRORS=""
1502 fi
1503
1504 AC_SUBST(WARNINGS_AS_ERRORS)
1505 AC_SUBST(HOTSPOT_SET_WARNINGS_AS_ERRORS)
1506
1507 case "${TOOLCHAIN_TYPE}" in
1508 microsoft)
1509 DISABLE_WARNING_PREFIX="-wd"
1510 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
1511 ;;
1512 solstudio)
1513 DISABLE_WARNING_PREFIX="-erroff="
1514 CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
1515 ;;
1516 gcc)
1517 # Prior to gcc 4.4, a -Wno-X where X is unknown for that version of gcc will cause an error
1518 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [-Wno-this-is-a-warning-that-do-not-exist],
1519 IF_TRUE: [GCC_CAN_DISABLE_WARNINGS=true],
1520 IF_FALSE: [GCC_CAN_DISABLE_WARNINGS=false]
1521 )
1522 if test "x$GCC_CAN_DISABLE_WARNINGS" = "xtrue"; then
1523 DISABLE_WARNING_PREFIX="-Wno-"
1524 else
1525 DISABLE_WARNING_PREFIX=
1526 fi
1527 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
1528 # Repeate the check for the BUILD_CC and BUILD_CXX. Need to also reset
1529 # CFLAGS since any target specific flags will likely not work with the
1530 # build compiler
1531 CC_OLD="$CC"
1532 CXX_OLD="$CXX"
1533 CC="$BUILD_CC"
1534 CXX="$BUILD_CXX"
1535 CFLAGS_OLD="$CFLAGS"
1536 CFLAGS=""
1537 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [-Wno-this-is-a-warning-that-do-not-exist],
1538 IF_TRUE: [BUILD_CC_CAN_DISABLE_WARNINGS=true],
1539 IF_FALSE: [BUILD_CC_CAN_DISABLE_WARNINGS=false]
1540 )
1541 if test "x$BUILD_CC_CAN_DISABLE_WARNINGS" = "xtrue"; then
1542 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
1543 else
1544 BUILD_CC_DISABLE_WARNING_PREFIX=
1545 fi
1546 CC="$CC_OLD"
1547 CXX="$CXX_OLD"
1548 CFLAGS="$CFLAGS_OLD"
1549 ;;
1550 clang)
1551 DISABLE_WARNING_PREFIX="-Wno-"
1552 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
1553 ;;
1554 xlc)
1555 DISABLE_WARNING_PREFIX="-qsuppress="
1556 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
1557 ;;
1558 esac
1559 AC_SUBST(DISABLE_WARNING_PREFIX)
1560 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
1561 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
1562 ])
1563
1564 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
1565 # Arguments:
1566 # $1 - Optional prefix for each variable defined.
1567 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
1568 [
1569 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
1570 # runs afoul of the more aggressive versions of these optimisations.
1571 # Notably, value range propagation now assumes that the this pointer of C++
1572 # member functions is non-null.
1573 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
1574 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
1575 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG -Werror],
1576 dnl IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
1577 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
1578 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
1579 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG -Werror],
1580 dnl IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
1581 AC_MSG_NOTICE([GCC >= 6 detected; adding ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} and ${NO_LIFETIME_DSE_CFLAG}])
1582 $1CFLAGS_JDK="[$]$1CFLAGS_JDK ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
1583 $1JVM_CFLAGS="[$]$1JVM_CFLAGS ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
1584 ])