1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
34
35
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
38
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
45
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
52
53 # Setup a number of variables describing how native output files are
54 # named on this platform/toolchain.
55 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
56 [
57 # Define filename patterns
58 if test "x$OPENJDK_TARGET_OS" = xwindows; then
59 LIBRARY_PREFIX=
60 SHARED_LIBRARY_SUFFIX='.dll'
61 STATIC_LIBRARY_SUFFIX='.lib'
62 SHARED_LIBRARY='[$]1.dll'
63 STATIC_LIBRARY='[$]1.lib'
64 OBJ_SUFFIX='.obj'
65 EXE_SUFFIX='.exe'
66 else
67 LIBRARY_PREFIX=lib
68 SHARED_LIBRARY_SUFFIX='.so'
69 STATIC_LIBRARY_SUFFIX='.a'
70 SHARED_LIBRARY='lib[$]1.so'
71 STATIC_LIBRARY='lib[$]1.a'
72 OBJ_SUFFIX='.o'
73 EXE_SUFFIX=''
74 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
75 SHARED_LIBRARY='lib[$]1.dylib'
76 SHARED_LIBRARY_SUFFIX='.dylib'
77 fi
78 fi
79
80 AC_SUBST(LIBRARY_PREFIX)
81 AC_SUBST(SHARED_LIBRARY_SUFFIX)
82 AC_SUBST(STATIC_LIBRARY_SUFFIX)
83 AC_SUBST(SHARED_LIBRARY)
84 AC_SUBST(STATIC_LIBRARY)
85 AC_SUBST(OBJ_SUFFIX)
86 AC_SUBST(EXE_SUFFIX)
87 ])
88
89 # Determine which toolchain type to use, and make sure it is valid for this
90 # platform. Setup various information about the selected toolchain.
91 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
92 [
93 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
94 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
95
96 # Use indirect variable referencing
97 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
98 VALID_TOOLCHAINS=${!toolchain_var_name}
99
100 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
101 # On Mac OS X, default toolchain to clang after Xcode 5
102 XCODE_VERSION_OUTPUT=`xcodebuild -version 2>&1 | $HEAD -n 1`
103 $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
104 if test $? -ne 0; then
105 AC_MSG_ERROR([Failed to determine Xcode version.])
106 fi
107 XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
108 $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
109 $CUT -f 1 -d .`
110 AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
111 if test $XCODE_MAJOR_VERSION -ge 5; then
112 DEFAULT_TOOLCHAIN="clang"
113 else
114 DEFAULT_TOOLCHAIN="gcc"
115 fi
116 else
117 # First toolchain type in the list is the default
118 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
119 fi
120
121 if test "x$with_toolchain_type" = xlist; then
122 # List all toolchains
123 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
124 for toolchain in $VALID_TOOLCHAINS; do
125 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
126 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
127 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
128 done
129
130 exit 0
131 elif test "x$with_toolchain_type" != x; then
132 # User override; check that it is valid
133 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
134 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
135 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
136 AC_MSG_ERROR([Cannot continue.])
137 fi
138 TOOLCHAIN_TYPE=$with_toolchain_type
139 else
140 # No flag given, use default
141 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
142 fi
143 AC_SUBST(TOOLCHAIN_TYPE)
144
145 TOOLCHAIN_CC_BINARY_clang="clang"
146 TOOLCHAIN_CC_BINARY_gcc="gcc"
147 TOOLCHAIN_CC_BINARY_microsoft="cl"
148 TOOLCHAIN_CC_BINARY_solstudio="cc"
149 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
150
151 TOOLCHAIN_CXX_BINARY_clang="clang++"
152 TOOLCHAIN_CXX_BINARY_gcc="g++"
153 TOOLCHAIN_CXX_BINARY_microsoft="cl"
154 TOOLCHAIN_CXX_BINARY_solstudio="CC"
155 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
156
157 # Use indirect variable referencing
158 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
159 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
160 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
161 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
162 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
163 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
164
165 TOOLCHAIN_SETUP_FILENAME_PATTERNS
166
167 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
168 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
169 else
170 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
171 fi
172 ])
173
174 # Before we start detecting the toolchain executables, we might need some
175 # special setup, e.g. additional paths etc.
176 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
177 [
178 # FIXME: Is this needed?
179 AC_LANG(C++)
180
181 # Store the CFLAGS etc passed to the configure script.
182 ORG_CFLAGS="$CFLAGS"
183 ORG_CXXFLAGS="$CXXFLAGS"
184 ORG_OBJCFLAGS="$OBJCFLAGS"
185
186 # On Windows, we need to detect the visual studio installation first.
187 # This will change the PATH, but we need to keep that new PATH even
188 # after toolchain detection is done, since the compiler (on x86) uses
189 # it for DLL resolution in runtime.
190 if test "x$OPENJDK_BUILD_OS" = "xwindows" && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
191 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
192 fi
193
194 # autoconf magic only relies on PATH, so update it if tools dir is specified
195 OLD_PATH="$PATH"
196
197 # For solaris we really need solaris tools, and not the GNU equivalent.
198 # The build tools on Solaris reside in /usr/ccs (C Compilation System),
199 # so add that to path before starting to probe.
200 # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.
201 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
202 if test "x$TOOLCHAIN_PATH" = x; then
203 PATH="/usr/ccs/bin:$PATH"
204 fi
205 fi
206
207 # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
208 # override all other locations.
209 if test "x$TOOLCHAIN_PATH" != x; then
210 PATH=$TOOLCHAIN_PATH:$PATH
211 fi
212 ])
213
214 # Restore path, etc
215 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
216 [
217 # Restore old path.
218 PATH="$OLD_PATH"
219
220 # Restore the flags to the user specified values.
221 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
222 CFLAGS="$ORG_CFLAGS"
223 CXXFLAGS="$ORG_CXXFLAGS"
224 OBJCFLAGS="$ORG_OBJCFLAGS"
225 ])
226
227 # Check if a compiler is of the toolchain type we expect, and save the version
228 # information from it. If the compiler does not match the expected type,
229 # this function will abort using AC_MSG_ERROR. If it matches, the version will
230 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
231 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
232 #
233 # $1 = compiler to test (CC or CXX)
234 # $2 = human readable name of compiler (C or C++)
235 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
236 [
237 COMPILER=[$]$1
238 COMPILER_NAME=$2
239
240 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
241 # cc -V output typically looks like
242 # cc: Sun C 5.12 Linux_i386 2011/11/16
243 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
244 # Check that this is likely to be the Solaris Studio cc.
245 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
246 if test $? -ne 0; then
247 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
248 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
249 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
250 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
251 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
252 fi
253 # Remove usage instructions (if present), and
254 # collapse compiler output into a single line
255 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
256 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
257 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
258 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
259 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
260 # xlc -qversion output typically looks like
261 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
262 # Version: 11.01.0000.0015
263 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
264 # Check that this is likely to be the IBM XL C compiler.
265 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
266 if test $? -ne 0; then
267 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
268 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
269 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
270 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
271 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
272 fi
273 # Collapse compiler output into a single line
274 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
275 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
276 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
277 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
278 # There is no specific version flag, but all output starts with a version string.
279 # First line typically looks something like:
280 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
281 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
282 # Check that this is likely to be Microsoft CL.EXE.
283 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
284 if test $? -ne 0; then
285 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
286 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
287 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
288 fi
289 # Collapse compiler output into a single line
290 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
291 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
292 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
293 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
294 # gcc --version output typically looks like
295 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
296 # Copyright (C) 2013 Free Software Foundation, Inc.
297 # This is free software; see the source for copying conditions. There is NO
298 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
299 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
300 # Check that this is likely to be GCC.
301 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
302 if test $? -ne 0; then
303 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
304 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
305 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
306 fi
307 # Remove Copyright and legalese from version string, and
308 # collapse into a single line
309 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
310 $SED -e 's/ *Copyright .*//'`
311 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
312 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
313 elif test "x$TOOLCHAIN_TYPE" = xclang; then
314 # clang --version output typically looks like
315 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
316 # clang version 3.3 (tags/RELEASE_33/final)
317 # or
318 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
319 # Target: x86_64-pc-linux-gnu
320 # Thread model: posix
321 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
322 # Check that this is likely to be clang
323 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
324 if test $? -ne 0; then
325 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
326 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
327 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
328 fi
329 # Collapse compiler output into a single line
330 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
331 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
332 $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
333 else
334 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
335 fi
336 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
337 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
338 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
339 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
340
341 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
342 ])
343
344 # Try to locate the given C or C++ compiler in the path, or otherwise.
345 #
346 # $1 = compiler to test (CC or CXX)
347 # $2 = human readable name of compiler (C or C++)
348 # $3 = list of compiler names to search for
349 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
350 [
351 COMPILER_NAME=$2
352 SEARCH_LIST="$3"
353
354 if test "x[$]$1" != x; then
355 # User has supplied compiler name already, always let that override.
356 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
357 if test "x`basename [$]$1`" = "x[$]$1"; then
358 # A command without a complete path is provided, search $PATH.
359
360 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
361 if test "x$POTENTIAL_$1" != x; then
362 $1=$POTENTIAL_$1
363 else
364 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
365 fi
366 else
367 # Otherwise it might already be a complete path
368 if test ! -x "[$]$1"; then
369 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
370 fi
371 fi
372 else
373 # No user supplied value. Locate compiler ourselves.
374
375 # If we are cross compiling, assume cross compilation tools follows the
376 # cross compilation standard where they are prefixed with the autoconf
377 # standard name for the target. For example the binary
378 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
379 # If we are not cross compiling, then the default compiler name will be
380 # used.
381
382 $1=
383 # If TOOLCHAIN_PATH is set, check for all compiler names in there first
384 # before checking the rest of the PATH.
385 if test -n "$TOOLCHAIN_PATH"; then
386 PATH_save="$PATH"
387 PATH="$TOOLCHAIN_PATH"
388 AC_PATH_PROGS(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
389 $1=$TOOLCHAIN_PATH_$1
390 PATH="$PATH_save"
391 fi
392
393 # AC_PATH_PROGS can't be run multiple times with the same variable,
394 # so create a new name for this run.
395 if test "x[$]$1" = x; then
396 AC_PATH_PROGS(POTENTIAL_$1, $SEARCH_LIST)
397 $1=$POTENTIAL_$1
398 fi
399
400 if test "x[$]$1" = x; then
401 HELP_MSG_MISSING_DEPENDENCY([devkit])
402 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
403 fi
404 fi
405
406 # Now we have a compiler binary in $1. Make sure it's okay.
407 BASIC_FIXUP_EXECUTABLE($1)
408 TEST_COMPILER="[$]$1"
409 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
410 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
411 if test "x$OPENJDK_BUILD_OS" != xaix; then
412 # FIXME: This test should not be needed anymore; we don't do that for any platform.
413 AC_MSG_CHECKING([resolved symbolic links for $1])
414 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
415 AC_MSG_RESULT([$TEST_COMPILER])
416 fi
417 AC_MSG_CHECKING([if $1 is disguised ccache])
418
419 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
420 if test "x$COMPILER_BASENAME" = "xccache"; then
421 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
422 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
423 # We want to control ccache invocation ourselves, so ignore this cc and try
424 # searching again.
425
426 # Remove the path to the fake ccache cc from the PATH
427 RETRY_COMPILER_SAVED_PATH="$PATH"
428 COMPILER_DIRNAME=`$DIRNAME [$]$1`
429 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
430
431 # Try again looking for our compiler
432 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
433 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
434 PATH="$RETRY_COMPILER_SAVED_PATH"
435
436 AC_MSG_CHECKING([for resolved symbolic links for $1])
437 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
438 AC_MSG_RESULT([$PROPER_COMPILER_$1])
439 $1="$PROPER_COMPILER_$1"
440 else
441 AC_MSG_RESULT([no, keeping $1])
442 fi
443
444 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
445 ])
446
447 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
448 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
449 # archiver (AR). Verify that the compilers are correct according to the
450 # toolchain type.
451 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
452 [
453 #
454 # Setup the compilers (CC and CXX)
455 #
456 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
457 # Now that we have resolved CC ourself, let autoconf have its go at it
458 AC_PROG_CC([$CC])
459
460 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
461 # Now that we have resolved CXX ourself, let autoconf have its go at it
462 AC_PROG_CXX([$CXX])
463
464 #
465 # Setup the preprocessor (CPP and CXXCPP)
466 #
467 AC_PROG_CPP
468 BASIC_FIXUP_EXECUTABLE(CPP)
469 AC_PROG_CXXCPP
470 BASIC_FIXUP_EXECUTABLE(CXXCPP)
471
472 #
473 # Setup the linker (LD)
474 #
475 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
476 # In the Microsoft toolchain we have a separate LD command "link".
477 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
478 # a cygwin program for something completely different.
479 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
480 BASIC_FIXUP_EXECUTABLE(LD)
481 # Verify that we indeed succeeded with this trick.
482 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
483 "$LD" --version > /dev/null
484 if test $? -eq 0 ; then
485 AC_MSG_RESULT([no])
486 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
487 else
488 AC_MSG_RESULT([yes])
489 fi
490 LDCXX="$LD"
491 else
492 # All other toolchains use the compiler to link.
493 LD="$CC"
494 LDCXX="$CXX"
495 fi
496 AC_SUBST(LD)
497 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
498 AC_SUBST(LDCXX)
499
500 #
501 # Setup the assembler (AS)
502 #
503 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
504 # FIXME: should this really be solaris, or solstudio?
505 BASIC_PATH_PROGS(AS, as)
506 BASIC_FIXUP_EXECUTABLE(AS)
507 else
508 # FIXME: is this correct for microsoft?
509 AS="$CC -c"
510 fi
511 AC_SUBST(AS)
512
513 #
514 # Setup the archiver (AR)
515 #
516 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
517 # The corresponding ar tool is lib.exe (used to create static libraries)
518 AC_CHECK_PROG([AR], [lib],[lib],,,)
519 else
520 BASIC_CHECK_TOOLS(AR, ar)
521 fi
522 BASIC_FIXUP_EXECUTABLE(AR)
523 ])
524
525 # Setup additional tools that is considered a part of the toolchain, but not the
526 # core part. Many of these are highly platform-specific and do not exist,
527 # and/or are not needed on all platforms.
528 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
529 [
530 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
531 AC_PROG_OBJC
532 BASIC_FIXUP_EXECUTABLE(OBJC)
533 BASIC_PATH_PROGS(LIPO, lipo)
534 BASIC_FIXUP_EXECUTABLE(LIPO)
535 else
536 OBJC=
537 fi
538
539 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
540 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
541 BASIC_FIXUP_EXECUTABLE(MT)
542 # Setup the resource compiler (RC)
543 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
544 BASIC_FIXUP_EXECUTABLE(RC)
545 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
546 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
547 fi
548
549 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
550 BASIC_PATH_PROGS(STRIP, strip)
551 BASIC_FIXUP_EXECUTABLE(STRIP)
552 BASIC_PATH_PROGS(NM, nm)
553 BASIC_FIXUP_EXECUTABLE(NM)
554 BASIC_PATH_PROGS(GNM, gnm)
555 BASIC_FIXUP_EXECUTABLE(GNM)
556
557 BASIC_PATH_PROGS(MCS, mcs)
558 BASIC_FIXUP_EXECUTABLE(MCS)
559 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
560 # FIXME: we should unify this with the solaris case above.
561 BASIC_CHECK_TOOLS(STRIP, strip)
562 BASIC_FIXUP_EXECUTABLE(STRIP)
563 BASIC_CHECK_TOOLS(NM, nm)
564 BASIC_FIXUP_EXECUTABLE(NM)
565 GNM="$NM"
566 AC_SUBST(GNM)
567 fi
568
569 # objcopy is used for moving debug symbols to separate files when
570 # full debug symbols are enabled.
571 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
572 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
573 # Only call fixup if objcopy was found.
574 if test -n "$OBJCOPY"; then
575 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
576 fi
577 fi
578
579 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
580 if test "x$OBJDUMP" != x; then
581 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
582 # bails if argument is missing.
583 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
584 fi
585 ])
586
587 # Setup the build tools (i.e, the compiler and linker used to build programs
588 # that should be run on the build platform, not the target platform, as a build
589 # helper). Since the non-cross-compile case uses the normal, target compilers
590 # for this, we can only do this after these have been setup.
591 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
592 [
593 if test "x$COMPILE_TYPE" = "xcross"; then
594 # Now we need to find a C/C++ compiler that can build executables for the
595 # build platform. We can't use the AC_PROG_CC macro, since it can only be
596 # used once. Also, we need to do this without adding a tools dir to the
597 # path, otherwise we might pick up cross-compilers which don't use standard
598 # naming.
599
600 # FIXME: we should list the discovered compilers as an exclude pattern!
601 # If we do that, we can do this detection before POST_DETECTION, and still
602 # find the build compilers in the tools dir, if needed.
603 BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
604 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
605 BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
606 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
607 BASIC_PATH_PROGS(BUILD_LD, ld)
608 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
609 else
610 # If we are not cross compiling, use the normal target compilers for
611 # building the build platform executables.
612 BUILD_CC="$CC"
613 BUILD_CXX="$CXX"
614 BUILD_LD="$LD"
615 fi
616
617 AC_SUBST(BUILD_CC)
618 AC_SUBST(BUILD_CXX)
619 AC_SUBST(BUILD_LD)
620 ])
621
622 # Setup legacy variables that are still needed as alternative ways to refer to
623 # parts of the toolchain.
624 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
625 [
626 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
627 # For hotspot, we need these in Windows mixed path,
628 # so rewrite them all. Need added .exe suffix.
629 HOTSPOT_CXX="$CXX.exe"
630 HOTSPOT_LD="$LD.exe"
631 HOTSPOT_MT="$MT.exe"
632 HOTSPOT_RC="$RC.exe"
633 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
634 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
635 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
636 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
637 AC_SUBST(HOTSPOT_MT)
638 AC_SUBST(HOTSPOT_RC)
639 else
640 HOTSPOT_CXX="$CXX"
641 HOTSPOT_LD="$LD"
642 fi
643 AC_SUBST(HOTSPOT_CXX)
644 AC_SUBST(HOTSPOT_LD)
645
646 if test "x$TOOLCHAIN_TYPE" = xclang; then
647 USE_CLANG=true
648 fi
649 AC_SUBST(USE_CLANG)
650
651 # LDEXE is the linker to use, when creating executables. Not really used.
652 # FIXME: These should just be removed!
653 LDEXE="$LD"
654 LDEXECXX="$LDCXX"
655 AC_SUBST(LDEXE)
656 AC_SUBST(LDEXECXX)
657 ])
658
659 # Do some additional checks on the detected tools.
660 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
661 [
662 # The package path is used only on macosx?
663 # FIXME: clean this up, and/or move it elsewhere.
664 PACKAGE_PATH=/opt/local
665 AC_SUBST(PACKAGE_PATH)
666
667 # Check for extra potential brokenness.
668 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
669 # On Windows, double-check that we got the right compiler.
670 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
671 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
672 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
673 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
674 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
675 fi
676 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
677 if test "x$COMPILER_CPU_TEST" != "xx64"; then
678 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
679 fi
680 fi
681 fi
682
683 if test "x$TOOLCHAIN_TYPE" = xgcc; then
684 # If this is a --hash-style=gnu system, use --hash-style=both, why?
685 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
686 # This is later checked when setting flags.
687 fi
688
689 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
690 # in executable.'
691 USING_BROKEN_SUSE_LD=no
692 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
693 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
694 echo "SUNWprivate_1.1 { local: *; };" > version-script.map
695 echo "int main() { }" > main.c
696 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
697 AC_MSG_RESULT(no)
698 USING_BROKEN_SUSE_LD=no
699 else
700 AC_MSG_RESULT(yes)
701 USING_BROKEN_SUSE_LD=yes
702 fi
703 rm -rf version-script.map main.c a.out
704 fi
705 AC_SUBST(USING_BROKEN_SUSE_LD)
706 ])
707
708 # Setup the JTReg Regression Test Harness.
709 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
710 [
711 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
712 [Regression Test Harness @<:@probed@:>@])],
713 [],
714 [with_jtreg=no])
715
716 if test "x$with_jtreg" = xno; then
717 # jtreg disabled
718 AC_MSG_CHECKING([for jtreg])
719 AC_MSG_RESULT(no)
720 else
721 if test "x$with_jtreg" != xyes; then
722 # with path specified.
723 JT_HOME="$with_jtreg"
724 fi
725
726 if test "x$JT_HOME" != x; then
727 AC_MSG_CHECKING([for jtreg])
728
729 # use JT_HOME enviroment var.
730 BASIC_FIXUP_PATH([JT_HOME])
731
732 # jtreg win32 script works for everybody
733 JTREGEXE="$JT_HOME/win32/bin/jtreg"
734
735 if test ! -f "$JTREGEXE"; then
736 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
737 fi
738
739 AC_MSG_RESULT($JTREGEXE)
740 else
741 # try to find jtreg on path
742 BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
743 JT_HOME="`$DIRNAME $JTREGEXE`"
744 fi
745 fi
746
747 AC_SUBST(JT_HOME)
748 AC_SUBST(JTREGEXE)
749 ])