1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # All valid JVM features, regardless of platform
  27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
  28     graal vm-structs jni-check services management cmsgc g1gc parallelgc serialgc nmt cds \
  29     static-build link-time-opt aot jfr no-speculative-cti"
  30 
  31 # Deprecated JVM features (these are ignored, but with a warning)
  32 DEPRECATED_JVM_FEATURES="trace"
  33 
  34 # All valid JVM variants
  35 VALID_JVM_VARIANTS="server client minimal hardened core zero custom"
  36 
  37 ###############################################################################
  38 # Check if the specified JVM variant should be built. To be used in shell if
  39 # constructs, like this:
  40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
  41 #
  42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
  43 
  44 # Definition kept in one line to allow inlining in if statements.
  45 # Additional [] needed to keep m4 from mangling shell constructs.
  46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
  47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
  48 
  49 ###############################################################################
  50 # Check if the specified JVM features are explicitly enabled. To be used in
  51 # shell if constructs, like this:
  52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
  53 #
  54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
  55 
  56 # Definition kept in one line to allow inlining in if statements.
  57 # Additional [] needed to keep m4 from mangling shell constructs.
  58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
  59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
  60 
  61 ###############################################################################
  62 # Check which variants of the JVM that we want to build. Available variants are:
  63 #   server: normal interpreter, and a tiered C1/C2 compiler
  64 #   hardened: same as server but compiled with speculative calls disabled
  65 #   client: normal interpreter, and C1 (no C2 compiler)
  66 #   minimal: reduced form of client with optional features stripped out
  67 #   core: normal interpreter only, no compiler
  68 #   zero: C++ based interpreter only, no compiler
  69 #   custom: baseline JVM with no default features
  70 #
  71 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
  72 [
  73   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  74       [JVM variants (separated by commas) to build (server,hardened,client,minimal,core,zero,custom) @<:@server@:>@])])
  75 
  76   SETUP_HOTSPOT_TARGET_CPU_PORT
  77 
  78   if test "x$with_jvm_variants" = x; then
  79     with_jvm_variants="server"
  80   fi
  81   JVM_VARIANTS_OPT="$with_jvm_variants"
  82 
  83   # Has the user listed more than one variant?
  84   # Additional [] needed to keep m4 from mangling shell constructs.
  85   if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
  86     BUILDING_MULTIPLE_JVM_VARIANTS=true
  87   else
  88     BUILDING_MULTIPLE_JVM_VARIANTS=false
  89   fi
  90   # Replace the commas with AND for use in the build directory name.
  91   JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
  92 
  93   AC_MSG_CHECKING([which variants of the JVM to build])
  94   # JVM_VARIANTS is a space-separated list.
  95   # Also use minimal, not minimal1 (which is kept for backwards compatibility).
  96   JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
  97   AC_MSG_RESULT([$JVM_VARIANTS])
  98 
  99   # Check that the selected variants are valid
 100   BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
 101   if test "x$INVALID_VARIANTS" != x; then
 102     AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
 103     AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
 104     AC_MSG_ERROR([Cannot continue])
 105   fi
 106 
 107   # All "special" variants share the same output directory ("server")
 108   VALID_MULTIPLE_JVM_VARIANTS="server client minimal hardened"
 109   BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
 110   if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
 111     AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
 112   fi
 113 
 114   # The "main" variant is the one used by other libs to link against during the
 115   # build.
 116   if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
 117     MAIN_VARIANT_PRIO_ORDER="server client minimal hardened"
 118     for variant in $MAIN_VARIANT_PRIO_ORDER; do
 119       if HOTSPOT_CHECK_JVM_VARIANT($variant); then
 120         JVM_VARIANT_MAIN="$variant"
 121         break
 122       fi
 123     done
 124   else
 125     JVM_VARIANT_MAIN="$JVM_VARIANTS"
 126   fi
 127 
 128   AC_SUBST(JVM_VARIANTS)
 129   AC_SUBST(VALID_JVM_VARIANTS)
 130   AC_SUBST(JVM_VARIANT_MAIN)
 131   AC_SUBST(VALID_MULTIPLE_JVM_VARIANTS)
 132 
 133   if HOTSPOT_CHECK_JVM_VARIANT(zero); then
 134     # zero behaves as a platform and rewrites these values. This is really weird. :(
 135     # We are guaranteed that we do not build any other variants when building zero.
 136     HOTSPOT_TARGET_CPU=zero
 137     HOTSPOT_TARGET_CPU_ARCH=zero
 138   fi
 139 ])
 140 
 141 ###############################################################################
 142 # Check if dtrace should be enabled and has all prerequisites present.
 143 #
 144 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
 145 [
 146   # Test for dtrace dependencies
 147   AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
 148       [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
 149       are present.])])
 150 
 151   DTRACE_DEP_MISSING=false
 152 
 153   AC_MSG_CHECKING([for dtrace tool])
 154   if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
 155     AC_MSG_RESULT([$DTRACE])
 156   else
 157     AC_MSG_RESULT([not found, cannot build dtrace])
 158     DTRACE_DEP_MISSING=true
 159   fi
 160 
 161   AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
 162   if test "x$DTRACE_HEADERS_OK" != "xyes"; then
 163     DTRACE_DEP_MISSING=true
 164   fi
 165 
 166   AC_MSG_CHECKING([if dtrace should be built])
 167   if test "x$enable_dtrace" = "xyes"; then
 168     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 169       AC_MSG_RESULT([no, missing dependencies])
 170       HELP_MSG_MISSING_DEPENDENCY([dtrace])
 171       AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
 172     else
 173       INCLUDE_DTRACE=true
 174       AC_MSG_RESULT([yes, forced])
 175     fi
 176   elif test "x$enable_dtrace" = "xno"; then
 177     INCLUDE_DTRACE=false
 178     AC_MSG_RESULT([no, forced])
 179   elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
 180     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 181       INCLUDE_DTRACE=false
 182       AC_MSG_RESULT([no, missing dependencies])
 183     else
 184       INCLUDE_DTRACE=true
 185       AC_MSG_RESULT([yes, dependencies present])
 186     fi
 187   else
 188     AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
 189   fi
 190 ])
 191 
 192 ################################################################################
 193 # Check if AOT should be enabled
 194 #
 195 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
 196 [
 197   AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
 198       [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
 199 
 200   if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
 201     ENABLE_AOT="true"
 202   elif test "x$enable_aot" = "xyes"; then
 203     ENABLE_AOT="true"
 204   elif test "x$enable_aot" = "xno"; then
 205     ENABLE_AOT="false"
 206     AC_MSG_CHECKING([if aot should be enabled])
 207     AC_MSG_RESULT([no, forced])
 208   else
 209     AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
 210   fi
 211 
 212   if test "x$ENABLE_AOT" = "xtrue"; then
 213     # Only enable AOT on X64 platforms.
 214     if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 215       if test -e "${TOPDIR}/src/jdk.aot"; then
 216         if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
 217           ENABLE_AOT="true"
 218         else
 219           ENABLE_AOT="false"
 220           if test "x$enable_aot" = "xyes"; then
 221             AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
 222           fi
 223         fi
 224       else
 225         ENABLE_AOT="false"
 226         if test "x$enable_aot" = "xyes"; then
 227           AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
 228         fi
 229       fi
 230     else
 231       ENABLE_AOT="false"
 232       if test "x$enable_aot" = "xyes"; then
 233         AC_MSG_ERROR([AOT is currently only supported on x86_64. Remove --enable-aot.])
 234       fi
 235     fi
 236   fi
 237 
 238   AC_SUBST(ENABLE_AOT)
 239 ])
 240 
 241 ################################################################################
 242 # Allow to disable CDS
 243 #
 244 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
 245 [
 246   AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no@:>@],
 247       [enable class data sharing feature in non-minimal VM. Default is yes.])])
 248 
 249   if test "x$enable_cds" = "x" || test "x$enable_cds" = "xyes"; then
 250     ENABLE_CDS="true"
 251   elif test "x$enable_cds" = "xno"; then
 252     ENABLE_CDS="false"
 253   else
 254     AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
 255   fi
 256 
 257   AC_SUBST(ENABLE_CDS)
 258 ])
 259 
 260 ###############################################################################
 261 # Set up all JVM features for each JVM variant.
 262 #
 263 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
 264 [
 265   # Prettify the VALID_JVM_FEATURES string
 266   BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
 267 
 268   # The user can in some cases supply additional jvm features. For the custom
 269   # variant, this defines the entire variant.
 270   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
 271       [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
 272   if test "x$with_jvm_features" != x; then
 273     AC_MSG_CHECKING([user specified JVM feature list])
 274     USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
 275     AC_MSG_RESULT([$user_jvm_feature_list])
 276     # These features will be added to all variant defaults
 277     JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
 278     # These features will be removed from all variant defaults
 279     DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
 280 
 281     # Verify that the user has provided valid features
 282     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
 283     if test "x$INVALID_FEATURES" != x; then
 284       AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
 285       AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
 286       AC_MSG_ERROR([Cannot continue])
 287     fi
 288 
 289     # Check if the user has provided deprecated features
 290     BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
 291     if test "x$DEPRECATED_FEATURES" != x; then
 292       AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
 293       # Filter out deprecated features
 294       BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
 295       BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
 296     fi
 297 
 298   fi
 299 
 300   # Override hotspot cpu definitions for ARM platforms
 301   if test "x$OPENJDK_TARGET_CPU" = xarm; then
 302     HOTSPOT_TARGET_CPU=arm_32
 303     HOTSPOT_TARGET_CPU_DEFINE="ARM32"
 304   elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 305     HOTSPOT_TARGET_CPU=arm_64
 306     HOTSPOT_TARGET_CPU_ARCH=arm
 307   fi
 308 
 309   # Verify that dependencies are met for explicitly set features.
 310   if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
 311     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
 312   fi
 313 
 314   if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
 315     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
 316   fi
 317 
 318   if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
 319     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
 320   fi
 321 
 322   if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
 323     AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
 324   fi
 325 
 326   # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
 327   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 328     if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
 329       NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
 330     fi
 331   fi
 332 
 333   # Turn on additional features based on other parts of configure
 334   if test "x$INCLUDE_DTRACE" = "xtrue"; then
 335     JVM_FEATURES="$JVM_FEATURES dtrace"
 336   else
 337     if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
 338       AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
 339     fi
 340   fi
 341 
 342   if test "x$STATIC_BUILD" = "xtrue"; then
 343     JVM_FEATURES="$JVM_FEATURES static-build"
 344   else
 345     if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
 346       AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
 347     fi
 348   fi
 349 
 350   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 351     if HOTSPOT_CHECK_JVM_FEATURE(zero); then
 352       AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
 353     fi
 354   fi
 355 
 356   # Only enable jvmci on x86_64, sparcv9 and aarch64.
 357   if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 358      test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
 359      test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 360     JVM_FEATURES_jvmci="jvmci"
 361   else
 362     JVM_FEATURES_jvmci=""
 363   fi
 364 
 365   AC_MSG_CHECKING([if jdk.internal.vm.compiler should be built])
 366   if HOTSPOT_CHECK_JVM_FEATURE(graal); then
 367     AC_MSG_RESULT([yes, forced])
 368     if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
 369       AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
 370     fi
 371     INCLUDE_GRAAL="true"
 372   else
 373     # By default enable graal build on x64 or where AOT is available.
 374     # graal build requires jvmci.
 375     if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
 376         (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 377          test "x$ENABLE_AOT" = "xtrue") ; then
 378       AC_MSG_RESULT([yes])
 379       JVM_FEATURES_graal="graal"
 380       INCLUDE_GRAAL="true"
 381     else
 382       AC_MSG_RESULT([no])
 383       JVM_FEATURES_graal=""
 384       INCLUDE_GRAAL="false"
 385     fi
 386   fi
 387 
 388   AC_SUBST(INCLUDE_GRAAL)
 389 
 390   AC_MSG_CHECKING([if aot should be enabled])
 391   if test "x$ENABLE_AOT" = "xtrue"; then
 392     if test "x$enable_aot" = "xyes"; then
 393       AC_MSG_RESULT([yes, forced])
 394     else
 395       AC_MSG_RESULT([yes])
 396     fi
 397     JVM_FEATURES_aot="aot"
 398   else
 399     if test "x$enable_aot" = "xno"; then
 400       AC_MSG_RESULT([no, forced])
 401     else
 402       AC_MSG_RESULT([no])
 403     fi
 404     JVM_FEATURES_aot=""
 405   fi
 406 
 407   if test "x$OPENJDK_TARGET_CPU" = xarm ; then
 408     # Default to use link time optimizations on minimal on arm
 409     JVM_FEATURES_link_time_opt="link-time-opt"
 410   else
 411     JVM_FEATURES_link_time_opt=""
 412   fi
 413 
 414   # All variants but minimal (and custom) get these features
 415   NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc jni-check jvmti management nmt services vm-structs"
 416   if test "x$ENABLE_CDS" = "xtrue"; then
 417     NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
 418   fi
 419 
 420   # Enable features depending on variant.
 421   JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
 422   JVM_FEATURES_hardened="$JVM_FEATURES_server no-speculative-cti"
 423   JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
 424   JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
 425   JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
 426   JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
 427   JVM_FEATURES_custom="$JVM_FEATURES"
 428 
 429   AC_SUBST(JVM_FEATURES_server)
 430   AC_SUBST(JVM_FEATURES_hardened)
 431   AC_SUBST(JVM_FEATURES_client)
 432   AC_SUBST(JVM_FEATURES_core)
 433   AC_SUBST(JVM_FEATURES_minimal)
 434   AC_SUBST(JVM_FEATURES_zero)
 435   AC_SUBST(JVM_FEATURES_custom)
 436 
 437   # Used for verification of Makefiles by check-jvm-feature
 438   AC_SUBST(VALID_JVM_FEATURES)
 439 
 440   # We don't support --with-jvm-interpreter anymore, use zero instead.
 441   BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
 442 ])
 443 
 444 ###############################################################################
 445 # Finalize JVM features once all setup is complete, including custom setup.
 446 #
 447 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
 448 [
 449   for variant in $JVM_VARIANTS; do
 450     AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
 451     features_var_name=JVM_FEATURES_$variant
 452     JVM_FEATURES_FOR_VARIANT=${!features_var_name}
 453 
 454     # Filter out user-requested disabled features
 455     BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
 456 
 457     # Keep feature lists sorted and free of duplicates
 458     BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
 459 
 460     # Update real feature set variable
 461     eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
 462     AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
 463 
 464     # Verify that we have at least one gc selected
 465     GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
 466     if test "x$GC_FEATURES" = x; then
 467       AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
 468     fi
 469 
 470     # Validate features (for configure script errors, not user errors)
 471     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
 472     if test "x$INVALID_FEATURES" != x; then
 473       AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
 474     fi
 475   done
 476 ])
 477 
 478 ################################################################################
 479 #
 480 # Specify which sources will be used to build the 64-bit ARM port
 481 #
 482 # --with-cpu-port=arm64   will use hotspot/src/cpu/arm
 483 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
 484 #
 485 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
 486 [
 487   AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
 488       [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
 489 
 490   if test "x$with_cpu_port" != x; then
 491     if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
 492       AC_MSG_ERROR([--with-cpu-port only available on aarch64])
 493     fi
 494     if test "x$with_cpu_port" != xarm64 && \
 495         test "x$with_cpu_port" != xaarch64; then
 496       AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
 497     fi
 498     HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
 499   fi
 500 ])
 501 
 502 
 503 ################################################################################
 504 # Check if gtest should be built
 505 #
 506 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
 507 [
 508   AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
 509       [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
 510 
 511   if test -e "${TOPDIR}/test/hotspot/gtest"; then
 512     GTEST_DIR_EXISTS="true"
 513   else
 514     GTEST_DIR_EXISTS="false"
 515   fi
 516 
 517   AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
 518   if test "x$enable_hotspot_gtest" = "xyes"; then
 519     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 520       AC_MSG_RESULT([yes, forced])
 521       BUILD_GTEST="true"
 522     else
 523       AC_MSG_ERROR([Cannot build gtest without the test source])
 524     fi
 525   elif test "x$enable_hotspot_gtest" = "xno"; then
 526     AC_MSG_RESULT([no, forced])
 527     BUILD_GTEST="false"
 528   elif test "x$enable_hotspot_gtest" = "x"; then
 529     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 530       AC_MSG_RESULT([yes])
 531       BUILD_GTEST="true"
 532     else
 533       AC_MSG_RESULT([no])
 534       BUILD_GTEST="false"
 535     fi
 536   else
 537     AC_MSG_ERROR([--enable-gtest must be either yes or no])
 538   fi
 539 
 540   AC_SUBST(BUILD_GTEST)
 541 ])