1 #
   2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ###############################################################################
  27 # Create a function/macro that takes a series of named arguments. The call is
  28 # similar to AC_DEFUN, but the setup of the function looks like this:
  29 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
  30 # ... do something
  31 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])
  32 # ])
  33 # A star (*) in front of a named argument means that it is required and it's
  34 # presence will be verified. To pass e.g. the first value as a normal indexed
  35 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
  36 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
  37 # "ARG_FOO".
  38 #
  39 # The generated function can be called like this:
  40 # MYFUNC(FOO: [foo-val],
  41 #     BAR: [
  42 #         $ECHO hello world
  43 #     ])
  44 # Note that the argument value must start on the same line as the argument name.
  45 #
  46 # Argument 1: Name of the function to define
  47 # Argument 2: List of legal named arguments, with a * prefix for required arguments
  48 # Argument 3: Argument array to treat as named, typically $@
  49 # Argument 4: The main function body
  50 AC_DEFUN([BASIC_DEFUN_NAMED],
  51 [
  52   AC_DEFUN($1, [
  53     m4_foreach(arg, m4_split($2), [
  54       m4_if(m4_bregexp(arg, [^\*]), -1,
  55         [
  56           m4_set_add(legal_named_args, arg)
  57         ],
  58         [
  59           m4_set_add(legal_named_args, m4_substr(arg, 1))
  60           m4_set_add(required_named_args, m4_substr(arg, 1))
  61         ]
  62       )
  63     ])
  64 
  65     m4_foreach([arg], [$3], [
  66       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
  67       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
  68       m4_set_remove(required_named_args, arg_name)
  69       m4_set_remove(legal_named_args, arg_name)
  70       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
  71       m4_set_add(defined_args, arg_name)
  72       m4_undefine([arg_name])
  73     ])
  74     m4_set_empty(required_named_args, [], [
  75       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
  76     ])
  77     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
  78       m4_pushdef([ARG_][]arg, [])
  79       m4_set_add(defined_args, arg)
  80     ])
  81     m4_set_delete(legal_named_args)
  82     m4_set_delete(required_named_args)
  83 
  84     # Execute function body
  85     $4
  86 
  87     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
  88       m4_popdef([ARG_][]arg)
  89     ])
  90 
  91     m4_set_delete(defined_args)
  92   ])
  93 ])
  94 
  95 ###############################################################################
  96 # Check if a list of space-separated words are selected only from a list of
  97 # space-separated legal words. Typical use is to see if a user-specified
  98 # set of words is selected from a set of legal words.
  99 #
 100 # Sets the specified variable to list of non-matching (offending) words, or to
 101 # the empty string if all words are matching the legal set.
 102 #
 103 # $1: result variable name
 104 # $2: list of values to check
 105 # $3: list of legal values
 106 AC_DEFUN([BASIC_GET_NON_MATCHING_VALUES],
 107 [
 108   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 109   # Notice that the original variant fails on SLES 10 and 11
 110   # Some grep versions (at least bsd) behaves strangely on the base case with
 111   # no legal_values, so make it explicit.
 112   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 113   legal_values=`$ECHO $3 | $TR ' ' '\n'`
 114   if test -z "$legal_values"; then
 115     $1="$2"
 116   else
 117     result=`$GREP -Fvx "$legal_values" <<< "$values_to_check" | $GREP -v '^$'`
 118     $1=${result//$'\n'/ }
 119   fi
 120 ])
 121 
 122 ###############################################################################
 123 # Check if a list of space-separated words contains any word(s) from a list of
 124 # space-separated illegal words. Typical use is to see if a user-specified
 125 # set of words contains any from a set of illegal words.
 126 #
 127 # Sets the specified variable to list of matching illegal words, or to
 128 # the empty string if no words are matching the illegal set.
 129 #
 130 # $1: result variable name
 131 # $2: list of values to check
 132 # $3: list of illegal values
 133 AC_DEFUN([BASIC_GET_MATCHING_VALUES],
 134 [
 135   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 136   # Notice that the original variant fails on SLES 10 and 11
 137   # Some grep versions (at least bsd) behaves strangely on the base case with
 138   # no legal_values, so make it explicit.
 139   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 140   illegal_values=`$ECHO $3 | $TR ' ' '\n'`
 141   if test -z "$illegal_values"; then
 142     $1=""
 143   else
 144     result=`$GREP -Fx "$illegal_values" <<< "$values_to_check" | $GREP -v '^$'`
 145     $1=${result//$'\n'/ }
 146   fi
 147 ])
 148 
 149 ###############################################################################
 150 # Sort a space-separated list, and remove duplicates.
 151 #
 152 # Sets the specified variable to the resulting list.
 153 #
 154 # $1: result variable name
 155 # $2: list of values to sort
 156 AC_DEFUN([BASIC_SORT_LIST],
 157 [
 158   values_to_sort=`$ECHO $2 | $TR ' ' '\n'`
 159   result=`$SORT -u <<< "$values_to_sort" | $GREP -v '^$'`
 160   $1=${result//$'\n'/ }
 161 ])
 162 
 163 ###############################################################################
 164 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
 165 # If so, then append $1 to $2 \
 166 # Also set JVM_ARG_OK to true/false depending on outcome.
 167 AC_DEFUN([ADD_JVM_ARG_IF_OK],
 168 [
 169   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
 170   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
 171   OUTPUT=`$3 $1 $USER_BOOT_JDK_OPTIONS -version 2>&1`
 172   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
 173   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
 174   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
 175     $2="[$]$2 $1"
 176     JVM_ARG_OK=true
 177   else
 178     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
 179     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
 180     JVM_ARG_OK=false
 181   fi
 182 ])
 183 
 184 # Appends a string to a path variable, only adding the : when needed.
 185 AC_DEFUN([BASIC_APPEND_TO_PATH],
 186 [
 187   if test "x$2" != x; then
 188     if test "x[$]$1" = x; then
 189       $1="$2"
 190     else
 191       $1="[$]$1:$2"
 192     fi
 193   fi
 194 ])
 195 
 196 # Prepends a string to a path variable, only adding the : when needed.
 197 AC_DEFUN([BASIC_PREPEND_TO_PATH],
 198 [
 199   if test "x$2" != x; then
 200     if test "x[$]$1" = x; then
 201       $1="$2"
 202     else
 203       $1="$2:[$]$1"
 204     fi
 205   fi
 206 ])
 207 
 208 ###############################################################################
 209 # This will make sure the given variable points to a full and proper
 210 # path. This means:
 211 # 1) There will be no spaces in the path. On unix platforms,
 212 #    spaces in the path will result in an error. On Windows,
 213 #    the path will be rewritten using short-style to be space-free.
 214 # 2) The path will be absolute, and it will be in unix-style (on
 215 #     cygwin).
 216 # $1: The name of the variable to fix
 217 AC_DEFUN([BASIC_FIXUP_PATH],
 218 [
 219   # Only process if variable expands to non-empty
 220 
 221   if test "x[$]$1" != x; then
 222     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 223       BASIC_FIXUP_PATH_CYGWIN($1)
 224     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 225       BASIC_FIXUP_PATH_MSYS($1)
 226     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 227       BASIC_FIXUP_PATH_WSL($1)
 228     else
 229       # We're on a unix platform. Hooray! :)
 230       path="[$]$1"
 231       has_space=`$ECHO "$path" | $GREP " "`
 232       if test "x$has_space" != x; then
 233         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
 234         AC_MSG_ERROR([Spaces are not allowed in this path.])
 235       fi
 236 
 237       # Use eval to expand a potential ~
 238       eval path="$path"
 239       if test ! -f "$path" && test ! -d "$path"; then
 240         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 241       fi
 242 
 243       if test -d "$path"; then
 244         $1="`cd "$path"; $THEPWDCMD -L`"
 245       else
 246         dir="`$DIRNAME "$path"`"
 247         base="`$BASENAME "$path"`"
 248         $1="`cd "$dir"; $THEPWDCMD -L`/$base"
 249       fi
 250     fi
 251   fi
 252 ])
 253 
 254 ###############################################################################
 255 # This will make sure the given variable points to a executable
 256 # with a full and proper path. This means:
 257 # 1) There will be no spaces in the path. On unix platforms,
 258 #    spaces in the path will result in an error. On Windows,
 259 #    the path will be rewritten using short-style to be space-free.
 260 # 2) The path will be absolute, and it will be in unix-style (on
 261 #     cygwin).
 262 # Any arguments given to the executable is preserved.
 263 # If the input variable does not have a directory specification, then
 264 # it need to be in the PATH.
 265 # $1: The name of the variable to fix
 266 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 267 [
 268   # Only process if variable expands to non-empty
 269 
 270   if test "x[$]$1" != x; then
 271     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 272       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 273     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 274       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 275     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 276       BASIC_FIXUP_EXECUTABLE_WSL($1)
 277     else
 278       # We're on a unix platform. Hooray! :)
 279       # First separate the path from the arguments. This will split at the first
 280       # space.
 281       complete="[$]$1"
 282       path="${complete%% *}"
 283       tmp="$complete EOL"
 284       arguments="${tmp#* }"
 285 
 286       # Cannot rely on the command "which" here since it doesn't always work.
 287       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 288       if test -z "$is_absolute_path"; then
 289         # Path to executable is not absolute. Find it.
 290         IFS_save="$IFS"
 291         IFS=:
 292         for p in $PATH; do
 293           if test -f "$p/$path" && test -x "$p/$path"; then
 294             new_path="$p/$path"
 295             break
 296           fi
 297         done
 298         IFS="$IFS_save"
 299       else
 300         # This is an absolute path, we can use it without further modifications.
 301         new_path="$path"
 302       fi
 303 
 304       if test "x$new_path" = x; then
 305         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 306         has_space=`$ECHO "$complete" | $GREP " "`
 307         if test "x$has_space" != x; then
 308           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 309         fi
 310         AC_MSG_ERROR([Cannot locate the the path of $1])
 311       fi
 312     fi
 313 
 314     # Now join together the path and the arguments once again
 315     if test "x$arguments" != xEOL; then
 316       new_complete="$new_path ${arguments% *}"
 317     else
 318       new_complete="$new_path"
 319     fi
 320 
 321     if test "x$complete" != "x$new_complete"; then
 322       $1="$new_complete"
 323       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 324     fi
 325   fi
 326 ])
 327 
 328 ###############################################################################
 329 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 330 [
 331   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 332     # Follow a chain of symbolic links. Use readlink
 333     # where it exists, else fall back to horribly
 334     # complicated shell code.
 335     if test "x$READLINK_TESTED" != yes; then
 336       # On MacOSX there is a readlink tool with a different
 337       # purpose than the GNU readlink tool. Check the found readlink.
 338       READLINK_ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 339       # If READLINK_ISGNU is empty, then it's a non-GNU readlink. Don't use it.
 340       READLINK_TESTED=yes
 341     fi
 342 
 343     if test "x$READLINK" != x && test "x$READLINK_ISGNU" != x; then
 344       $1=`$READLINK -f [$]$1`
 345     else
 346       # Save the current directory for restoring afterwards
 347       STARTDIR=$PWD
 348       COUNTER=0
 349       sym_link_dir=`$DIRNAME [$]$1`
 350       sym_link_file=`$BASENAME [$]$1`
 351       cd $sym_link_dir
 352       # Use -P flag to resolve symlinks in directories.
 353       cd `$THEPWDCMD -P`
 354       sym_link_dir=`$THEPWDCMD -P`
 355       # Resolve file symlinks
 356       while test $COUNTER -lt 20; do
 357         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 358         if test "x$ISLINK" == x; then
 359           # This is not a symbolic link! We are done!
 360           break
 361         fi
 362         # Again resolve directory symlinks since the target of the just found
 363         # link could be in a different directory
 364         cd `$DIRNAME $ISLINK`
 365         sym_link_dir=`$THEPWDCMD -P`
 366         sym_link_file=`$BASENAME $ISLINK`
 367         let COUNTER=COUNTER+1
 368       done
 369       cd $STARTDIR
 370       $1=$sym_link_dir/$sym_link_file
 371     fi
 372   fi
 373 ])
 374 
 375 ###############################################################################
 376 # Register a --with argument but mark it as deprecated
 377 # $1: The name of the with argument to deprecate, not including --with-
 378 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 379 [
 380   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 381       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 382       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 383 ])
 384 
 385 ###############################################################################
 386 # Register a --enable argument but mark it as deprecated
 387 # $1: The name of the with argument to deprecate, not including --enable-
 388 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 389 # $3: Messages to user.
 390 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 391 [
 392   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 393       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 394   if test "x$enable_$2" != x; then
 395     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 396 
 397     if test "x$3" != x; then
 398       AC_MSG_WARN([$3])
 399     fi
 400 
 401   fi
 402 ])
 403 
 404 ###############################################################################
 405 AC_DEFUN_ONCE([BASIC_INIT],
 406 [
 407   # Save the original command line. This is passed to us by the wrapper configure script.
 408   AC_SUBST(CONFIGURE_COMMAND_LINE)
 409   # AUTOCONF might be set in the environment by the user. Preserve for "make reconfigure".
 410   AC_SUBST(AUTOCONF)
 411   # Save the path variable before it gets changed
 412   ORIGINAL_PATH="$PATH"
 413   AC_SUBST(ORIGINAL_PATH)
 414   DATE_WHEN_CONFIGURED=`LANG=C date`
 415   AC_SUBST(DATE_WHEN_CONFIGURED)
 416   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 417 ])
 418 
 419 ###############################################################################
 420 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 421 # $1: variable to check
 422 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 423 [
 424   if test "x[$]$1" = x; then
 425     AC_MSG_ERROR([Could not find required tool for $1])
 426   fi
 427 ])
 428 
 429 ###############################################################################
 430 # Check that there are no unprocessed overridden variables left.
 431 # If so, they are an incorrect argument and we will exit with an error.
 432 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 433 [
 434   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 435     # Replace the separating ! with spaces before presenting for end user.
 436     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 437     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 438   fi
 439 ])
 440 
 441 ###############################################################################
 442 # Setup a tool for the given variable. If correctly specified by the user,
 443 # use that value, otherwise search for the tool using the supplied code snippet.
 444 # $1: variable to set
 445 # $2: code snippet to call to look for the tool
 446 # $3: code snippet to call if variable was used to find tool
 447 AC_DEFUN([BASIC_SETUP_TOOL],
 448 [
 449   # Publish this variable in the help.
 450   AC_ARG_VAR($1, [Override default value for $1])
 451 
 452   if [[ -z "${$1+x}" ]]; then
 453     # The variable is not set by user, try to locate tool using the code snippet
 454     $2
 455   else
 456     # The variable is set, but is it from the command line or the environment?
 457 
 458     # Try to remove the string !$1! from our list.
 459     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 460     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 461       # If it failed, the variable was not from the command line. Ignore it,
 462       # but warn the user (except for BASH, which is always set by the calling BASH).
 463       if test "x$1" != xBASH; then
 464         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 465       fi
 466       # Try to locate tool using the code snippet
 467       $2
 468     else
 469       # If it succeeded, then it was overridden by the user. We will use it
 470       # for the tool.
 471 
 472       # First remove it from the list of overridden variables, so we can test
 473       # for unknown variables in the end.
 474       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 475 
 476       # Check if we try to supply an empty value
 477       if test "x[$]$1" = x; then
 478         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 479         AC_MSG_CHECKING([for $1])
 480         AC_MSG_RESULT([disabled])
 481       else
 482         # Check if the provided tool contains a complete path.
 483         tool_specified="[$]$1"
 484         tool_basename="${tool_specified##*/}"
 485         if test "x$tool_basename" = "x$tool_specified"; then
 486           # A command without a complete path is provided, search $PATH.
 487           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 488           AC_PATH_PROG($1, $tool_basename)
 489           if test "x[$]$1" = x; then
 490             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 491           fi
 492         else
 493           # Otherwise we believe it is a complete path. Use it as it is.
 494           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 495           AC_MSG_CHECKING([for $1])
 496           if test ! -x "$tool_specified"; then
 497             AC_MSG_RESULT([not found])
 498             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 499           fi
 500           AC_MSG_RESULT([$tool_specified])
 501         fi
 502       fi
 503     fi
 504     $3
 505   fi
 506 ])
 507 
 508 ###############################################################################
 509 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 510 # $1: variable to set
 511 # $2: executable name (or list of names) to look for
 512 # $3: [path]
 513 AC_DEFUN([BASIC_PATH_PROGS],
 514 [
 515   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
 516 ])
 517 
 518 ###############################################################################
 519 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 520 # $1: variable to set
 521 # $2: executable name (or list of names) to look for
 522 AC_DEFUN([BASIC_CHECK_TOOLS],
 523 [
 524   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 525 ])
 526 
 527 ###############################################################################
 528 # Like BASIC_PATH_PROGS but fails if no tool was found.
 529 # $1: variable to set
 530 # $2: executable name (or list of names) to look for
 531 # $3: [path]
 532 AC_DEFUN([BASIC_REQUIRE_PROGS],
 533 [
 534   BASIC_PATH_PROGS($1, $2, , $3)
 535   BASIC_CHECK_NONEMPTY($1)
 536 ])
 537 
 538 ###############################################################################
 539 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 540 # $1: variable to set
 541 # $2: autoconf macro to call to look for the special tool
 542 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 543 [
 544   BASIC_SETUP_TOOL($1, [$2])
 545   BASIC_CHECK_NONEMPTY($1)
 546 ])
 547 
 548 ###############################################################################
 549 # Setup the most fundamental tools that relies on not much else to set up,
 550 # but is used by much of the early bootstrap code.
 551 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 552 [
 553   # Start with tools that do not need have cross compilation support
 554   # and can be expected to be found in the default PATH. These tools are
 555   # used by configure.
 556 
 557   # First are all the simple required tools.
 558   BASIC_REQUIRE_PROGS(BASENAME, basename)
 559   BASIC_REQUIRE_PROGS(BASH, bash)
 560   BASIC_REQUIRE_PROGS(CAT, cat)
 561   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 562   BASIC_REQUIRE_PROGS(CMP, cmp)
 563   BASIC_REQUIRE_PROGS(COMM, comm)
 564   BASIC_REQUIRE_PROGS(CP, cp)
 565   BASIC_REQUIRE_PROGS(CUT, cut)
 566   BASIC_REQUIRE_PROGS(DATE, date)
 567   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 568   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 569   BASIC_REQUIRE_PROGS(ECHO, echo)
 570   BASIC_REQUIRE_PROGS(EXPR, expr)
 571   BASIC_REQUIRE_PROGS(FILE, file)
 572   BASIC_REQUIRE_PROGS(FIND, find)
 573   BASIC_REQUIRE_PROGS(HEAD, head)
 574   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
 575   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
 576   BASIC_REQUIRE_PROGS(LN, ln)
 577   BASIC_REQUIRE_PROGS(LS, ls)
 578   # gmkdir is known to be safe for concurrent invocations with -p flag.
 579   BASIC_REQUIRE_PROGS(MKDIR, [gmkdir mkdir])
 580   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 581   BASIC_REQUIRE_PROGS(MV, mv)
 582   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 583   BASIC_REQUIRE_PROGS(PRINTF, printf)
 584   BASIC_REQUIRE_PROGS(READLINK, [greadlink readlink])
 585   BASIC_REQUIRE_PROGS(RM, rm)
 586   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 587   BASIC_REQUIRE_PROGS(SH, sh)
 588   BASIC_REQUIRE_PROGS(SORT, sort)
 589   BASIC_REQUIRE_PROGS(TAIL, tail)
 590   BASIC_REQUIRE_PROGS(TAR, gtar tar)
 591   BASIC_REQUIRE_PROGS(TEE, tee)
 592   BASIC_REQUIRE_PROGS(TOUCH, touch)
 593   BASIC_REQUIRE_PROGS(TR, tr)
 594   BASIC_REQUIRE_PROGS(UNAME, uname)
 595   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 596   BASIC_REQUIRE_PROGS(WC, wc)
 597   BASIC_REQUIRE_PROGS(WHICH, which)
 598   BASIC_REQUIRE_PROGS(XARGS, xargs)
 599 
 600   # Then required tools that require some special treatment.
 601   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 602   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 603   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 604   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 605   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 606 
 607   # Always force rm.
 608   RM="$RM -f"
 609 
 610   # pwd behaves differently on various platforms and some don't support the -L flag.
 611   # Always use the bash builtin pwd to get uniform behavior.
 612   THEPWDCMD=pwd
 613 
 614   # These are not required on all platforms
 615   BASIC_PATH_PROGS(CYGPATH, cygpath)
 616   BASIC_PATH_PROGS(WSLPATH, wslpath)
 617   BASIC_PATH_PROGS(DF, df)
 618   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 619   BASIC_PATH_PROGS(NICE, nice)
 620 
 621   BASIC_PATH_PROGS(LSB_RELEASE, lsb_release)
 622   BASIC_PATH_PROGS(CMD, [cmd.exe /mnt/c/Windows/System32/cmd.exe])
 623 ])
 624 
 625 ###############################################################################
 626 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 627 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 628 [
 629   # Save the current directory this script was started from
 630   CURDIR="$PWD"
 631 
 632   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 633   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 634   # was not available at that time.
 635   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 636   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 637     ORIGINAL_PATH="$REWRITTEN_PATH"
 638     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 639   fi
 640 
 641   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 642     PATH_SEP=";"
 643     EXE_SUFFIX=".exe"
 644     BASIC_CHECK_PATHS_WINDOWS
 645   else
 646     PATH_SEP=":"
 647     EXE_SUFFIX=""
 648   fi
 649   AC_SUBST(PATH_SEP)
 650   AC_SUBST(EXE_SUFFIX)
 651 
 652   # We get the top-level directory from the supporting wrappers.
 653   AC_MSG_CHECKING([for top-level directory])
 654   AC_MSG_RESULT([$TOPDIR])
 655   AC_SUBST(TOPDIR)
 656 
 657   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 658   BASIC_FIXUP_PATH(CURDIR)
 659   BASIC_FIXUP_PATH(TOPDIR)
 660 
 661   # Locate the directory of this script.
 662   AUTOCONF_DIR=$TOPDIR/make/autoconf
 663 
 664   # Setup username (for use in adhoc version strings etc)
 665   # Outer [ ] to quote m4.
 666   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
 667   AC_SUBST(USERNAME)
 668 ])
 669 
 670 ###############################################################################
 671 # Evaluates platform specific overrides for devkit variables.
 672 # $1: Name of variable
 673 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 674 [
 675   if test "x[$]$1" = x; then
 676     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 677   fi
 678 ])
 679 
 680 ###############################################################################
 681 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 682 [
 683   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 684       [use this devkit for compilers, tools and resources])])
 685 
 686   if test "x$with_devkit" = xyes; then
 687     AC_MSG_ERROR([--with-devkit must have a value])
 688   elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
 689     BASIC_FIXUP_PATH([with_devkit])
 690     DEVKIT_ROOT="$with_devkit"
 691     # Check for a meta data info file in the root of the devkit
 692     if test -f "$DEVKIT_ROOT/devkit.info"; then
 693       . $DEVKIT_ROOT/devkit.info
 694       # This potentially sets the following:
 695       # A descriptive name of the devkit
 696       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 697       # Corresponds to --with-extra-path
 698       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 699       # Corresponds to --with-toolchain-path
 700       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 701       # Corresponds to --with-sysroot
 702       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 703 
 704       # Identifies the Visual Studio version in the devkit
 705       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 706       # The Visual Studio include environment variable
 707       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 708       # The Visual Studio lib environment variable
 709       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 710       # Corresponds to --with-msvcr-dll
 711       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 712       # Corresponds to --with-msvcp-dll
 713       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 714       # Corresponds to --with-ucrt-dll-dir
 715       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_UCRT_DLL_DIR])
 716     fi
 717 
 718     AC_MSG_CHECKING([for devkit])
 719     if test "x$DEVKIT_NAME" != x; then
 720       AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 721     else
 722       AC_MSG_RESULT([$DEVKIT_ROOT])
 723     fi
 724 
 725     BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 726 
 727     # Fallback default of just /bin if DEVKIT_PATH is not defined
 728     if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 729       DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 730     fi
 731     BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 732 
 733     # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 734     # places for backwards compatiblity.
 735     if test "x$DEVKIT_SYSROOT" != x; then
 736       SYSROOT="$DEVKIT_SYSROOT"
 737     elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 738       SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 739     elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 740       SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 741     fi
 742 
 743     if test "x$DEVKIT_ROOT" != x; then
 744       DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
 745       if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 746         DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
 747       fi
 748       AC_SUBST(DEVKIT_LIB_DIR)
 749     fi
 750   fi
 751 
 752   # You can force the sysroot if the sysroot encoded into the compiler tools
 753   # is not correct.
 754   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 755       [alias for --with-sysroot for backwards compatability])],
 756       [SYSROOT=$with_sys_root]
 757   )
 758 
 759   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 760       [use this directory as sysroot])],
 761       [SYSROOT=$with_sysroot]
 762   )
 763 
 764   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 765       [alias for --with-toolchain-path for backwards compatibility])],
 766       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 767   )
 768 
 769   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 770       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 771       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 772   )
 773 
 774   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 775       [prepend these directories to the default path])],
 776       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 777   )
 778 
 779   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 780     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 781     # If not, detect if Xcode is installed by running xcodebuild -version
 782     # if no Xcode installed, xcodebuild exits with 1
 783     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 784     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 785       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 786       # fall back on the stub binary in /usr/bin/xcodebuild
 787       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 788     else
 789       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 790       # when only the command line tools are installed there are no SDKs, so headers
 791       # are copied into the system frameworks
 792       XCODEBUILD=
 793       AC_SUBST(XCODEBUILD)
 794     fi
 795 
 796     AC_MSG_CHECKING([for sdk name])
 797     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 798         [use the platform SDK of the given name. @<:@macosx@:>@])],
 799         [SDKNAME=$with_sdk_name]
 800     )
 801     AC_MSG_RESULT([$SDKNAME])
 802 
 803     # if toolchain path is specified then don't rely on system headers, they may not compile
 804     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 805     test -z "$TOOLCHAIN_PATH" && \
 806       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 807 
 808     if test -z "$SYSROOT"; then
 809       if test -n "$XCODEBUILD"; then
 810         # if we don't have system headers, use default SDK name (last resort)
 811         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 812           SDKNAME=${SDKNAME:-macosx}
 813         fi
 814 
 815         if test -n "$SDKNAME"; then
 816           # Call xcodebuild to determine SYSROOT
 817           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
 818         fi
 819       else
 820         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 821           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 822         fi
 823       fi
 824     else
 825       # warn user if --with-sdk-name was also set
 826       if test -n "$with_sdk_name"; then
 827         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 828       fi
 829     fi
 830 
 831     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 832       # If no system framework headers, then SYSROOT must be set, or we won't build
 833       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 834     fi
 835 
 836     # Perform a basic sanity test
 837     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 838       if test -z "$SYSROOT"; then
 839         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 840       else
 841         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 842       fi
 843     fi
 844 
 845     # set SDKROOT too, Xcode tools will pick it up
 846     SDKROOT="$SYSROOT"
 847     AC_SUBST(SDKROOT)
 848   fi
 849 
 850   # Prepend the extra path to the global path
 851   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 852 
 853   AC_MSG_CHECKING([for sysroot])
 854   AC_MSG_RESULT([$SYSROOT])
 855   AC_MSG_CHECKING([for toolchain path])
 856   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 857   AC_MSG_CHECKING([for extra path])
 858   AC_MSG_RESULT([$EXTRA_PATH])
 859 ])
 860 
 861 ###############################################################################
 862 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 863 [
 864 
 865   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 866       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 867       [ CONF_NAME=${with_conf_name} ])
 868 
 869   # Test from where we are running configure, in or outside of src root.
 870   AC_MSG_CHECKING([where to store configuration])
 871   if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
 872       || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
 873       || test "x$CURDIR" = "x$TOPDIR/make" ; then
 874     # We are running configure from the src root.
 875     # Create a default ./build/target-variant-debuglevel output root.
 876     if test "x${CONF_NAME}" = x; then
 877       AC_MSG_RESULT([in default location])
 878       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
 879     else
 880       AC_MSG_RESULT([in build directory with custom name])
 881     fi
 882 
 883     if test "x$CUSTOM_ROOT" != x; then
 884       OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
 885     else
 886       OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
 887     fi
 888     $MKDIR -p "$OUTPUTDIR"
 889     if test ! -d "$OUTPUTDIR"; then
 890       AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
 891     fi
 892   else
 893     # We are running configure from outside of the src dir.
 894     # Then use the current directory as output dir!
 895     # If configuration is situated in normal build directory, just use the build
 896     # directory name as configuration name, otherwise use the complete path.
 897     if test "x${CONF_NAME}" = x; then
 898       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
 899     fi
 900     OUTPUTDIR="$CURDIR"
 901     AC_MSG_RESULT([in current directory])
 902 
 903     # WARNING: This might be a bad thing to do. You need to be sure you want to
 904     # have a configuration in this directory. Do some sanity checks!
 905 
 906     if test ! -e "$OUTPUTDIR/spec.gmk"; then
 907       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 908       # other files
 909       files_present=`$LS $OUTPUTDIR`
 910       # Configure has already touched config.log and confdefs.h in the current dir when this check
 911       # is performed.
 912       filtered_files=`$ECHO "$files_present" \
 913           | $SED -e 's/config.log//g' \
 914               -e 's/configure.log//g' \
 915               -e 's/confdefs.h//g' \
 916               -e 's/configure-support//g' \
 917               -e 's/ //g' \
 918           | $TR -d '\n'`
 919       if test "x$filtered_files" != x; then
 920         AC_MSG_NOTICE([Current directory is $CURDIR.])
 921         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 922         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 923         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 924         AC_MSG_NOTICE([seriously mess up just about everything.])
 925         AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
 926         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 927         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 928       fi
 929     fi
 930   fi
 931   AC_MSG_CHECKING([what configuration name to use])
 932   AC_MSG_RESULT([$CONF_NAME])
 933 
 934   BASIC_FIXUP_PATH(OUTPUTDIR)
 935 
 936   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
 937   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 938 
 939   SPEC="$OUTPUTDIR/spec.gmk"
 940   AC_SUBST(SPEC)
 941   AC_SUBST(CONF_NAME)
 942   AC_SUBST(OUTPUTDIR)
 943   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 944 
 945   # The spec.gmk file contains all variables for the make system.
 946   AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 947   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 948   AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 949   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
 950   AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
 951   # The compare.sh is used to compare the build output to other builds.
 952   AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 953   # The generated Makefile knows where the spec.gmk is and where the source is.
 954   # You can run make from the OUTPUTDIR, or from the top-level Makefile
 955   # which will look for generated configurations
 956   AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
 957 ])
 958 
 959 #%%% Simple tools %%%
 960 
 961 ###############################################################################
 962 # Check if we have found a usable version of make
 963 # $1: the path to a potential make binary (or empty)
 964 # $2: the description on how we found this
 965 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 966 [
 967   MAKE_CANDIDATE="$1"
 968   DESCRIPTION="$2"
 969 
 970   # On Cygwin, we require a newer version of make than on other platforms
 971   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 972     MAKE_VERSION_EXPR="-e 4\."
 973     MAKE_REQUIRED_VERSION="4.0"
 974    else
 975     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 976     MAKE_REQUIRED_VERSION="3.81"
 977   fi
 978 
 979   if test "x$MAKE_CANDIDATE" != x; then
 980     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 981     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 982     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 983     if test "x$IS_GNU_MAKE" = x; then
 984       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 985     else
 986       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 987       if test "x$IS_MODERN_MAKE" = x; then
 988         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 989       else
 990         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 991           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 992             MAKE_EXPECTED_ENV='cygwin'
 993           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 994             MAKE_EXPECTED_ENV='msys'
 995           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 996             MAKE_EXPECTED_ENV='x86_64-.*-linux-gnu'
 997           else
 998             AC_MSG_ERROR([Unknown Windows environment])
 999           fi
1000           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
1001           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
1002         else
1003           # Not relevant for non-Windows
1004           IS_MAKE_CORRECT_ENV=true
1005         fi
1006         if test "x$IS_MAKE_CORRECT_ENV" = x; then
1007           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
1008         else
1009           FOUND_MAKE=$MAKE_CANDIDATE
1010           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
1011         fi
1012       fi
1013     fi
1014   fi
1015 ])
1016 
1017 ###############################################################################
1018 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
1019 [
1020   # Check if make supports the output sync option and if so, setup using it.
1021   AC_MSG_CHECKING([if make --output-sync is supported])
1022   if $MAKE --version -O > /dev/null 2>&1; then
1023     OUTPUT_SYNC_SUPPORTED=true
1024     AC_MSG_RESULT([yes])
1025     AC_MSG_CHECKING([for output-sync value])
1026     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
1027       [set make output sync type if supported by make. @<:@recurse@:>@])],
1028       [OUTPUT_SYNC=$with_output_sync])
1029     if test "x$OUTPUT_SYNC" = "x"; then
1030       OUTPUT_SYNC=none
1031     fi
1032     AC_MSG_RESULT([$OUTPUT_SYNC])
1033     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
1034       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
1035     fi
1036   else
1037     OUTPUT_SYNC_SUPPORTED=false
1038     AC_MSG_RESULT([no])
1039   fi
1040   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
1041   AC_SUBST(OUTPUT_SYNC)
1042 ])
1043 
1044 ###############################################################################
1045 # Goes looking for a usable version of GNU make.
1046 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
1047 [
1048   BASIC_SETUP_TOOL([MAKE],
1049   [
1050     # Try our hardest to locate a correct version of GNU make
1051     AC_PATH_PROGS(CHECK_GMAKE, gmake)
1052     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
1053 
1054     if test "x$FOUND_MAKE" = x; then
1055       AC_PATH_PROGS(CHECK_MAKE, make)
1056       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
1057     fi
1058 
1059     if test "x$FOUND_MAKE" = x; then
1060       if test "x$TOOLCHAIN_PATH" != x; then
1061         # We have a toolchain path, check that as well before giving up.
1062         OLD_PATH=$PATH
1063         PATH=$TOOLCHAIN_PATH:$PATH
1064         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
1065         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
1066         if test "x$FOUND_MAKE" = x; then
1067           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
1068           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
1069         fi
1070         PATH=$OLD_PATH
1071       fi
1072     fi
1073 
1074     if test "x$FOUND_MAKE" = x; then
1075       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
1076     fi
1077   ],[
1078     # If MAKE was set by user, verify the version
1079     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
1080     if test "x$FOUND_MAKE" = x; then
1081       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
1082     fi
1083   ])
1084 
1085   MAKE=$FOUND_MAKE
1086   AC_SUBST(MAKE)
1087   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
1088 
1089   BASIC_CHECK_MAKE_OUTPUT_SYNC
1090 ])
1091 
1092 ###############################################################################
1093 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
1094 [
1095   # Test if find supports -delete
1096   AC_MSG_CHECKING([if find supports -delete])
1097   FIND_DELETE="-delete"
1098 
1099   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
1100 
1101   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
1102 
1103   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
1104   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1105     # No, it does not.
1106     $RM $DELETEDIR/TestIfFindSupportsDelete
1107     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1108       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1109       FIND_DELETE="-print | $XARGS $RM"
1110     else
1111       FIND_DELETE="-exec $RM \{\} \+"
1112     fi
1113     AC_MSG_RESULT([no])
1114   else
1115     AC_MSG_RESULT([yes])
1116   fi
1117   $RMDIR $DELETEDIR
1118   AC_SUBST(FIND_DELETE)
1119 ])
1120 
1121 ###############################################################################
1122 AC_DEFUN([BASIC_CHECK_TAR],
1123 [
1124   # Test which kind of tar was found
1125   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1126     TAR_TYPE="gnu"
1127   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1128     TAR_TYPE="bsd"
1129   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1130     TAR_TYPE="bsd"
1131   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1132     TAR_TYPE="solaris"
1133   fi
1134   AC_MSG_CHECKING([what type of tar was found])
1135   AC_MSG_RESULT([$TAR_TYPE])
1136 
1137   TAR_CREATE_FILE_PARAM=""
1138 
1139   if test "x$TAR_TYPE" = "xgnu"; then
1140     TAR_INCLUDE_PARAM="T"
1141     TAR_SUPPORTS_TRANSFORM="true"
1142     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1143       # When using gnu tar for Solaris targets, need to use compatibility mode
1144       TAR_CREATE_EXTRA_PARAM="--format=ustar"
1145     fi
1146   else
1147     TAR_INCLUDE_PARAM="I"
1148     TAR_SUPPORTS_TRANSFORM="false"
1149   fi
1150   AC_SUBST(TAR_TYPE)
1151   AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1152   AC_SUBST(TAR_INCLUDE_PARAM)
1153   AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1154 ])
1155 
1156 ###############################################################################
1157 AC_DEFUN([BASIC_CHECK_GREP],
1158 [
1159   # Test that grep supports -Fx with a list of pattern which includes null pattern.
1160   # This is a problem for the grep resident on AIX.
1161   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1162   # Multiple subsequent spaces..
1163   STACK_SPACES='aaa   bbb   ccc'
1164   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1165   # patterns in it.
1166   STACK_LIST=${STACK_SPACES// /$'\n'}
1167   NEEDLE_SPACES='ccc bbb aaa'
1168   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1169   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1170   if test "x$RESULT" == "x"; then
1171     AC_MSG_RESULT([yes])
1172   else
1173     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1174       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1175     fi
1176     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1177   fi
1178 ])
1179 
1180 ###############################################################################
1181 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1182 [
1183   BASIC_CHECK_GNU_MAKE
1184 
1185   BASIC_CHECK_FIND_DELETE
1186   BASIC_CHECK_TAR
1187   BASIC_CHECK_GREP
1188   BASIC_SETUP_PANDOC
1189 
1190   # These tools might not be installed by default,
1191   # need hint on how to install them.
1192   BASIC_REQUIRE_PROGS(UNZIP, unzip)
1193   # Since zip uses "ZIP" as a environment variable for passing options, we need
1194   # to name our variable differently, hence ZIPEXE.
1195   BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1196 
1197   # Non-required basic tools
1198 
1199   BASIC_PATH_PROGS(LDD, ldd)
1200   if test "x$LDD" = "x"; then
1201     # List shared lib dependencies is used for
1202     # debug output and checking for forbidden dependencies.
1203     # We can build without it.
1204     LDD="true"
1205   fi
1206   BASIC_PATH_PROGS(READELF, [greadelf readelf])
1207   BASIC_PATH_PROGS(DOT, dot)
1208   BASIC_PATH_PROGS(HG, hg)
1209   BASIC_PATH_PROGS(GIT, git)
1210   BASIC_PATH_PROGS(STAT, stat)
1211   BASIC_PATH_PROGS(TIME, time)
1212   BASIC_PATH_PROGS(FLOCK, flock)
1213   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1214   # be in the user path.
1215   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1216   BASIC_PATH_PROGS(PATCH, [gpatch patch])
1217   # Check if it's GNU time
1218   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1219   if test "x$IS_GNU_TIME" != x; then
1220     IS_GNU_TIME=yes
1221   else
1222     IS_GNU_TIME=no
1223   fi
1224   AC_SUBST(IS_GNU_TIME)
1225 
1226   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1227     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1228     BASIC_REQUIRE_PROGS(MIG, mig)
1229     BASIC_REQUIRE_PROGS(XATTR, xattr)
1230     BASIC_PATH_PROGS(CODESIGN, codesign)
1231     if test "x$CODESIGN" != "x"; then
1232       # Verify that the openjdk_codesign certificate is present
1233       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1234       $RM codesign-testfile
1235       $TOUCH codesign-testfile
1236       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1237       $RM codesign-testfile
1238       if test "x$CODESIGN" = x; then
1239         AC_MSG_RESULT([no])
1240       else
1241         AC_MSG_RESULT([yes])
1242       fi
1243     fi
1244     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1245   elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1246     BASIC_REQUIRE_PROGS(ELFEDIT, elfedit)
1247   fi
1248 ])
1249 
1250 ###############################################################################
1251 # Check if build directory is on local disk. If not possible to determine,
1252 # we prefer to claim it's local.
1253 # Argument 1: directory to test
1254 # Argument 2: what to do if it is on local disk
1255 # Argument 3: what to do otherwise (remote disk or failure)
1256 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1257 [
1258   # df -l lists only local disks; if the given directory is not found then
1259   # a non-zero exit code is given
1260   if test "x$DF" = x; then
1261     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1262       # msys does not have df; use Windows "net use" instead.
1263       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1264       if test "x$IS_NETWORK_DISK" = x; then
1265         $2
1266       else
1267         $3
1268       fi
1269     else
1270       # No df here, say it's local
1271       $2
1272     fi
1273   else
1274     # JDK-8189619
1275     # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1276     # is the same. On older AIXes we just continue to live with a "not local build" warning.
1277     if test "x$OPENJDK_TARGET_OS" = xaix; then
1278       DF_LOCAL_ONLY_OPTION='-T local'
1279     else
1280       DF_LOCAL_ONLY_OPTION='-l'
1281     fi
1282     if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1283       $2
1284     else
1285       # In WSL, local Windows drives are considered remote by df, but we are
1286       # required to build into a directory accessible from windows, so consider
1287       # them local here.
1288       if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
1289         if $DF $1 | $GREP -q "^[[A-Z]]:"; then
1290           $2
1291         else
1292           $3
1293         fi
1294       else
1295         $3
1296       fi
1297     fi
1298   fi
1299 ])
1300 
1301 ###############################################################################
1302 # Check that source files have basic read permissions set. This might
1303 # not be the case in cygwin in certain conditions.
1304 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1305 [
1306   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1307     file_to_test="$TOPDIR/LICENSE"
1308     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1309       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1310     fi
1311   fi
1312 ])
1313 
1314 ###############################################################################
1315 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1316 [
1317   AC_MSG_CHECKING([if build directory is on local disk])
1318   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1319       [OUTPUT_DIR_IS_LOCAL="yes"],
1320       [OUTPUT_DIR_IS_LOCAL="no"])
1321   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1322 
1323   BASIC_CHECK_SRC_PERMS
1324 
1325   # Check if the user has any old-style ALT_ variables set.
1326   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1327 
1328   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1329   # Since we can't properly handle the dependencies for this, warn the user about the situation
1330   if test -e $OUTPUTDIR/spec.gmk; then
1331     IS_RECONFIGURE=yes
1332   else
1333     IS_RECONFIGURE=no
1334   fi
1335 ])
1336 
1337 ###############################################################################
1338 # Check for support for specific options in bash
1339 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1340 [
1341   # Check bash version
1342   # Extra [ ] to stop m4 mangling
1343   [ BASH_VER=`$BASH --version | $SED -n  -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1344   AC_MSG_CHECKING([bash version])
1345   AC_MSG_RESULT([$BASH_VER])
1346 
1347   BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1348   BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1349   if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1350     AC_MSG_ERROR([bash version 3.2 or better is required])
1351   fi
1352 
1353   # Test if bash supports pipefail.
1354   AC_MSG_CHECKING([if bash supports pipefail])
1355   if ${BASH} -c 'set -o pipefail'; then
1356     BASH_ARGS="$BASH_ARGS -o pipefail"
1357     AC_MSG_RESULT([yes])
1358   else
1359     AC_MSG_RESULT([no])
1360   fi
1361 
1362   AC_MSG_CHECKING([if bash supports errexit (-e)])
1363   if ${BASH} -e -c 'true'; then
1364     BASH_ARGS="$BASH_ARGS -e"
1365     AC_MSG_RESULT([yes])
1366   else
1367     AC_MSG_RESULT([no])
1368   fi
1369 
1370   AC_SUBST(BASH_ARGS)
1371 ])
1372 
1373 ################################################################################
1374 #
1375 # Setup Pandoc
1376 #
1377 AC_DEFUN_ONCE([BASIC_SETUP_PANDOC],
1378 [
1379   BASIC_PATH_PROGS(PANDOC, pandoc)
1380 
1381   PANDOC_MARKDOWN_FLAG="markdown"
1382   if test -n "$PANDOC"; then
1383     AC_MSG_CHECKING(if the pandoc smart extension needs to be disabled for markdown)
1384     if $PANDOC --list-extensions | $GREP -q '\+smart'; then
1385       AC_MSG_RESULT([yes])
1386       PANDOC_MARKDOWN_FLAG="markdown-smart"
1387     else
1388       AC_MSG_RESULT([no])
1389     fi
1390   fi
1391 
1392   if test -n "$PANDOC"; then
1393     ENABLE_PANDOC="true"
1394   else
1395     ENABLE_PANDOC="false"
1396   fi
1397   AC_SUBST(ENABLE_PANDOC)
1398   AC_SUBST(PANDOC_MARKDOWN_FLAG)
1399 ])
1400 
1401 ################################################################################
1402 #
1403 # Default make target
1404 #
1405 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1406 [
1407   AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1408       [set the default make target @<:@exploded-image@:>@])])
1409   if test "x$with_default_make_target" = "x" \
1410       || test "x$with_default_make_target" = "xyes"; then
1411     DEFAULT_MAKE_TARGET="exploded-image"
1412   elif test "x$with_default_make_target" = "xno"; then
1413     AC_MSG_ERROR([--without-default-make-target is not a valid option])
1414   else
1415     DEFAULT_MAKE_TARGET="$with_default_make_target"
1416   fi
1417 
1418   AC_SUBST(DEFAULT_MAKE_TARGET)
1419 ])
1420 
1421 ###############################################################################
1422 # Setup the default value for LOG=
1423 #
1424 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_LOG],
1425 [
1426   AC_ARG_WITH(log, [AS_HELP_STRING([--with-log],
1427       [[default vaue for make LOG argument [warn]]])])
1428   AC_MSG_CHECKING([for default LOG value])
1429   if test "x$with_log" = x; then
1430     DEFAULT_LOG=""
1431   else
1432     # Syntax for valid LOG options is a bit too complex for it to be worth
1433     # implementing a test for correctness in configure. Just accept it.
1434     DEFAULT_LOG=$with_log
1435   fi
1436   AC_MSG_RESULT([$DEFAULT_LOG])
1437   AC_SUBST(DEFAULT_LOG)
1438 ])
1439 
1440 ###############################################################################
1441 # Code to run after AC_OUTPUT
1442 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1443 [
1444   # Try to move config.log (generated by autoconf) to the configure-support directory.
1445   if test -e ./config.log; then
1446     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1447   fi
1448 
1449   # Rotate our log file (configure.log)
1450   if test -e "$OUTPUTDIR/configure.log.old"; then
1451     $RM -f "$OUTPUTDIR/configure.log.old"
1452   fi
1453   if test -e "$OUTPUTDIR/configure.log"; then
1454     $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1455   fi
1456 
1457   # Move configure.log from current directory to the build output root
1458   if test -e ./configure.log; then
1459     $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1460   fi
1461 
1462   # Make the compare script executable
1463   $CHMOD +x $OUTPUTDIR/compare.sh
1464 ])