1 #
   2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
  27 [
  28   ###############################################################################
  29   #
  30   # Check which variant of the JDK that we want to build.
  31   # Currently we have:
  32   #    normal:   standard edition
  33   # but the custom make system may add other variants
  34   #
  35   # Effectively the JDK variant gives a name to a specific set of
  36   # modules to compile into the JDK. In the future, these modules
  37   # might even be Jigsaw modules.
  38   #
  39   AC_MSG_CHECKING([which variant of the JDK to build])
  40   AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
  41       [JDK variant to build (normal) @<:@normal@:>@])])
  42 
  43   if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
  44     JDK_VARIANT="normal"
  45   else
  46     AC_MSG_ERROR([The available JDK variants are: normal])
  47   fi
  48 
  49   AC_SUBST(JDK_VARIANT)
  50 
  51   AC_MSG_RESULT([$JDK_VARIANT])
  52 ])
  53 
  54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
  55 [
  56 ###############################################################################
  57 #
  58 # Check which interpreter of the JVM we want to build.
  59 # Currently we have:
  60 #    template: Template interpreter (the default)
  61 #    cpp     : C++ interpreter
  62 AC_MSG_CHECKING([which interpreter of the JVM to build])
  63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
  64         [JVM interpreter to build (template, cpp) @<:@template@:>@])])
  65 
  66 if test "x$with_jvm_interpreter" = x; then
  67      with_jvm_interpreter="template"
  68 fi
  69 
  70 JVM_INTERPRETER="$with_jvm_interpreter"
  71 
  72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
  73    AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
  74 fi
  75 
  76 AC_SUBST(JVM_INTERPRETER)
  77 
  78 AC_MSG_RESULT([$with_jvm_interpreter])
  79 ])
  80 
  81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
  82 [
  83 
  84   ###############################################################################
  85   #
  86   # Check which variants of the JVM that we want to build.
  87   # Currently we have:
  88   #    server: normal interpreter and a tiered C1/C2 compiler
  89   #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
  90   #    minimal1: reduced form of client with optional VM services and features stripped out
  91   #    kernel: kernel footprint JVM that passes the TCK without major performance problems,
  92   #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc
  93   #    zero: no machine code interpreter, no compiler
  94   #    zeroshark: zero interpreter and shark/llvm compiler backend
  95 #    core: interpreter only, no compiler (only works on some platforms)
  96   AC_MSG_CHECKING([which variants of the JVM to build])
  97   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  98         [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
  99 
 100   if test "x$with_jvm_variants" = x; then
 101     with_jvm_variants="server"
 102   fi
 103 
 104   JVM_VARIANTS=",$with_jvm_variants,"
 105   TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
 106 
 107   if test "x$TEST_VARIANTS" != "x,"; then
 108      AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
 109   fi
 110   AC_MSG_RESULT([$with_jvm_variants])
 111 
 112   JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
 113   JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
 114   JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
 115   JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
 116   JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
 117   JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
 118   JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
 119 
 120   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 121     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 122       AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
 123     fi
 124   fi
 125   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 126     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 127       AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
 128     fi
 129   fi
 130   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 131     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 132       AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
 133     fi
 134   fi
 135 
 136   # Replace the commas with AND for use in the build directory name.
 137   ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
 138   COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
 139   if test "x$COUNT_VARIANTS" != "x,1"; then
 140     BUILDING_MULTIPLE_JVM_VARIANTS=yes
 141   else
 142     BUILDING_MULTIPLE_JVM_VARIANTS=no
 143   fi
 144 
 145   AC_SUBST(JVM_VARIANTS)
 146   AC_SUBST(JVM_VARIANT_SERVER)
 147   AC_SUBST(JVM_VARIANT_CLIENT)
 148   AC_SUBST(JVM_VARIANT_MINIMAL1)
 149   AC_SUBST(JVM_VARIANT_KERNEL)
 150   AC_SUBST(JVM_VARIANT_ZERO)
 151   AC_SUBST(JVM_VARIANT_ZEROSHARK)
 152   AC_SUBST(JVM_VARIANT_CORE)
 153 
 154   INCLUDE_SA=true
 155   if test "x$JVM_VARIANT_ZERO" = xtrue ; then
 156     INCLUDE_SA=false
 157   fi
 158   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
 159     INCLUDE_SA=false
 160   fi
 161   if test "x$OPENJDK_TARGET_OS" = xaix ; then
 162     INCLUDE_SA=false
 163   fi
 164   if test "x$OPENJDK_TARGET_CPU" = xaarch64; then
 165     INCLUDE_SA=false
 166   fi
 167   AC_SUBST(INCLUDE_SA)
 168 
 169   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 170     MACOSX_UNIVERSAL="true"
 171   fi
 172 
 173   AC_SUBST(MACOSX_UNIVERSAL)
 174 ])
 175 
 176 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
 177 [
 178   ###############################################################################
 179   #
 180   # Set the debug level
 181   #    release: no debug information, all optimizations, no asserts.
 182   #    optimized: no debug information, all optimizations, no asserts, HotSpot target is 'optimized'.
 183   #    fastdebug: debug information (-g), all optimizations, all asserts
 184   #    slowdebug: debug information (-g), no optimizations, all asserts
 185   #
 186   DEBUG_LEVEL="release"
 187   AC_MSG_CHECKING([which debug level to use])
 188   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
 189       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
 190       [
 191         ENABLE_DEBUG="${enableval}"
 192         DEBUG_LEVEL="fastdebug"
 193       ], [ENABLE_DEBUG="no"])
 194 
 195   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
 196       [set the debug level (release, fastdebug, slowdebug, optimized (HotSpot build only)) @<:@release@:>@])],
 197       [
 198         DEBUG_LEVEL="${withval}"
 199         if test "x$ENABLE_DEBUG" = xyes; then
 200           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
 201         fi
 202       ])
 203   AC_MSG_RESULT([$DEBUG_LEVEL])
 204 
 205   if test "x$DEBUG_LEVEL" != xrelease && \
 206       test "x$DEBUG_LEVEL" != xoptimized && \
 207       test "x$DEBUG_LEVEL" != xfastdebug && \
 208       test "x$DEBUG_LEVEL" != xslowdebug; then
 209     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
 210   fi
 211 
 212 
 213   ###############################################################################
 214   #
 215   # Setup legacy vars/targets and new vars to deal with different debug levels.
 216   #
 217 
 218   case $DEBUG_LEVEL in
 219     release )
 220       VARIANT="OPT"
 221       FASTDEBUG="false"
 222       DEBUG_CLASSFILES="false"
 223       BUILD_VARIANT_RELEASE=""
 224       HOTSPOT_DEBUG_LEVEL="product"
 225       HOTSPOT_EXPORT="product"
 226       ;;
 227     fastdebug )
 228       VARIANT="DBG"
 229       FASTDEBUG="true"
 230       DEBUG_CLASSFILES="true"
 231       BUILD_VARIANT_RELEASE="-fastdebug"
 232       HOTSPOT_DEBUG_LEVEL="fastdebug"
 233       HOTSPOT_EXPORT="fastdebug"
 234       ;;
 235     slowdebug )
 236       VARIANT="DBG"
 237       FASTDEBUG="false"
 238       DEBUG_CLASSFILES="true"
 239       BUILD_VARIANT_RELEASE="-debug"
 240       HOTSPOT_DEBUG_LEVEL="debug"
 241       HOTSPOT_EXPORT="debug"
 242       ;;
 243     optimized )
 244       VARIANT="OPT"
 245       FASTDEBUG="false"
 246       DEBUG_CLASSFILES="false"
 247       BUILD_VARIANT_RELEASE="-optimized"
 248       HOTSPOT_DEBUG_LEVEL="optimized"
 249       HOTSPOT_EXPORT="optimized"
 250       ;;
 251   esac
 252 
 253   # The debug level 'optimized' is a little special because it is currently only
 254   # applicable to the HotSpot build where it means to build a completely
 255   # optimized version of the VM without any debugging code (like for the
 256   # 'release' debug level which is called 'product' in the HotSpot build) but
 257   # with the exception that it can contain additional code which is otherwise
 258   # protected by '#ifndef PRODUCT' macros. These 'optimized' builds are used to
 259   # test new and/or experimental features which are not intended for customer
 260   # shipment. Because these new features need to be tested and benchmarked in
 261   # real world scenarios, we want to build the containing JDK at the 'release'
 262   # debug level.
 263   if test "x$DEBUG_LEVEL" = xoptimized; then
 264     DEBUG_LEVEL="release"
 265   fi
 266 
 267   #####
 268   # Generate the legacy makefile targets for hotspot.
 269   # The hotspot api for selecting the build artifacts, really, needs to be improved.
 270   # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
 271   # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
 272   # But until then ...
 273   HOTSPOT_TARGET=""
 274 
 275   if test "x$JVM_VARIANT_SERVER" = xtrue; then
 276     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
 277   fi
 278 
 279   if test "x$JVM_VARIANT_CLIENT" = xtrue; then
 280     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
 281   fi
 282 
 283   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
 284     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
 285   fi
 286 
 287   if test "x$JVM_VARIANT_KERNEL" = xtrue; then
 288     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
 289   fi
 290 
 291   if test "x$JVM_VARIANT_ZERO" = xtrue; then
 292     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
 293   fi
 294 
 295   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
 296     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
 297   fi
 298 
 299   if test "x$JVM_VARIANT_CORE" = xtrue; then
 300     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
 301   fi
 302 
 303   HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
 304 
 305   # On Macosx universal binaries are produced, but they only contain
 306   # 64 bit intel. This invalidates control of which jvms are built
 307   # from configure, but only server is valid anyway. Fix this
 308   # when hotspot makefiles are rewritten.
 309   if test "x$MACOSX_UNIVERSAL" = xtrue; then
 310     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
 311   fi
 312 
 313   #####
 314 
 315   AC_SUBST(DEBUG_LEVEL)
 316   AC_SUBST(VARIANT)
 317   AC_SUBST(FASTDEBUG)
 318   AC_SUBST(DEBUG_CLASSFILES)
 319   AC_SUBST(BUILD_VARIANT_RELEASE)
 320 ])
 321 
 322 
 323 ###############################################################################
 324 #
 325 # Should we build only OpenJDK even if closed sources are present?
 326 #
 327 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
 328 [
 329   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
 330       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
 331 
 332   AC_MSG_CHECKING([for presence of closed sources])
 333   if test -d "$SRC_ROOT/jdk/src/closed"; then
 334     CLOSED_SOURCE_PRESENT=yes
 335   else
 336     CLOSED_SOURCE_PRESENT=no
 337   fi
 338   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
 339 
 340   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
 341   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
 342   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
 343 
 344   if test "x$CLOSED_SOURCE_PRESENT" = xno; then
 345     OPENJDK=true
 346     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 347       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
 348     fi
 349   else
 350     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
 351       OPENJDK=true
 352     else
 353       OPENJDK=false
 354     fi
 355   fi
 356 
 357   if test "x$OPENJDK" = "xtrue"; then
 358     SET_OPENJDK="OPENJDK=true"
 359   fi
 360 
 361   AC_SUBST(SET_OPENJDK)
 362 
 363   # custom-make-dir is deprecated. Please use your custom-hook.m4 to override
 364   # the IncludeCustomExtension macro.
 365   BASIC_DEPRECATED_ARG_WITH(custom-make-dir)
 366 ])
 367 
 368 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
 369 [
 370 
 371   ###############################################################################
 372   #
 373   # Should we build a JDK/JVM with headful support (ie a graphical ui)?
 374   # We always build headless support.
 375   #
 376   AC_MSG_CHECKING([headful support])
 377   AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
 378       [disable building headful support (graphical UI support) @<:@enabled@:>@])],
 379       [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
 380 
 381   SUPPORT_HEADLESS=yes
 382   BUILD_HEADLESS="BUILD_HEADLESS:=true"
 383 
 384   if test "x$SUPPORT_HEADFUL" = xyes; then
 385     # We are building both headful and headless.
 386     headful_msg="include support for both headful and headless"
 387   fi
 388 
 389   if test "x$SUPPORT_HEADFUL" = xno; then
 390     # Thus we are building headless only.
 391     BUILD_HEADLESS="BUILD_HEADLESS:=true"
 392     headful_msg="headless only"
 393   fi
 394 
 395   AC_MSG_RESULT([$headful_msg])
 396 
 397   AC_SUBST(SUPPORT_HEADLESS)
 398   AC_SUBST(SUPPORT_HEADFUL)
 399   AC_SUBST(BUILD_HEADLESS)
 400 
 401   # Control wether Hotspot runs Queens test after build.
 402   AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
 403       [run the Queens test after Hotspot build @<:@disabled@:>@])],,
 404       [enable_hotspot_test_in_build=no])
 405   if test "x$enable_hotspot_test_in_build" = "xyes"; then
 406     TEST_IN_BUILD=true
 407   else
 408     TEST_IN_BUILD=false
 409   fi
 410   AC_SUBST(TEST_IN_BUILD)
 411 
 412   ###############################################################################
 413   #
 414   # Choose cacerts source file
 415   #
 416   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
 417       [specify alternative cacerts file])])
 418   if test "x$with_cacerts_file" != x; then
 419     CACERTS_FILE=$with_cacerts_file
 420   fi
 421   AC_SUBST(CACERTS_FILE)
 422 
 423   ###############################################################################
 424   #
 425   # Enable or disable unlimited crypto
 426   #
 427   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
 428       [Enable unlimited crypto policy @<:@disabled@:>@])],,
 429       [enable_unlimited_crypto=no])
 430   if test "x$enable_unlimited_crypto" = "xyes"; then
 431     UNLIMITED_CRYPTO=true
 432   else
 433     UNLIMITED_CRYPTO=false
 434   fi
 435   AC_SUBST(UNLIMITED_CRYPTO)
 436 
 437   ###############################################################################
 438   #
 439   # Compress jars
 440   #
 441   COMPRESS_JARS=false
 442 
 443   AC_SUBST(COMPRESS_JARS)
 444 
 445   # Setup default copyright year. Mostly overridden when building close to a new year.
 446   AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
 447       [Set copyright year value for build @<:@current year@:>@])])
 448   if test "x$with_copyright_year" = xyes; then
 449     AC_MSG_ERROR([Copyright year must have a value])
 450   elif test "x$with_copyright_year" != x; then
 451     COPYRIGHT_YEAR="$with_copyright_year"
 452   else
 453     COPYRIGHT_YEAR=`date +'%Y'`
 454   fi
 455   AC_SUBST(COPYRIGHT_YEAR)
 456 ])
 457 
 458 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
 459 [
 460   HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
 461   AC_SUBST(HOTSPOT_MAKE_ARGS)
 462 
 463   # The name of the Service Agent jar.
 464   SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
 465   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 466     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
 467   fi
 468   AC_SUBST(SALIB_NAME)
 469 ])
 470 
 471 ###############################################################################
 472 #
 473 # Enable or disable the elliptic curve crypto implementation
 474 #
 475 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
 476 [
 477   AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
 478 
 479   if test -d "${SRC_ROOT}/jdk/src/jdk.crypto.ec/share/native/libsunec/impl"; then
 480     ENABLE_INTREE_EC=yes
 481     AC_MSG_RESULT([yes])
 482   else
 483     ENABLE_INTREE_EC=no
 484     AC_MSG_RESULT([no])
 485   fi
 486 
 487   AC_SUBST(ENABLE_INTREE_EC)
 488 ])
 489 
 490 
 491 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
 492 [
 493   #
 494   # NATIVE_DEBUG_SYMBOLS
 495   # This must be done after the toolchain is setup, since we're looking at objcopy.
 496   #
 497   AC_MSG_CHECKING([what type of native debug symbols to use])
 498   AC_ARG_WITH([native-debug-symbols],
 499       [AS_HELP_STRING([--with-native-debug-symbols],
 500       [set the native debug symbol configuration (none, internal, external, zipped) @<:@zipped@:>@])],
 501       [],
 502       [with_native_debug_symbols="zipped"])
 503   NATIVE_DEBUG_SYMBOLS=$with_native_debug_symbols
 504   AC_MSG_RESULT([$NATIVE_DEBUG_SYMBOLS])
 505 
 506   if test "x$NATIVE_DEBUG_SYMBOLS" = xzipped; then
 507 
 508     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 509       if test "x$OBJCOPY" = x; then
 510         # enabling of enable-debug-symbols and can't find objcopy
 511         # this is an error
 512         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 513       fi
 514     fi
 515 
 516     ENABLE_DEBUG_SYMBOLS=true
 517     ZIP_DEBUGINFO_FILES=true
 518     DEBUG_BINARIES=true
 519     STRIP_POLICY=min_strip
 520   elif test "x$NATIVE_DEBUG_SYMBOLS" = xnone; then
 521     ENABLE_DEBUG_SYMBOLS=false
 522     ZIP_DEBUGINFO_FILES=false
 523     DEBUG_BINARIES=false
 524     STRIP_POLICY=no_strip
 525   elif test "x$NATIVE_DEBUG_SYMBOLS" = xinternal; then
 526     ENABLE_DEBUG_SYMBOLS=false  # -g option only
 527     ZIP_DEBUGINFO_FILES=false
 528     DEBUG_BINARIES=true
 529     STRIP_POLICY=no_strip
 530     STRIP=""
 531   elif test "x$NATIVE_DEBUG_SYMBOLS" = xexternal; then
 532 
 533     if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 534       if test "x$OBJCOPY" = x; then
 535         # enabling of enable-debug-symbols and can't find objcopy
 536         # this is an error
 537         AC_MSG_ERROR([Unable to find objcopy, cannot enable native debug symbols])
 538       fi
 539     fi
 540 
 541     ENABLE_DEBUG_SYMBOLS=true
 542     ZIP_DEBUGINFO_FILES=false
 543     DEBUG_BINARIES=true
 544     STRIP_POLICY=min_strip
 545   else
 546     AC_MSG_ERROR([Allowed native debug symbols are: none, internal, external, zipped])
 547   fi
 548 
 549   # --enable-debug-symbols is deprecated.
 550   # Please use --with-native-debug-symbols=[internal,external,zipped] .
 551   BASIC_DEPRECATED_ARG_ENABLE(debug-symbols, debug_symbols,
 552         [Please use --with-native-debug-symbols=[[internal,external,zipped]] .])
 553 
 554   # --enable-zip-debug-info is deprecated.
 555   # Please use --with-native-debug-symbols=zipped .
 556   BASIC_DEPRECATED_ARG_ENABLE(zip-debug-info, zip_debug_info,
 557                               [Please use --with-native-debug-symbols=zipped .])
 558 
 559   AC_SUBST(NATIVE_DEBUG_SYMBOLS)
 560   AC_SUBST(DEBUG_BINARIES)
 561   AC_SUBST(STRIP_POLICY)
 562   AC_SUBST(ENABLE_DEBUG_SYMBOLS)
 563   AC_SUBST(ZIP_DEBUGINFO_FILES)
 564 ])
 565 
 566 ################################################################################
 567 #
 568 # Gcov coverage data for hotspot
 569 #
 570 AC_DEFUN_ONCE([JDKOPT_SETUP_CODE_COVERAGE],
 571 [
 572   AC_ARG_ENABLE(native-coverage, [AS_HELP_STRING([--enable-native-coverage],
 573       [enable native compilation with code coverage data@<:@disabled@:>@])])
 574   GCOV_ENABLED="false"
 575   if test "x$enable_native_coverage" = "xyes"; then
 576     if test "x$TOOLCHAIN_TYPE" = "xgcc"; then
 577       AC_MSG_CHECKING([if native coverage is enabled])
 578       AC_MSG_RESULT([yes])
 579       GCOV_CFLAGS="-fprofile-arcs -ftest-coverage -fno-inline"
 580       GCOV_LDFLAGS="-fprofile-arcs"
 581       LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $GCOV_CFLAGS"
 582       LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $GCOV_CFLAGS"
 583       LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $GCOV_LDFLAGS"
 584       CFLAGS_JDKLIB="$CFLAGS_JDKLIB $GCOV_CFLAGS"
 585       CFLAGS_JDKEXE="$CFLAGS_JDKEXE $GCOV_CFLAGS"
 586       CXXFLAGS_JDKLIB="$CXXFLAGS_JDKLIB $GCOV_CFLAGS"
 587       CXXFLAGS_JDKEXE="$CXXFLAGS_JDKEXE $GCOV_CFLAGS"
 588       LDFLAGS_JDKLIB="$LDFLAGS_JDKLIB $GCOV_LDFLAGS"
 589       LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE $GCOV_LDFLAGS"
 590       GCOV_ENABLED="true"
 591     else
 592       AC_MSG_ERROR([--enable-native-coverage only works with toolchain type gcc])
 593     fi
 594   elif test "x$enable_native_coverage" = "xno"; then
 595     AC_MSG_CHECKING([if native coverage is enabled])
 596     AC_MSG_RESULT([no])
 597   elif test "x$enable_native_coverage" != "x"; then
 598     AC_MSG_ERROR([--enable-native-coverage can only be assigned "yes" or "no"])
 599   fi
 600 
 601   AC_SUBST(GCOV_ENABLED)
 602 ])
 603 
 604 ################################################################################
 605 #
 606 # Static build support.  When enabled will generate static 
 607 # libraries instead of shared libraries for all JDK libs.
 608 #
 609 AC_DEFUN_ONCE([JDKOPT_SETUP_STATIC_BUILD],
 610 [
 611   AC_ARG_ENABLE([static-build], [AS_HELP_STRING([--enable-static-build],
 612     [enable static library build @<:@disabled@:>@])])
 613   STATIC_BUILD=false
 614   if test "x$enable_static_build" = "xyes"; then
 615     AC_MSG_CHECKING([if static build is enabled])
 616     AC_MSG_RESULT([yes])
 617     if test "x$OPENJDK_TARGET_OS" != "xmacosx"; then
 618       AC_MSG_ERROR([--enable-static-build is only supported for macosx builds])
 619     fi
 620     STATIC_BUILD_CFLAGS="-DSTATIC_BUILD=1"
 621     LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $STATIC_BUILD_CFLAGS"
 622     LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $STATIC_BUILD_CFLAGS"
 623     CFLAGS_JDKLIB_EXTRA="$CFLAGS_JDKLIB_EXTRA $STATIC_BUILD_CFLAGS"
 624     CXXFLAGS_JDKLIB_EXTRA="$CXXFLAGS_JDKLIB_EXTRA $STATIC_BUILD_CFLAGS"
 625     STATIC_BUILD=true
 626   elif test "x$enable_static_build" = "xno"; then
 627     AC_MSG_CHECKING([if static build is enabled])
 628     AC_MSG_RESULT([no])
 629   elif test "x$enable_static_build" != "x"; then
 630     AC_MSG_ERROR([--enable-static-build can only be assigned "yes" or "no"])
 631   fi
 632 
 633   AC_SUBST(STATIC_BUILD)
 634 ])
 635 
 636