1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc zgc nmt cds \
29 static-build link-time-opt aot jfr no-speculative-cti"
30
31 # Deprecated JVM features (these are ignored, but with a warning)
32 DEPRECATED_JVM_FEATURES="trace"
33
34 # All valid JVM variants
35 VALID_JVM_VARIANTS="server client minimal nonspeculative core zero custom"
36
37 ###############################################################################
38 # Check if the specified JVM variant should be built. To be used in shell if
39 # constructs, like this:
40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
41 #
42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
43
44 # Definition kept in one line to allow inlining in if statements.
45 # Additional [] needed to keep m4 from mangling shell constructs.
46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
48
49 ###############################################################################
50 # Check if the specified JVM features are explicitly enabled. To be used in
51 # shell if constructs, like this:
52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
53 #
54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
55
56 # Definition kept in one line to allow inlining in if statements.
57 # Additional [] needed to keep m4 from mangling shell constructs.
58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
60
61 ###############################################################################
62 # Check which variants of the JVM that we want to build. Available variants are:
63 # server: normal interpreter, and a tiered C1/C2 compiler
64 # nonspeculative: same as server but compiled with speculative calls disabled
65 # client: normal interpreter, and C1 (no C2 compiler)
66 # minimal: reduced form of client with optional features stripped out
67 # core: normal interpreter only, no compiler
68 # zero: C++ based interpreter only, no compiler
69 # custom: baseline JVM with no default features
70 #
71 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
72 [
73 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
74 [JVM variants (separated by commas) to build (server,nonspeculative,client,minimal,core,zero,custom) @<:@server@:>@])])
75
76 SETUP_HOTSPOT_TARGET_CPU_PORT
77
78 if test "x$with_jvm_variants" = x; then
79 with_jvm_variants="server"
80 fi
81 JVM_VARIANTS_OPT="$with_jvm_variants"
82
83 # Has the user listed more than one variant?
84 # Additional [] needed to keep m4 from mangling shell constructs.
85 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
86 BUILDING_MULTIPLE_JVM_VARIANTS=true
87 else
88 BUILDING_MULTIPLE_JVM_VARIANTS=false
89 fi
90 # Replace the commas with AND for use in the build directory name.
91 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
92
93 AC_MSG_CHECKING([which variants of the JVM to build])
94 # JVM_VARIANTS is a space-separated list.
95 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
96 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
97 AC_MSG_RESULT([$JVM_VARIANTS])
98
99 # Check that the selected variants are valid
100 BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
101 if test "x$INVALID_VARIANTS" != x; then
102 AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
103 AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
104 AC_MSG_ERROR([Cannot continue])
105 fi
106
107 # All "special" variants share the same output directory ("server")
108 VALID_MULTIPLE_JVM_VARIANTS="server client minimal nonspeculative"
109 BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
110 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
111 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
112 fi
113
114 # The "main" variant is the one used by other libs to link against during the
115 # build.
116 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
117 MAIN_VARIANT_PRIO_ORDER="server client minimal nonspeculative"
118 for variant in $MAIN_VARIANT_PRIO_ORDER; do
119 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
120 JVM_VARIANT_MAIN="$variant"
121 break
122 fi
123 done
124 else
125 JVM_VARIANT_MAIN="$JVM_VARIANTS"
126 fi
127
128 AC_SUBST(JVM_VARIANTS)
129 AC_SUBST(VALID_JVM_VARIANTS)
130 AC_SUBST(JVM_VARIANT_MAIN)
131 AC_SUBST(VALID_MULTIPLE_JVM_VARIANTS)
132
133 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
134 # zero behaves as a platform and rewrites these values. This is really weird. :(
135 # We are guaranteed that we do not build any other variants when building zero.
136 HOTSPOT_TARGET_CPU=zero
137 HOTSPOT_TARGET_CPU_ARCH=zero
138 fi
139 ])
140
141 ###############################################################################
142 # Check if dtrace should be enabled and has all prerequisites present.
143 #
144 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
145 [
146 # Test for dtrace dependencies
147 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
148 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
149 are present.])])
150
151 DTRACE_DEP_MISSING=false
152
153 AC_MSG_CHECKING([for dtrace tool])
154 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
155 AC_MSG_RESULT([$DTRACE])
156 else
157 AC_MSG_RESULT([not found, cannot build dtrace])
158 DTRACE_DEP_MISSING=true
159 fi
160
161 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
162 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
163 DTRACE_DEP_MISSING=true
164 fi
165
166 AC_MSG_CHECKING([if dtrace should be built])
167 if test "x$enable_dtrace" = "xyes"; then
168 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
169 AC_MSG_RESULT([no, missing dependencies])
170 HELP_MSG_MISSING_DEPENDENCY([dtrace])
171 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
172 else
173 INCLUDE_DTRACE=true
174 AC_MSG_RESULT([yes, forced])
175 fi
176 elif test "x$enable_dtrace" = "xno"; then
177 INCLUDE_DTRACE=false
178 AC_MSG_RESULT([no, forced])
179 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
180 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
181 INCLUDE_DTRACE=false
182 AC_MSG_RESULT([no, missing dependencies])
183 else
184 INCLUDE_DTRACE=true
185 AC_MSG_RESULT([yes, dependencies present])
186 fi
187 else
188 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
189 fi
190 ])
191
192 ################################################################################
193 # Check if AOT should be enabled
194 #
195 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
196 [
197 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
198 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
199
200 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
201 ENABLE_AOT="true"
202 elif test "x$enable_aot" = "xyes"; then
203 ENABLE_AOT="true"
204 elif test "x$enable_aot" = "xno"; then
205 ENABLE_AOT="false"
206 else
207 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
208 fi
209
210 if test "x$ENABLE_AOT" = "xtrue"; then
211 # Only enable AOT on X64 platforms.
212 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
213 if test -e "${TOPDIR}/src/jdk.aot"; then
214 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
215 ENABLE_AOT="true"
216 else
217 ENABLE_AOT="false"
218 if test "x$enable_aot" = "xyes"; then
219 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
220 fi
221 fi
222 else
223 ENABLE_AOT="false"
224 if test "x$enable_aot" = "xyes"; then
225 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
226 fi
227 fi
228 else
229 ENABLE_AOT="false"
230 if test "x$enable_aot" = "xyes"; then
231 AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
232 fi
233 fi
234 fi
235
236 AC_SUBST(ENABLE_AOT)
237 ])
238
239 ################################################################################
240 # Allow to disable CDS
241 #
242 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
243 [
244 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
245 [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
246
247 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
248 ENABLE_CDS="true"
249 elif test "x$enable_cds" = "xyes"; then
250 ENABLE_CDS="true"
251 elif test "x$enable_cds" = "xno"; then
252 ENABLE_CDS="false"
253 else
254 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
255 fi
256
257 # Disable CDS on AIX.
258 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
259 ENABLE_CDS="false"
260 if test "x$enable_cds" = "xyes"; then
261 AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
262 fi
263 fi
264
265 AC_SUBST(ENABLE_CDS)
266 ])
267
268 ###############################################################################
269 # Set up all JVM features for each JVM variant.
270 #
271 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
272 [
273 # Prettify the VALID_JVM_FEATURES string
274 BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
275
276 # The user can in some cases supply additional jvm features. For the custom
277 # variant, this defines the entire variant.
278 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
279 [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
280 if test "x$with_jvm_features" != x; then
281 AC_MSG_CHECKING([user specified JVM feature list])
282 USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
283 AC_MSG_RESULT([$user_jvm_feature_list])
284 # These features will be added to all variant defaults
285 JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
286 # These features will be removed from all variant defaults
287 DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
288
289 # Verify that the user has provided valid features
290 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
291 if test "x$INVALID_FEATURES" != x; then
292 AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
293 AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
294 AC_MSG_ERROR([Cannot continue])
295 fi
296
297 # Check if the user has provided deprecated features
298 BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
299 if test "x$DEPRECATED_FEATURES" != x; then
300 AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
301 # Filter out deprecated features
302 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
303 BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
304 fi
305
306 fi
307
308 # Override hotspot cpu definitions for ARM platforms
309 if test "x$OPENJDK_TARGET_CPU" = xarm; then
310 HOTSPOT_TARGET_CPU=arm_32
311 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
312 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
313 HOTSPOT_TARGET_CPU=arm_64
314 HOTSPOT_TARGET_CPU_ARCH=arm
315 fi
316
317 # Verify that dependencies are met for explicitly set features.
318 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
319 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
320 fi
321
322 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
323 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
324 fi
325
326 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
327 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
328 fi
329
330 if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
331 AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
332 fi
333
334 # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
335 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
336 if test "x$OPENJDK_TARGET_OS" != xaix; then
337 if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
338 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
339 fi
340 fi
341 fi
342
343 # Only enable ZGC on Linux x86_64
344 AC_MSG_CHECKING([if zgc should be built])
345 if HOTSPOT_CHECK_JVM_FEATURE(zgc); then
346 if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
347 AC_MSG_RESULT([yes])
348 else
349 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
350 AC_MSG_RESULT([no, platform not supported])
351 fi
352 else
353 AC_MSG_RESULT([no])
354 fi
355
356 # Turn on additional features based on other parts of configure
357 if test "x$INCLUDE_DTRACE" = "xtrue"; then
358 JVM_FEATURES="$JVM_FEATURES dtrace"
359 else
360 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
361 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
362 fi
363 fi
364
365 if test "x$STATIC_BUILD" = "xtrue"; then
366 JVM_FEATURES="$JVM_FEATURES static-build"
367 else
368 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
369 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
370 fi
371 fi
372
373 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
374 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
375 AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
376 fi
377 fi
378
379 AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
380 # Check if jvmci is diabled
381 DISABLE_JVMCI=`$ECHO $DISABLED_JVM_FEATURES | $GREP jvmci`
382 if test "x$DISABLE_JVMCI" = "xjvmci"; then
383 AC_MSG_RESULT([no, forced])
384 JVM_FEATURES_jvmci=""
385 INCLUDE_JVMCI="false"
386 else
387 # Only enable jvmci on x86_64, sparcv9 and aarch64
388 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
389 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
390 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
391 AC_MSG_RESULT([yes])
392 JVM_FEATURES_jvmci="jvmci"
393 INCLUDE_JVMCI="true"
394 else
395 AC_MSG_RESULT([no])
396 JVM_FEATURES_jvmci=""
397 INCLUDE_JVMCI="false"
398 if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
399 AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
400 fi
401 fi
402 fi
403
404 AC_SUBST(INCLUDE_JVMCI)
405
406 AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
407 # Check if graal is diabled
408 DISABLE_GRAAL=`$ECHO $DISABLED_JVM_FEATURES | $GREP graal`
409 if test "x$DISABLE_GRAAL" = "xgraal"; then
410 AC_MSG_RESULT([no, forced])
411 JVM_FEATURES_graal=""
412 INCLUDE_GRAAL="false"
413 else
414 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
415 AC_MSG_RESULT([yes, forced])
416 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
417 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
418 fi
419 JVM_FEATURES_graal="graal"
420 INCLUDE_GRAAL="true"
421 else
422 # By default enable graal build on x64 or where AOT is available.
423 # graal build requires jvmci.
424 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
425 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
426 test "x$ENABLE_AOT" = "xtrue") ; then
427 AC_MSG_RESULT([yes])
428 JVM_FEATURES_graal="graal"
429 INCLUDE_GRAAL="true"
430 else
431 AC_MSG_RESULT([no])
432 JVM_FEATURES_graal=""
433 INCLUDE_GRAAL="false"
434 fi
435 fi
436 fi
437
438 AC_SUBST(INCLUDE_GRAAL)
439
440 # Disable aot with '--with-jvm-features=-aot'
441 DISABLE_AOT=`$ECHO $DISABLED_JVM_FEATURES | $GREP aot`
442 if test "x$DISABLE_AOT" = "xaot"; then
443 ENABLE_AOT="false"
444 fi
445
446 AC_MSG_CHECKING([if aot should be enabled])
447 if test "x$ENABLE_AOT" = "xtrue"; then
448 if test "x$JVM_FEATURES_graal" != "xgraal"; then
449 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
450 AC_MSG_RESULT([yes, forced])
451 AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
452 else
453 AC_MSG_RESULT([no])
454 fi
455 JVM_FEATURES_aot=""
456 ENABLE_AOT="false"
457 else
458 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
459 AC_MSG_RESULT([yes, forced])
460 else
461 AC_MSG_RESULT([yes])
462 fi
463 JVM_FEATURES_aot="aot"
464 fi
465 else
466 if test "x$enable_aot" = "xno" || test "x$DISABLE_AOT" = "xaot"; then
467 AC_MSG_RESULT([no, forced])
468 else
469 AC_MSG_RESULT([no])
470 fi
471 JVM_FEATURES_aot=""
472 if HOTSPOT_CHECK_JVM_FEATURE(aot); then
473 AC_MSG_ERROR([To enable aot, you must use --enable-aot])
474 fi
475 fi
476
477 AC_SUBST(ENABLE_AOT)
478
479 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
480 # Default to use link time optimizations on minimal on arm
481 JVM_FEATURES_link_time_opt="link-time-opt"
482 else
483 JVM_FEATURES_link_time_opt=""
484 fi
485
486 JVM_FEATURES_NONSPECULATIVE="no-speculative-cti"
487
488 # All variants but minimal (and custom) get these features
489 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc jni-check jvmti management nmt services vm-structs"
490
491 AC_MSG_CHECKING([if cds should be enabled])
492 if test "x$ENABLE_CDS" = "xtrue"; then
493 if test "x$enable_cds" = "xyes"; then
494 AC_MSG_RESULT([yes, forced])
495 else
496 AC_MSG_RESULT([yes])
497 fi
498 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
499 else
500 if test "x$enable_cds" = "xno"; then
501 AC_MSG_RESULT([no, forced])
502 else
503 AC_MSG_RESULT([no])
504 fi
505 fi
506
507 # Enable features depending on variant.
508 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES \
509 $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
510 JVM_FEATURES_nonspeculative="$JVM_FEATURES_NONSPECULATIVE"
511 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
512 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
513 JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
514 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
515 JVM_FEATURES_custom="$JVM_FEATURES"
516
517 AC_SUBST(JVM_FEATURES_server)
518 AC_SUBST(JVM_FEATURES_nonspeculative)
519 AC_SUBST(JVM_FEATURES_client)
520 AC_SUBST(JVM_FEATURES_core)
521 AC_SUBST(JVM_FEATURES_minimal)
522 AC_SUBST(JVM_FEATURES_zero)
523 AC_SUBST(JVM_FEATURES_custom)
524
525 # Used for verification of Makefiles by check-jvm-feature
526 AC_SUBST(VALID_JVM_FEATURES)
527 ])
528
529 ###############################################################################
530 # Finalize JVM features once all setup is complete, including custom setup.
531 #
532 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
533 [
534 # The nonspeculative variant should have all the features of server. Add them here
535 # to catch any custom additions automatically.
536 JVM_FEATURES_nonspeculative="$JVM_FEATURES_nonspeculative $JVM_FEATURES_server"
537
538 # Fail fast if either of JVM variant nonspeculative or JVM_FEATURES_NONSPECULATIVE are
539 # requested but the required flags are not available
540 if HOTSPOT_CHECK_JVM_VARIANT([nonspeculative]) \
541 || HOTSPOT_CHECK_JVM_FEATURE([no-speculative-cti]); then
542 if test -z "$NO_SPECULATIVE_CTI_CFLAGS"; then
543 AC_MSG_ERROR([Speculative calls mitigation flags not availble])
544 fi
545 fi
546
547 for variant in $JVM_VARIANTS; do
548 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
549 features_var_name=JVM_FEATURES_$variant
550 JVM_FEATURES_FOR_VARIANT=${!features_var_name}
551
552 # Filter out user-requested disabled features
553 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
554
555 # Keep feature lists sorted and free of duplicates
556 BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
557
558 # Update real feature set variable
559 eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
560 AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
561
562 # Verify that we have at least one gc selected
563 GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
564 if test "x$GC_FEATURES" = x; then
565 AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
566 fi
567
568 # Validate features (for configure script errors, not user errors)
569 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
570 if test "x$INVALID_FEATURES" != x; then
571 AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
572 fi
573 done
574 ])
575
576 ################################################################################
577 #
578 # Specify which sources will be used to build the 64-bit ARM port
579 #
580 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
581 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
582 #
583 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
584 [
585 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
586 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
587
588 if test "x$with_cpu_port" != x; then
589 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
590 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
591 fi
592 if test "x$with_cpu_port" != xarm64 && \
593 test "x$with_cpu_port" != xaarch64; then
594 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
595 fi
596 HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
597 fi
598 ])
599
600
601 ################################################################################
602 # Check if gtest should be built
603 #
604 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
605 [
606 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
607 [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
608
609 if test -e "${TOPDIR}/test/hotspot/gtest"; then
610 GTEST_DIR_EXISTS="true"
611 else
612 GTEST_DIR_EXISTS="false"
613 fi
614
615 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
616 if test "x$enable_hotspot_gtest" = "xyes"; then
617 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
618 AC_MSG_RESULT([yes, forced])
619 BUILD_GTEST="true"
620 else
621 AC_MSG_ERROR([Cannot build gtest without the test source])
622 fi
623 elif test "x$enable_hotspot_gtest" = "xno"; then
624 AC_MSG_RESULT([no, forced])
625 BUILD_GTEST="false"
626 elif test "x$enable_hotspot_gtest" = "x"; then
627 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
628 AC_MSG_RESULT([yes])
629 BUILD_GTEST="true"
630 else
631 AC_MSG_RESULT([no])
632 BUILD_GTEST="false"
633 fi
634 else
635 AC_MSG_ERROR([--enable-gtest must be either yes or no])
636 fi
637
638 AC_SUBST(BUILD_GTEST)
639 ])