1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
  27 # Converts autoconf style CPU name to OpenJDK style, into
  28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
  29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
  30 [
  31   # First argument is the cpu name from the trip/quad
  32   case "$1" in
  33     x86_64)
  34       VAR_CPU=x86_64
  35       VAR_CPU_ARCH=x86
  36       VAR_CPU_BITS=64
  37       VAR_CPU_ENDIAN=little
  38       ;;
  39     i?86)
  40       VAR_CPU=x86
  41       VAR_CPU_ARCH=x86
  42       VAR_CPU_BITS=32
  43       VAR_CPU_ENDIAN=little
  44       ;;
  45     alpha*)
  46       VAR_CPU=alpha
  47       VAR_CPU_ARCH=alpha
  48       VAR_CPU_BITS=64
  49       VAR_CPU_ENDIAN=little
  50       ;;
  51     arm*)
  52       VAR_CPU=arm
  53       VAR_CPU_ARCH=arm
  54       VAR_CPU_BITS=32
  55       VAR_CPU_ENDIAN=little
  56       ;;
  57     aarch64)
  58       VAR_CPU=aarch64
  59       VAR_CPU_ARCH=aarch64
  60       VAR_CPU_BITS=64
  61       VAR_CPU_ENDIAN=little
  62       ;;
  63     ia64)
  64       VAR_CPU=ia64
  65       VAR_CPU_ARCH=ia64
  66       VAR_CPU_BITS=64
  67       VAR_CPU_ENDIAN=little
  68       ;;
  69     m68k)
  70       VAR_CPU=m68k
  71       VAR_CPU_ARCH=m68k
  72       VAR_CPU_BITS=32
  73       VAR_CPU_ENDIAN=big
  74       ;;
  75     mips)
  76       VAR_CPU=mips
  77       VAR_CPU_ARCH=mips
  78       VAR_CPU_BITS=32
  79       VAR_CPU_ENDIAN=big
  80       ;;
  81     mipsel)
  82       VAR_CPU=mipsel
  83       VAR_CPU_ARCH=mipsel
  84       VAR_CPU_BITS=32
  85       VAR_CPU_ENDIAN=little
  86       ;;
  87     mips64)
  88       VAR_CPU=mips64
  89       VAR_CPU_ARCH=mips64
  90       VAR_CPU_BITS=64
  91       VAR_CPU_ENDIAN=big
  92       ;;
  93     mips64el)
  94       VAR_CPU=mips64el
  95       VAR_CPU_ARCH=mips64el
  96       VAR_CPU_BITS=64
  97       VAR_CPU_ENDIAN=little
  98       ;;
  99     powerpc)
 100       VAR_CPU=ppc
 101       VAR_CPU_ARCH=ppc
 102       VAR_CPU_BITS=32
 103       VAR_CPU_ENDIAN=big
 104       ;;
 105     powerpc64)
 106       VAR_CPU=ppc64
 107       VAR_CPU_ARCH=ppc
 108       VAR_CPU_BITS=64
 109       VAR_CPU_ENDIAN=big
 110       ;;
 111     powerpc64le)
 112       VAR_CPU=ppc64le
 113       VAR_CPU_ARCH=ppc
 114       VAR_CPU_BITS=64
 115       VAR_CPU_ENDIAN=little
 116       ;;
 117     s390)
 118       VAR_CPU=s390
 119       VAR_CPU_ARCH=s390
 120       VAR_CPU_BITS=32
 121       VAR_CPU_ENDIAN=big
 122       ;;
 123     s390x)
 124       VAR_CPU=s390x
 125       VAR_CPU_ARCH=s390
 126       VAR_CPU_BITS=64
 127       VAR_CPU_ENDIAN=big
 128       ;;
 129     sh*eb)
 130       VAR_CPU=sh
 131       VAR_CPU_ARCH=sh
 132       VAR_CPU_BITS=32
 133       VAR_CPU_ENDIAN=big
 134       ;;
 135     sh*)
 136       VAR_CPU=sh
 137       VAR_CPU_ARCH=sh
 138       VAR_CPU_BITS=32
 139       VAR_CPU_ENDIAN=little
 140       ;;
 141     sparc)
 142       VAR_CPU=sparc
 143       VAR_CPU_ARCH=sparc
 144       VAR_CPU_BITS=32
 145       VAR_CPU_ENDIAN=big
 146       ;;
 147     sparcv9|sparc64)
 148       VAR_CPU=sparcv9
 149       VAR_CPU_ARCH=sparc
 150       VAR_CPU_BITS=64
 151       VAR_CPU_ENDIAN=big
 152       ;;
 153     *)
 154       AC_MSG_ERROR([unsupported cpu $1])
 155       ;;
 156   esac
 157 ])
 158 
 159 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
 160 # Converts autoconf style OS name to OpenJDK style, into
 161 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
 162 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
 163 [
 164   case "$1" in
 165     *linux*)
 166       VAR_OS=linux
 167       VAR_OS_TYPE=unix
 168       ;;
 169     *solaris*)
 170       VAR_OS=solaris
 171       VAR_OS_TYPE=unix
 172       ;;
 173     *darwin*)
 174       VAR_OS=macosx
 175       VAR_OS_TYPE=unix
 176       ;;
 177     *bsd*)
 178       VAR_OS=bsd
 179       VAR_OS_TYPE=unix
 180       ;;
 181     *cygwin*)
 182       VAR_OS=windows
 183       VAR_OS_ENV=windows.cygwin
 184       ;;
 185     *mingw*)
 186       VAR_OS=windows
 187       VAR_OS_ENV=windows.msys
 188       ;;
 189     *aix*)
 190       VAR_OS=aix
 191       VAR_OS_TYPE=unix
 192       ;;
 193     *)
 194       AC_MSG_ERROR([unsupported operating system $1])
 195       ;;
 196   esac
 197 ])
 198 
 199 # Expects $host_os $host_cpu $build_os and $build_cpu
 200 # and $with_target_bits to have been setup!
 201 #
 202 # Translate the standard triplet(quadruplet) definition
 203 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
 204 # OPENJDK_BUILD_OS, etc.
 205 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
 206 [
 207   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
 208   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
 209   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
 210   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
 211   OPENJDK_TARGET_AUTOCONF_NAME="$host"
 212   OPENJDK_BUILD_AUTOCONF_NAME="$build"
 213   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
 214   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
 215 
 216   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 217   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
 218   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
 219   # ..and setup our own variables. (Do this explicitly to facilitate searching)
 220   OPENJDK_BUILD_OS="$VAR_OS"
 221   if test "x$VAR_OS_TYPE" != x; then
 222     OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
 223   else
 224     OPENJDK_BUILD_OS_TYPE="$VAR_OS"
 225   fi
 226   if test "x$VAR_OS_ENV" != x; then
 227     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
 228   else
 229     OPENJDK_BUILD_OS_ENV="$VAR_OS"
 230   fi
 231   OPENJDK_BUILD_CPU="$VAR_CPU"
 232   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
 233   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
 234   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 235   AC_SUBST(OPENJDK_BUILD_OS)
 236   AC_SUBST(OPENJDK_BUILD_OS_TYPE)
 237   AC_SUBST(OPENJDK_BUILD_OS_ENV)
 238   AC_SUBST(OPENJDK_BUILD_CPU)
 239   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
 240   AC_SUBST(OPENJDK_BUILD_CPU_BITS)
 241   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
 242 
 243   AC_MSG_CHECKING([openjdk-build os-cpu])
 244   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
 245 
 246   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
 247   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
 248   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
 249   # ... and setup our own variables. (Do this explicitly to facilitate searching)
 250   OPENJDK_TARGET_OS="$VAR_OS"
 251   if test "x$VAR_OS_TYPE" != x; then
 252     OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
 253   else
 254     OPENJDK_TARGET_OS_TYPE="$VAR_OS"
 255   fi
 256   if test "x$VAR_OS_ENV" != x; then
 257     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
 258   else
 259     OPENJDK_TARGET_OS_ENV="$VAR_OS"
 260   fi
 261   OPENJDK_TARGET_CPU="$VAR_CPU"
 262   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
 263   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
 264   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
 265   AC_SUBST(OPENJDK_TARGET_OS)
 266   AC_SUBST(OPENJDK_TARGET_OS_TYPE)
 267   AC_SUBST(OPENJDK_TARGET_OS_ENV)
 268   AC_SUBST(OPENJDK_TARGET_CPU)
 269   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
 270   AC_SUBST(OPENJDK_TARGET_CPU_BITS)
 271   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
 272 
 273   AC_MSG_CHECKING([openjdk-target os-cpu])
 274   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
 275 ])
 276 
 277 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
 278 # accordingly. Must be done after setting up build and target system, but before
 279 # doing anything else with these values.
 280 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
 281 [
 282   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
 283        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
 284 
 285   # We have three types of compiles:
 286   # native  == normal compilation, target system == build system
 287   # cross   == traditional cross compilation, target system != build system; special toolchain needed
 288   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
 289   #
 290   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
 291     # We're doing a proper cross-compilation
 292     COMPILE_TYPE="cross"
 293   else
 294     COMPILE_TYPE="native"
 295   fi
 296 
 297   if test "x$with_target_bits" != x; then
 298     if test "x$COMPILE_TYPE" = "xcross"; then
 299       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
 300     fi
 301 
 302     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 303       # A reduced build is requested
 304       COMPILE_TYPE="reduced"
 305       OPENJDK_TARGET_CPU_BITS=32
 306       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 307         OPENJDK_TARGET_CPU=x86
 308       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 309         OPENJDK_TARGET_CPU=sparc
 310       else
 311         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
 312       fi
 313     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
 314       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
 315     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
 316       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
 317     else
 318       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
 319     fi
 320   fi
 321   AC_SUBST(COMPILE_TYPE)
 322 
 323   AC_MSG_CHECKING([compilation type])
 324   AC_MSG_RESULT([$COMPILE_TYPE])
 325 ])
 326 
 327 # Setup the legacy variables, for controlling the old makefiles.
 328 #
 329 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
 330 [
 331   PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
 332   PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
 333 ])
 334 
 335 # $1 - Either TARGET or BUILD to setup the variables for.
 336 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
 337 [
 338   # Also store the legacy naming of the cpu.
 339   # Ie i586 and amd64 instead of x86 and x86_64
 340   OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
 341   if test "x$OPENJDK_$1_CPU" = xx86; then
 342     OPENJDK_$1_CPU_LEGACY="i586"
 343   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 344     # On all platforms except MacOSX replace x86_64 with amd64.
 345     OPENJDK_$1_CPU_LEGACY="amd64"
 346   elif test "x$OPENJDK_$1_CPU" = xalpha; then
 347     # Avoid name collisions with variables named alpha
 348     OPENJDK_$1_CPU_LEGACY="_alpha_"
 349   elif test "x$OPENJDK_$1_CPU" = xsh; then
 350     # Avoid name collisions with variables named sh
 351     OPENJDK_$1_CPU_LEGACY="_sh_"
 352   fi
 353   AC_SUBST(OPENJDK_$1_CPU_LEGACY)
 354 
 355   # And the second legacy naming of the cpu.
 356   # Ie i386 and amd64 instead of x86 and x86_64.
 357   OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
 358   if test "x$OPENJDK_$1_CPU" = xx86; then
 359     OPENJDK_$1_CPU_LEGACY_LIB="i386"
 360   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 361     OPENJDK_$1_CPU_LEGACY_LIB="amd64"
 362   fi
 363   AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
 364 
 365   # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
 366   # /amd64 or /sparcv9. This string is appended to some library paths, like this:
 367   # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
 368   OPENJDK_$1_CPU_ISADIR=""
 369   if test "x$OPENJDK_$1_OS" = xsolaris; then
 370     if test "x$OPENJDK_$1_CPU" = xx86_64; then
 371       OPENJDK_$1_CPU_ISADIR="/amd64"
 372     elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 373       OPENJDK_$1_CPU_ISADIR="/sparcv9"
 374     fi
 375   fi
 376   AC_SUBST(OPENJDK_$1_CPU_ISADIR)
 377 
 378   # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
 379   OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
 380   if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
 381     # On linux only, we replace x86 with i386.
 382     OPENJDK_$1_CPU_OSARCH="i386"
 383   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 384     # On all platforms except macosx, we replace x86_64 with amd64.
 385     OPENJDK_$1_CPU_OSARCH="amd64"
 386   fi
 387   AC_SUBST(OPENJDK_$1_CPU_OSARCH)
 388 
 389   OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
 390   if test "x$OPENJDK_$1_CPU" = xx86; then
 391     OPENJDK_$1_CPU_JLI="i386"
 392   elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
 393     # On all platforms except macosx, we replace x86_64 with amd64.
 394     OPENJDK_$1_CPU_JLI="amd64"
 395   fi
 396 
 397   # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
 398   # Macosx is osx and x86_64 is x64
 399   if test "x$OPENJDK_$1_OS" = xmacosx; then
 400     OPENJDK_$1_OS_BUNDLE="osx"
 401   else
 402     OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
 403   fi
 404   if test "x$OPENJDK_$1_CPU" = xx86_64; then
 405     OPENJDK_$1_CPU_BUNDLE="x64"
 406   else
 407     OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
 408   fi
 409   OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
 410   AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
 411 
 412   if test "x$COMPILE_TYPE" = "xcross"; then
 413     # FIXME: ... or should this include reduced builds..?
 414     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
 415   else
 416     DEFINE_CROSS_COMPILE_ARCH=""
 417   fi
 418   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
 419 
 420   # Convert openjdk platform names to hotspot names
 421 
 422   HOTSPOT_$1_OS=${OPENJDK_$1_OS}
 423   if test "x$OPENJDK_$1_OS" = xmacosx; then
 424     HOTSPOT_$1_OS=bsd
 425   fi
 426   AC_SUBST(HOTSPOT_$1_OS)
 427 
 428   HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
 429   if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
 430     HOTSPOT_$1_OS_TYPE=posix
 431   fi
 432   AC_SUBST(HOTSPOT_$1_OS_TYPE)
 433 
 434   HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
 435   if test "x$OPENJDK_$1_CPU" = xx86; then
 436     HOTSPOT_$1_CPU=x86_32
 437   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 438     HOTSPOT_$1_CPU=sparc
 439   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 440     HOTSPOT_$1_CPU=ppc_64
 441   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 442     HOTSPOT_$1_CPU=ppc_64
 443   fi
 444   AC_SUBST(HOTSPOT_$1_CPU)
 445 
 446   # This is identical with OPENJDK_*, but define anyway for consistency.
 447   HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
 448   AC_SUBST(HOTSPOT_$1_CPU_ARCH)
 449 
 450   # Setup HOTSPOT_$1_CPU_DEFINE
 451   if test "x$OPENJDK_$1_CPU" = xx86; then
 452     HOTSPOT_$1_CPU_DEFINE=IA32
 453   elif test "x$OPENJDK_$1_CPU" = xx86_64; then
 454     HOTSPOT_$1_CPU_DEFINE=AMD64
 455   elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
 456     HOTSPOT_$1_CPU_DEFINE=SPARC
 457   elif test "x$OPENJDK_$1_CPU" = xaarch64; then
 458     HOTSPOT_$1_CPU_DEFINE=AARCH64
 459   elif test "x$OPENJDK_$1_CPU" = xppc64; then
 460     HOTSPOT_$1_CPU_DEFINE=PPC64
 461   elif test "x$OPENJDK_$1_CPU" = xppc64le; then
 462     HOTSPOT_$1_CPU_DEFINE=PPC64
 463 
 464   # The cpu defines below are for zero, we don't support them directly.
 465   elif test "x$OPENJDK_$1_CPU" = xsparc; then
 466     HOTSPOT_$1_CPU_DEFINE=SPARC
 467   elif test "x$OPENJDK_$1_CPU" = xppc; then
 468     HOTSPOT_$1_CPU_DEFINE=PPC32
 469   elif test "x$OPENJDK_$1_CPU" = xs390; then
 470     HOTSPOT_$1_CPU_DEFINE=S390
 471   elif test "x$OPENJDK_$1_CPU" = xs390x; then
 472     HOTSPOT_$1_CPU_DEFINE=S390
 473   elif test "x$OPENJDK_$1_CPU" != x; then
 474     HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
 475   fi
 476   AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
 477 
 478   # For historical reasons, the OS include directories have odd names.
 479   OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
 480   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 481     OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
 482   elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 483     OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
 484   fi
 485   AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
 486 ])
 487 
 488 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
 489 [
 490   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
 491     RELEASE_FILE_OS_NAME=SunOS
 492   fi
 493   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
 494     RELEASE_FILE_OS_NAME=Linux
 495   fi
 496   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 497     RELEASE_FILE_OS_NAME=Windows
 498   fi
 499   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 500     RELEASE_FILE_OS_NAME="Darwin"
 501   fi
 502   if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 503     RELEASE_FILE_OS_NAME="AIX"
 504   fi
 505   RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
 506 
 507   AC_SUBST(RELEASE_FILE_OS_NAME)
 508   AC_SUBST(RELEASE_FILE_OS_ARCH)
 509 ])
 510 
 511 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
 512 [
 513   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 514     OPENJDK_MODULE_TARGET_OS_NAME="macos"
 515   else
 516     OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
 517   fi
 518 
 519   if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 520     OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
 521   else
 522     OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
 523   fi
 524 
 525   OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
 526   AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
 527 ])
 528 
 529 #%%% Build and target systems %%%
 530 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
 531 [
 532   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
 533   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the
 534   # product you're building. The target of this build is called "host". Since this is confusing to most people, we
 535   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
 536   # to use the configure naming style.
 537   AC_CANONICAL_BUILD
 538   AC_CANONICAL_HOST
 539   AC_CANONICAL_TARGET
 540 
 541   PLATFORM_EXTRACT_TARGET_AND_BUILD
 542   PLATFORM_SETUP_TARGET_CPU_BITS
 543   PLATFORM_SET_MODULE_TARGET_OS_VALUES
 544   PLATFORM_SET_RELEASE_FILE_OS_VALUES
 545   PLATFORM_SETUP_LEGACY_VARS
 546 ])
 547 
 548 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
 549 [
 550   ###############################################################################
 551 
 552   # Note that this is the build platform OS version!
 553 
 554   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
 555   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
 556   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
 557   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
 558   AC_SUBST(OS_VERSION_MAJOR)
 559   AC_SUBST(OS_VERSION_MINOR)
 560   AC_SUBST(OS_VERSION_MICRO)
 561 ])
 562 
 563 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
 564 [
 565   ###############################################################################
 566   #
 567   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
 568   # (The JVM can use 32 or 64 bit Java pointers but that decision
 569   # is made at runtime.)
 570   #
 571 
 572   # Make compilation sanity check
 573   AC_CHECK_HEADERS([stdio.h], , [
 574     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
 575     if test "x$COMPILE_TYPE" = xreduced; then
 576       HELP_MSG_MISSING_DEPENDENCY([reduced])
 577       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 578     elif test "x$COMPILE_TYPE" = xcross; then
 579       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 580     fi
 581     AC_MSG_ERROR([Cannot continue.])
 582   ])
 583 
 584   AC_CHECK_SIZEOF([int *], [1111])
 585 
 586   # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
 587   if test "x$ac_cv_sizeof_int_p" = x; then
 588     # The test failed, lets stick to the assumed value.
 589     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
 590   else
 591     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
 592 
 593     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
 594       AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
 595       if test "x$COMPILE_TYPE" = xreduced; then
 596         HELP_MSG_MISSING_DEPENDENCY([reduced])
 597         AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
 598       elif test "x$COMPILE_TYPE" = xcross; then
 599         AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
 600       fi
 601       AC_MSG_ERROR([Cannot continue.])
 602     fi
 603   fi
 604 
 605   AC_MSG_CHECKING([for target address size])
 606   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
 607 ])
 608 
 609 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
 610 [
 611   ###############################################################################
 612   #
 613   # Is the target little of big endian?
 614   #
 615   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
 616 
 617   if test "x$ENDIAN" = xuniversal_endianness; then
 618     AC_MSG_ERROR([Building with both big and little endianness is not supported])
 619   fi
 620   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
 621     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
 622   fi
 623 ])