1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2\
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # This will make sure the given variable points to a full and proper
47 # path. This means:
48 # 1) There will be no spaces in the path. On posix platforms,
49 # spaces in the path will result in an error. On Windows,
50 # the path will be rewritten using short-style to be space-free.
51 # 2) The path will be absolute, and it will be in unix-style (on
52 # cygwin).
53 # $1: The name of the variable to fix
54 AC_DEFUN([BASIC_FIXUP_PATH],
55 [
56 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
57 BASIC_FIXUP_PATH_CYGWIN($1)
58 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
59 BASIC_FIXUP_PATH_MSYS($1)
60 else
61 # We're on a posix platform. Hooray! :)
62 path="[$]$1"
63
64 if test ! -f "$path" && test ! -d "$path"; then
65 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
66 fi
67
68 has_space=`$ECHO "$path" | $GREP " "`
69 if test "x$has_space" != x; then
70 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
71 AC_MSG_ERROR([Spaces are not allowed in this path.])
72 fi
73 fi
74 ])
75
76 # This will make sure the given variable points to a executable
77 # with a full and proper path. This means:
78 # 1) There will be no spaces in the path. On posix platforms,
79 # spaces in the path will result in an error. On Windows,
80 # the path will be rewritten using short-style to be space-free.
81 # 2) The path will be absolute, and it will be in unix-style (on
82 # cygwin).
83 # Any arguments given to the executable is preserved.
84 # If the input variable does not have a directory specification, then
85 # it need to be in the PATH.
86 # $1: The name of the variable to fix
87 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
88 [
89 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
90 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
91 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
92 BASIC_FIXUP_EXECUTABLE_MSYS($1)
93 else
94 # We're on a posix platform. Hooray! :)
95 # First separate the path from the arguments. This will split at the first
96 # space.
97 complete="[$]$1"
98 path="${complete%% *}"
99 tmp="$complete EOL"
100 arguments="${tmp#* }"
101
102 # Cannot rely on the command "which" here since it doesn't always work.
103 is_absolute_path=`$ECHO "$path" | $GREP ^/`
104 if test -z "$is_absolute_path"; then
105 # Path to executable is not absolute. Find it.
106 IFS_save="$IFS"
107 IFS=:
108 for p in $PATH; do
109 if test -f "$p/$path" && test -x "$p/$path"; then
110 new_path="$p/$path"
111 break
112 fi
113 done
114 IFS="$IFS_save"
115 else
116 AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
117 new_path="$path"
118 fi
119
120 if test "x$new_path" = x; then
121 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
122 has_space=`$ECHO "$complete" | $GREP " "`
123 if test "x$has_space" != x; then
124 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
125 fi
126 AC_MSG_ERROR([Cannot locate the the path of $1])
127 fi
128 fi
129
130 # Now join together the path and the arguments once again
131 if test "x$arguments" != xEOL; then
132 new_complete="$new_path ${arguments% *}"
133 else
134 new_complete="$new_path"
135 fi
136
137 if test "x$complete" != "x$new_complete"; then
138 $1="$new_complete"
139 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
140 fi
141 ])
142
143 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
144 [
145 if test "x$OPENJDK_BUILD_OS" != xwindows; then
146 # Follow a chain of symbolic links. Use readlink
147 # where it exists, else fall back to horribly
148 # complicated shell code.
149 if test "x$READLINK_TESTED" != yes; then
150 # On MacOSX there is a readlink tool with a different
151 # purpose than the GNU readlink tool. Check the found readlink.
152 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
153 if test "x$ISGNU" = x; then
154 # A readlink that we do not know how to use.
155 # Are there other non-GNU readlinks out there?
156 READLINK_TESTED=yes
157 READLINK=
158 fi
159 fi
160
161 if test "x$READLINK" != x; then
162 $1=`$READLINK -f [$]$1`
163 else
164 # Save the current directory for restoring afterwards
165 STARTDIR=$PWD
166 COUNTER=0
167 sym_link_dir=`$DIRNAME [$]$1`
168 sym_link_file=`$BASENAME [$]$1`
169 # Use the system pwd and not the shell builtin to resolve directory symlinks
170 cd $sym_link_dir
171 cd `$THEPWDCMD`
172 sym_link_dir=`$THEPWDCMD`
173 # Resolve file symlinks
174 while test $COUNTER -lt 20; do
175 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
176 if test "x$ISLINK" == x; then
177 # This is not a symbolic link! We are done!
178 break
179 fi
180 # Again resolve directory symlinks since the target of the just found
181 # link could be in a different directory
182 cd `$DIRNAME $ISLINK`
183 sym_link_dir=`$THEPWDCMD`
184 sym_link_file=`$BASENAME $ISLINK`
185 let COUNTER=COUNTER+1
186 done
187 cd $STARTDIR
188 $1=$sym_link_dir/$sym_link_file
189 fi
190 fi
191 ])
192
193 AC_DEFUN_ONCE([BASIC_INIT],
194 [
195 # Save the original command line. This is passed to us by the wrapper configure script.
196 AC_SUBST(CONFIGURE_COMMAND_LINE)
197 DATE_WHEN_CONFIGURED=`LANG=C date`
198 AC_SUBST(DATE_WHEN_CONFIGURED)
199 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
200 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
201 ])
202
203 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
204 # $1: variable to check
205 # $2: executable name to print in warning (optional)
206 AC_DEFUN([BASIC_CHECK_NONEMPTY],
207 [
208 if test "x[$]$1" = x; then
209 if test "x$2" = x; then
210 PROG_NAME=translit($1,A-Z,a-z)
211 else
212 PROG_NAME=$2
213 fi
214 AC_MSG_NOTICE([Could not find $PROG_NAME!])
215 AC_MSG_ERROR([Cannot continue])
216 fi
217 ])
218
219 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
220 # Arguments as AC_PATH_PROG:
221 # $1: variable to set
222 # $2: executable name to look for
223 AC_DEFUN([BASIC_REQUIRE_PROG],
224 [
225 AC_PATH_PROGS($1, $2)
226 BASIC_CHECK_NONEMPTY($1, $2)
227 ])
228
229 # Setup the most fundamental tools that relies on not much else to set up,
230 # but is used by much of the early bootstrap code.
231 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
232 [
233
234 # Start with tools that do not need have cross compilation support
235 # and can be expected to be found in the default PATH. These tools are
236 # used by configure. Nor are these tools expected to be found in the
237 # devkit from the builddeps server either, since they are
238 # needed to download the devkit.
239
240 # First are all the simple required tools.
241 BASIC_REQUIRE_PROG(BASENAME, basename)
242 BASIC_REQUIRE_PROG(BASH, bash)
243 BASIC_REQUIRE_PROG(CAT, cat)
244 BASIC_REQUIRE_PROG(CHMOD, chmod)
245 BASIC_REQUIRE_PROG(CMP, cmp)
246 BASIC_REQUIRE_PROG(COMM, comm)
247 BASIC_REQUIRE_PROG(CP, cp)
248 BASIC_REQUIRE_PROG(CPIO, cpio)
249 BASIC_REQUIRE_PROG(CUT, cut)
250 BASIC_REQUIRE_PROG(DATE, date)
251 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
252 BASIC_REQUIRE_PROG(DIRNAME, dirname)
253 BASIC_REQUIRE_PROG(ECHO, echo)
254 BASIC_REQUIRE_PROG(EXPR, expr)
255 BASIC_REQUIRE_PROG(FILE, file)
256 BASIC_REQUIRE_PROG(FIND, find)
257 BASIC_REQUIRE_PROG(HEAD, head)
258 BASIC_REQUIRE_PROG(LN, ln)
259 BASIC_REQUIRE_PROG(LS, ls)
260 BASIC_REQUIRE_PROG(MKDIR, mkdir)
261 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
262 BASIC_REQUIRE_PROG(MV, mv)
263 BASIC_REQUIRE_PROG(PRINTF, printf)
264 BASIC_REQUIRE_PROG(THEPWDCMD, pwd)
265 BASIC_REQUIRE_PROG(RM, rm)
266 BASIC_REQUIRE_PROG(SH, sh)
267 BASIC_REQUIRE_PROG(SORT, sort)
268 BASIC_REQUIRE_PROG(TAIL, tail)
269 BASIC_REQUIRE_PROG(TAR, tar)
270 BASIC_REQUIRE_PROG(TEE, tee)
271 BASIC_REQUIRE_PROG(TOUCH, touch)
272 BASIC_REQUIRE_PROG(TR, tr)
273 BASIC_REQUIRE_PROG(UNAME, uname)
274 BASIC_REQUIRE_PROG(UNIQ, uniq)
275 BASIC_REQUIRE_PROG(WC, wc)
276 BASIC_REQUIRE_PROG(WHICH, which)
277 BASIC_REQUIRE_PROG(XARGS, xargs)
278
279 # Then required tools that require some special treatment.
280 AC_PROG_AWK
281 BASIC_CHECK_NONEMPTY(AWK)
282 AC_PROG_GREP
283 BASIC_CHECK_NONEMPTY(GREP)
284 AC_PROG_EGREP
285 BASIC_CHECK_NONEMPTY(EGREP)
286 AC_PROG_FGREP
287 BASIC_CHECK_NONEMPTY(FGREP)
288 AC_PROG_SED
289 BASIC_CHECK_NONEMPTY(SED)
290
291 AC_PATH_PROGS(NAWK, [nawk gawk awk])
292 BASIC_CHECK_NONEMPTY(NAWK)
293
294 # Always force rm.
295 RM="$RM -f"
296
297 # These are not required on all platforms
298 AC_PATH_PROG(CYGPATH, cygpath)
299 AC_PATH_PROG(READLINK, readlink)
300 AC_PATH_PROG(DF, df)
301 AC_PATH_PROG(SETFILE, SetFile)
302 ])
303
304 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
305 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
306 [
307 # Locate the directory of this script.
308 SCRIPT="[$]0"
309 BASIC_REMOVE_SYMBOLIC_LINKS(SCRIPT)
310 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD`
311
312 # Where is the source? It is located two levels above the configure script.
313 CURDIR="$PWD"
314 cd "$AUTOCONF_DIR/../.."
315 SRC_ROOT="`$THEPWDCMD -L`"
316
317 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
318 PATH_SEP=";"
319 BASIC_CHECK_PATHS_WINDOWS
320 else
321 PATH_SEP=":"
322 fi
323
324 AC_SUBST(SRC_ROOT)
325 AC_SUBST(PATH_SEP)
326 cd "$CURDIR"
327
328 BASIC_FIXUP_PATH(SRC_ROOT)
329 BASIC_FIXUP_PATH(CURDIR)
330
331 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
332 # Add extra search paths on solaris for utilities like ar and as etc...
333 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
334 fi
335
336 # You can force the sys-root if the sys-root encoded into the cross compiler tools
337 # is not correct.
338 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
339 [pass this sys-root to the compilers and tools (for cross-compiling)])])
340
341 if test "x$with_sys_root" != x; then
342 SYS_ROOT=$with_sys_root
343 else
344 SYS_ROOT=/
345 fi
346 AC_SUBST(SYS_ROOT)
347
348 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
349 [search this directory for compilers and tools (for cross-compiling)])], [TOOLS_DIR=$with_tools_dir])
350
351 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
352 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
353 [
354 if test "x$with_sys_root" != x; then
355 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
356 fi
357 if test "x$with_tools_dir" != x; then
358 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-tools-dir at the same time])
359 fi
360 TOOLS_DIR=$with_devkit/bin
361 SYS_ROOT=$with_devkit/$host_alias/libc
362 ])
363
364 ])
365
366 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
367 [
368
369 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
370 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
371 [ CONF_NAME=${with_conf_name} ])
372
373 # Test from where we are running configure, in or outside of src root.
374 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
375 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
376 || test "x$CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
377 # We are running configure from the src root.
378 # Create a default ./build/target-variant-debuglevel output root.
379 if test "x${CONF_NAME}" = x; then
380 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
381 fi
382 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
383 $MKDIR -p "$OUTPUT_ROOT"
384 if test ! -d "$OUTPUT_ROOT"; then
385 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
386 fi
387 else
388 # We are running configure from outside of the src dir.
389 # Then use the current directory as output dir!
390 # If configuration is situated in normal build directory, just use the build
391 # directory name as configuration name, otherwise use the complete path.
392 if test "x${CONF_NAME}" = x; then
393 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
394 fi
395 OUTPUT_ROOT="$CURDIR"
396
397 # WARNING: This might be a bad thing to do. You need to be sure you want to
398 # have a configuration in this directory. Do some sanity checks!
399
400 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
401 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
402 # other files
403 files_present=`$LS $OUTPUT_ROOT`
404 # Configure has already touched config.log and confdefs.h in the current dir when this check
405 # is performed.
406 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
407 | $TR -d '\n'`
408 if test "x$filtered_files" != x; then
409 AC_MSG_NOTICE([Current directory is $CURDIR.])
410 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
411 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
412 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
413 AC_MSG_NOTICE([seriously mess up just about everything.])
414 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
415 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
416 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
417 fi
418 fi
419 fi
420 AC_MSG_CHECKING([what configuration name to use])
421 AC_MSG_RESULT([$CONF_NAME])
422
423 BASIC_FIXUP_PATH(OUTPUT_ROOT)
424
425 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
426 AC_SUBST(CONF_NAME, $CONF_NAME)
427 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
428
429 # Most of the probed defines are put into config.h
430 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
431 # The spec.gmk file contains all variables for the make system.
432 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
433 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
434 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
435 # The bootcycle-spec.gmk file contains support for boot cycle builds.
436 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
437 # The compare.sh is used to compare the build output to other builds.
438 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
439 # Spec.sh is currently used by compare-objects.sh
440 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
441 # The generated Makefile knows where the spec.gmk is and where the source is.
442 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
443 # which will look for generated configurations
444 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
445
446 # Save the arguments given to us
447 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
448 ])
449
450 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
451 [
452 # Setup default logging of stdout and stderr to build.log in the output root.
453 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
454 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
455 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
456 AC_SUBST(BUILD_LOG)
457 AC_SUBST(BUILD_LOG_PREVIOUS)
458 AC_SUBST(BUILD_LOG_WRAPPER)
459 ])
460
461
462 #%%% Simple tools %%%
463
464 # Check if we have found a usable version of make
465 # $1: the path to a potential make binary (or empty)
466 # $2: the description on how we found this
467 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
468 [
469 MAKE_CANDIDATE="$1"
470 DESCRIPTION="$2"
471 if test "x$MAKE_CANDIDATE" != x; then
472 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
473 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
474 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
475 if test "x$IS_GNU_MAKE" = x; then
476 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
477 else
478 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
479 if test "x$IS_MODERN_MAKE" = x; then
480 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
481 else
482 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
483 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
484 MAKE_EXPECTED_ENV='cygwin'
485 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
486 MAKE_EXPECTED_ENV='msys'
487 else
488 AC_MSG_ERROR([Unknown Windows environment])
489 fi
490 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
491 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
492 else
493 # Not relevant for non-Windows
494 IS_MAKE_CORRECT_ENV=true
495 fi
496 if test "x$IS_MAKE_CORRECT_ENV" = x; then
497 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
498 else
499 FOUND_MAKE=$MAKE_CANDIDATE
500 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
501 fi
502 fi
503 fi
504 fi
505 ])
506
507 # Goes looking for a usable version of GNU make.
508 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
509 [
510 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
511 if test "x$MAKE" != x; then
512 # User has supplied a make, test it.
513 if test ! -f "$MAKE"; then
514 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
515 fi
516 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
517 if test "x$FOUND_MAKE" = x; then
518 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
519 fi
520 else
521 # Try our hardest to locate a correct version of GNU make
522 AC_PATH_PROGS(CHECK_GMAKE, gmake)
523 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
524
525 if test "x$FOUND_MAKE" = x; then
526 AC_PATH_PROGS(CHECK_MAKE, make)
527 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
528 fi
529
530 if test "x$FOUND_MAKE" = x; then
531 if test "x$TOOLS_DIR" != x; then
532 # We have a tools-dir, check that as well before giving up.
533 OLD_PATH=$PATH
534 PATH=$TOOLS_DIR:$PATH
535 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
536 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
537 if test "x$FOUND_MAKE" = x; then
538 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
539 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
540 fi
541 PATH=$OLD_PATH
542 fi
543 fi
544
545 if test "x$FOUND_MAKE" = x; then
546 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
547 fi
548 fi
549
550 MAKE=$FOUND_MAKE
551 AC_SUBST(MAKE)
552 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
553 ])
554
555 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
556 [
557 # Test if find supports -delete
558 AC_MSG_CHECKING([if find supports -delete])
559 FIND_DELETE="-delete"
560
561 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
562
563 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
564
565 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
566 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
567 # No, it does not.
568 rm $DELETEDIR/TestIfFindSupportsDelete
569 FIND_DELETE="-exec rm \{\} \+"
570 AC_MSG_RESULT([no])
571 else
572 AC_MSG_RESULT([yes])
573 fi
574 rmdir $DELETEDIR
575 AC_SUBST(FIND_DELETE)
576 ])
577
578 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
579 [
580 BASIC_CHECK_GNU_MAKE
581
582 BASIC_CHECK_FIND_DELETE
583
584 # These tools might not be installed by default,
585 # need hint on how to install them.
586 BASIC_REQUIRE_PROG(UNZIP, unzip)
587 BASIC_REQUIRE_PROG(ZIP, zip)
588
589 # Non-required basic tools
590
591 AC_PATH_PROG(LDD, ldd)
592 if test "x$LDD" = "x"; then
593 # List shared lib dependencies is used for
594 # debug output and checking for forbidden dependencies.
595 # We can build without it.
596 LDD="true"
597 fi
598 AC_PATH_PROG(OTOOL, otool)
599 if test "x$OTOOL" = "x"; then
600 OTOOL="true"
601 fi
602 AC_PATH_PROGS(READELF, [readelf greadelf])
603 AC_PATH_PROG(HG, hg)
604 AC_PATH_PROG(STAT, stat)
605 AC_PATH_PROG(TIME, time)
606
607 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
608 BASIC_REQUIRE_PROG(COMM, comm)
609 fi
610
611 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
612 BASIC_REQUIRE_PROG(XATTR, xattr)
613 fi
614 ])
615
616 # Check if build directory is on local disk. If not possible to determine,
617 # we prefer to claim it's local.
618 # Argument 1: directory to test
619 # Argument 2: what to do if it is on local disk
620 # Argument 3: what to do otherwise (remote disk or failure)
621 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
622 [
623 # df -l lists only local disks; if the given directory is not found then
624 # a non-zero exit code is given
625 if test "x$DF" = x; then
626 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
627 # msys does not have df; use Windows "net use" instead.
628 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
629 if test "x$IS_NETWORK_DISK" = x; then
630 $2
631 else
632 $3
633 fi
634 else
635 # No df here, say it's local
636 $2
637 fi
638 else
639 if $DF -l $1 > /dev/null 2>&1; then
640 $2
641 else
642 $3
643 fi
644 fi
645 ])
646
647 # Check that source files have basic read permissions set. This might
648 # not be the case in cygwin in certain conditions.
649 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
650 [
651 if test x"$OPENJDK_BUILD_OS" = xwindows; then
652 file_to_test="$SRC_ROOT/LICENSE"
653 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
654 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
655 fi
656 fi
657 ])
658
659 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
660 [
661
662 AC_MSG_CHECKING([if build directory is on local disk])
663 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
664 [OUTPUT_DIR_IS_LOCAL="yes"],
665 [OUTPUT_DIR_IS_LOCAL="no"])
666 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
667
668 BASIC_CHECK_SRC_PERMS
669
670 # Check if the user has any old-style ALT_ variables set.
671 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
672
673 # Before generating output files, test if they exist. If they do, this is a reconfigure.
674 # Since we can't properly handle the dependencies for this, warn the user about the situation
675 if test -e $OUTPUT_ROOT/spec.gmk; then
676 IS_RECONFIGURE=yes
677 else
678 IS_RECONFIGURE=no
679 fi
680
681 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
682 HIDE_PERFORMANCE_HINTS=yes
683 else
684 HIDE_PERFORMANCE_HINTS=no
685 # Hide it the next time around...
686 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
687 fi
688
689 ])