1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN([ADD_JVM_ARG_IF_OK],
27 [
28 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
29 # If so, then append $1 to $2
30 FOUND_WARN=`$3 $1 -version 2>&1 | grep -i warn`
31 FOUND_VERSION=`$3 $1 -version 2>&1 | grep " version \""`
32 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
33 $2="[$]$2 $1"
34 fi
35 ])
36
37 # This will make sure the given variable points to a full and proper
38 # path. This means:
39 # 1) There will be no spaces in the path. On posix platforms,
40 # spaces in the path will result in an error. On Windows,
41 # the path will be rewritten using short-style to be space-free.
42 # 2) The path will be absolute, and it will be in unix-style (on
43 # cygwin).
44 # $1: The name of the variable to fix
45 AC_DEFUN([BASIC_FIXUP_PATH],
46 [
47 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
48 BASIC_FIXUP_PATH_CYGWIN($1)
49 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
50 BASIC_FIXUP_PATH_MSYS($1)
51 else
52 # We're on a posix platform. Hooray! :)
53 path="[$]$1"
54
55 if test ! -f "$path" && test ! -d "$path"; then
56 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
57 fi
58
59 has_space=`$ECHO "$path" | $GREP " "`
60 if test "x$has_space" != x; then
61 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
62 AC_MSG_ERROR([Spaces are not allowed in this path.])
63 fi
64 fi
65 ])
66
67 # This will make sure the given variable points to a executable
68 # with a full and proper path. This means:
69 # 1) There will be no spaces in the path. On posix platforms,
70 # spaces in the path will result in an error. On Windows,
71 # the path will be rewritten using short-style to be space-free.
72 # 2) The path will be absolute, and it will be in unix-style (on
73 # cygwin).
74 # Any arguments given to the executable is preserved.
75 # If the input variable does not have a directory specification, then
76 # it need to be in the PATH.
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
79 [
80 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
81 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
82 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
83 BASIC_FIXUP_EXECUTABLE_MSYS($1)
84 else
85 # We're on a posix platform. Hooray! :)
86 # First separate the path from the arguments. This will split at the first
87 # space.
88 complete="[$]$1"
89 path="${complete%% *}"
90 tmp="$complete EOL"
91 arguments="${tmp#* }"
92
93 # Cannot rely on the command "which" here since it doesn't always work.
94 is_absolute_path=`$ECHO "$path" | $GREP ^/`
95 if test -z "$is_absolute_path"; then
96 # Path to executable is not absolute. Find it.
97 IFS_save="$IFS"
98 IFS=:
99 for p in $PATH; do
100 if test -f "$p/$path" && test -x "$p/$path"; then
101 new_path="$p/$path"
102 break
103 fi
104 done
105 IFS="$IFS_save"
106 else
107 AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
108 new_path="$path"
109 fi
110
111 if test "x$new_path" = x; then
112 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
113 has_space=`$ECHO "$complete" | $GREP " "`
114 if test "x$has_space" != x; then
115 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
116 fi
117 AC_MSG_ERROR([Cannot locate the the path of $1])
118 fi
119 fi
120
121 # Now join together the path and the arguments once again
122 if test "x$arguments" != xEOL; then
123 new_complete="$new_path ${arguments% *}"
124 else
125 new_complete="$new_path"
126 fi
127
128 if test "x$complete" != "x$new_complete"; then
129 $1="$new_complete"
130 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
131 fi
132 ])
133
134 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
135 [
136 if test "x$OPENJDK_BUILD_OS" != xwindows; then
137 # Follow a chain of symbolic links. Use readlink
138 # where it exists, else fall back to horribly
139 # complicated shell code.
140 if test "x$READLINK_TESTED" != yes; then
141 # On MacOSX there is a readlink tool with a different
142 # purpose than the GNU readlink tool. Check the found readlink.
143 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
144 if test "x$ISGNU" = x; then
145 # A readlink that we do not know how to use.
146 # Are there other non-GNU readlinks out there?
147 READLINK_TESTED=yes
148 READLINK=
149 fi
150 fi
151
152 if test "x$READLINK" != x; then
153 $1=`$READLINK -f [$]$1`
154 else
155 # Save the current directory for restoring afterwards
156 STARTDIR=$PWD
157 COUNTER=0
158 sym_link_dir=`$DIRNAME [$]$1`
159 sym_link_file=`$BASENAME [$]$1`
160 # Use the system pwd and not the shell builtin to resolve directory symlinks
161 cd $sym_link_dir
162 cd `$THEPWDCMD`
163 sym_link_dir=`$THEPWDCMD`
164 # Resolve file symlinks
165 while test $COUNTER -lt 20; do
166 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
167 if test "x$ISLINK" == x; then
168 # This is not a symbolic link! We are done!
169 break
170 fi
171 # Again resolve directory symlinks since the target of the just found
172 # link could be in a different directory
173 cd `$DIRNAME $ISLINK`
174 sym_link_dir=`$THEPWDCMD`
175 sym_link_file=`$BASENAME $ISLINK`
176 let COUNTER=COUNTER+1
177 done
178 cd $STARTDIR
179 $1=$sym_link_dir/$sym_link_file
180 fi
181 fi
182 ])
183
184 AC_DEFUN_ONCE([BASIC_INIT],
185 [
186 # Save the original command line. This is passed to us by the wrapper configure script.
187 AC_SUBST(CONFIGURE_COMMAND_LINE)
188 DATE_WHEN_CONFIGURED=`LANG=C date`
189 AC_SUBST(DATE_WHEN_CONFIGURED)
190 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
191 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
192 ])
193
194 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
195 # $1: variable to check
196 # $2: executable name to print in warning (optional)
197 AC_DEFUN([BASIC_CHECK_NONEMPTY],
198 [
199 if test "x[$]$1" = x; then
200 if test "x$2" = x; then
201 PROG_NAME=translit($1,A-Z,a-z)
202 else
203 PROG_NAME=$2
204 fi
205 AC_MSG_NOTICE([Could not find $PROG_NAME!])
206 AC_MSG_ERROR([Cannot continue])
207 fi
208 ])
209
210 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
211 # Arguments as AC_PATH_PROG:
212 # $1: variable to set
213 # $2: executable name to look for
214 AC_DEFUN([BASIC_REQUIRE_PROG],
215 [
216 AC_PATH_PROGS($1, $2)
217 BASIC_CHECK_NONEMPTY($1, $2)
218 ])
219
220 # Setup the most fundamental tools that relies on not much else to set up,
221 # but is used by much of the early bootstrap code.
222 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
223 [
224
225 # Start with tools that do not need have cross compilation support
226 # and can be expected to be found in the default PATH. These tools are
227 # used by configure. Nor are these tools expected to be found in the
228 # devkit from the builddeps server either, since they are
229 # needed to download the devkit.
230
231 # First are all the simple required tools.
232 BASIC_REQUIRE_PROG(BASENAME, basename)
233 BASIC_REQUIRE_PROG(BASH, bash)
234 BASIC_REQUIRE_PROG(CAT, cat)
235 BASIC_REQUIRE_PROG(CHMOD, chmod)
236 BASIC_REQUIRE_PROG(CMP, cmp)
237 BASIC_REQUIRE_PROG(COMM, comm)
238 BASIC_REQUIRE_PROG(CP, cp)
239 BASIC_REQUIRE_PROG(CPIO, cpio)
240 BASIC_REQUIRE_PROG(CUT, cut)
241 BASIC_REQUIRE_PROG(DATE, date)
242 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
243 BASIC_REQUIRE_PROG(DIRNAME, dirname)
244 BASIC_REQUIRE_PROG(ECHO, echo)
245 BASIC_REQUIRE_PROG(EXPR, expr)
246 BASIC_REQUIRE_PROG(FILE, file)
247 BASIC_REQUIRE_PROG(FIND, find)
248 BASIC_REQUIRE_PROG(HEAD, head)
249 BASIC_REQUIRE_PROG(LN, ln)
250 BASIC_REQUIRE_PROG(LS, ls)
251 BASIC_REQUIRE_PROG(MKDIR, mkdir)
252 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
253 BASIC_REQUIRE_PROG(MV, mv)
254 BASIC_REQUIRE_PROG(PRINTF, printf)
255 BASIC_REQUIRE_PROG(THEPWDCMD, pwd)
256 BASIC_REQUIRE_PROG(RM, rm)
257 BASIC_REQUIRE_PROG(SH, sh)
258 BASIC_REQUIRE_PROG(SORT, sort)
259 BASIC_REQUIRE_PROG(TAIL, tail)
260 BASIC_REQUIRE_PROG(TAR, tar)
261 BASIC_REQUIRE_PROG(TEE, tee)
262 BASIC_REQUIRE_PROG(TOUCH, touch)
263 BASIC_REQUIRE_PROG(TR, tr)
264 BASIC_REQUIRE_PROG(UNAME, uname)
265 BASIC_REQUIRE_PROG(UNIQ, uniq)
266 BASIC_REQUIRE_PROG(WC, wc)
267 BASIC_REQUIRE_PROG(WHICH, which)
268 BASIC_REQUIRE_PROG(XARGS, xargs)
269
270 # Then required tools that require some special treatment.
271 AC_PROG_AWK
272 BASIC_CHECK_NONEMPTY(AWK)
273 AC_PROG_GREP
274 BASIC_CHECK_NONEMPTY(GREP)
275 AC_PROG_EGREP
276 BASIC_CHECK_NONEMPTY(EGREP)
277 AC_PROG_FGREP
278 BASIC_CHECK_NONEMPTY(FGREP)
279 AC_PROG_SED
280 BASIC_CHECK_NONEMPTY(SED)
281
282 AC_PATH_PROGS(NAWK, [nawk gawk awk])
283 BASIC_CHECK_NONEMPTY(NAWK)
284
285 # Always force rm.
286 RM="$RM -f"
287
288 # These are not required on all platforms
289 AC_PATH_PROG(CYGPATH, cygpath)
290 AC_PATH_PROG(READLINK, readlink)
291 AC_PATH_PROG(DF, df)
292 AC_PATH_PROG(SETFILE, SetFile)
293 ])
294
295 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
296 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
297 [
298 # Locate the directory of this script.
299 SCRIPT="[$]0"
300 BASIC_REMOVE_SYMBOLIC_LINKS(SCRIPT)
301 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD`
302
303 # Where is the source? It is located two levels above the configure script.
304 CURDIR="$PWD"
305 cd "$AUTOCONF_DIR/../.."
306 SRC_ROOT="`$THEPWDCMD`"
307
308 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
309 PATH_SEP=";"
310 BASIC_CHECK_PATHS_WINDOWS
311 else
312 PATH_SEP=":"
313 fi
314
315 AC_SUBST(SRC_ROOT)
316 AC_SUBST(PATH_SEP)
317 cd "$CURDIR"
318
319 BASIC_FIXUP_PATH(SRC_ROOT)
320 BASIC_FIXUP_PATH(CURDIR)
321
322 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
323 # Add extra search paths on solaris for utilities like ar and as etc...
324 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
325 fi
326
327 # You can force the sys-root if the sys-root encoded into the cross compiler tools
328 # is not correct.
329 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
330 [pass this sys-root to the compilers and tools (for cross-compiling)])])
331
332 if test "x$with_sys_root" != x; then
333 SYS_ROOT=$with_sys_root
334 else
335 SYS_ROOT=/
336 fi
337 AC_SUBST(SYS_ROOT)
338
339 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
340 [search this directory for compilers and tools (for cross-compiling)])], [TOOLS_DIR=$with_tools_dir])
341
342 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
343 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
344 [
345 if test "x$with_sys_root" != x; then
346 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
347 fi
348 if test "x$with_tools_dir" != x; then
349 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-tools-dir at the same time])
350 fi
351 TOOLS_DIR=$with_devkit/bin
352 if test -d "$with_devkit/$host_alias/libc"; then
353 SYS_ROOT=$with_devkit/$host_alias/libc
354 elif test -d "$with_devkit/$host/sys-root"; then
355 SYS_ROOT=$with_devkit/$host/sys-root
356 fi
357 ])
358
359 ])
360
361 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
362 [
363
364 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
365 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
366 [ CONF_NAME=${with_conf_name} ])
367
368 # Test from where we are running configure, in or outside of src root.
369 # To enable comparison of directories, CURDIR needs to be symlink free
370 # just like SRC_ROOT already is
371 NOSYM_CURDIR="$CURDIR"
372 BASIC_REMOVE_SYMBOLIC_LINKS(NOSYM_CURDIR)
373 if test "x$NOSYM_CURDIR" = "x$SRC_ROOT" || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common" \
374 || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common/autoconf" \
375 || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
376 # We are running configure from the src root.
377 # Create a default ./build/target-variant-debuglevel output root.
378 if test "x${CONF_NAME}" = x; then
379 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
380 fi
381 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
382 $MKDIR -p "$OUTPUT_ROOT"
383 if test ! -d "$OUTPUT_ROOT"; then
384 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
385 fi
386 else
387 # We are running configure from outside of the src dir.
388 # Then use the current directory as output dir!
389 # If configuration is situated in normal build directory, just use the build
390 # directory name as configuration name, otherwise use the complete path.
391 if test "x${CONF_NAME}" = x; then
392 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
393 fi
394 OUTPUT_ROOT="$CURDIR"
395
396 # WARNING: This might be a bad thing to do. You need to be sure you want to
397 # have a configuration in this directory. Do some sanity checks!
398
399 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
400 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
401 # other files
402 files_present=`$LS $OUTPUT_ROOT`
403 # Configure has already touched config.log and confdefs.h in the current dir when this check
404 # is performed.
405 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
406 | $TR -d '\n'`
407 if test "x$filtered_files" != x; then
408 AC_MSG_NOTICE([Current directory is $CURDIR.])
409 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
410 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
411 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
412 AC_MSG_NOTICE([seriously mess up just about everything.])
413 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
414 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
415 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
416 fi
417 fi
418 fi
419 AC_MSG_CHECKING([what configuration name to use])
420 AC_MSG_RESULT([$CONF_NAME])
421
422 BASIC_FIXUP_PATH(OUTPUT_ROOT)
423
424 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
425 AC_SUBST(CONF_NAME, $CONF_NAME)
426 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
427
428 # Most of the probed defines are put into config.h
429 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
430 # The spec.gmk file contains all variables for the make system.
431 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
432 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
433 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
434 # The bootcycle-spec.gmk file contains support for boot cycle builds.
435 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
436 # The compare.sh is used to compare the build output to other builds.
437 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
438 # Spec.sh is currently used by compare-objects.sh
439 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
440 # The generated Makefile knows where the spec.gmk is and where the source is.
441 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
442 # which will look for generated configurations
443 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
444
445 # Save the arguments given to us
446 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
447 ])
448
449 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
450 [
451 # Setup default logging of stdout and stderr to build.log in the output root.
452 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
453 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
454 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
455 AC_SUBST(BUILD_LOG)
456 AC_SUBST(BUILD_LOG_PREVIOUS)
457 AC_SUBST(BUILD_LOG_WRAPPER)
458 ])
459
460
461 #%%% Simple tools %%%
462
463 # Check if we have found a usable version of make
464 # $1: the path to a potential make binary (or empty)
465 # $2: the description on how we found this
466 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
467 [
468 MAKE_CANDIDATE="$1"
469 DESCRIPTION="$2"
470 if test "x$MAKE_CANDIDATE" != x; then
471 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
472 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
473 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
474 if test "x$IS_GNU_MAKE" = x; then
475 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
476 else
477 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
478 if test "x$IS_MODERN_MAKE" = x; then
479 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
480 else
481 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
482 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
483 MAKE_EXPECTED_ENV='cygwin'
484 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
485 MAKE_EXPECTED_ENV='msys'
486 else
487 AC_MSG_ERROR([Unknown Windows environment])
488 fi
489 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
490 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
491 else
492 # Not relevant for non-Windows
493 IS_MAKE_CORRECT_ENV=true
494 fi
495 if test "x$IS_MAKE_CORRECT_ENV" = x; then
496 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
497 else
498 FOUND_MAKE=$MAKE_CANDIDATE
499 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
500 fi
501 fi
502 fi
503 fi
504 ])
505
506 # Goes looking for a usable version of GNU make.
507 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
508 [
509 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
510 if test "x$MAKE" != x; then
511 # User has supplied a make, test it.
512 if test ! -f "$MAKE"; then
513 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
514 fi
515 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
516 if test "x$FOUND_MAKE" = x; then
517 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
518 fi
519 else
520 # Try our hardest to locate a correct version of GNU make
521 AC_PATH_PROGS(CHECK_GMAKE, gmake)
522 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
523
524 if test "x$FOUND_MAKE" = x; then
525 AC_PATH_PROGS(CHECK_MAKE, make)
526 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
527 fi
528
529 if test "x$FOUND_MAKE" = x; then
530 if test "x$TOOLS_DIR" != x; then
531 # We have a tools-dir, check that as well before giving up.
532 OLD_PATH=$PATH
533 PATH=$TOOLS_DIR:$PATH
534 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
535 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
536 if test "x$FOUND_MAKE" = x; then
537 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
538 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
539 fi
540 PATH=$OLD_PATH
541 fi
542 fi
543
544 if test "x$FOUND_MAKE" = x; then
545 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
546 fi
547 fi
548
549 MAKE=$FOUND_MAKE
550 AC_SUBST(MAKE)
551 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
552 ])
553
554 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
555 [
556 # Test if find supports -delete
557 AC_MSG_CHECKING([if find supports -delete])
558 FIND_DELETE="-delete"
559
560 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
561
562 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
563
564 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
565 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
566 # No, it does not.
567 rm $DELETEDIR/TestIfFindSupportsDelete
568 FIND_DELETE="-exec rm \{\} \+"
569 AC_MSG_RESULT([no])
570 else
571 AC_MSG_RESULT([yes])
572 fi
573 rmdir $DELETEDIR
574 AC_SUBST(FIND_DELETE)
575 ])
576
577 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
578 [
579 BASIC_CHECK_GNU_MAKE
580
581 BASIC_CHECK_FIND_DELETE
582
583 # These tools might not be installed by default,
584 # need hint on how to install them.
585 BASIC_REQUIRE_PROG(UNZIP, unzip)
586 BASIC_REQUIRE_PROG(ZIP, zip)
587
588 # Non-required basic tools
589
590 AC_PATH_PROG(LDD, ldd)
591 if test "x$LDD" = "x"; then
592 # List shared lib dependencies is used for
593 # debug output and checking for forbidden dependencies.
594 # We can build without it.
595 LDD="true"
596 fi
597 AC_PATH_PROG(OTOOL, otool)
598 if test "x$OTOOL" = "x"; then
599 OTOOL="true"
600 fi
601 AC_PATH_PROGS(READELF, [readelf greadelf])
602 AC_PATH_PROG(HG, hg)
603 AC_PATH_PROG(STAT, stat)
604 AC_PATH_PROG(TIME, time)
605
606 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
607 BASIC_REQUIRE_PROG(COMM, comm)
608 fi
609
610 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
611 BASIC_REQUIRE_PROG(XATTR, xattr)
612 fi
613 ])
614
615 # Check if build directory is on local disk. If not possible to determine,
616 # we prefer to claim it's local.
617 # Argument 1: directory to test
618 # Argument 2: what to do if it is on local disk
619 # Argument 3: what to do otherwise (remote disk or failure)
620 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
621 [
622 # df -l lists only local disks; if the given directory is not found then
623 # a non-zero exit code is given
624 if test "x$DF" = x; then
625 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
626 # msys does not have df; use Windows "net use" instead.
627 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
628 if test "x$IS_NETWORK_DISK" = x; then
629 $2
630 else
631 $3
632 fi
633 else
634 # No df here, say it's local
635 $2
636 fi
637 else
638 if $DF -l $1 > /dev/null 2>&1; then
639 $2
640 else
641 $3
642 fi
643 fi
644 ])
645
646 # Check that source files have basic read permissions set. This might
647 # not be the case in cygwin in certain conditions.
648 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
649 [
650 if test x"$OPENJDK_BUILD_OS" = xwindows; then
651 file_to_test="$SRC_ROOT/LICENSE"
652 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
653 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
654 fi
655 fi
656 ])
657
658 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
659 [
660
661 AC_MSG_CHECKING([if build directory is on local disk])
662 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
663 [OUTPUT_DIR_IS_LOCAL="yes"],
664 [OUTPUT_DIR_IS_LOCAL="no"])
665 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
666
667 BASIC_CHECK_SRC_PERMS
668
669 # Check if the user has any old-style ALT_ variables set.
670 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
671
672 # Before generating output files, test if they exist. If they do, this is a reconfigure.
673 # Since we can't properly handle the dependencies for this, warn the user about the situation
674 if test -e $OUTPUT_ROOT/spec.gmk; then
675 IS_RECONFIGURE=yes
676 else
677 IS_RECONFIGURE=no
678 fi
679
680 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
681 HIDE_PERFORMANCE_HINTS=yes
682 else
683 HIDE_PERFORMANCE_HINTS=no
684 # Hide it the next time around...
685 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
686 fi
687
688 ])