1 #
   2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 #
  28 
  29 AC_DEFUN([FLAGS_SETUP_LDFLAGS],
  30 [
  31   FLAGS_SETUP_LDFLAGS_HELPER
  32 
  33   # Setup the target toolchain
  34 
  35   # On some platforms (mac) the linker warns about non existing -L dirs.
  36   # For any of the variants server, client or minimal, the dir matches the
  37   # variant name. The "main" variant should be used for linking. For the
  38   # rest, the dir is just server.
  39   if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
  40       || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
  41     TARGET_JVM_VARIANT_PATH=$JVM_VARIANT_MAIN
  42   else
  43     TARGET_JVM_VARIANT_PATH=server
  44   fi
  45   FLAGS_SETUP_LDFLAGS_CPU_DEP([TARGET])
  46 
  47   # Setup the build toolchain
  48 
  49   # When building a buildjdk, it's always only the server variant
  50   BUILD_JVM_VARIANT_PATH=server
  51 
  52   FLAGS_SETUP_LDFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
  53 
  54   LDFLAGS_TESTEXE="${TARGET_LDFLAGS_JDK_LIBPATH}"
  55   AC_SUBST(LDFLAGS_TESTEXE)
  56 ])
  57 
  58 ################################################################################
  59 
  60 # CPU independent LDFLAGS setup, used for both target and build toolchain.
  61 AC_DEFUN([FLAGS_SETUP_LDFLAGS_HELPER],
  62 [
  63   # Setup basic LDFLAGS
  64   if test "x$TOOLCHAIN_TYPE" = xgcc; then
  65     # Add -z,defs, to forbid undefined symbols in object files.
  66     # add -z,relro (mark relocations read only) for all libs
  67     # add -z,now ("full relro" - more of the Global Offset Table GOT is marked read only)
  68     BASIC_LDFLAGS="-Wl,--hash-style=gnu -Wl,-z,defs -Wl,-z,relro -Wl,-z,now"
  69     # Linux : remove unused code+data in link step
  70     if test "x$ENABLE_LINKTIME_GC" = xtrue; then
  71       if test "x$OPENJDK_TARGET_CPU" = xs390x; then
  72         BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,--gc-sections -Wl,--print-gc-sections"
  73       else
  74         BASIC_LDFLAGS_JDK_ONLY="$BASIC_LDFLAGS_JDK_ONLY -Wl,--gc-sections"
  75       fi
  76     fi
  77 
  78     BASIC_LDFLAGS_JVM_ONLY="-Wl,-O1"
  79 
  80   elif test "x$TOOLCHAIN_TYPE" = xclang; then
  81     BASIC_LDFLAGS_JVM_ONLY="-mno-omit-leaf-frame-pointer -mstack-alignment=16 \
  82         -fPIC"
  83 
  84   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
  85     BASIC_LDFLAGS="-b64 -brtl -bnorwexec -bnolibpath -bexpall -bernotok -btextpsize:64K \
  86         -bdatapsize:64K -bstackpsize:64K"
  87     # libjvm.so has gotten too large for normal TOC size; compile with qpic=large and link with bigtoc
  88     BASIC_LDFLAGS_JVM_ONLY="-Wl,-lC_r -bbigtoc"
  89 
  90   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
  91     BASIC_LDFLAGS="-nologo -opt:ref"
  92     BASIC_LDFLAGS_JDK_ONLY="-incremental:no"
  93     BASIC_LDFLAGS_JVM_ONLY="-opt:icf,8 -subsystem:windows"
  94   fi
  95 
  96   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
  97     if test -n "$HAS_NOEXECSTACK"; then
  98       BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,noexecstack"
  99     fi
 100   fi
 101 
 102   # Setup OS-dependent LDFLAGS
 103   if test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xgcc; then
 104     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 105       # Assume clang or gcc.
 106       # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
 107       OS_LDFLAGS_JVM_ONLY="-Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
 108       OS_LDFLAGS_JDK_ONLY="-mmacosx-version-min=$MACOSX_VERSION_MIN"
 109     fi
 110   fi
 111 
 112   # Setup debug level-dependent LDFLAGS
 113   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 114     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 115       if test x$DEBUG_LEVEL = xrelease; then
 116         DEBUGLEVEL_LDFLAGS_JDK_ONLY="$DEBUGLEVEL_LDFLAGS_JDK_ONLY -Wl,-O1"
 117       fi
 118     fi
 119 
 120   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 121     # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
 122     # Hotspot now overflows its 64K TOC (currently only for debug),
 123     # so we build with '-qpic=large -bbigtoc'.
 124     if test "x$DEBUG_LEVEL" != xrelease; then
 125       DEBUGLEVEL_LDFLAGS_JVM_ONLY="$DEBUGLEVEL_LDFLAGS_JVM_ONLY -bbigtoc"
 126     fi
 127   fi
 128 
 129   # Setup LDFLAGS for linking executables
 130   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 131     EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -Wl,--allow-shlib-undefined"
 132     # Enabling pie on 32 bit builds prevents the JVM from allocating a continuous
 133     # java heap.
 134     if test "x$OPENJDK_TARGET_CPU_BITS" != "x32"; then
 135       EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -pie"
 136     fi
 137   fi
 138 
 139   if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
 140     if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 141       BASIC_LDFLAGS="$BASIC_LDFLAGS -pdbaltpath:%_PDB%"
 142     fi
 143   fi
 144 
 145   # Export some intermediate variables for compatibility
 146   LDFLAGS_CXX_JDK="$BASIC_LDFLAGS_ONLYCXX $BASIC_LDFLAGS_ONLYCXX_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY"
 147   AC_SUBST(LDFLAGS_CXX_JDK)
 148 ])
 149 
 150 ################################################################################
 151 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
 152 #      conditionals against.
 153 # $2 - Optional prefix for each variable defined.
 154 AC_DEFUN([FLAGS_SETUP_LDFLAGS_CPU_DEP],
 155 [
 156   # Setup CPU-dependent basic LDFLAGS. These can differ between the target and
 157   # build toolchain.
 158   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 159     if test "x${OPENJDK_$1_CPU}" = xx86; then
 160       $1_CPU_LDFLAGS_JVM_ONLY="-march=i586"
 161     elif test "x$OPENJDK_$1_CPU" = xarm; then
 162       $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
 163       $1_CPU_LDFLAGS="$ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
 164     fi
 165 
 166   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 167     if test "x${OPENJDK_$1_CPU}" = "xx86"; then
 168       $1_CPU_LDFLAGS="-safeseh"
 169       # NOTE: Old build added -machine. Probably not needed.
 170       $1_CPU_LDFLAGS_JVM_ONLY="-machine:I386"
 171       $1_CPU_EXECUTABLE_LDFLAGS="-stack:327680"
 172     elif test "x${OPENJDK_$1_CPU}" = "xx86_64"; then
 173       $1_CPU_LDFLAGS_JVM_ONLY="-machine:AMD64"
 174       $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
 175     elif test "x${OPENJDK_$1_CPU}" = "xaarch64"; then
 176       $1_CPU_LDFLAGS_JVM_ONLY="-machine:ARM64"
 177       $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
 178     fi
 179   fi
 180 
 181   # JVM_VARIANT_PATH depends on if this is build or target...
 182   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 183     $1_LDFLAGS_JDK_LIBPATH="-libpath:${OUTPUTDIR}/support/modules_libs/java.base"
 184   else
 185     $1_LDFLAGS_JDK_LIBPATH="-L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base \
 186         -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/${$1_JVM_VARIANT_PATH}"
 187   fi
 188 
 189   # Export variables according to old definitions, prefix with $2 if present.
 190   LDFLAGS_JDK_COMMON="$BASIC_LDFLAGS $BASIC_LDFLAGS_JDK_ONLY \
 191       $OS_LDFLAGS_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY ${$2EXTRA_LDFLAGS}"
 192   $2LDFLAGS_JDKLIB="$LDFLAGS_JDK_COMMON $BASIC_LDFLAGS_JDK_LIB_ONLY \
 193       ${$1_LDFLAGS_JDK_LIBPATH} $SHARED_LIBRARY_FLAGS"
 194   $2LDFLAGS_JDKEXE="$LDFLAGS_JDK_COMMON $EXECUTABLE_LDFLAGS \
 195       ${$1_CPU_EXECUTABLE_LDFLAGS}"
 196 
 197   $2JVM_LDFLAGS="$BASIC_LDFLAGS $BASIC_LDFLAGS_JVM_ONLY $OS_LDFLAGS_JVM_ONLY \
 198       $DEBUGLEVEL_LDFLAGS $DEBUGLEVEL_LDFLAGS_JVM_ONLY $BASIC_LDFLAGS_ONLYCXX \
 199       ${$1_CPU_LDFLAGS} ${$1_CPU_LDFLAGS_JVM_ONLY} ${$2EXTRA_LDFLAGS}"
 200 
 201   AC_SUBST($2LDFLAGS_JDKLIB)
 202   AC_SUBST($2LDFLAGS_JDKEXE)
 203 
 204   AC_SUBST($2JVM_LDFLAGS)
 205 ])