1 #
2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 aarch64)
52 VAR_CPU=aarch64
53 VAR_CPU_ARCH=aarch64
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 powerpc)
58 VAR_CPU=ppc
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=big
62 ;;
63 powerpc64)
64 VAR_CPU=ppc64
65 VAR_CPU_ARCH=ppc
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=big
68 ;;
69 powerpc64le)
70 VAR_CPU=ppc64le
71 VAR_CPU_ARCH=ppc
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 s390)
76 VAR_CPU=s390
77 VAR_CPU_ARCH=s390
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 s390x)
82 VAR_CPU=s390x
83 VAR_CPU_ARCH=s390
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 sparc)
88 VAR_CPU=sparc
89 VAR_CPU_ARCH=sparc
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=big
92 ;;
93 sparcv9|sparc64)
94 VAR_CPU=sparcv9
95 VAR_CPU_ARCH=sparc
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 *)
100 AC_MSG_ERROR([unsupported cpu $1])
101 ;;
102 esac
103 ])
104
105 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
106 # Converts autoconf style OS name to OpenJDK style, into
107 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
108 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
109 [
110 case "$1" in
111 *linux*)
112 VAR_OS=linux
113 VAR_OS_TYPE=unix
114 ;;
115 *solaris*)
116 VAR_OS=solaris
117 VAR_OS_TYPE=unix
118 ;;
119 *darwin*)
120 VAR_OS=macosx
121 VAR_OS_TYPE=unix
122 ;;
123 *bsd*)
124 VAR_OS=bsd
125 VAR_OS_TYPE=unix
126 ;;
127 *cygwin*)
128 VAR_OS=windows
129 VAR_OS_ENV=windows.cygwin
130 ;;
131 *mingw*)
132 VAR_OS=windows
133 VAR_OS_ENV=windows.msys
134 ;;
135 *aix*)
136 VAR_OS=aix
137 VAR_OS_TYPE=unix
138 ;;
139 *)
140 AC_MSG_ERROR([unsupported operating system $1])
141 ;;
142 esac
143 ])
144
145 # Expects $host_os $host_cpu $build_os and $build_cpu
146 # and $with_target_bits to have been setup!
147 #
148 # Translate the standard triplet(quadruplet) definition
149 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
150 # OPENJDK_BUILD_OS, etc.
151 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
152 [
153 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
154 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
155 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
156 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
157 OPENJDK_TARGET_AUTOCONF_NAME="$host"
158 OPENJDK_BUILD_AUTOCONF_NAME="$build"
159 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
160 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
161
162 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
163 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
164 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
165 # ..and setup our own variables. (Do this explicitely to facilitate searching)
166 OPENJDK_BUILD_OS="$VAR_OS"
167 if test "x$VAR_OS_TYPE" != x; then
168 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
169 else
170 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
171 fi
172 if test "x$VAR_OS_ENV" != x; then
173 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
174 else
175 OPENJDK_BUILD_OS_ENV="$VAR_OS"
176 fi
177 OPENJDK_BUILD_CPU="$VAR_CPU"
178 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
179 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
180 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
181 AC_SUBST(OPENJDK_BUILD_OS)
182 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
183 AC_SUBST(OPENJDK_BUILD_OS_ENV)
184 AC_SUBST(OPENJDK_BUILD_CPU)
185 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
186 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
187 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
188
189 AC_MSG_CHECKING([openjdk-build os-cpu])
190 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
191
192 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
193 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
194 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
195 # ... and setup our own variables. (Do this explicitely to facilitate searching)
196 OPENJDK_TARGET_OS="$VAR_OS"
197 if test "x$VAR_OS_TYPE" != x; then
198 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
199 else
200 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
201 fi
202 if test "x$VAR_OS_ENV" != x; then
203 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
204 else
205 OPENJDK_TARGET_OS_ENV="$VAR_OS"
206 fi
207 OPENJDK_TARGET_CPU="$VAR_CPU"
208 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
209 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
210 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
211 AC_SUBST(OPENJDK_TARGET_OS)
212 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
213 AC_SUBST(OPENJDK_TARGET_OS_ENV)
214 AC_SUBST(OPENJDK_TARGET_CPU)
215 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
216 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
217 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
218
219 AC_MSG_CHECKING([openjdk-target os-cpu])
220 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
221 ])
222
223 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
224 # accordingly. Must be done after setting up build and target system, but before
225 # doing anything else with these values.
226 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
227 [
228 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
229 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
230
231 # We have three types of compiles:
232 # native == normal compilation, target system == build system
233 # cross == traditional cross compilation, target system != build system; special toolchain needed
234 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
235 #
236 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
237 # We're doing a proper cross-compilation
238 COMPILE_TYPE="cross"
239 else
240 COMPILE_TYPE="native"
241 fi
242
243 if test "x$with_target_bits" != x; then
244 if test "x$COMPILE_TYPE" = "xcross"; then
245 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
246 fi
247
248 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
249 # A reduced build is requested
250 COMPILE_TYPE="reduced"
251 OPENJDK_TARGET_CPU_BITS=32
252 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
253 OPENJDK_TARGET_CPU=x86
254 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
255 OPENJDK_TARGET_CPU=sparc
256 else
257 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
258 fi
259 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
260 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
261 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
262 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
263 else
264 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
265 fi
266 fi
267 AC_SUBST(COMPILE_TYPE)
268
269 AC_MSG_CHECKING([compilation type])
270 AC_MSG_RESULT([$COMPILE_TYPE])
271 ])
272
273 # Setup the legacy variables, for controlling the old makefiles.
274 #
275 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
276 [
277 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
278 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
279
280 # ZERO_ARCHDEF is used to enable architecture-specific code.
281 # This is used in legacy hotspot build.
282 ZERO_ARCHDEF="$HOTSPOT_TARGET_CPU_DEFINE"
283 AC_SUBST(ZERO_ARCHDEF)
284
285 ])
286
287 # $1 - Either TARGET or BUILD to setup the variables for.
288 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
289 [
290 # Also store the legacy naming of the cpu.
291 # Ie i586 and amd64 instead of x86 and x86_64
292 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
293 if test "x$OPENJDK_$1_CPU" = xx86; then
294 OPENJDK_$1_CPU_LEGACY="i586"
295 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
296 # On all platforms except MacOSX replace x86_64 with amd64.
297 OPENJDK_$1_CPU_LEGACY="amd64"
298 fi
299 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
300
301 # And the second legacy naming of the cpu.
302 # Ie i386 and amd64 instead of x86 and x86_64.
303 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
304 if test "x$OPENJDK_$1_CPU" = xx86; then
305 OPENJDK_$1_CPU_LEGACY_LIB="i386"
306 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
307 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
308 fi
309 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
310
311 # This is the name of the cpu (but using i386 and amd64 instead of
312 # x86 and x86_64, respectively), preceeded by a /, to be used when
313 # locating libraries. On macosx, it's empty, though.
314 OPENJDK_$1_CPU_LIBDIR="/$OPENJDK_$1_CPU_LEGACY_LIB"
315 if test "x$OPENJDK_$1_OS" = xmacosx; then
316 OPENJDK_$1_CPU_LIBDIR=""
317 fi
318 AC_SUBST(OPENJDK_$1_CPU_LIBDIR)
319
320 # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
321 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
322 # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
323 OPENJDK_$1_CPU_ISADIR=""
324 if test "x$OPENJDK_$1_OS" = xsolaris; then
325 if test "x$OPENJDK_$1_CPU" = xx86_64; then
326 OPENJDK_$1_CPU_ISADIR="/amd64"
327 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
328 OPENJDK_$1_CPU_ISADIR="/sparcv9"
329 fi
330 fi
331 AC_SUBST(OPENJDK_$1_CPU_ISADIR)
332
333 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
334 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
335 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
336 # On linux only, we replace x86 with i386.
337 OPENJDK_$1_CPU_OSARCH="i386"
338 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
339 # On all platforms except macosx, we replace x86_64 with amd64.
340 OPENJDK_$1_CPU_OSARCH="amd64"
341 fi
342 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
343
344 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
345 if test "x$OPENJDK_$1_CPU" = xx86; then
346 OPENJDK_$1_CPU_JLI="i386"
347 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
348 # On all platforms except macosx, we replace x86_64 with amd64.
349 OPENJDK_$1_CPU_JLI="amd64"
350 fi
351 # Now setup the -D flags for building libjli.
352 OPENJDK_$1_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_$1_CPU_JLI\"'"
353 if test "x$OPENJDK_$1_OS" = xsolaris; then
354 if test "x$OPENJDK_$1_CPU_ARCH" = xsparc; then
355 OPENJDK_$1_CPU_JLI_CFLAGS="$OPENJDK_$1_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
356 elif test "x$OPENJDK_$1_CPU_ARCH" = xx86; then
357 OPENJDK_$1_CPU_JLI_CFLAGS="$OPENJDK_$1_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
358 fi
359 fi
360 AC_SUBST(OPENJDK_$1_CPU_JLI_CFLAGS)
361
362 if test "x$OPENJDK_$1_OS" = xmacosx; then
363 OPENJDK_$1_OS_EXPORT_DIR=macosx
364 else
365 OPENJDK_$1_OS_EXPORT_DIR=${OPENJDK_$1_OS_TYPE}
366 fi
367 AC_SUBST(OPENJDK_$1_OS_EXPORT_DIR)
368
369 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
370 # Macosx is osx and x86_64 is x64
371 if test "x$OPENJDK_$1_OS" = xmacosx; then
372 OPENJDK_$1_OS_BUNDLE="osx"
373 else
374 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
375 fi
376 if test "x$OPENJDK_$1_CPU" = xx86_64; then
377 OPENJDK_$1_CPU_BUNDLE="x64"
378 else
379 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
380 fi
381 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
382 AC_SUBST(OPENJDK_$1_OS_BUNDLE)
383 AC_SUBST(OPENJDK_$1_CPU_BUNDLE)
384 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
385
386 if test "x$OPENJDK_$1_CPU_BITS" = x64; then
387 A_LP64="LP64:="
388 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
389 # unpack200.exe
390 if test "x$OPENJDK_$1_OS" = xlinux || test "x$OPENJDK_$1_OS" = xmacosx; then
391 OPENJDK_$1_ADD_LP64="-D_LP64=1"
392 fi
393 fi
394 AC_SUBST(LP64,$A_LP64)
395
396 if test "x$COMPILE_TYPE" = "xcross"; then
397 # FIXME: ... or should this include reduced builds..?
398 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
399 else
400 DEFINE_CROSS_COMPILE_ARCH=""
401 fi
402 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
403
404 # Convert openjdk platform names to hotspot names
405
406 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
407 if test "x$OPENJDK_$1_OS" = xmacosx; then
408 HOTSPOT_$1_OS=bsd
409 fi
410 AC_SUBST(HOTSPOT_$1_OS)
411
412 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
413 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
414 HOTSPOT_$1_OS_TYPE=posix
415 fi
416 AC_SUBST(HOTSPOT_$1_OS_TYPE)
417
418 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
419 if test "x$OPENJDK_$1_CPU" = xx86; then
420 HOTSPOT_$1_CPU=x86_32
421 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
422 HOTSPOT_$1_CPU=sparc
423 elif test "x$OPENJDK_$1_CPU" = xppc64; then
424 HOTSPOT_$1_CPU=ppc_64
425 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
426 HOTSPOT_$1_CPU=ppc_64
427 fi
428 AC_SUBST(HOTSPOT_$1_CPU)
429
430 # This is identical with OPENJDK_*, but define anyway for consistency.
431 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
432 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
433
434 # Setup HOTSPOT_$1_CPU_DEFINE
435 if test "x$OPENJDK_$1_CPU" = xx86; then
436 HOTSPOT_$1_CPU_DEFINE=IA32
437 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
438 HOTSPOT_$1_CPU_DEFINE=AMD64
439 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
440 HOTSPOT_$1_CPU_DEFINE=SPARC
441 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
442 HOTSPOT_$1_CPU_DEFINE=AARCH64
443 elif test "x$OPENJDK_$1_CPU" = xppc64; then
444 HOTSPOT_$1_CPU_DEFINE=PPC64
445 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
446 HOTSPOT_$1_CPU_DEFINE=PPC64
447
448 # The cpu defines below are for zero, we don't support them directly.
449 elif test "x$OPENJDK_$1_CPU" = xsparc; then
450 HOTSPOT_$1_CPU_DEFINE=SPARC
451 elif test "x$OPENJDK_$1_CPU" = xppc; then
452 HOTSPOT_$1_CPU_DEFINE=PPC32
453 elif test "x$OPENJDK_$1_CPU" = xs390; then
454 HOTSPOT_$1_CPU_DEFINE=S390
455 elif test "x$OPENJDK_$1_CPU" = xs390x; then
456 HOTSPOT_$1_CPU_DEFINE=S390
457 fi
458 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
459
460 ])
461
462 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
463 [
464 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
465 REQUIRED_OS_NAME=SunOS
466 REQUIRED_OS_VERSION=5.10
467 fi
468 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
469 REQUIRED_OS_NAME=Linux
470 REQUIRED_OS_VERSION=2.6
471 fi
472 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
473 REQUIRED_OS_NAME=Windows
474 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
475 REQUIRED_OS_VERSION=5.2
476 else
477 REQUIRED_OS_VERSION=5.1
478 fi
479 fi
480 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
481 REQUIRED_OS_NAME=Darwin
482 REQUIRED_OS_VERSION=11.2
483 fi
484 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
485 REQUIRED_OS_NAME=AIX
486 REQUIRED_OS_VERSION=7.1
487 fi
488
489 AC_SUBST(REQUIRED_OS_NAME)
490 AC_SUBST(REQUIRED_OS_VERSION)
491 ])
492
493 #%%% Build and target systems %%%
494 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
495 [
496 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
497 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
498 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
499 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
500 # to use the configure naming style.
501 AC_CANONICAL_BUILD
502 AC_CANONICAL_HOST
503 AC_CANONICAL_TARGET
504
505 PLATFORM_EXTRACT_TARGET_AND_BUILD
506 PLATFORM_SETUP_TARGET_CPU_BITS
507 PLATFORM_SET_RELEASE_FILE_OS_VALUES
508 PLATFORM_SETUP_LEGACY_VARS
509 ])
510
511 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
512 [
513 ###############################################################################
514
515 # Note that this is the build platform OS version!
516
517 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
518 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
519 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
520 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
521 AC_SUBST(OS_VERSION_MAJOR)
522 AC_SUBST(OS_VERSION_MINOR)
523 AC_SUBST(OS_VERSION_MICRO)
524 ])
525
526 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
527 # Add -mX to various FLAGS variables.
528 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
529 [
530 # When we add flags to the "official" CFLAGS etc, we need to
531 # keep track of these additions in ADDED_CFLAGS etc. These
532 # will later be checked to make sure only controlled additions
533 # have been made to CFLAGS etc.
534 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
535 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
536 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
537
538 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
539 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
540 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
541
542 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
543 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
544 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
545
546 JVM_CFLAGS="$JVM_CFLAGS $ADDED_CFLAGS"
547 JVM_LDFLAGS="$JVM_LDFLAGS $ADDED_LDFLAGS"
548 JVM_ASFLAGS="$JVM_ASFLAGS $ADDED_CFLAGS"
549 ])
550
551 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
552 [
553 ###############################################################################
554 #
555 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
556 # (The JVM can use 32 or 64 bit Java pointers but that decision
557 # is made at runtime.)
558 #
559
560 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
561 # Always specify -m flag on Solaris
562 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
563 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
564 elif test "x$COMPILE_TYPE" = xreduced; then
565 if test "x$OPENJDK_TARGET_OS_TYPE" = xunix; then
566 # Specify -m if running reduced on unix platforms
567 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
568 fi
569 fi
570 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
571 JVM_CFLAGS="$JVM_CFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
572 JVM_LDFLAGS="$JVM_LDFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
573 JVM_ASFLAGS="$JVM_ASFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
574 fi
575
576 # Make compilation sanity check
577 AC_CHECK_HEADERS([stdio.h], , [
578 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
579 if test "x$COMPILE_TYPE" = xreduced; then
580 HELP_MSG_MISSING_DEPENDENCY([reduced])
581 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
582 elif test "x$COMPILE_TYPE" = xcross; then
583 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
584 fi
585 AC_MSG_ERROR([Cannot continue.])
586 ])
587
588 AC_CHECK_SIZEOF([int *], [1111])
589
590 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
591 if test "x$ac_cv_sizeof_int_p" = x; then
592 # The test failed, lets stick to the assumed value.
593 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
594 else
595 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
596
597 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
598 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
599 # Let's try to implicitely set the compilers target architecture and retry the test
600 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
601 AC_MSG_NOTICE([Retrying with platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
602 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
603
604 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
605 unset ac_cv_sizeof_int_p
606 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
607 cat >>confdefs.h <<_ACEOF
608 #undef SIZEOF_INT_P
609 _ACEOF
610
611 AC_CHECK_SIZEOF([int *], [1111])
612
613 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
614
615 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
616 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
617 if test "x$COMPILE_TYPE" = xreduced; then
618 HELP_MSG_MISSING_DEPENDENCY([reduced])
619 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
620 elif test "x$COMPILE_TYPE" = xcross; then
621 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
622 fi
623 AC_MSG_ERROR([Cannot continue.])
624 fi
625 fi
626 fi
627
628 AC_MSG_CHECKING([for target address size])
629 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
630 ])
631
632 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
633 [
634 ###############################################################################
635 #
636 # Is the target little of big endian?
637 #
638 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
639
640 if test "x$ENDIAN" = xuniversal_endianness; then
641 AC_MSG_ERROR([Building with both big and little endianness is not supported])
642 fi
643 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
644 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
645 fi
646 ])