1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x$2" != x; then
50 if test "x[$]$1" = x; then
51 $1="$2"
52 else
53 $1="[$]$1:$2"
54 fi
55 fi
56 ])
57
58 # Appends a string to a path variable, only adding the : when needed.
59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
60 [
61 if test "x$2" != x; then
62 if test "x[$]$1" = x; then
63 $1="$2"
64 else
65 $1="$2:[$]$1"
66 fi
67 fi
68 ])
69
70 # This will make sure the given variable points to a full and proper
71 # path. This means:
72 # 1) There will be no spaces in the path. On posix platforms,
73 # spaces in the path will result in an error. On Windows,
74 # the path will be rewritten using short-style to be space-free.
75 # 2) The path will be absolute, and it will be in unix-style (on
76 # cygwin).
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_PATH],
79 [
80 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
81 BASIC_FIXUP_PATH_CYGWIN($1)
82 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
83 BASIC_FIXUP_PATH_MSYS($1)
84 else
85 # We're on a posix platform. Hooray! :)
86 path="[$]$1"
87 has_space=`$ECHO "$path" | $GREP " "`
88 if test "x$has_space" != x; then
89 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
90 AC_MSG_ERROR([Spaces are not allowed in this path.])
91 fi
92
93 # Use eval to expand a potential ~
94 eval path="$path"
95 if test ! -f "$path" && test ! -d "$path"; then
96 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
97 fi
98
99 $1="`cd "$path"; $THEPWDCMD -L`"
100 fi
101 ])
102
103 # This will make sure the given variable points to a executable
104 # with a full and proper path. This means:
105 # 1) There will be no spaces in the path. On posix platforms,
106 # spaces in the path will result in an error. On Windows,
107 # the path will be rewritten using short-style to be space-free.
108 # 2) The path will be absolute, and it will be in unix-style (on
109 # cygwin).
110 # Any arguments given to the executable is preserved.
111 # If the input variable does not have a directory specification, then
112 # it need to be in the PATH.
113 # $1: The name of the variable to fix
114 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
115 [
116 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
117 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
118 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
119 BASIC_FIXUP_EXECUTABLE_MSYS($1)
120 else
121 # We're on a posix platform. Hooray! :)
122 # First separate the path from the arguments. This will split at the first
123 # space.
124 complete="[$]$1"
125 path="${complete%% *}"
126 tmp="$complete EOL"
127 arguments="${tmp#* }"
128
129 # Cannot rely on the command "which" here since it doesn't always work.
130 is_absolute_path=`$ECHO "$path" | $GREP ^/`
131 if test -z "$is_absolute_path"; then
132 # Path to executable is not absolute. Find it.
133 IFS_save="$IFS"
134 IFS=:
135 for p in $PATH; do
136 if test -f "$p/$path" && test -x "$p/$path"; then
137 new_path="$p/$path"
138 break
139 fi
140 done
141 IFS="$IFS_save"
142 else
143 # This is an absolute path, we can use it without further modifications.
144 new_path="$path"
145 fi
146
147 if test "x$new_path" = x; then
148 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
149 has_space=`$ECHO "$complete" | $GREP " "`
150 if test "x$has_space" != x; then
151 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
152 fi
153 AC_MSG_ERROR([Cannot locate the the path of $1])
154 fi
155 fi
156
157 # Now join together the path and the arguments once again
158 if test "x$arguments" != xEOL; then
159 new_complete="$new_path ${arguments% *}"
160 else
161 new_complete="$new_path"
162 fi
163
164 if test "x$complete" != "x$new_complete"; then
165 $1="$new_complete"
166 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
167 fi
168 ])
169
170 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
171 [
172 if test "x$OPENJDK_BUILD_OS" != xwindows; then
173 # Follow a chain of symbolic links. Use readlink
174 # where it exists, else fall back to horribly
175 # complicated shell code.
176 if test "x$READLINK_TESTED" != yes; then
177 # On MacOSX there is a readlink tool with a different
178 # purpose than the GNU readlink tool. Check the found readlink.
179 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
180 if test "x$ISGNU" = x; then
181 # A readlink that we do not know how to use.
182 # Are there other non-GNU readlinks out there?
183 READLINK_TESTED=yes
184 READLINK=
185 fi
186 fi
187
188 if test "x$READLINK" != x; then
189 $1=`$READLINK -f [$]$1`
190 else
191 # Save the current directory for restoring afterwards
192 STARTDIR=$PWD
193 COUNTER=0
194 sym_link_dir=`$DIRNAME [$]$1`
195 sym_link_file=`$BASENAME [$]$1`
196 cd $sym_link_dir
197 # Use -P flag to resolve symlinks in directories.
198 cd `$THEPWDCMD -P`
199 sym_link_dir=`$THEPWDCMD -P`
200 # Resolve file symlinks
201 while test $COUNTER -lt 20; do
202 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
203 if test "x$ISLINK" == x; then
204 # This is not a symbolic link! We are done!
205 break
206 fi
207 # Again resolve directory symlinks since the target of the just found
208 # link could be in a different directory
209 cd `$DIRNAME $ISLINK`
210 sym_link_dir=`$THEPWDCMD -P`
211 sym_link_file=`$BASENAME $ISLINK`
212 let COUNTER=COUNTER+1
213 done
214 cd $STARTDIR
215 $1=$sym_link_dir/$sym_link_file
216 fi
217 fi
218 ])
219
220 # Register a --with argument but mark it as deprecated
221 # $1: The name of the with argument to deprecate, not including --with-
222 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
223 [
224 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
225 [Deprecated. Option is kept for backwards compatibility and is ignored])],
226 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
227 ])
228
229 # Register a --enable argument but mark it as deprecated
230 # $1: The name of the with argument to deprecate, not including --enable-
231 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
232 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
233 [
234 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
235 [Deprecated. Option is kept for backwards compatibility and is ignored])])
236 if test "x$enable_$2" != x; then
237 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
238 fi
239 ])
240
241 AC_DEFUN_ONCE([BASIC_INIT],
242 [
243 # Save the original command line. This is passed to us by the wrapper configure script.
244 AC_SUBST(CONFIGURE_COMMAND_LINE)
245 DATE_WHEN_CONFIGURED=`LANG=C date`
246 AC_SUBST(DATE_WHEN_CONFIGURED)
247 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
248 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
249 ])
250
251 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
252 # $1: variable to check
253 AC_DEFUN([BASIC_CHECK_NONEMPTY],
254 [
255 if test "x[$]$1" = x; then
256 AC_MSG_ERROR([Could not find required tool for $1])
257 fi
258 ])
259
260 # Check that there are no unprocessed overridden variables left.
261 # If so, they are an incorrect argument and we will exit with an error.
262 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
263 [
264 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
265 # Replace the separating ! with spaces before presenting for end user.
266 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
267 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
268 fi
269 ])
270
271 # Setup a tool for the given variable. If correctly specified by the user,
272 # use that value, otherwise search for the tool using the supplied code snippet.
273 # $1: variable to set
274 # $2: code snippet to call to look for the tool
275 AC_DEFUN([BASIC_SETUP_TOOL],
276 [
277 # Publish this variable in the help.
278 AC_ARG_VAR($1, [Override default value for $1])
279
280 if test "x[$]$1" = x; then
281 # The variable is not set by user, try to locate tool using the code snippet
282 $2
283 else
284 # The variable is set, but is it from the command line or the environment?
285
286 # Try to remove the string !$1! from our list.
287 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
288 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
289 # If it failed, the variable was not from the command line. Ignore it,
290 # but warn the user (except for BASH, which is always set by the calling BASH).
291 if test "x$1" != xBASH; then
292 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
293 fi
294 # Try to locate tool using the code snippet
295 $2
296 else
297 # If it succeeded, then it was overridden by the user. We will use it
298 # for the tool.
299
300 # First remove it from the list of overridden variables, so we can test
301 # for unknown variables in the end.
302 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
303
304 # Check if the provided tool contains a complete path.
305 tool_specified="[$]$1"
306 tool_basename="${tool_specified##*/}"
307 if test "x$tool_basename" = "x$tool_specified"; then
308 # A command without a complete path is provided, search $PATH.
309 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
310 AC_PATH_PROG($1, $tool_basename)
311 if test "x[$]$1" = x; then
312 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
313 fi
314 else
315 # Otherwise we believe it is a complete path. Use it as it is.
316 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
317 AC_MSG_CHECKING([for $1])
318 if test ! -x "$tool_specified"; then
319 AC_MSG_RESULT([not found])
320 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
321 fi
322 AC_MSG_RESULT([$tool_specified])
323 fi
324 fi
325 fi
326 ])
327
328 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
329 # $1: variable to set
330 # $2: executable name (or list of names) to look for
331 AC_DEFUN([BASIC_PATH_PROGS],
332 [
333 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
334 ])
335
336 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
337 # $1: variable to set
338 # $2: executable name (or list of names) to look for
339 AC_DEFUN([BASIC_CHECK_TOOLS],
340 [
341 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
342 ])
343
344 # Like BASIC_PATH_PROGS but fails if no tool was found.
345 # $1: variable to set
346 # $2: executable name (or list of names) to look for
347 AC_DEFUN([BASIC_REQUIRE_PROGS],
348 [
349 BASIC_PATH_PROGS($1, $2)
350 BASIC_CHECK_NONEMPTY($1)
351 ])
352
353 # Like BASIC_SETUP_TOOL but fails if no tool was found.
354 # $1: variable to set
355 # $2: autoconf macro to call to look for the special tool
356 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
357 [
358 BASIC_SETUP_TOOL($1, [$2])
359 BASIC_CHECK_NONEMPTY($1)
360 ])
361
362 # Setup the most fundamental tools that relies on not much else to set up,
363 # but is used by much of the early bootstrap code.
364 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
365 [
366 # Start with tools that do not need have cross compilation support
367 # and can be expected to be found in the default PATH. These tools are
368 # used by configure. Nor are these tools expected to be found in the
369 # devkit from the builddeps server either, since they are
370 # needed to download the devkit.
371
372 # First are all the simple required tools.
373 BASIC_REQUIRE_PROGS(BASENAME, basename)
374 BASIC_REQUIRE_PROGS(BASH, bash)
375 BASIC_REQUIRE_PROGS(CAT, cat)
376 BASIC_REQUIRE_PROGS(CHMOD, chmod)
377 BASIC_REQUIRE_PROGS(CMP, cmp)
378 BASIC_REQUIRE_PROGS(COMM, comm)
379 BASIC_REQUIRE_PROGS(CP, cp)
380 BASIC_REQUIRE_PROGS(CPIO, cpio)
381 BASIC_REQUIRE_PROGS(CUT, cut)
382 BASIC_REQUIRE_PROGS(DATE, date)
383 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
384 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
385 BASIC_REQUIRE_PROGS(ECHO, echo)
386 BASIC_REQUIRE_PROGS(EXPR, expr)
387 BASIC_REQUIRE_PROGS(FILE, file)
388 BASIC_REQUIRE_PROGS(FIND, find)
389 BASIC_REQUIRE_PROGS(HEAD, head)
390 BASIC_REQUIRE_PROGS(LN, ln)
391 BASIC_REQUIRE_PROGS(LS, ls)
392 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
393 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
394 BASIC_REQUIRE_PROGS(MV, mv)
395 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
396 BASIC_REQUIRE_PROGS(PRINTF, printf)
397 BASIC_REQUIRE_PROGS(RM, rm)
398 BASIC_REQUIRE_PROGS(SH, sh)
399 BASIC_REQUIRE_PROGS(SORT, sort)
400 BASIC_REQUIRE_PROGS(TAIL, tail)
401 BASIC_REQUIRE_PROGS(TAR, tar)
402 BASIC_REQUIRE_PROGS(TEE, tee)
403 BASIC_REQUIRE_PROGS(TOUCH, touch)
404 BASIC_REQUIRE_PROGS(TR, tr)
405 BASIC_REQUIRE_PROGS(UNAME, uname)
406 BASIC_REQUIRE_PROGS(UNIQ, uniq)
407 BASIC_REQUIRE_PROGS(WC, wc)
408 BASIC_REQUIRE_PROGS(WHICH, which)
409 BASIC_REQUIRE_PROGS(XARGS, xargs)
410
411 # Then required tools that require some special treatment.
412 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
413 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
414 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
415 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
416 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
417
418 # Always force rm.
419 RM="$RM -f"
420
421 # pwd behaves differently on various platforms and some don't support the -L flag.
422 # Always use the bash builtin pwd to get uniform behavior.
423 THEPWDCMD=pwd
424
425 # These are not required on all platforms
426 BASIC_PATH_PROGS(CYGPATH, cygpath)
427 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
428 BASIC_PATH_PROGS(DF, df)
429 BASIC_PATH_PROGS(SETFILE, SetFile)
430 ])
431
432 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
433 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
434 [
435 # Save the current directory this script was started from
436 CURDIR="$PWD"
437
438 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
439 PATH_SEP=";"
440 BASIC_CHECK_PATHS_WINDOWS
441 else
442 PATH_SEP=":"
443 fi
444 AC_SUBST(PATH_SEP)
445
446 # We get the top-level directory from the supporting wrappers.
447 AC_MSG_CHECKING([for top-level directory])
448 AC_MSG_RESULT([$TOPDIR])
449 AC_SUBST(TOPDIR)
450
451 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
452 BASIC_FIXUP_PATH(CURDIR)
453 BASIC_FIXUP_PATH(TOPDIR)
454 # SRC_ROOT is a traditional alias for TOPDIR.
455 SRC_ROOT=$TOPDIR
456
457 # Locate the directory of this script.
458 AUTOCONF_DIR=$TOPDIR/common/autoconf
459
460 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
461 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
462 [
463 BASIC_FIXUP_PATH([with_devkit])
464 DEVKIT_ROOT="$with_devkit"
465 # Check for a meta data info file in the root of the devkit
466 if test -f "$DEVKIT_ROOT/devkit.info"; then
467 # This potentially sets the following:
468 # DEVKIT_NAME: A descriptive name of the devkit
469 # DEVKIT_TOOLCHAIN_PATH: Corresponds to --with-toolchain-path
470 # DEVKIT_EXTRA_PATH: Corresponds to --with-extra-path
471 # DEVKIT_SYSROOT: Corresponds to --with-sysroot
472 . $DEVKIT_ROOT/devkit.info
473 fi
474
475 AC_MSG_CHECKING([for devkit])
476 if test "x$DEVKIT_NAME" != x; then
477 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
478 else
479 AC_MSG_RESULT([$DEVKIT_ROOT])
480 fi
481
482 if test "x$DEVKIT_EXTRA_PATH" != x; then
483 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
484 fi
485
486 # Fallback default of just /bin if DEVKIT_PATH is not defined
487 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
488 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
489 fi
490 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
491
492 # If a separate sysroot has not been defined, use the one in the devkit
493 if test "x$DEVKIT_SYSROOT" != x; then
494 SYSROOT="$DEVKIT_SYSROOT"
495 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
496 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
497 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
498 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
499 fi
500 ]
501 )
502
503 # You can force the sysroot if the sysroot encoded into the cross compiler tools
504 # is not correct.
505 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
506 [alias for --with-sysroot for backwards compatability])],
507 [SYSROOT=$with_sys_root]
508 )
509
510 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
511 [use this directory as sysroot)])],
512 [SYSROOT=$with_sysroot]
513 )
514
515 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
516 [alias for --with-toolchain-path for backwards compatibility])],
517 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
518 )
519
520 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
521 [prepend these directories when searching for toolchain binaries (compilers etc)])],
522 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
523 )
524
525 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
526 [prepend these directories to the default path])],
527 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
528 )
529
530 # Prepend the extra path to the global path
531 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
532
533 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
534 # Add extra search paths on solaris for utilities like ar and as etc...
535 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
536 fi
537
538 AC_MSG_CHECKING([for sysroot])
539 AC_MSG_RESULT([$SYSROOT])
540 AC_MSG_CHECKING([for toolchain path])
541 AC_MSG_RESULT([$TOOLCHAIN_PATH])
542 AC_MSG_CHECKING([for extra path])
543 AC_MSG_RESULT([$EXTRA_PATH])
544 ])
545
546 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
547 [
548
549 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
550 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
551 [ CONF_NAME=${with_conf_name} ])
552
553 # Test from where we are running configure, in or outside of src root.
554 AC_MSG_CHECKING([where to store configuration])
555 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
556 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
557 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
558 # We are running configure from the src root.
559 # Create a default ./build/target-variant-debuglevel output root.
560 if test "x${CONF_NAME}" = x; then
561 AC_MSG_RESULT([in default location])
562 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
563 else
564 AC_MSG_RESULT([in build directory with custom name])
565 fi
566 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
567 $MKDIR -p "$OUTPUT_ROOT"
568 if test ! -d "$OUTPUT_ROOT"; then
569 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
570 fi
571 else
572 # We are running configure from outside of the src dir.
573 # Then use the current directory as output dir!
574 # If configuration is situated in normal build directory, just use the build
575 # directory name as configuration name, otherwise use the complete path.
576 if test "x${CONF_NAME}" = x; then
577 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
578 fi
579 OUTPUT_ROOT="$CURDIR"
580 AC_MSG_RESULT([in current directory])
581
582 # WARNING: This might be a bad thing to do. You need to be sure you want to
583 # have a configuration in this directory. Do some sanity checks!
584
585 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
586 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
587 # other files
588 files_present=`$LS $OUTPUT_ROOT`
589 # Configure has already touched config.log and confdefs.h in the current dir when this check
590 # is performed.
591 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
592 | $TR -d '\n'`
593 if test "x$filtered_files" != x; then
594 AC_MSG_NOTICE([Current directory is $CURDIR.])
595 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
596 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
597 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
598 AC_MSG_NOTICE([seriously mess up just about everything.])
599 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
600 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
601 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
602 fi
603 fi
604 fi
605 AC_MSG_CHECKING([what configuration name to use])
606 AC_MSG_RESULT([$CONF_NAME])
607
608 BASIC_FIXUP_PATH(OUTPUT_ROOT)
609
610 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
611 AC_SUBST(CONF_NAME, $CONF_NAME)
612 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
613
614 # Most of the probed defines are put into config.h
615 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
616 # The spec.gmk file contains all variables for the make system.
617 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
618 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
619 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
620 # The bootcycle-spec.gmk file contains support for boot cycle builds.
621 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
622 # The compare.sh is used to compare the build output to other builds.
623 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
624 # Spec.sh is currently used by compare-objects.sh
625 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
626 # The generated Makefile knows where the spec.gmk is and where the source is.
627 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
628 # which will look for generated configurations
629 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
630 ])
631
632 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
633 [
634 # Setup default logging of stdout and stderr to build.log in the output root.
635 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
636 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
637 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
638 AC_SUBST(BUILD_LOG)
639 AC_SUBST(BUILD_LOG_PREVIOUS)
640 AC_SUBST(BUILD_LOG_WRAPPER)
641 ])
642
643
644 #%%% Simple tools %%%
645
646 # Check if we have found a usable version of make
647 # $1: the path to a potential make binary (or empty)
648 # $2: the description on how we found this
649 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
650 [
651 MAKE_CANDIDATE="$1"
652 DESCRIPTION="$2"
653 if test "x$MAKE_CANDIDATE" != x; then
654 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
655 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
656 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
657 if test "x$IS_GNU_MAKE" = x; then
658 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
659 else
660 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
661 if test "x$IS_MODERN_MAKE" = x; then
662 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
663 else
664 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
665 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
666 MAKE_EXPECTED_ENV='cygwin'
667 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
668 MAKE_EXPECTED_ENV='msys'
669 else
670 AC_MSG_ERROR([Unknown Windows environment])
671 fi
672 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
673 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
674 else
675 # Not relevant for non-Windows
676 IS_MAKE_CORRECT_ENV=true
677 fi
678 if test "x$IS_MAKE_CORRECT_ENV" = x; then
679 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
680 else
681 FOUND_MAKE=$MAKE_CANDIDATE
682 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
683 fi
684 fi
685 fi
686 fi
687 ])
688
689 # Goes looking for a usable version of GNU make.
690 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
691 [
692 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
693 if test "x$MAKE" != x; then
694 # User has supplied a make, test it.
695 if test ! -f "$MAKE"; then
696 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
697 fi
698 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
699 if test "x$FOUND_MAKE" = x; then
700 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
701 fi
702 else
703 # Try our hardest to locate a correct version of GNU make
704 AC_PATH_PROGS(CHECK_GMAKE, gmake)
705 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
706
707 if test "x$FOUND_MAKE" = x; then
708 AC_PATH_PROGS(CHECK_MAKE, make)
709 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
710 fi
711
712 if test "x$FOUND_MAKE" = x; then
713 if test "x$TOOLCHAIN_PATH" != x; then
714 # We have a toolchain path, check that as well before giving up.
715 OLD_PATH=$PATH
716 PATH=$TOOLCHAIN_PATH:$PATH
717 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
718 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
719 if test "x$FOUND_MAKE" = x; then
720 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
721 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
722 fi
723 PATH=$OLD_PATH
724 fi
725 fi
726
727 if test "x$FOUND_MAKE" = x; then
728 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
729 fi
730 fi
731
732 MAKE=$FOUND_MAKE
733 AC_SUBST(MAKE)
734 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
735 ])
736
737 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
738 [
739 # Test if find supports -delete
740 AC_MSG_CHECKING([if find supports -delete])
741 FIND_DELETE="-delete"
742
743 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
744
745 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
746
747 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
748 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
749 # No, it does not.
750 rm $DELETEDIR/TestIfFindSupportsDelete
751 FIND_DELETE="-exec rm \{\} \+"
752 AC_MSG_RESULT([no])
753 else
754 AC_MSG_RESULT([yes])
755 fi
756 rmdir $DELETEDIR
757 AC_SUBST(FIND_DELETE)
758 ])
759
760 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
761 [
762 BASIC_CHECK_GNU_MAKE
763
764 BASIC_CHECK_FIND_DELETE
765
766 # These tools might not be installed by default,
767 # need hint on how to install them.
768 BASIC_REQUIRE_PROGS(UNZIP, unzip)
769 BASIC_REQUIRE_PROGS(ZIP, zip)
770
771 # Non-required basic tools
772
773 BASIC_PATH_PROGS(LDD, ldd)
774 if test "x$LDD" = "x"; then
775 # List shared lib dependencies is used for
776 # debug output and checking for forbidden dependencies.
777 # We can build without it.
778 LDD="true"
779 fi
780 BASIC_PATH_PROGS(OTOOL, otool)
781 if test "x$OTOOL" = "x"; then
782 OTOOL="true"
783 fi
784 BASIC_PATH_PROGS(READELF, [greadelf readelf])
785 BASIC_PATH_PROGS(HG, hg)
786 BASIC_PATH_PROGS(STAT, stat)
787 BASIC_PATH_PROGS(TIME, time)
788 # Check if it's GNU time
789 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
790 if test "x$IS_GNU_TIME" != x; then
791 IS_GNU_TIME=yes
792 else
793 IS_GNU_TIME=no
794 fi
795 AC_SUBST(IS_GNU_TIME)
796
797 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
798 BASIC_REQUIRE_PROGS(COMM, comm)
799 fi
800
801 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
802 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
803 BASIC_REQUIRE_PROGS(XATTR, xattr)
804 BASIC_PATH_PROGS(CODESIGN, codesign)
805 if test "x$CODESIGN" != "x"; then
806 # Verify that the openjdk_codesign certificate is present
807 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
808 rm -f codesign-testfile
809 touch codesign-testfile
810 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
811 rm -f codesign-testfile
812 if test "x$CODESIGN" = x; then
813 AC_MSG_RESULT([no])
814 else
815 AC_MSG_RESULT([yes])
816 fi
817 fi
818 fi
819 ])
820
821 # Check if build directory is on local disk. If not possible to determine,
822 # we prefer to claim it's local.
823 # Argument 1: directory to test
824 # Argument 2: what to do if it is on local disk
825 # Argument 3: what to do otherwise (remote disk or failure)
826 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
827 [
828 # df -l lists only local disks; if the given directory is not found then
829 # a non-zero exit code is given
830 if test "x$DF" = x; then
831 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
832 # msys does not have df; use Windows "net use" instead.
833 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
834 if test "x$IS_NETWORK_DISK" = x; then
835 $2
836 else
837 $3
838 fi
839 else
840 # No df here, say it's local
841 $2
842 fi
843 else
844 if $DF -l $1 > /dev/null 2>&1; then
845 $2
846 else
847 $3
848 fi
849 fi
850 ])
851
852 # Check that source files have basic read permissions set. This might
853 # not be the case in cygwin in certain conditions.
854 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
855 [
856 if test x"$OPENJDK_BUILD_OS" = xwindows; then
857 file_to_test="$SRC_ROOT/LICENSE"
858 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
859 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
860 fi
861 fi
862 ])
863
864 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
865 [
866 # Did user specify any unknown variables?
867 BASIC_CHECK_LEFTOVER_OVERRIDDEN
868
869 AC_MSG_CHECKING([if build directory is on local disk])
870 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
871 [OUTPUT_DIR_IS_LOCAL="yes"],
872 [OUTPUT_DIR_IS_LOCAL="no"])
873 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
874
875 BASIC_CHECK_SRC_PERMS
876
877 # Check if the user has any old-style ALT_ variables set.
878 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
879
880 # Before generating output files, test if they exist. If they do, this is a reconfigure.
881 # Since we can't properly handle the dependencies for this, warn the user about the situation
882 if test -e $OUTPUT_ROOT/spec.gmk; then
883 IS_RECONFIGURE=yes
884 else
885 IS_RECONFIGURE=no
886 fi
887 ])