1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64*x32)
34 VAR_CPU=x32
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=32
37 VAR_CPU_ENDIAN=little
38 ;;
39 x86_64)
40 VAR_CPU=x86_64
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=64
43 VAR_CPU_ENDIAN=little
44 ;;
45 i?86)
46 VAR_CPU=x86
47 VAR_CPU_ARCH=x86
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 alpha*)
52 VAR_CPU=alpha
53 VAR_CPU_ARCH=alpha
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 arm*)
58 VAR_CPU=arm
59 VAR_CPU_ARCH=arm
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=little
62 ;;
63 aarch64)
64 VAR_CPU=aarch64
65 VAR_CPU_ARCH=aarch64
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=little
68 ;;
69 ia64)
70 VAR_CPU=ia64
71 VAR_CPU_ARCH=ia64
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 m68k)
76 VAR_CPU=m68k
77 VAR_CPU_ARCH=m68k
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 mips)
82 VAR_CPU=mips
83 VAR_CPU_ARCH=mips
84 VAR_CPU_BITS=32
85 VAR_CPU_ENDIAN=big
86 ;;
87 mipsel)
88 VAR_CPU=mipsel
89 VAR_CPU_ARCH=mipsel
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=little
92 ;;
93 mips64)
94 VAR_CPU=mips64
95 VAR_CPU_ARCH=mips64
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 mips64el)
100 VAR_CPU=mips64el
101 VAR_CPU_ARCH=mips64el
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=little
104 ;;
105 powerpc)
106 VAR_CPU=ppc
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=32
109 VAR_CPU_ENDIAN=big
110 ;;
111 powerpc64)
112 VAR_CPU=ppc64
113 VAR_CPU_ARCH=ppc
114 VAR_CPU_BITS=64
115 VAR_CPU_ENDIAN=big
116 ;;
117 powerpc64le)
118 VAR_CPU=ppc64le
119 VAR_CPU_ARCH=ppc
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=little
122 ;;
123 riscv64)
124 VAR_CPU=riscv64
125 VAR_CPU_ARCH=riscv
126 VAR_CPU_BITS=64
127 VAR_CPU_ENDIAN=little
128 ;;
129 s390)
130 VAR_CPU=s390
131 VAR_CPU_ARCH=s390
132 VAR_CPU_BITS=32
133 VAR_CPU_ENDIAN=big
134 ;;
135 s390x)
136 VAR_CPU=s390x
137 VAR_CPU_ARCH=s390
138 VAR_CPU_BITS=64
139 VAR_CPU_ENDIAN=big
140 ;;
141 sh*eb)
142 VAR_CPU=sh
143 VAR_CPU_ARCH=sh
144 VAR_CPU_BITS=32
145 VAR_CPU_ENDIAN=big
146 ;;
147 sh*)
148 VAR_CPU=sh
149 VAR_CPU_ARCH=sh
150 VAR_CPU_BITS=32
151 VAR_CPU_ENDIAN=little
152 ;;
153 sparc)
154 VAR_CPU=sparc
155 VAR_CPU_ARCH=sparc
156 VAR_CPU_BITS=32
157 VAR_CPU_ENDIAN=big
158 ;;
159 sparcv9|sparc64)
160 VAR_CPU=sparcv9
161 VAR_CPU_ARCH=sparc
162 VAR_CPU_BITS=64
163 VAR_CPU_ENDIAN=big
164 ;;
165 sparc)
166 VAR_CPU=sparc
167 VAR_CPU_ARCH=sparc
168 VAR_CPU_BITS=32
169 VAR_CPU_ENDIAN=big
170 ;;
171 sparcv9|sparc64)
172 VAR_CPU=sparcv9
173 VAR_CPU_ARCH=sparc
174 VAR_CPU_BITS=64
175 VAR_CPU_ENDIAN=big
176 ;;
177 *)
178 AC_MSG_ERROR([unsupported cpu $1])
179 ;;
180 esac
181 ])
182
183 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
184 # Converts autoconf style OS name to OpenJDK style, into
185 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
186 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
187 [
188 case "$1" in
189 *linux*)
190 VAR_OS=linux
191 VAR_OS_TYPE=unix
192 ;;
193 *darwin*)
194 VAR_OS=macosx
195 VAR_OS_TYPE=unix
196 ;;
197 *bsd*)
198 VAR_OS=bsd
199 VAR_OS_TYPE=unix
200 ;;
201 *cygwin*)
202 VAR_OS=windows
203 VAR_OS_ENV=windows.cygwin
204 ;;
205 *wsl*)
206 VAR_OS=windows
207 VAR_OS_ENV=windows.wsl
208 ;;
209 *mingw*)
210 VAR_OS=windows
211 VAR_OS_ENV=windows.msys
212 ;;
213 *aix*)
214 VAR_OS=aix
215 VAR_OS_TYPE=unix
216 ;;
217 *)
218 AC_MSG_ERROR([unsupported operating system $1])
219 ;;
220 esac
221 ])
222
223 # Expects $host_os $host_cpu $build_os and $build_cpu
224 # and $with_target_bits to have been setup!
225 #
226 # Translate the standard triplet(quadruplet) definition
227 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
228 # OPENJDK_BUILD_OS, etc.
229 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
230 [
231 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
232 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
233 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
234 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
235 OPENJDK_TARGET_AUTOCONF_NAME="$host"
236 OPENJDK_BUILD_AUTOCONF_NAME="$build"
237 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
238 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
239
240 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
241 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
242 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
243 # ..and setup our own variables. (Do this explicitly to facilitate searching)
244 OPENJDK_BUILD_OS="$VAR_OS"
245 if test "x$VAR_OS_TYPE" != x; then
246 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
247 else
248 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
249 fi
250 if test "x$VAR_OS_ENV" != x; then
251 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
252 else
253 OPENJDK_BUILD_OS_ENV="$VAR_OS"
254 fi
255 OPENJDK_BUILD_CPU="$VAR_CPU"
256 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
257 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
258 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
259 AC_SUBST(OPENJDK_BUILD_OS)
260 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
261 AC_SUBST(OPENJDK_BUILD_OS_ENV)
262 AC_SUBST(OPENJDK_BUILD_CPU)
263 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
264 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
265 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
266
267 AC_MSG_CHECKING([openjdk-build os-cpu])
268 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
269
270 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
271 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
272 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
273 # ... and setup our own variables. (Do this explicitly to facilitate searching)
274 OPENJDK_TARGET_OS="$VAR_OS"
275 if test "x$VAR_OS_TYPE" != x; then
276 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
277 else
278 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
279 fi
280 if test "x$VAR_OS_ENV" != x; then
281 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
282 else
283 OPENJDK_TARGET_OS_ENV="$VAR_OS"
284 fi
285 OPENJDK_TARGET_CPU="$VAR_CPU"
286 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
287 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
288 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
289 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
290
291 AC_SUBST(OPENJDK_TARGET_OS)
292 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
293 AC_SUBST(OPENJDK_TARGET_OS_ENV)
294 AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
295 AC_SUBST(OPENJDK_TARGET_CPU)
296 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
297 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
298 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
299
300 AC_MSG_CHECKING([openjdk-target os-cpu])
301 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
302 ])
303
304 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
305 # accordingly. Must be done after setting up build and target system, but before
306 # doing anything else with these values.
307 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
308 [
309 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
310 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
311
312 # We have three types of compiles:
313 # native == normal compilation, target system == build system
314 # cross == traditional cross compilation, target system != build system; special toolchain needed
315 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
316 #
317 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
318 # We're doing a proper cross-compilation
319 COMPILE_TYPE="cross"
320 else
321 COMPILE_TYPE="native"
322 fi
323
324 if test "x$with_target_bits" != x; then
325 if test "x$COMPILE_TYPE" = "xcross"; then
326 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
327 fi
328
329 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
330 # A reduced build is requested
331 COMPILE_TYPE="reduced"
332 OPENJDK_TARGET_CPU_BITS=32
333 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
334 OPENJDK_TARGET_CPU=x86
335 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
336 OPENJDK_TARGET_CPU=sparc
337 else
338 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
339 fi
340 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
341 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
342 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
343 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
344 else
345 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
346 fi
347 fi
348 AC_SUBST(COMPILE_TYPE)
349
350 AC_MSG_CHECKING([compilation type])
351 AC_MSG_RESULT([$COMPILE_TYPE])
352 ])
353
354 # Setup the legacy variables, for controlling the old makefiles.
355 #
356 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
357 [
358 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
359 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
360 ])
361
362 # $1 - Either TARGET or BUILD to setup the variables for.
363 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
364 [
365 # Also store the legacy naming of the cpu.
366 # Ie i586 and amd64 instead of x86 and x86_64
367 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
368 if test "x$OPENJDK_$1_CPU" = xx86; then
369 OPENJDK_$1_CPU_LEGACY="i586"
370 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
371 # On all platforms except MacOSX replace x86_64 with amd64.
372 OPENJDK_$1_CPU_LEGACY="amd64"
373 elif test "x$OPENJDK_$1_CPU" = xalpha; then
374 # Avoid name collisions with variables named alpha
375 OPENJDK_$1_CPU_LEGACY="_alpha_"
376 elif test "x$OPENJDK_$1_CPU" = xsh; then
377 # Avoid name collisions with variables named sh
378 OPENJDK_$1_CPU_LEGACY="_sh_"
379 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
380 OPENJDK_$1_CPU_LEGACY="arm64"
381 fi
382 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
383
384 # And the second legacy naming of the cpu.
385 # Ie i386 and amd64 instead of x86 and x86_64.
386 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
387 if test "x$OPENJDK_$1_CPU" = xx86; then
388 OPENJDK_$1_CPU_LEGACY_LIB="i386"
389 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
390 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
391 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
392 OPENJDK_$1_CPU_LEGACY_LIB="arm64"
393 fi
394 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
395
396 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
397 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
398 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
399 # On linux only, we replace x86 with i386.
400 OPENJDK_$1_CPU_OSARCH="i386"
401 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
402 # On all platforms except macosx, we replace x86_64 with amd64.
403 OPENJDK_$1_CPU_OSARCH="amd64"
404 fi
405 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
406
407 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
408 if test "x$OPENJDK_$1_CPU" = xx86; then
409 OPENJDK_$1_CPU_JLI="i386"
410 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
411 # On all platforms except macosx, we replace x86_64 with amd64.
412 OPENJDK_$1_CPU_JLI="amd64"
413 fi
414
415 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
416 # Macosx is osx and x86_64 is x64
417 if test "x$OPENJDK_$1_OS" = xmacosx; then
418 OPENJDK_$1_OS_BUNDLE="osx"
419 else
420 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
421 fi
422 if test "x$OPENJDK_$1_CPU" = xx86_64; then
423 OPENJDK_$1_CPU_BUNDLE="x64"
424 else
425 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
426 fi
427 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
428 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
429
430 if test "x$COMPILE_TYPE" = "xcross"; then
431 # FIXME: ... or should this include reduced builds..?
432 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
433 else
434 DEFINE_CROSS_COMPILE_ARCH=""
435 fi
436 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
437
438 # Convert openjdk platform names to hotspot names
439
440 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
441 if test "x$OPENJDK_$1_OS" = xmacosx; then
442 HOTSPOT_$1_OS=bsd
443 fi
444 AC_SUBST(HOTSPOT_$1_OS)
445
446 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
447 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
448 HOTSPOT_$1_OS_TYPE=posix
449 fi
450 AC_SUBST(HOTSPOT_$1_OS_TYPE)
451
452 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
453 if test "x$OPENJDK_$1_CPU" = xx86; then
454 HOTSPOT_$1_CPU=x86_32
455 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
456 HOTSPOT_$1_CPU=sparc
457 elif test "x$OPENJDK_$1_CPU" = xppc64; then
458 HOTSPOT_$1_CPU=ppc_64
459 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
460 HOTSPOT_$1_CPU=ppc_64
461 fi
462 AC_SUBST(HOTSPOT_$1_CPU)
463
464 # This is identical with OPENJDK_*, but define anyway for consistency.
465 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
466 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
467
468 # Setup HOTSPOT_$1_CPU_DEFINE
469 if test "x$OPENJDK_$1_CPU" = xx86; then
470 HOTSPOT_$1_CPU_DEFINE=IA32
471 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
472 HOTSPOT_$1_CPU_DEFINE=AMD64
473 elif test "x$OPENJDK_$1_CPU" = xx32; then
474 HOTSPOT_$1_CPU_DEFINE=X32
475 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
476 HOTSPOT_$1_CPU_DEFINE=SPARC
477 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
478 HOTSPOT_$1_CPU_DEFINE=AARCH64
479 elif test "x$OPENJDK_$1_CPU" = xppc64; then
480 HOTSPOT_$1_CPU_DEFINE=PPC64
481 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
482 HOTSPOT_$1_CPU_DEFINE=PPC64
483
484 # The cpu defines below are for zero, we don't support them directly.
485 elif test "x$OPENJDK_$1_CPU" = xsparc; then
486 HOTSPOT_$1_CPU_DEFINE=SPARC
487 elif test "x$OPENJDK_$1_CPU" = xppc; then
488 HOTSPOT_$1_CPU_DEFINE=PPC32
489 elif test "x$OPENJDK_$1_CPU" = xs390; then
490 HOTSPOT_$1_CPU_DEFINE=S390
491 elif test "x$OPENJDK_$1_CPU" = xs390x; then
492 HOTSPOT_$1_CPU_DEFINE=S390
493 elif test "x$OPENJDK_$1_CPU" = xriscv64; then
494 HOTSPOT_$1_CPU_DEFINE=RISCV
495 elif test "x$OPENJDK_$1_CPU" != x; then
496 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
497 fi
498 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
499
500 # For historical reasons, the OS include directories have odd names.
501 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
502 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
503 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
504 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
505 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
506 fi
507 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
508 ])
509
510 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
511 [
512 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
513 RELEASE_FILE_OS_NAME=Linux
514 fi
515 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
516 RELEASE_FILE_OS_NAME=Windows
517 fi
518 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
519 RELEASE_FILE_OS_NAME="Darwin"
520 fi
521 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
522 RELEASE_FILE_OS_NAME="AIX"
523 fi
524 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
525
526 AC_SUBST(RELEASE_FILE_OS_NAME)
527 AC_SUBST(RELEASE_FILE_OS_ARCH)
528 ])
529
530 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
531 [
532 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
533 OPENJDK_MODULE_TARGET_OS_NAME="macos"
534 else
535 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
536 fi
537
538 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
539 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
540 elif test "x$OPENJDK_TARGET_CPU" = xaarch64; then
541 OPENJDK_MODULE_TARGET_OS_ARCH="arm64"
542 else
543 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
544 fi
545
546 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
547 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
548 ])
549
550 #%%% Build and target systems %%%
551 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
552 [
553 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
554 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
555 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
556 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
557 # to use the configure naming style.
558 AC_CANONICAL_BUILD
559 AC_CANONICAL_HOST
560 AC_CANONICAL_TARGET
561
562 PLATFORM_EXTRACT_TARGET_AND_BUILD
563 PLATFORM_SETUP_TARGET_CPU_BITS
564 PLATFORM_SET_MODULE_TARGET_OS_VALUES
565 PLATFORM_SET_RELEASE_FILE_OS_VALUES
566 PLATFORM_SETUP_LEGACY_VARS
567
568 # Deprecated in JDK 15
569 UTIL_DEPRECATED_ARG_ENABLE(deprecated-ports)
570 ])
571
572 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
573 [
574 ###############################################################################
575
576 # Note that this is the build platform OS version!
577
578 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
579 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
580 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
581 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
582 AC_SUBST(OS_VERSION_MAJOR)
583 AC_SUBST(OS_VERSION_MINOR)
584 AC_SUBST(OS_VERSION_MICRO)
585 ])
586
587 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
588 [
589 ###############################################################################
590 #
591 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
592 # (The JVM can use 32 or 64 bit Java pointers but that decision
593 # is made at runtime.)
594 #
595
596 # Make compilation sanity check
597 AC_CHECK_HEADERS([stdio.h], , [
598 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
599 if test "x$COMPILE_TYPE" = xreduced; then
600 HELP_MSG_MISSING_DEPENDENCY([reduced])
601 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
602 elif test "x$COMPILE_TYPE" = xcross; then
603 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
604 fi
605 AC_MSG_ERROR([Cannot continue.])
606 ])
607
608 AC_CHECK_SIZEOF([int *], [1111])
609
610 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
611 if test "x$ac_cv_sizeof_int_p" = x; then
612 # The test failed, lets stick to the assumed value.
613 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
614 else
615 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
616
617 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
618 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
619 if test "x$COMPILE_TYPE" = xreduced; then
620 HELP_MSG_MISSING_DEPENDENCY([reduced])
621 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
622 elif test "x$COMPILE_TYPE" = xcross; then
623 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
624 fi
625 AC_MSG_ERROR([Cannot continue.])
626 fi
627 fi
628
629 AC_MSG_CHECKING([for target address size])
630 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
631 ])
632
633 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
634 [
635 ###############################################################################
636 #
637 # Is the target little of big endian?
638 #
639 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
640
641 if test "x$ENDIAN" = xuniversal_endianness; then
642 AC_MSG_ERROR([Building with both big and little endianness is not supported])
643 fi
644 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
645 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
646 fi
647 ])