1 #
2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
28 fprof vm-structs jni-check services management all-gcs nmt cds \
29 static-build link-time-opt"
30
31 # All valid JVM variants
32 VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
33
34 ###############################################################################
35 # Check if the specified JVM variant should be built. To be used in shell if
36 # constructs, like this:
37 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
38 #
39 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
40
41 # Definition kept in one line to allow inlining in if statements.
42 # Additional [] needed to keep m4 from mangling shell constructs.
43 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
44 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
45
46 ###############################################################################
47 # Check if the specified JVM features are explicitly enabled. To be used in
48 # shell if constructs, like this:
49 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
50 #
51 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
52
53 # Definition kept in one line to allow inlining in if statements.
54 # Additional [] needed to keep m4 from mangling shell constructs.
55 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
56 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
57
58 ###############################################################################
59 # Check which variants of the JVM that we want to build. Available variants are:
60 # server: normal interpreter, and a tiered C1/C2 compiler
61 # client: normal interpreter, and C1 (no C2 compiler)
62 # minimal: reduced form of client with optional features stripped out
63 # core: normal interpreter only, no compiler
64 # zero: C++ based interpreter only, no compiler
65 # zeroshark: C++ based interpreter, and a llvm-based compiler
66 # custom: baseline JVM with no default features
67 #
68 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
69 [
70 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
71 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
72
73 SETUP_HOTSPOT_TARGET_CPU_PORT
74
75 if test "x$with_jvm_variants" = x; then
76 with_jvm_variants="server"
77 fi
78 JVM_VARIANTS_OPT="$with_jvm_variants"
79
80 # Has the user listed more than one variant?
81 # Additional [] needed to keep m4 from mangling shell constructs.
82 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
83 BUILDING_MULTIPLE_JVM_VARIANTS=true
84 else
85 BUILDING_MULTIPLE_JVM_VARIANTS=false
86 fi
87 # Replace the commas with AND for use in the build directory name.
88 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
89
90 AC_MSG_CHECKING([which variants of the JVM to build])
91 # JVM_VARIANTS is a space-separated list.
92 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
93 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
94 AC_MSG_RESULT([$JVM_VARIANTS])
95
96 # Check that the selected variants are valid
97
98 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
99 # Notice that the original variant failes on SLES 10 and 11
100 NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
101 STACK=${JVM_VARIANTS// /$'\n'}
102 INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
103 if test "x$INVALID_VARIANTS" != x; then
104 AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
105 AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
106 fi
107
108 # All "special" variants share the same output directory ("server")
109 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
110 NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
111 STACK=${JVM_VARIANTS// /$'\n'}
112 INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
113 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
114 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
115 fi
116
117 # The "main" variant is the one used by other libs to link against during the
118 # build.
119 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
120 MAIN_VARIANT_PRIO_ORDER="server client minimal"
121 for variant in $MAIN_VARIANT_PRIO_ORDER; do
122 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
123 JVM_VARIANT_MAIN="$variant"
124 break
125 fi
126 done
127 else
128 JVM_VARIANT_MAIN="$JVM_VARIANTS"
129 fi
130
131 AC_SUBST(JVM_VARIANTS)
132 AC_SUBST(VALID_JVM_VARIANTS)
133 AC_SUBST(JVM_VARIANT_MAIN)
134
135 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
136 # zero behaves as a platform and rewrites these values. This is really weird. :(
137 # We are guaranteed that we do not build any other variants when building zero.
138 HOTSPOT_TARGET_CPU=zero
139 HOTSPOT_TARGET_CPU_ARCH=zero
140 fi
141 ])
142
143 ###############################################################################
144 # Check if dtrace should be enabled and has all prerequisites present.
145 #
146 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
147 [
148 # Test for dtrace dependencies
149 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
150 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
151 are present.])])
152
153 DTRACE_DEP_MISSING=false
154
155 AC_MSG_CHECKING([for dtrace tool])
156 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
157 AC_MSG_RESULT([$DTRACE])
158 else
159 AC_MSG_RESULT([not found, cannot build dtrace])
160 DTRACE_DEP_MISSING=true
161 fi
162
163 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
164 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
165 DTRACE_DEP_MISSING=true
166 fi
167
168 AC_MSG_CHECKING([if dtrace should be built])
169 if test "x$enable_dtrace" = "xyes"; then
170 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
171 AC_MSG_RESULT([no, missing dependencies])
172 HELP_MSG_MISSING_DEPENDENCY([dtrace])
173 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
174 else
175 INCLUDE_DTRACE=true
176 AC_MSG_RESULT([yes, forced])
177 fi
178 elif test "x$enable_dtrace" = "xno"; then
179 INCLUDE_DTRACE=false
180 AC_MSG_RESULT([no, forced])
181 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
182 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
183 INCLUDE_DTRACE=false
184 AC_MSG_RESULT([no, missing dependencies])
185 else
186 INCLUDE_DTRACE=true
187 AC_MSG_RESULT([yes, dependencies present])
188 fi
189 else
190 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
191 fi
192 AC_SUBST(INCLUDE_DTRACE)
193 ])
194
195 ###############################################################################
196 # Set up all JVM features for each JVM variant.
197 #
198 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
199 [
200 # The user can in some cases supply additional jvm features. For the custom
201 # variant, this defines the entire variant.
202 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
203 [additional JVM features to enable (separated by comma), use '--help' to show possible values @<:@none@:>@])])
204 if test "x$with_jvm_features" != x; then
205 AC_MSG_CHECKING([additional JVM features])
206 JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
207 AC_MSG_RESULT([$JVM_FEATURES])
208 fi
209
210 # Override hotspot cpu definitions for ARM platforms
211 if test "x$OPENJDK_TARGET_CPU" = xarm; then
212 HOTSPOT_TARGET_CPU=arm_32
213 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
214 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
215 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
216 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$with_cpu_port" = xarm64; then
217 HOTSPOT_TARGET_CPU=arm_64
218 HOTSPOT_TARGET_CPU_ARCH=arm
219 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
220 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
221 fi
222
223 # Verify that dependencies are met for explicitly set features.
224 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
225 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
226 fi
227
228 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
229 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
230 fi
231
232 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
233 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
234 fi
235
236 if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
237 AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
238 fi
239
240 if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
241 AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
242 fi
243
244 # Turn on additional features based on other parts of configure
245 if test "x$INCLUDE_DTRACE" = "xtrue"; then
246 JVM_FEATURES="$JVM_FEATURES dtrace"
247 else
248 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
249 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
250 fi
251 fi
252
253 if test "x$STATIC_BUILD" = "xtrue"; then
254 JVM_FEATURES="$JVM_FEATURES static-build"
255 else
256 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
257 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
258 fi
259 fi
260
261 if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
262 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
263 AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
264 fi
265 fi
266
267 if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
268 if HOTSPOT_CHECK_JVM_FEATURE(shark); then
269 AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
270 fi
271 fi
272
273 # Only enable jvmci on x86_64, sparcv9 and aarch64.
274 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
275 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
276 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
277 JVM_FEATURES_jvmci="jvmci"
278 else
279 JVM_FEATURES_jvmci=""
280 fi
281
282 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
283 # Default to use link time optimizations on minimal on arm
284 JVM_FEATURES_link_time_opt="link-time-opt"
285 else
286 JVM_FEATURES_link_time_opt=""
287 fi
288
289 # All variants but minimal (and custom) get these features
290 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti fprof vm-structs jni-check services management all-gcs nmt cds"
291
292 # Enable features depending on variant.
293 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
294 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
295 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
296 JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES $JVM_FEATURES_link_time_opt"
297 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
298 JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
299 JVM_FEATURES_custom="$JVM_FEATURES"
300
301 AC_SUBST(JVM_FEATURES_server)
302 AC_SUBST(JVM_FEATURES_client)
303 AC_SUBST(JVM_FEATURES_core)
304 AC_SUBST(JVM_FEATURES_minimal)
305 AC_SUBST(JVM_FEATURES_zero)
306 AC_SUBST(JVM_FEATURES_zeroshark)
307 AC_SUBST(JVM_FEATURES_custom)
308
309 # Used for verification of Makefiles by check-jvm-feature
310 AC_SUBST(VALID_JVM_FEATURES)
311
312 # We don't support --with-jvm-interpreter anymore, use zero instead.
313 BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
314 ])
315
316 ###############################################################################
317 # Validate JVM features once all setup is complete, including custom setup.
318 #
319 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
320 [
321 # Keep feature lists sorted and free of duplicates
322 JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
323 JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
324 JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
325 JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
326 JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
327 JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
328 JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
329
330 # Validate features
331 for variant in $JVM_VARIANTS; do
332 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
333 features_var_name=JVM_FEATURES_$variant
334 JVM_FEATURES_TO_TEST=${!features_var_name}
335 AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
336 NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
337 STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
338 INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
339 if test "x$INVALID_FEATURES" != x; then
340 AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
341 fi
342 done
343 ])
344
345 ################################################################################
346 #
347 # Specify which sources will be used to build the 64-bit ARM port
348 #
349 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
350 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
351 #
352 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
353 [
354 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
355 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
356
357 if test "x$with_cpu_port" != x; then
358 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
359 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
360 fi
361
362 if test "x$with_cpu_port" != x; then
363 if test "x$with_cpu_port" != xarm64 && \
364 test "x$with_cpu_port" != xaarch64; then
365 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
366 fi
367 fi
368 fi
369 ])
370
371
372 ################################################################################
373 # Check if gtest should be built
374 #
375 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
376 [
377 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
378 [Disables building of the Hotspot unit tests])])
379
380 if test -e "$HOTSPOT_TOPDIR/test/native"; then
381 GTEST_DIR_EXISTS="true"
382 else
383 GTEST_DIR_EXISTS="false"
384 fi
385
386 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
387 if test "x$enable_hotspot_gtest" = "xyes"; then
388 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
389 AC_MSG_RESULT([yes, forced])
390 BUILD_GTEST="true"
391 else
392 AC_MSG_ERROR([Cannot build gtest without the test source])
393 fi
394 elif test "x$enable_hotspot_gtest" = "xno"; then
395 AC_MSG_RESULT([no, forced])
396 BUILD_GTEST="false"
397 elif test "x$enable_hotspot_gtest" = "x"; then
398 if test "x$GTEST_DIR_EXISTS" = "xtrue" && test "x$OPENJDK_TARGET_OS" != "xaix"; then
399 AC_MSG_RESULT([yes])
400 BUILD_GTEST="true"
401 else
402 AC_MSG_RESULT([no])
403 BUILD_GTEST="false"
404 fi
405 else
406 AC_MSG_ERROR([--enable-gtest must be either yes or no])
407 fi
408
409 AC_SUBST(BUILD_GTEST)
410 ])