1 #
2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
28 graal fprof vm-structs jni-check services management all-gcs nmt cds \
29 static-build link-time-opt aot"
30
31 # All valid JVM variants
32 VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
33
34 ###############################################################################
35 # Check if the specified JVM variant should be built. To be used in shell if
36 # constructs, like this:
37 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
38 #
39 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
40
41 # Definition kept in one line to allow inlining in if statements.
42 # Additional [] needed to keep m4 from mangling shell constructs.
43 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
44 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
45
46 ###############################################################################
47 # Check if the specified JVM features are explicitly enabled. To be used in
48 # shell if constructs, like this:
49 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
50 #
51 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
52
53 # Definition kept in one line to allow inlining in if statements.
54 # Additional [] needed to keep m4 from mangling shell constructs.
55 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
56 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
57
58 ###############################################################################
59 # Check which variants of the JVM that we want to build. Available variants are:
60 # server: normal interpreter, and a tiered C1/C2 compiler
61 # client: normal interpreter, and C1 (no C2 compiler)
62 # minimal: reduced form of client with optional features stripped out
63 # core: normal interpreter only, no compiler
64 # zero: C++ based interpreter only, no compiler
65 # zeroshark: C++ based interpreter, and a llvm-based compiler
66 # custom: baseline JVM with no default features
67 #
68 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
69 [
70 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
71 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
72
73 SETUP_HOTSPOT_TARGET_CPU_PORT
74
75 if test "x$with_jvm_variants" = x; then
76 with_jvm_variants="server"
77 fi
78 JVM_VARIANTS_OPT="$with_jvm_variants"
79
80 # Has the user listed more than one variant?
81 # Additional [] needed to keep m4 from mangling shell constructs.
82 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
83 BUILDING_MULTIPLE_JVM_VARIANTS=true
84 else
85 BUILDING_MULTIPLE_JVM_VARIANTS=false
86 fi
87 # Replace the commas with AND for use in the build directory name.
88 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
89
90 AC_MSG_CHECKING([which variants of the JVM to build])
91 # JVM_VARIANTS is a space-separated list.
92 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
93 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
94 AC_MSG_RESULT([$JVM_VARIANTS])
95
96 # Check that the selected variants are valid
97
98 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
99 # Notice that the original variant failes on SLES 10 and 11
100 NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
101 STACK=${JVM_VARIANTS// /$'\n'}
102 INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
103 if test "x$INVALID_VARIANTS" != x; then
104 AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
105 AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
106 fi
107
108 # All "special" variants share the same output directory ("server")
109 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
110 NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
111 STACK=${JVM_VARIANTS// /$'\n'}
112 INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
113 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
114 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
115 fi
116
117 # The "main" variant is the one used by other libs to link against during the
118 # build.
119 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
120 MAIN_VARIANT_PRIO_ORDER="server client minimal"
121 for variant in $MAIN_VARIANT_PRIO_ORDER; do
122 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
123 JVM_VARIANT_MAIN="$variant"
124 break
125 fi
126 done
127 else
128 JVM_VARIANT_MAIN="$JVM_VARIANTS"
129 fi
130
131 AC_SUBST(JVM_VARIANTS)
132 AC_SUBST(VALID_JVM_VARIANTS)
133 AC_SUBST(JVM_VARIANT_MAIN)
134
135 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
136 # zero behaves as a platform and rewrites these values. This is really weird. :(
137 # We are guaranteed that we do not build any other variants when building zero.
138 HOTSPOT_TARGET_CPU=zero
139 HOTSPOT_TARGET_CPU_ARCH=zero
140 fi
141 ])
142
143 ###############################################################################
144 # Check if dtrace should be enabled and has all prerequisites present.
145 #
146 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
147 [
148 # Test for dtrace dependencies
149 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
150 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
151 are present.])])
152
153 DTRACE_DEP_MISSING=false
154
155 AC_MSG_CHECKING([for dtrace tool])
156 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
157 AC_MSG_RESULT([$DTRACE])
158 else
159 AC_MSG_RESULT([not found, cannot build dtrace])
160 DTRACE_DEP_MISSING=true
161 fi
162
163 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
164 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
165 DTRACE_DEP_MISSING=true
166 fi
167
168 AC_MSG_CHECKING([if dtrace should be built])
169 if test "x$enable_dtrace" = "xyes"; then
170 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
171 AC_MSG_RESULT([no, missing dependencies])
172 HELP_MSG_MISSING_DEPENDENCY([dtrace])
173 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
174 else
175 INCLUDE_DTRACE=true
176 AC_MSG_RESULT([yes, forced])
177 fi
178 elif test "x$enable_dtrace" = "xno"; then
179 INCLUDE_DTRACE=false
180 AC_MSG_RESULT([no, forced])
181 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
182 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
183 INCLUDE_DTRACE=false
184 AC_MSG_RESULT([no, missing dependencies])
185 else
186 INCLUDE_DTRACE=true
187 AC_MSG_RESULT([yes, dependencies present])
188 fi
189 else
190 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
191 fi
192 AC_SUBST(INCLUDE_DTRACE)
193 ])
194
195 ################################################################################
196 # Check if AOT should be enabled
197 #
198 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
199 [
200 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
201 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
202
203 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
204 ENABLE_AOT="true"
205 elif test "x$enable_aot" = "xyes"; then
206 ENABLE_AOT="true"
207 elif test "x$enable_aot" = "xno"; then
208 ENABLE_AOT="false"
209 AC_MSG_CHECKING([if aot should be enabled])
210 AC_MSG_RESULT([no, forced])
211 else
212 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
213 fi
214
215 if test "x$ENABLE_AOT" = "xtrue"; then
216 # Only enable AOT on X64 platforms.
217 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" ||
218 test "x$OPENJDK_TARGET_CPU" = "xamd64"; then
219 if test -e "$HOTSPOT_TOPDIR/src/jdk.aot"; then
220 if test -e "$HOTSPOT_TOPDIR/src/jdk.vm.compiler"; then
221 ENABLE_AOT="true"
222 else
223 ENABLE_AOT="false"
224 if test "x$enable_aot" = "xyes"; then
225 AC_MSG_ERROR([Cannot build AOT without hotspot/src/jdk.vm.compiler sources. Remove --enable-aot.])
226 fi
227 fi
228 else
229 ENABLE_AOT="false"
230 if test "x$enable_aot" = "xyes"; then
231 AC_MSG_ERROR([Cannot build AOT without hotspot/src/jdk.aot sources. Remove --enable-aot.])
232 fi
233 fi
234 else
235 ENABLE_AOT="false"
236 if test "x$enable_aot" = "xyes"; then
237 AC_MSG_ERROR([AOT is currently only supported on Linux-x86_64. Remove --enable-aot.])
238 fi
239 fi
240 fi
241
242 AC_SUBST(ENABLE_AOT)
243 ])
244
245 ###############################################################################
246 # Set up all JVM features for each JVM variant.
247 #
248 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
249 [
250 # The user can in some cases supply additional jvm features. For the custom
251 # variant, this defines the entire variant.
252 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
253 [additional JVM features to enable (separated by comma), use '--help' to show possible values @<:@none@:>@])])
254 if test "x$with_jvm_features" != x; then
255 AC_MSG_CHECKING([additional JVM features])
256 JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
257 AC_MSG_RESULT([$JVM_FEATURES])
258 fi
259
260 # Override hotspot cpu definitions for ARM platforms
261 if test "x$OPENJDK_TARGET_CPU" = xarm; then
262 HOTSPOT_TARGET_CPU=arm_32
263 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
264 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
265 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
266 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
267 HOTSPOT_TARGET_CPU=arm_64
268 HOTSPOT_TARGET_CPU_ARCH=arm
269 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
270 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
271 fi
272
273 # Verify that dependencies are met for explicitly set features.
274 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
275 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
276 fi
277
278 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
279 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
280 fi
281
282 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
283 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
284 fi
285
286 if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
287 AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
288 fi
289
290 if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
291 AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
292 fi
293
294 # Turn on additional features based on other parts of configure
295 if test "x$INCLUDE_DTRACE" = "xtrue"; then
296 JVM_FEATURES="$JVM_FEATURES dtrace"
297 else
298 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
299 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
300 fi
301 fi
302
303 if test "x$STATIC_BUILD" = "xtrue"; then
304 JVM_FEATURES="$JVM_FEATURES static-build"
305 else
306 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
307 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
308 fi
309 fi
310
311 if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
312 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
313 AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
314 fi
315 fi
316
317 if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
318 if HOTSPOT_CHECK_JVM_FEATURE(shark); then
319 AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
320 fi
321 fi
322
323 # Only enable jvmci on x86_64, sparcv9 and aarch64.
324 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
325 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
326 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
327 JVM_FEATURES_jvmci="jvmci"
328 else
329 JVM_FEATURES_jvmci=""
330 fi
331
332 AC_MSG_CHECKING([if jdk.vm.compiler should be built])
333 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
334 AC_MSG_RESULT([yes, forced])
335 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
336 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
337 fi
338 INCLUDE_GRAAL="true"
339 else
340 # By default enable graal build where AOT is available
341 if test "x$ENABLE_AOT" = "xtrue"; then
342 AC_MSG_RESULT([yes])
343 JVM_FEATURES_graal="graal"
344 INCLUDE_GRAAL="true"
345 else
346 AC_MSG_RESULT([no])
347 JVM_FEATURES_graal=""
348 INCLUDE_GRAAL="false"
349 fi
350 fi
351
352 AC_SUBST(INCLUDE_GRAAL)
353
354 AC_MSG_CHECKING([if aot should be enabled])
355 if test "x$ENABLE_AOT" = "xtrue"; then
356 if test "x$enable_aot" = "xyes"; then
357 AC_MSG_RESULT([yes, forced])
358 else
359 AC_MSG_RESULT([yes])
360 fi
361 JVM_FEATURES_aot="aot"
362 else
363 if test "x$enable_aot" = "xno"; then
364 AC_MSG_RESULT([no, forced])
365 else
366 AC_MSG_RESULT([no])
367 fi
368 JVM_FEATURES_aot=""
369 fi
370
371 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
372 # Default to use link time optimizations on minimal on arm
373 JVM_FEATURES_link_time_opt="link-time-opt"
374 else
375 JVM_FEATURES_link_time_opt=""
376 fi
377
378 # All variants but minimal (and custom) get these features
379 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti fprof vm-structs jni-check services management all-gcs nmt cds"
380
381 # Enable features depending on variant.
382 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
383 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
384 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
385 JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES $JVM_FEATURES_link_time_opt"
386 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
387 JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
388 JVM_FEATURES_custom="$JVM_FEATURES"
389
390 AC_SUBST(JVM_FEATURES_server)
391 AC_SUBST(JVM_FEATURES_client)
392 AC_SUBST(JVM_FEATURES_core)
393 AC_SUBST(JVM_FEATURES_minimal)
394 AC_SUBST(JVM_FEATURES_zero)
395 AC_SUBST(JVM_FEATURES_zeroshark)
396 AC_SUBST(JVM_FEATURES_custom)
397
398 # Used for verification of Makefiles by check-jvm-feature
399 AC_SUBST(VALID_JVM_FEATURES)
400
401 # We don't support --with-jvm-interpreter anymore, use zero instead.
402 BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
403 ])
404
405 ###############################################################################
406 # Validate JVM features once all setup is complete, including custom setup.
407 #
408 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
409 [
410 # Keep feature lists sorted and free of duplicates
411 JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
412 JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
413 JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
414 JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
415 JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
416 JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
417 JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
418
419 # Validate features
420 for variant in $JVM_VARIANTS; do
421 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
422 features_var_name=JVM_FEATURES_$variant
423 JVM_FEATURES_TO_TEST=${!features_var_name}
424 AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
425 NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
426 STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
427 INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
428 if test "x$INVALID_FEATURES" != x; then
429 AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
430 fi
431 done
432 ])
433
434 ################################################################################
435 #
436 # Specify which sources will be used to build the 64-bit ARM port
437 #
438 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
439 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
440 #
441 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
442 [
443 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
444 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
445
446 if test "x$with_cpu_port" != x; then
447 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
448 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
449 fi
450 if test "x$with_cpu_port" != xarm64 && \
451 test "x$with_cpu_port" != xaarch64; then
452 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
453 fi
454 HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
455 fi
456 ])
457
458
459 ################################################################################
460 # Check if gtest should be built
461 #
462 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
463 [
464 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
465 [Disables building of the Hotspot unit tests])])
466
467 if test -e "$HOTSPOT_TOPDIR/test/native"; then
468 GTEST_DIR_EXISTS="true"
469 else
470 GTEST_DIR_EXISTS="false"
471 fi
472
473 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
474 if test "x$enable_hotspot_gtest" = "xyes"; then
475 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
476 AC_MSG_RESULT([yes, forced])
477 BUILD_GTEST="true"
478 else
479 AC_MSG_ERROR([Cannot build gtest without the test source])
480 fi
481 elif test "x$enable_hotspot_gtest" = "xno"; then
482 AC_MSG_RESULT([no, forced])
483 BUILD_GTEST="false"
484 elif test "x$enable_hotspot_gtest" = "x"; then
485 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
486 AC_MSG_RESULT([yes])
487 BUILD_GTEST="true"
488 else
489 AC_MSG_RESULT([no])
490 BUILD_GTEST="false"
491 fi
492 else
493 AC_MSG_ERROR([--enable-gtest must be either yes or no])
494 fi
495
496 AC_SUBST(BUILD_GTEST)
497 ])