1 #
   2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
  27 # If so, then append $1 to $2 \
  28 # Also set JVM_ARG_OK to true/false depending on outcome.
  29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
  30 [
  31   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
  32   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
  33   OUTPUT=`$3 $1 -version 2>&1`
  34   FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
  35   FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
  36   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
  37     $2="[$]$2 $1"
  38     JVM_ARG_OK=true
  39   else
  40     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
  41     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
  42     JVM_ARG_OK=false
  43   fi
  44 ])
  45 
  46 # Appends a string to a path variable, only adding the : when needed.
  47 AC_DEFUN([BASIC_APPEND_TO_PATH],
  48 [
  49   if test "x$2" != x; then
  50     if test "x[$]$1" = x; then
  51       $1="$2"
  52     else
  53       $1="[$]$1:$2"
  54     fi
  55   fi
  56 ])
  57 
  58 # Prepends a string to a path variable, only adding the : when needed.
  59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
  60 [
  61   if test "x$2" != x; then
  62     if test "x[$]$1" = x; then
  63       $1="$2"
  64     else
  65       $1="$2:[$]$1"
  66     fi
  67   fi
  68 ])
  69 
  70 # This will make sure the given variable points to a full and proper
  71 # path. This means:
  72 # 1) There will be no spaces in the path. On posix platforms,
  73 #    spaces in the path will result in an error. On Windows,
  74 #    the path will be rewritten using short-style to be space-free.
  75 # 2) The path will be absolute, and it will be in unix-style (on
  76 #     cygwin).
  77 # $1: The name of the variable to fix
  78 AC_DEFUN([BASIC_FIXUP_PATH],
  79 [
  80   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
  81     BASIC_FIXUP_PATH_CYGWIN($1)
  82   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
  83     BASIC_FIXUP_PATH_MSYS($1)
  84   else
  85     # We're on a posix platform. Hooray! :)
  86     path="[$]$1"
  87     has_space=`$ECHO "$path" | $GREP " "`
  88     if test "x$has_space" != x; then
  89       AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
  90       AC_MSG_ERROR([Spaces are not allowed in this path.])
  91     fi
  92 
  93     # Use eval to expand a potential ~
  94     eval path="$path"
  95     if test ! -f "$path" && test ! -d "$path"; then
  96       AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
  97     fi
  98 
  99     $1="`cd "$path"; $THEPWDCMD -L`"
 100   fi
 101 ])
 102 
 103 # This will make sure the given variable points to a executable
 104 # with a full and proper path. This means:
 105 # 1) There will be no spaces in the path. On posix platforms,
 106 #    spaces in the path will result in an error. On Windows,
 107 #    the path will be rewritten using short-style to be space-free.
 108 # 2) The path will be absolute, and it will be in unix-style (on
 109 #     cygwin).
 110 # Any arguments given to the executable is preserved.
 111 # If the input variable does not have a directory specification, then
 112 # it need to be in the PATH.
 113 # $1: The name of the variable to fix
 114 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 115 [
 116   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 117     BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 118   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 119     BASIC_FIXUP_EXECUTABLE_MSYS($1)
 120   else
 121     # We're on a posix platform. Hooray! :)
 122     # First separate the path from the arguments. This will split at the first
 123     # space.
 124     complete="[$]$1"
 125     path="${complete%% *}"
 126     tmp="$complete EOL"
 127     arguments="${tmp#* }"
 128 
 129     # Cannot rely on the command "which" here since it doesn't always work.
 130     is_absolute_path=`$ECHO "$path" | $GREP ^/`
 131     if test -z "$is_absolute_path"; then
 132       # Path to executable is not absolute. Find it.
 133       IFS_save="$IFS"
 134       IFS=:
 135       for p in $PATH; do
 136         if test -f "$p/$path" && test -x "$p/$path"; then
 137           new_path="$p/$path"
 138           break
 139         fi
 140       done
 141       IFS="$IFS_save"
 142     else
 143       # This is an absolute path, we can use it without further modifications.
 144       new_path="$path"
 145     fi
 146 
 147     if test "x$new_path" = x; then
 148       AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 149       has_space=`$ECHO "$complete" | $GREP " "`
 150       if test "x$has_space" != x; then
 151         AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 152       fi
 153       AC_MSG_ERROR([Cannot locate the the path of $1])
 154     fi
 155   fi
 156 
 157   # Now join together the path and the arguments once again
 158   if test "x$arguments" != xEOL; then
 159     new_complete="$new_path ${arguments% *}"
 160   else
 161     new_complete="$new_path"
 162   fi
 163 
 164   if test "x$complete" != "x$new_complete"; then
 165     $1="$new_complete"
 166     AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 167   fi
 168 ])
 169 
 170 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 171 [
 172   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 173     # Follow a chain of symbolic links. Use readlink
 174     # where it exists, else fall back to horribly
 175     # complicated shell code.
 176     if test "x$READLINK_TESTED" != yes; then
 177       # On MacOSX there is a readlink tool with a different
 178       # purpose than the GNU readlink tool. Check the found readlink.
 179       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 180       if test "x$ISGNU" = x; then
 181         # A readlink that we do not know how to use.
 182         # Are there other non-GNU readlinks out there?
 183         READLINK_TESTED=yes
 184         READLINK=
 185       fi
 186     fi
 187 
 188     if test "x$READLINK" != x; then
 189       $1=`$READLINK -f [$]$1`
 190     else
 191       # Save the current directory for restoring afterwards
 192       STARTDIR=$PWD
 193       COUNTER=0
 194       sym_link_dir=`$DIRNAME [$]$1`
 195       sym_link_file=`$BASENAME [$]$1`
 196       cd $sym_link_dir
 197       # Use -P flag to resolve symlinks in directories.
 198       cd `$THEPWDCMD -P`
 199       sym_link_dir=`$THEPWDCMD -P`
 200       # Resolve file symlinks
 201       while test $COUNTER -lt 20; do
 202         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 203         if test "x$ISLINK" == x; then
 204           # This is not a symbolic link! We are done!
 205           break
 206         fi
 207         # Again resolve directory symlinks since the target of the just found
 208         # link could be in a different directory
 209         cd `$DIRNAME $ISLINK`
 210         sym_link_dir=`$THEPWDCMD -P`
 211         sym_link_file=`$BASENAME $ISLINK`
 212         let COUNTER=COUNTER+1
 213       done
 214       cd $STARTDIR
 215       $1=$sym_link_dir/$sym_link_file
 216     fi
 217   fi
 218 ])
 219 
 220 # Register a --with argument but mark it as deprecated
 221 # $1: The name of the with argument to deprecate, not including --with-
 222 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 223 [
 224   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 225       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 226       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 227 ])
 228 
 229 # Register a --enable argument but mark it as deprecated
 230 # $1: The name of the with argument to deprecate, not including --enable-
 231 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 232 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 233 [
 234   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 235       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 236   if test "x$enable_$2" != x; then
 237     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 238   fi
 239 ])
 240 
 241 AC_DEFUN_ONCE([BASIC_INIT],
 242 [
 243   # Save the original command line. This is passed to us by the wrapper configure script.
 244   AC_SUBST(CONFIGURE_COMMAND_LINE)
 245   DATE_WHEN_CONFIGURED=`LANG=C date`
 246   AC_SUBST(DATE_WHEN_CONFIGURED)
 247   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 248   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
 249 ])
 250 
 251 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 252 # $1: variable to check
 253 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 254 [
 255   if test "x[$]$1" = x; then
 256     AC_MSG_ERROR([Could not find required tool for $1])
 257   fi
 258 ])
 259 
 260 # Check that there are no unprocessed overridden variables left.
 261 # If so, they are an incorrect argument and we will exit with an error.
 262 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 263 [
 264   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 265     # Replace the separating ! with spaces before presenting for end user.
 266     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 267     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 268   fi
 269 ])
 270 
 271 # Setup a tool for the given variable. If correctly specified by the user, 
 272 # use that value, otherwise search for the tool using the supplied code snippet.
 273 # $1: variable to set
 274 # $2: code snippet to call to look for the tool
 275 AC_DEFUN([BASIC_SETUP_TOOL],
 276 [
 277   # Publish this variable in the help.
 278   AC_ARG_VAR($1, [Override default value for $1])
 279 
 280   if test "x[$]$1" = x; then
 281     # The variable is not set by user, try to locate tool using the code snippet
 282     $2
 283   else
 284     # The variable is set, but is it from the command line or the environment?
 285 
 286     # Try to remove the string !$1! from our list.
 287     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 288     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 289       # If it failed, the variable was not from the command line. Ignore it,
 290       # but warn the user (except for BASH, which is always set by the calling BASH).
 291       if test "x$1" != xBASH; then
 292         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 293       fi
 294       # Try to locate tool using the code snippet
 295       $2
 296     else
 297       # If it succeeded, then it was overridden by the user. We will use it
 298       # for the tool.
 299 
 300       # First remove it from the list of overridden variables, so we can test
 301       # for unknown variables in the end.
 302       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 303 
 304       # Check if the provided tool contains a complete path.
 305       tool_specified="[$]$1"
 306       tool_basename="${tool_specified##*/}"
 307       if test "x$tool_basename" = "x$tool_specified"; then
 308         # A command without a complete path is provided, search $PATH.
 309         AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 310         AC_PATH_PROG($1, $tool_basename)
 311         if test "x[$]$1" = x; then
 312           AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 313         fi
 314       else
 315         # Otherwise we believe it is a complete path. Use it as it is.
 316         AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 317         AC_MSG_CHECKING([for $1])
 318         if test ! -x "$tool_specified"; then
 319           AC_MSG_RESULT([not found])
 320           AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 321         fi
 322         AC_MSG_RESULT([$tool_specified])
 323       fi
 324     fi
 325   fi
 326 ])
 327 
 328 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 329 # $1: variable to set
 330 # $2: executable name (or list of names) to look for
 331 AC_DEFUN([BASIC_PATH_PROGS],
 332 [
 333   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
 334 ])
 335 
 336 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 337 # $1: variable to set
 338 # $2: executable name (or list of names) to look for
 339 AC_DEFUN([BASIC_CHECK_TOOLS],
 340 [
 341   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 342 ])
 343 
 344 # Like BASIC_PATH_PROGS but fails if no tool was found.
 345 # $1: variable to set
 346 # $2: executable name (or list of names) to look for
 347 AC_DEFUN([BASIC_REQUIRE_PROGS],
 348 [
 349   BASIC_PATH_PROGS($1, $2)
 350   BASIC_CHECK_NONEMPTY($1)
 351 ])
 352 
 353 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 354 # $1: variable to set
 355 # $2: autoconf macro to call to look for the special tool
 356 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 357 [
 358   BASIC_SETUP_TOOL($1, [$2])
 359   BASIC_CHECK_NONEMPTY($1)
 360 ])
 361 
 362 # Setup the most fundamental tools that relies on not much else to set up,
 363 # but is used by much of the early bootstrap code.
 364 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 365 [
 366   # Start with tools that do not need have cross compilation support
 367   # and can be expected to be found in the default PATH. These tools are
 368   # used by configure. Nor are these tools expected to be found in the
 369   # devkit from the builddeps server either, since they are
 370   # needed to download the devkit.
 371 
 372   # First are all the simple required tools.
 373   BASIC_REQUIRE_PROGS(BASENAME, basename)
 374   BASIC_REQUIRE_PROGS(BASH, bash)
 375   BASIC_REQUIRE_PROGS(CAT, cat)
 376   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 377   BASIC_REQUIRE_PROGS(CMP, cmp)
 378   BASIC_REQUIRE_PROGS(COMM, comm)
 379   BASIC_REQUIRE_PROGS(CP, cp)
 380   BASIC_REQUIRE_PROGS(CPIO, cpio)
 381   BASIC_REQUIRE_PROGS(CUT, cut)
 382   BASIC_REQUIRE_PROGS(DATE, date)
 383   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 384   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 385   BASIC_REQUIRE_PROGS(ECHO, echo)
 386   BASIC_REQUIRE_PROGS(EXPR, expr)
 387   BASIC_REQUIRE_PROGS(FILE, file)
 388   BASIC_REQUIRE_PROGS(FIND, find)
 389   BASIC_REQUIRE_PROGS(HEAD, head)
 390   BASIC_REQUIRE_PROGS(LN, ln)
 391   BASIC_REQUIRE_PROGS(LS, ls)
 392   BASIC_REQUIRE_PROGS(MKDIR, mkdir)
 393   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 394   BASIC_REQUIRE_PROGS(MV, mv)
 395   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 396   BASIC_REQUIRE_PROGS(PRINTF, printf)
 397   BASIC_REQUIRE_PROGS(RM, rm)
 398   BASIC_REQUIRE_PROGS(SH, sh)
 399   BASIC_REQUIRE_PROGS(SORT, sort)
 400   BASIC_REQUIRE_PROGS(TAIL, tail)
 401   BASIC_REQUIRE_PROGS(TAR, tar)
 402   BASIC_REQUIRE_PROGS(TEE, tee)
 403   BASIC_REQUIRE_PROGS(TOUCH, touch)
 404   BASIC_REQUIRE_PROGS(TR, tr)
 405   BASIC_REQUIRE_PROGS(UNAME, uname)
 406   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 407   BASIC_REQUIRE_PROGS(WC, wc)
 408   BASIC_REQUIRE_PROGS(WHICH, which)
 409   BASIC_REQUIRE_PROGS(XARGS, xargs)
 410 
 411   # Then required tools that require some special treatment.
 412   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 413   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 414   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 415   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 416   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 417 
 418   # Always force rm.
 419   RM="$RM -f"
 420 
 421   # pwd behaves differently on various platforms and some don't support the -L flag.
 422   # Always use the bash builtin pwd to get uniform behavior.
 423   THEPWDCMD=pwd
 424 
 425   # These are not required on all platforms
 426   BASIC_PATH_PROGS(CYGPATH, cygpath)
 427   BASIC_PATH_PROGS(READLINK, [greadlink readlink])
 428   BASIC_PATH_PROGS(DF, df)
 429   BASIC_PATH_PROGS(SETFILE, SetFile)
 430 ])
 431 
 432 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 433 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 434 [
 435   # Save the current directory this script was started from
 436   CURDIR="$PWD"
 437 
 438   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 439     PATH_SEP=";"
 440     BASIC_CHECK_PATHS_WINDOWS
 441   else
 442     PATH_SEP=":"
 443   fi
 444   AC_SUBST(PATH_SEP)
 445 
 446   # We get the top-level directory from the supporting wrappers.
 447   AC_MSG_CHECKING([for top-level directory])
 448   AC_MSG_RESULT([$TOPDIR])
 449   AC_SUBST(TOPDIR)
 450 
 451   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 452   BASIC_FIXUP_PATH(CURDIR)
 453   BASIC_FIXUP_PATH(TOPDIR)
 454   # SRC_ROOT is a traditional alias for TOPDIR.
 455   SRC_ROOT=$TOPDIR
 456 
 457   # Locate the directory of this script.
 458   AUTOCONF_DIR=$TOPDIR/common/autoconf
 459 ])
 460 
 461 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 462 [
 463   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 464       [use this devkit for compilers, tools and resources])],
 465       [
 466         BASIC_FIXUP_PATH([with_devkit])
 467         DEVKIT_ROOT="$with_devkit"
 468         # Check for a meta data info file in the root of the devkit
 469         if test -f "$DEVKIT_ROOT/devkit.info"; then
 470           # This potentially sets the following:
 471           # DEVKIT_NAME: A descriptive name of the devkit
 472           # DEVKIT_TOOLCHAIN_PATH: Corresponds to --with-toolchain-path
 473           # DEVKIT_EXTRA_PATH: Corresponds to --with-extra-path
 474           # DEVKIT_SYSROOT: Corresponds to --with-sysroot
 475           . $DEVKIT_ROOT/devkit.info
 476         fi
 477 
 478         AC_MSG_CHECKING([for devkit])
 479         if test "x$DEVKIT_NAME" != x; then
 480           AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 481         else
 482           AC_MSG_RESULT([$DEVKIT_ROOT])
 483         fi
 484 
 485         if test "x$DEVKIT_EXTRA_PATH" != x; then
 486           BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 487         fi
 488 
 489         # Fallback default of just /bin if DEVKIT_PATH is not defined
 490         if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 491           DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 492         fi
 493         BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 494 
 495         # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 496         # places for backwards compatiblity.
 497         if test "x$DEVKIT_SYSROOT" != x; then
 498           SYSROOT="$DEVKIT_SYSROOT"
 499         elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 500           SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 501         elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 502           SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 503         fi
 504       ]
 505   )
 506 
 507   # You can force the sysroot if the sysroot encoded into the compiler tools
 508   # is not correct.
 509   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 510       [alias for --with-sysroot for backwards compatability])],
 511       [SYSROOT=$with_sys_root]
 512   )
 513 
 514   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 515       [use this directory as sysroot)])],
 516       [SYSROOT=$with_sysroot]
 517   )


 518 
 519   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 520       [alias for --with-toolchain-path for backwards compatibility])],
 521       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 522   )
 523 
 524   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 525       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 526       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 527   )
 528 
 529   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 530       [prepend these directories to the default path])],
 531       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 532   )
 533 
 534   # Prepend the extra path to the global path
 535   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 536 
 537   if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
 538     # Add extra search paths on solaris for utilities like ar and as etc...
 539     PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
 540   fi
 541 
 542   AC_MSG_CHECKING([for sysroot])
 543   AC_MSG_RESULT([$SYSROOT])
 544   AC_MSG_CHECKING([for toolchain path])
 545   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 546   AC_MSG_CHECKING([for extra path])
 547   AC_MSG_RESULT([$EXTRA_PATH])
 548 ])
 549 
 550 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 551 [
 552 
 553   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 554       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 555       [ CONF_NAME=${with_conf_name} ])
 556 
 557   # Test from where we are running configure, in or outside of src root.
 558   AC_MSG_CHECKING([where to store configuration])
 559   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
 560       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
 561       || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
 562     # We are running configure from the src root.
 563     # Create a default ./build/target-variant-debuglevel output root.
 564     if test "x${CONF_NAME}" = x; then
 565       AC_MSG_RESULT([in default location])
 566       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
 567     else
 568       AC_MSG_RESULT([in build directory with custom name])
 569     fi
 570     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
 571     $MKDIR -p "$OUTPUT_ROOT"
 572     if test ! -d "$OUTPUT_ROOT"; then
 573       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
 574     fi
 575   else
 576     # We are running configure from outside of the src dir.
 577     # Then use the current directory as output dir!
 578     # If configuration is situated in normal build directory, just use the build
 579     # directory name as configuration name, otherwise use the complete path.
 580     if test "x${CONF_NAME}" = x; then
 581       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
 582     fi
 583     OUTPUT_ROOT="$CURDIR"
 584     AC_MSG_RESULT([in current directory])
 585 
 586     # WARNING: This might be a bad thing to do. You need to be sure you want to
 587     # have a configuration in this directory. Do some sanity checks!
 588 
 589     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
 590       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 591       # other files
 592       files_present=`$LS $OUTPUT_ROOT`
 593       # Configure has already touched config.log and confdefs.h in the current dir when this check
 594       # is performed.
 595       filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
 596       | $TR -d '\n'`
 597       if test "x$filtered_files" != x; then
 598         AC_MSG_NOTICE([Current directory is $CURDIR.])
 599         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 600         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 601         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 602         AC_MSG_NOTICE([seriously mess up just about everything.])
 603         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
 604         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 605         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 606       fi
 607     fi
 608   fi
 609   AC_MSG_CHECKING([what configuration name to use])
 610   AC_MSG_RESULT([$CONF_NAME])
 611 
 612   BASIC_FIXUP_PATH(OUTPUT_ROOT)
 613 
 614   AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
 615   AC_SUBST(CONF_NAME, $CONF_NAME)
 616   AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
 617 
 618   # Most of the probed defines are put into config.h
 619   AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
 620   # The spec.gmk file contains all variables for the make system.
 621   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 622   # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
 623   AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
 624   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 625   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 626   # The compare.sh is used to compare the build output to other builds.
 627   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 628   # Spec.sh is currently used by compare-objects.sh
 629   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
 630   # The generated Makefile knows where the spec.gmk is and where the source is.
 631   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
 632   # which will look for generated configurations
 633   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
 634 ])
 635 
 636 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
 637 [
 638   # Setup default logging of stdout and stderr to build.log in the output root.
 639   BUILD_LOG='$(OUTPUT_ROOT)/build.log'
 640   BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
 641   BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
 642   AC_SUBST(BUILD_LOG)
 643   AC_SUBST(BUILD_LOG_PREVIOUS)
 644   AC_SUBST(BUILD_LOG_WRAPPER)
 645 ])
 646 
 647 
 648 #%%% Simple tools %%%
 649 
 650 # Check if we have found a usable version of make
 651 # $1: the path to a potential make binary (or empty)
 652 # $2: the description on how we found this
 653 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 654 [
 655   MAKE_CANDIDATE="$1"
 656   DESCRIPTION="$2"
 657   if test "x$MAKE_CANDIDATE" != x; then
 658     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 659     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 660     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 661     if test "x$IS_GNU_MAKE" = x; then
 662       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 663     else
 664       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
 665       if test "x$IS_MODERN_MAKE" = x; then
 666         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 667       else
 668         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 669           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 670             MAKE_EXPECTED_ENV='cygwin'
 671           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 672             MAKE_EXPECTED_ENV='msys'
 673           else
 674             AC_MSG_ERROR([Unknown Windows environment])
 675           fi
 676           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 677           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 678         else
 679           # Not relevant for non-Windows
 680           IS_MAKE_CORRECT_ENV=true
 681         fi
 682         if test "x$IS_MAKE_CORRECT_ENV" = x; then
 683           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
 684         else
 685           FOUND_MAKE=$MAKE_CANDIDATE
 686           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
 687         fi
 688       fi
 689     fi
 690   fi
 691 ])
 692 
 693 # Goes looking for a usable version of GNU make.
 694 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
 695 [
 696   # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
 697   if test "x$MAKE" != x; then
 698     # User has supplied a make, test it.
 699     if test ! -f "$MAKE"; then
 700       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
 701     fi
 702     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
 703     if test "x$FOUND_MAKE" = x; then
 704       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
 705     fi
 706   else
 707     # Try our hardest to locate a correct version of GNU make
 708     AC_PATH_PROGS(CHECK_GMAKE, gmake)
 709     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
 710 
 711     if test "x$FOUND_MAKE" = x; then
 712       AC_PATH_PROGS(CHECK_MAKE, make)
 713       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
 714     fi
 715 
 716     if test "x$FOUND_MAKE" = x; then
 717       if test "x$TOOLCHAIN_PATH" != x; then
 718         # We have a toolchain path, check that as well before giving up.
 719         OLD_PATH=$PATH
 720         PATH=$TOOLCHAIN_PATH:$PATH
 721         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
 722         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
 723         if test "x$FOUND_MAKE" = x; then
 724           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
 725           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
 726         fi
 727         PATH=$OLD_PATH
 728       fi
 729     fi
 730 
 731     if test "x$FOUND_MAKE" = x; then
 732       AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
 733     fi
 734   fi
 735 
 736   MAKE=$FOUND_MAKE
 737   AC_SUBST(MAKE)
 738   AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
 739 ])
 740 
 741 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
 742 [
 743   # Test if find supports -delete
 744   AC_MSG_CHECKING([if find supports -delete])
 745   FIND_DELETE="-delete"
 746 
 747   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
 748 
 749   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
 750 
 751   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
 752   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
 753     # No, it does not.
 754     rm $DELETEDIR/TestIfFindSupportsDelete
 755     FIND_DELETE="-exec rm \{\} \+"
 756     AC_MSG_RESULT([no])
 757   else
 758     AC_MSG_RESULT([yes])
 759   fi
 760   rmdir $DELETEDIR
 761   AC_SUBST(FIND_DELETE)
 762 ])
 763 
 764 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
 765 [
 766   BASIC_CHECK_GNU_MAKE
 767 
 768   BASIC_CHECK_FIND_DELETE
 769 
 770   # These tools might not be installed by default,
 771   # need hint on how to install them.
 772   BASIC_REQUIRE_PROGS(UNZIP, unzip)
 773   BASIC_REQUIRE_PROGS(ZIP, zip)
 774 
 775   # Non-required basic tools
 776 
 777   BASIC_PATH_PROGS(LDD, ldd)
 778   if test "x$LDD" = "x"; then
 779     # List shared lib dependencies is used for
 780     # debug output and checking for forbidden dependencies.
 781     # We can build without it.
 782     LDD="true"
 783   fi
 784   BASIC_PATH_PROGS(OTOOL, otool)
 785   if test "x$OTOOL" = "x"; then
 786     OTOOL="true"
 787   fi
 788   BASIC_PATH_PROGS(READELF, [greadelf readelf])
 789   BASIC_PATH_PROGS(HG, hg)
 790   BASIC_PATH_PROGS(STAT, stat)
 791   BASIC_PATH_PROGS(TIME, time)
 792   # Check if it's GNU time
 793   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
 794   if test "x$IS_GNU_TIME" != x; then
 795     IS_GNU_TIME=yes
 796   else
 797     IS_GNU_TIME=no
 798   fi
 799   AC_SUBST(IS_GNU_TIME)
 800 
 801   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 802     BASIC_REQUIRE_PROGS(COMM, comm)
 803   fi
 804 
 805   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 806     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
 807     BASIC_REQUIRE_PROGS(XATTR, xattr)
 808     BASIC_PATH_PROGS(CODESIGN, codesign)
 809     if test "x$CODESIGN" != "x"; then
 810       # Verify that the openjdk_codesign certificate is present
 811       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
 812       rm -f codesign-testfile
 813       touch codesign-testfile
 814       codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
 815       rm -f codesign-testfile
 816       if test "x$CODESIGN" = x; then
 817         AC_MSG_RESULT([no])
 818       else
 819         AC_MSG_RESULT([yes])
 820       fi
 821     fi
 822   fi
 823 ])
 824 
 825 # Check if build directory is on local disk. If not possible to determine,
 826 # we prefer to claim it's local.
 827 # Argument 1: directory to test
 828 # Argument 2: what to do if it is on local disk
 829 # Argument 3: what to do otherwise (remote disk or failure)
 830 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
 831 [
 832   # df -l lists only local disks; if the given directory is not found then
 833   # a non-zero exit code is given
 834   if test "x$DF" = x; then
 835     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 836       # msys does not have df; use Windows "net use" instead.
 837       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
 838       if test "x$IS_NETWORK_DISK" = x; then
 839         $2
 840       else
 841         $3
 842       fi
 843     else
 844       # No df here, say it's local
 845       $2
 846     fi
 847   else
 848     if $DF -l $1 > /dev/null 2>&1; then
 849       $2
 850     else
 851       $3
 852     fi
 853   fi
 854 ])
 855 
 856 # Check that source files have basic read permissions set. This might
 857 # not be the case in cygwin in certain conditions.
 858 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
 859 [
 860   if test x"$OPENJDK_BUILD_OS" = xwindows; then
 861     file_to_test="$SRC_ROOT/LICENSE"
 862     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
 863       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
 864     fi
 865   fi
 866 ])
 867 
 868 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
 869 [
 870   # Did user specify any unknown variables?
 871   BASIC_CHECK_LEFTOVER_OVERRIDDEN
 872 
 873   AC_MSG_CHECKING([if build directory is on local disk])
 874   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
 875       [OUTPUT_DIR_IS_LOCAL="yes"],
 876       [OUTPUT_DIR_IS_LOCAL="no"])
 877   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
 878 
 879   BASIC_CHECK_SRC_PERMS
 880 
 881   # Check if the user has any old-style ALT_ variables set.
 882   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
 883 
 884   # Before generating output files, test if they exist. If they do, this is a reconfigure.
 885   # Since we can't properly handle the dependencies for this, warn the user about the situation
 886   if test -e $OUTPUT_ROOT/spec.gmk; then
 887     IS_RECONFIGURE=yes
 888   else
 889     IS_RECONFIGURE=no
 890   fi
 891 ])
--- EOF ---