1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 C_FLAG_REORDER=''
39
40 # Default works for linux, might work on other platforms as well.
41 SHARED_LIBRARY_FLAGS='-shared'
42 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
43 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
44 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
45 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
46
47 elif test "x$TOOLCHAIN_TYPE" = xclang; then
48 C_FLAG_REORDER=''
49
50 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
51 # Linking is different on MacOSX
52 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
53 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
54 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
55 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
56 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
57
58 else
59 # Default works for linux, might work on other platforms as well.
60 SHARED_LIBRARY_FLAGS='-shared'
61 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
62 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
63 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
64
65 # arm specific settings
66 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
67 # '-Wl,-z,origin' isn't used on arm.
68 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
69 else
70 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
71 fi
72 fi
73
74 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
75 C_FLAG_REORDER='-xF'
76 SHARED_LIBRARY_FLAGS="-G"
77 SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
78 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
79 SET_SHARED_LIBRARY_NAME='-h [$]1'
80 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
81
82 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
83 C_FLAG_REORDER=''
84 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
85 SET_EXECUTABLE_ORIGIN=""
86 SET_SHARED_LIBRARY_ORIGIN=''
87 SET_SHARED_LIBRARY_NAME=''
88 SET_SHARED_LIBRARY_MAPFILE=''
89
90 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
91 C_FLAG_REORDER=''
92 SHARED_LIBRARY_FLAGS="-dll"
93 SET_EXECUTABLE_ORIGIN=''
94 SET_SHARED_LIBRARY_ORIGIN=''
95 SET_SHARED_LIBRARY_NAME=''
96 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
97 fi
98
99 AC_SUBST(C_FLAG_REORDER)
100 AC_SUBST(SET_EXECUTABLE_ORIGIN)
101 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
102 AC_SUBST(SET_SHARED_LIBRARY_NAME)
103 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
104 AC_SUBST(SHARED_LIBRARY_FLAGS)
105 ])
106
107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
108 [
109 # By default don't set any specific assembler debug
110 # info flags for toolchains unless we know they work.
111 # See JDK-8207057.
112 ASFLAGS_DEBUG_SYMBOLS=""
113 # Debug symbols
114 if test "x$TOOLCHAIN_TYPE" = xgcc; then
115 CFLAGS_DEBUG_SYMBOLS="-g"
116 ASFLAGS_DEBUG_SYMBOLS="-g"
117 elif test "x$TOOLCHAIN_TYPE" = xclang; then
118 CFLAGS_DEBUG_SYMBOLS="-g"
119 ASFLAGS_DEBUG_SYMBOLS="-g"
120 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
121 # -g0 enables debug symbols without disabling inlining.
122 CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
123 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
124 CFLAGS_DEBUG_SYMBOLS="-g1"
125 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
126 CFLAGS_DEBUG_SYMBOLS="-Z7"
127 fi
128
129 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
130 AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
131 ])
132
133 AC_DEFUN([FLAGS_SETUP_WARNINGS],
134 [
135 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
136 [do not consider native warnings to be an error @<:@enabled@:>@])])
137
138 # Set default value.
139 if test "x$TOOLCHAIN_TYPE" = xxlc; then
140 WARNINGS_AS_ERRORS=false
141 else
142 WARNINGS_AS_ERRORS=true
143 fi
144
145 AC_MSG_CHECKING([if native warnings are errors])
146 if test "x$enable_warnings_as_errors" = "xyes"; then
147 AC_MSG_RESULT([yes (explicitly set)])
148 WARNINGS_AS_ERRORS=true
149 elif test "x$enable_warnings_as_errors" = "xno"; then
150 AC_MSG_RESULT([no (explicitly set)])
151 WARNINGS_AS_ERRORS=false
152 elif test "x$enable_warnings_as_errors" = "x"; then
153 AC_MSG_RESULT([${WARNINGS_AS_ERRORS} (default)])
154 else
155 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
156 fi
157
158 AC_SUBST(WARNINGS_AS_ERRORS)
159
160 case "${TOOLCHAIN_TYPE}" in
161 microsoft)
162 DISABLE_WARNING_PREFIX="-wd"
163 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
164
165 WARNINGS_ENABLE_ALL="-W3"
166 DISABLED_WARNINGS="4800"
167 ;;
168
169 solstudio)
170 DISABLE_WARNING_PREFIX="-erroff="
171 CFLAGS_WARNINGS_ARE_ERRORS="-errwarn=%all"
172
173 WARNINGS_ENABLE_ALL_CFLAGS="-v -fd -xtransition"
174 WARNINGS_ENABLE_ALL_CXXFLAGS="+w +w2"
175
176 DISABLED_WARNINGS_C="E_OLD_STYLE_FUNC_DECL E_OLD_STYLE_FUNC_DEF E_SEMANTICS_OF_OP_CHG_IN_ANSI_C E_NO_REPLACEMENT_IN_STRING E_DECLARATION_IN_CODE"
177 DISABLED_WARNINGS_CXX="inllargeuse inllargeint notused wemptydecl notemsource"
178 ;;
179
180 gcc)
181 DISABLE_WARNING_PREFIX="-Wno-"
182 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
183
184 # Additional warnings that are not activated by -Wall and -Wextra
185 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare \
186 -Wunused-function -Wundef -Wunused-value -Wreturn-type \
187 -Wtrampolines"
188 WARNINGS_ENABLE_ADDITIONAL_CXX="-Woverloaded-virtual -Wreorder"
189 WARNINGS_ENABLE_ALL_CFLAGS="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
190 WARNINGS_ENABLE_ALL_CXXFLAGS="$WARNINGS_ENABLE_ALL_CFLAGS $WARNINGS_ENABLE_ADDITIONAL_CXX"
191
192 DISABLED_WARNINGS="unused-parameter unused"
193 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
194 ;;
195
196 clang)
197 DISABLE_WARNING_PREFIX="-Wno-"
198 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
199
200 # Additional warnings that are not activated by -Wall and -Wextra
201 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare -Wreorder \
202 -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual"
203 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
204
205 DISABLED_WARNINGS="unknown-warning-option unused-parameter unused"
206
207 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
208 # missing-method-return-type triggers in JavaNativeFoundation framework
209 DISABLED_WARNINGS="$DISABLED_WARNINGS missing-method-return-type"
210 fi
211
212 ;;
213
214 xlc)
215 DISABLE_WARNING_PREFIX="-Wno-"
216 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
217
218 # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
219 WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
220 DISABLED_WARNINGS=""
221 ;;
222 esac
223 AC_SUBST(DISABLE_WARNING_PREFIX)
224 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
225 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
226 AC_SUBST(DISABLED_WARNINGS)
227 AC_SUBST(DISABLED_WARNINGS_C)
228 AC_SUBST(DISABLED_WARNINGS_CXX)
229 ])
230
231 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
232 [
233 # bounds, memory and behavior checking options
234 if test "x$TOOLCHAIN_TYPE" = xgcc; then
235 case $DEBUG_LEVEL in
236 release )
237 # no adjustment
238 ;;
239 fastdebug )
240 # no adjustment
241 ;;
242 slowdebug )
243 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
244 # get's added conditionally on whether we produce debug symbols or not.
245 # This is most likely not really correct.
246
247 # Add runtime stack smashing and undefined behavior checks.
248 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
249 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
250
251 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
252 ;;
253 esac
254 fi
255 ])
256
257 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
258 [
259 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
260 CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
261
262 C_O_FLAG_HIGHEST_JVM="-xO4"
263 C_O_FLAG_DEBUG_JVM=""
264 C_O_FLAG_SIZE=""
265 C_O_FLAG_DEBUG=""
266 C_O_FLAG_NONE=""
267 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
268 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
269 C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
270 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
271 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
272 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
273 -xprefetch=auto,explicit $CC_HIGHEST"
274 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
275 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
276 fi
277 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
278 C_O_FLAG_HIGHEST_JVM="-O3"
279 C_O_FLAG_HIGHEST="-O3"
280 C_O_FLAG_HI="-O3"
281 C_O_FLAG_NORM="-O2"
282 C_O_FLAG_SIZE="-Os"
283 C_O_FLAG_DEBUG="-O0"
284 C_O_FLAG_DEBUG_JVM="-O0"
285 C_O_FLAG_NONE="-O0"
286 # -D_FORTIFY_SOURCE=2 hardening option needs optimization (at least -O1) enabled
287 # set for lower O-levels -U_FORTIFY_SOURCE to overwrite previous settings
288 if test "x$OPENJDK_TARGET_OS" = xlinux -a "x$DEBUG_LEVEL" = "xfastdebug"; then
289 ENABLE_FORTIFY_CFLAGS="-D_FORTIFY_SOURCE=2"
290 DISABLE_FORTIFY_CFLAGS="-U_FORTIFY_SOURCE"
291 C_O_FLAG_HIGHEST_JVM="${C_O_FLAG_HIGHEST_JVM} ${ENABLE_FORTIFY_CFLAGS}"
292 C_O_FLAG_HIGHEST="${C_O_FLAG_HIGHEST} ${ENABLE_FORTIFY_CFLAGS}"
293 C_O_FLAG_HI="${C_O_FLAG_HI} ${ENABLE_FORTIFY_CFLAGS}"
294 C_O_FLAG_NORM="${C_O_FLAG_NORM} ${ENABLE_FORTIFY_CFLAGS}"
295 C_O_FLAG_SIZE="${C_O_FLAG_SIZE} ${DISABLE_FORTIFY_CFLAGS}"
296 C_O_FLAG_DEBUG="${C_O_FLAG_DEBUG} ${DISABLE_FORTIFY_CFLAGS}"
297 C_O_FLAG_DEBUG_JVM="${C_O_FLAG_DEBUG_JVM} ${DISABLE_FORTIFY_CFLAGS}"
298 C_O_FLAG_NONE="${C_O_FLAG_NONE} ${DISABLE_FORTIFY_CFLAGS}"
299 fi
300 elif test "x$TOOLCHAIN_TYPE" = xclang; then
301 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
302 # On MacOSX we optimize for size, something
303 # we should do for all platforms?
304 C_O_FLAG_HIGHEST_JVM="-Os"
305 C_O_FLAG_HIGHEST="-Os"
306 C_O_FLAG_HI="-Os"
307 C_O_FLAG_NORM="-Os"
308 C_O_FLAG_DEBUG_JVM=""
309 else
310 C_O_FLAG_HIGHEST_JVM="-O3"
311 C_O_FLAG_HIGHEST="-O3"
312 C_O_FLAG_HI="-O3"
313 C_O_FLAG_NORM="-O2"
314 C_O_FLAG_DEBUG_JVM="-O0"
315 fi
316 C_O_FLAG_SIZE="-Os"
317 C_O_FLAG_DEBUG="-O0"
318 C_O_FLAG_NONE="-O0"
319 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
320 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
321 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
322 C_O_FLAG_HI="-O3 -qinline -qinlglue"
323 C_O_FLAG_NORM="-O2"
324 C_O_FLAG_DEBUG="-qnoopt"
325 # FIXME: Value below not verified.
326 C_O_FLAG_DEBUG_JVM=""
327 C_O_FLAG_NONE="-qnoopt"
328 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
329 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
330 C_O_FLAG_HIGHEST="-O2"
331 C_O_FLAG_HI="-O1"
332 C_O_FLAG_NORM="-O1"
333 C_O_FLAG_DEBUG="-Od"
334 C_O_FLAG_DEBUG_JVM=""
335 C_O_FLAG_NONE="-Od"
336 C_O_FLAG_SIZE="-Os"
337 fi
338
339 # Now copy to C++ flags
340 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
341 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
342 CXX_O_FLAG_HI="$C_O_FLAG_HI"
343 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
344 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
345 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
346 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
347 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
348
349 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
350 # In solstudio, also add this to C (but not C++) flags...
351 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
352 fi
353
354 # Adjust optimization flags according to debug level.
355 case $DEBUG_LEVEL in
356 release )
357 # no adjustment
358 ;;
359 fastdebug )
360 # Not quite so much optimization
361 C_O_FLAG_HI="$C_O_FLAG_NORM"
362 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
363 ;;
364 slowdebug )
365 # Disable optimization
366 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
367 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
368 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
369 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
370 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
371 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
372 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
373 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
374 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
375 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
376 ;;
377 esac
378
379 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
380 AC_SUBST(C_O_FLAG_HIGHEST)
381 AC_SUBST(C_O_FLAG_HI)
382 AC_SUBST(C_O_FLAG_NORM)
383 AC_SUBST(C_O_FLAG_NONE)
384 AC_SUBST(C_O_FLAG_SIZE)
385 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
386 AC_SUBST(CXX_O_FLAG_HIGHEST)
387 AC_SUBST(CXX_O_FLAG_HI)
388 AC_SUBST(CXX_O_FLAG_NORM)
389 AC_SUBST(CXX_O_FLAG_NONE)
390 AC_SUBST(CXX_O_FLAG_SIZE)
391 ])
392
393 AC_DEFUN([FLAGS_SETUP_CFLAGS],
394 [
395 ### CFLAGS
396
397 FLAGS_SETUP_CFLAGS_HELPER
398
399 FLAGS_OS=$OPENJDK_TARGET_OS
400 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
401 FLAGS_CPU=$OPENJDK_TARGET_CPU
402 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
403 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
404 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
405 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
406 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
407
408 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
409
410 # Repeat the check for the BUILD_CC and BUILD_CXX. Need to also reset CFLAGS
411 # since any target specific flags will likely not work with the build compiler.
412 CC_OLD="$CC"
413 CXX_OLD="$CXX"
414 CFLAGS_OLD="$CFLAGS"
415 CXXFLAGS_OLD="$CXXFLAGS"
416 CC="$BUILD_CC"
417 CXX="$BUILD_CXX"
418 CFLAGS=""
419 CXXFLAGS=""
420
421 FLAGS_OS=$OPENJDK_BUILD_OS
422 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
423 FLAGS_CPU=$OPENJDK_BUILD_CPU
424 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
425 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
426 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
427 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
428 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
429
430 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_], [BUILD_])
431
432 CC="$CC_OLD"
433 CXX="$CXX_OLD"
434 CFLAGS="$CFLAGS_OLD"
435 CXXFLAGS="$CXXFLAGS_OLD"
436 ])
437
438 ################################################################################
439 # platform independent
440 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
441 [
442 #### OS DEFINES, these should be independent on toolchain
443 if test "x$OPENJDK_TARGET_OS" = xlinux; then
444 CFLAGS_OS_DEF_JVM="-DLINUX"
445 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
446 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
447 CFLAGS_OS_DEF_JVM="-DSOLARIS"
448 CFLAGS_OS_DEF_JDK="-D__solaris__"
449 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
450 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
451 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
452 elif test "x$OPENJDK_TARGET_OS" = xaix; then
453 CFLAGS_OS_DEF_JVM="-DAIX"
454 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
455 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
456 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
457 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
458 fi
459
460 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
461
462 #### GLOBAL DEFINES
463 # Set some common defines. These works for all compilers, but assume
464 # -D is universally accepted.
465
466 # Always enable optional macros for VM.
467 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
468
469 # Setup some hard coded includes
470 ALWAYS_CFLAGS_JDK=" \
471 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
472 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
473 -I${TOPDIR}/src/java.base/share/native/libjava \
474 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
475 -I${TOPDIR}/src/hotspot/share/include \
476 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
477
478 ###############################################################################
479
480 # Adjust flags according to debug level.
481 # Setup debug/release defines
482 if test "x$DEBUG_LEVEL" = xrelease; then
483 DEBUG_CFLAGS_JDK="-DNDEBUG"
484 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
485 DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
486 fi
487 else
488 DEBUG_CFLAGS_JDK="-DDEBUG"
489
490 if test "x$TOOLCHAIN_TYPE" = xxlc; then
491 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
492 # Hotspot now overflows its 64K TOC (currently only for debug),
493 # so for debug we build with '-qpic=large -bbigtoc'.
494 DEBUG_CFLAGS_JVM="-qpic=large"
495 fi
496 fi
497
498 if test "x$DEBUG_LEVEL" != xrelease; then
499 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
500 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
501 fi
502
503 #### TOOLCHAIN DEFINES
504
505 if test "x$TOOLCHAIN_TYPE" = xgcc; then
506 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
507 elif test "x$TOOLCHAIN_TYPE" = xclang; then
508 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
509 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
510 ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
511 ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
512 ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
513 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
514 ALWAYS_DEFINES_JVM="-D_REENTRANT"
515 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
516 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
517 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
518 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
519 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
520 fi
521
522 ###############################################################################
523 #
524 #
525 # CFLAGS BASIC
526 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
527 # COMMON to gcc and clang
528 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
529 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
530 fi
531
532 if test "x$TOOLCHAIN_TYPE" = xgcc; then
533 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new -fstack-protector"
534 TOOLCHAIN_CFLAGS_JDK="-pipe -fstack-protector"
535 # reduce lib size on linux in link step, this needs also special compile flags
536 # do this on s390x also for libjvm (where serviceability agent is not supported)
537 if test "x$ENABLE_LINKTIME_GC" = xtrue; then
538 TOOLCHAIN_CFLAGS_JDK="$TOOLCHAIN_CFLAGS_JDK -ffunction-sections -fdata-sections"
539 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
540 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -ffunction-sections -fdata-sections"
541 fi
542 fi
543 # technically NOT for CXX (but since this gives *worse* performance, use
544 # no-strict-aliasing everywhere!)
545 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing"
546
547 elif test "x$TOOLCHAIN_TYPE" = xclang; then
548 # Restrict the debug information created by Clang to avoid
549 # too big object files and speed the build up a little bit
550 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
551 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
552
553 # In principle the stack alignment below is cpu- and ABI-dependent and
554 # should agree with values of StackAlignmentInBytes in various
555 # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
556 # works for all platforms.
557 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
558
559 if test "x$OPENJDK_TARGET_OS" = xlinux; then
560 if test "x$DEBUG_LEVEL" = xrelease; then
561 # Clang does not inline as much as GCC does for functions with "inline" keyword by default.
562 # This causes noticeable slowdown in pause time for G1, and possibly in other areas.
563 # Increasing the inline hint threshold avoids the slowdown for Clang-built JVM.
564 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mllvm -inlinehint-threshold=100000"
565 fi
566 TOOLCHAIN_CFLAGS_JDK="-pipe"
567 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
568 fi
569 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
570 TOOLCHAIN_FLAGS="-errtags -errfmt"
571 TOOLCHAIN_CFLAGS="-errshort=tags"
572
573 TOOLCHAIN_CFLAGS_JDK="-mt $TOOLCHAIN_FLAGS"
574 TOOLCHAIN_CFLAGS_JDK_CONLY="-W0,-noglobal $TOOLCHAIN_CFLAGS" # C only
575 TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
576 TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
577 -library=stlport4 -mt -features=no%except $TOOLCHAIN_FLAGS"
578 if test "x$DEBUG_LEVEL" = xslowdebug; then
579 # Previously -g was used instead of -g0 for slowdebug; this is equivalent
580 # to setting +d.
581 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
582 fi
583
584 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
585 # Suggested additions: -qsrcmsg to get improved error reporting
586 # set -qtbtable=full for a better traceback table/better stacks in hs_err when xlc16 is used
587 TOOLCHAIN_CFLAGS_JDK="-qtbtable=full -qchars=signed -qfullpath -qsaveopt -qstackprotect" # add on both CFLAGS
588 TOOLCHAIN_CFLAGS_JVM="-qtbtable=full -qtune=balanced \
589 -qalias=noansi -qstrict -qtls=default -qnortti -qnoeh -qignerrno -qstackprotect"
590 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
591 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
592 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
593 fi
594
595 # CFLAGS C language level for JDK sources (hotspot only uses C++)
596 # Ideally we would have a common level across all toolchains so that all sources
597 # are sure to conform to the same standard. Unfortunately neither our sources nor
598 # our toolchains are in a condition to support that. But what we loosely aim for is
599 # C99 level.
600 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xxlc; then
601 # Explicitly set C99. clang and xlclang support the same flag.
602 LANGSTD_CFLAGS="-std=c99"
603 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
604 # We can't turn on -std=c99 without breaking compilation of the splashscreen/png
605 # utilities. But we can enable c99 as below (previously achieved by using -Xa).
606 # It is the no_lib that makes the difference.
607 LANGSTD_CFLAGS="-xc99=all,no_lib"
608 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
609 # MSVC doesn't support C99/C11 explicitly, unless you compile as C++:
610 # LANGSTD_CFLAGS="-TP"
611 # but that requires numerous changes to the sources files. So we are limited
612 # to C89/C90 plus whatever extensions Visual Studio has decided to implement.
613 # This is the lowest bar for shared code.
614 LANGSTD_CFLAGS=""
615 fi
616 TOOLCHAIN_CFLAGS_JDK_CONLY="$LANGSTD_CFLAGS $TOOLCHAIN_CFLAGS_JDK_CONLY"
617
618 # CFLAGS WARNINGS STUFF
619 # Set JVM_CFLAGS warning handling
620 if test "x$TOOLCHAIN_TYPE" = xgcc; then
621 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
622 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
623 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
624
625 elif test "x$TOOLCHAIN_TYPE" = xclang; then
626 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
627
628 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
629 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
630 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
631 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
632
633 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
634 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
635
636 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
637 WARNING_CFLAGS="" # currently left empty
638 fi
639
640 # Set some additional per-OS defines.
641
642 # Additional macosx handling
643 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
644 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
645 -mmacosx-version-min=$MACOSX_VERSION_MIN"
646
647 if test -n "$MACOSX_VERSION_MAX"; then
648 OS_CFLAGS="$OS_CFLAGS \
649 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
650 fi
651 fi
652
653 # Where does this really belong??
654 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
655 PICFLAG="-fPIC"
656 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
657 PICFLAG="-KPIC"
658 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
659 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
660 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
661 # will have to patch this single instruction with a call to some out-of-order code which
662 # does the load from the TOC. This is of course slower, and we also would have
663 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
664 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
665 # can be patched directly by the linker and does not require a jump to out-of-order code.
666 #
667 # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
668 # for all libjvm variants (both gtest and normal) but no other binaries. So, build
669 # libjvm with -qpic=large and link with -bbigtoc.
670 JVM_PICFLAG="-qpic=large"
671 JDK_PICFLAG="-qpic"
672 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
673 PICFLAG=""
674 fi
675
676 if test "x$TOOLCHAIN_TYPE" != xxlc; then
677 JVM_PICFLAG="$PICFLAG"
678 JDK_PICFLAG="$PICFLAG"
679 fi
680
681 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
682 # Linking is different on MacOSX
683 JDK_PICFLAG=''
684 if test "x$STATIC_BUILD" = xtrue; then
685 JVM_PICFLAG=""
686 fi
687 fi
688
689 # Optional POSIX functionality needed by the JVM
690 #
691 # Check if clock_gettime is available and in which library. This indicates
692 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
693 # don't let it update LIBS.
694 save_LIBS="$LIBS"
695 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
696 if test "x$LIBS" = "x-lrt "; then
697 CLOCK_GETTIME_IN_LIBRT=true
698 fi
699 LIBS="$save_LIBS"
700
701 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
702 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
703 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
704 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
705 fi
706 fi
707
708 # Extra flags needed when building optional static versions of certain
709 # JDK libraries.
710 STATIC_LIBS_CFLAGS="-DSTATIC_BUILD=1"
711 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
712 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -ffunction-sections -fdata-sections \
713 -DJNIEXPORT='__attribute__((visibility(\"hidden\")))'"
714 else
715 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -DJNIEXPORT="
716 fi
717 if test "x$TOOLCHAIN_TYPE" = xgcc; then
718 # Disable relax-relocation to enable compatibility with older linkers
719 RELAX_RELOCATIONS_FLAG="-Xassembler -mrelax-relocations=no"
720 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${RELAX_RELOCATIONS_FLAG}],
721 IF_TRUE: [STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS ${RELAX_RELOCATIONS_FLAG}"])
722 fi
723 AC_SUBST(STATIC_LIBS_CFLAGS)
724 ])
725
726 ################################################################################
727 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
728 # conditionals against.
729 # $2 - Optional prefix for each variable defined.
730 # $3 - Optional prefix for compiler variables (either BUILD_ or nothing).
731 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
732 [
733 #### CPU DEFINES, these should (in theory) be independent on toolchain
734
735 # Setup target CPU
736 # Setup endianness
737 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
738 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
739 fi
740 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
741 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
742 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
743 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
744 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
745 else
746 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
747 fi
748 else
749 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
750 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
751 else
752 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
753 fi
754 fi
755
756 # setup CPU bit size
757 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
758 -D$FLAGS_CPU_LEGACY"
759
760 if test "x$FLAGS_CPU_BITS" = x64; then
761 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
762 # unpack200.exe.
763 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
764 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
765 fi
766 if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
767 # Solaris does not have _LP64=1 in the old build.
768 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
769 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
770 fi
771 fi
772
773 # toolchain dependend, per-cpu
774 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
775 if test "x$FLAGS_CPU_ARCH" = xx86; then
776 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
777 fi
778 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
779 if test "x$FLAGS_CPU" = xx86_64; then
780 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
781 else
782 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
783 fi
784 fi
785
786 # CFLAGS PER CPU
787 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
788 # COMMON to gcc and clang
789 if test "x$FLAGS_CPU" = xx86; then
790 # Force compatibility with i586 on 32 bit intel platforms.
791 $1_CFLAGS_CPU="-march=i586"
792 fi
793 fi
794
795 if test "x$TOOLCHAIN_TYPE" = xgcc; then
796 if test "x$FLAGS_CPU" = xarm; then
797 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
798 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
799 $1_CFLAGS_CPU_JVM="-DARM"
800 elif test "x$FLAGS_CPU_ARCH" = xppc; then
801 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
802 if test "x$FLAGS_CPU" = xppc64; then
803 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
804 # Use ppc64 instructions, but schedule for power5
805 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
806 elif test "x$FLAGS_CPU" = xppc64le; then
807 # Little endian machine uses ELFv2 ABI.
808 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
809 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
810 fi
811 elif test "x$FLAGS_CPU" = xs390x; then
812 $1_CFLAGS_CPU="-mbackchain -march=z10"
813 fi
814
815 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
816 # for all archs except arm and ppc, prevent gcc to omit frame pointer
817 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
818 fi
819
820 $1_CXXSTD_CXXFLAG="-std=gnu++98"
821 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${$1_CXXSTD_CXXFLAG}],
822 PREFIX: $3, IF_FALSE: [$1_CXXSTD_CXXFLAG=""])
823 $1_TOOLCHAIN_CFLAGS_JDK_CXXONLY="${$1_CXXSTD_CXXFLAG}"
824 $1_TOOLCHAIN_CFLAGS_JVM="${$1_TOOLCHAIN_CFLAGS_JVM} ${$1_CXXSTD_CXXFLAG}"
825 $2ADLC_CXXFLAG="${$1_CXXSTD_CXXFLAG}"
826
827 elif test "x$TOOLCHAIN_TYPE" = xclang; then
828 if test "x$FLAGS_OS" = xlinux; then
829 # ppc test not really needed for clang
830 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
831 # for all archs except arm and ppc, prevent gcc to omit frame pointer
832 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
833 fi
834 fi
835
836 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
837 if test "x$FLAGS_CPU" = xx86_64; then
838 # NOTE: -xregs=no%frameptr is supposed to be default on x64
839 $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
840 elif test "x$FLAGS_CPU" = xsparcv9; then
841 $1_CFLAGS_CPU_JVM="-xarch=sparc"
842 $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
843 fi
844
845 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
846 if test "x$FLAGS_CPU" = xppc64; then
847 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
848 fi
849
850 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
851 if test "x$FLAGS_CPU" = xx86; then
852 $1_CFLAGS_CPU_JVM="-arch:IA32"
853 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
854 if test "x$DEBUG_LEVEL" != xrelease; then
855 # NOTE: This is probably redundant; -homeparams is default on
856 # non-release builds.
857 $1_CFLAGS_CPU_JVM="-homeparams"
858 fi
859 fi
860 fi
861
862 if test "x$TOOLCHAIN_TYPE" = xgcc; then
863 FLAGS_SETUP_GCC6_COMPILER_FLAGS($1, $3)
864 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
865
866 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
867 fi
868
869 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
870 # Check if compiler supports -fmacro-prefix-map. If so, use that to make
871 # the __FILE__ macro resolve to paths relative to the workspace root.
872 workspace_root_trailing_slash="${WORKSPACE_ROOT%/}/"
873 FILE_MACRO_CFLAGS="-fmacro-prefix-map=${workspace_root_trailing_slash}="
874 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${FILE_MACRO_CFLAGS}],
875 PREFIX: $3,
876 IF_FALSE: [
877 FILE_MACRO_CFLAGS=
878 ]
879 )
880 fi
881
882 # EXPORT to API
883 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM \
884 $TOOLCHAIN_CFLAGS_JVM ${$1_TOOLCHAIN_CFLAGS_JVM} \
885 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
886 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG $FILE_MACRO_CFLAGS"
887
888 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
889 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
890 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK \
891 $FILE_MACRO_CFLAGS"
892
893 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
894 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
895 # change in the future.)
896
897 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
898 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
899 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY \
900 $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
901 ${$1_TOOLCHAIN_CFLAGS_JDK_CXXONLY} \
902 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
903
904 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
905 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
906
907 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
908
909 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK}"
910 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK}"
911 $2CFLAGS_JDKLIB="${$2CFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
912 $2CXXFLAGS_JDKLIB="${$2CXXFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
913
914 AC_SUBST($2JVM_CFLAGS)
915 AC_SUBST($2CFLAGS_JDKLIB)
916 AC_SUBST($2CFLAGS_JDKEXE)
917 AC_SUBST($2CXXFLAGS_JDKLIB)
918 AC_SUBST($2CXXFLAGS_JDKEXE)
919 AC_SUBST($2ADLC_CXXFLAG)
920
921 COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
922 # Check that the compiler supports -ffp-contract=off flag
923 # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
924 # otherwise.
925 # These flags are required for GCC-based builds of
926 # fdlibm with optimization without losing precision.
927 # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
928 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
929 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
930 PREFIX: $3,
931 IF_TRUE: [$2FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
932 IF_FALSE: [$2FDLIBM_CFLAGS=""])
933 fi
934 AC_SUBST($2FDLIBM_CFLAGS)
935 ])
936
937 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
938 # Arguments:
939 # $1 - Prefix for each variable defined.
940 # $2 - Prefix for compiler variables (either BUILD_ or nothing).
941 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
942 [
943 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
944 # runs afoul of the more aggressive versions of these optimisations.
945 # Notably, value range propagation now assumes that the this pointer of C++
946 # member functions is non-null.
947 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
948 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG],
949 PREFIX: $2, IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
950 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
951 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG],
952 PREFIX: $2, IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
953 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
954 ])
955
956 # Documentation on common flags used for solstudio in HIGHEST.
957 #
958 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
959 # done with care, there are some assumptions below that need to
960 # be understood about the use of pointers, and IEEE behavior.
961 #
962 # -fns: Use non-standard floating point mode (not IEEE 754)
963 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
964 # -fsingle: Use single precision floating point with 'float'
965 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
966 # (Source with excessing pointer casting and data access with mixed
967 # pointer types are not recommended)
968 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
969 # (If you expect perfect errno behavior, do not use this)
970 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
971 # -xrestrict: Pointer parameters to functions do not overlap
972 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
973 # If you pass in multiple pointers to the same data, do not use this)
974 # -xlibmil: Inline some library routines
975 # (If you expect perfect errno behavior, do not use this)
976 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
977 # (If you expect perfect errno behavior, do not use this)
978 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now