1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ###############################################################################
  27 # Create a function/macro that takes a series of named arguments. The call is
  28 # similar to AC_DEFUN, but the setup of the function looks like this:
  29 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
  30 # ... do something
  31 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])
  32 # ])
  33 # A star (*) in front of a named argument means that it is required and it's
  34 # presence will be verified. To pass e.g. the first value as a normal indexed
  35 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
  36 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
  37 # "ARG_FOO".
  38 #
  39 # The generated function can be called like this:
  40 # MYFUNC(FOO: [foo-val],
  41 #     BAR: [
  42 #         $ECHO hello world
  43 #     ])
  44 # Note that the argument value must start on the same line as the argument name.
  45 #
  46 # Argument 1: Name of the function to define
  47 # Argument 2: List of legal named arguments, with a * prefix for required arguments
  48 # Argument 3: Argument array to treat as named, typically $@
  49 # Argument 4: The main function body
  50 AC_DEFUN([BASIC_DEFUN_NAMED],
  51 [
  52   AC_DEFUN($1, [
  53     m4_foreach(arg, m4_split($2), [
  54       m4_if(m4_bregexp(arg, [^\*]), -1,
  55         [
  56           m4_set_add(legal_named_args, arg)
  57         ],
  58         [
  59           m4_set_add(legal_named_args, m4_substr(arg, 1))
  60           m4_set_add(required_named_args, m4_substr(arg, 1))
  61         ]
  62       )
  63     ])
  64 
  65     m4_foreach([arg], [$3], [
  66       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
  67       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
  68       m4_set_remove(required_named_args, arg_name)
  69       m4_set_remove(legal_named_args, arg_name)
  70       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
  71       m4_set_add(defined_args, arg_name)
  72       m4_undefine([arg_name])
  73     ])
  74     m4_set_empty(required_named_args, [], [
  75       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
  76     ])
  77     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
  78       m4_pushdef([ARG_][]arg, [])
  79       m4_set_add(defined_args, arg)
  80     ])
  81     m4_set_delete(legal_named_args)
  82     m4_set_delete(required_named_args)
  83 
  84     # Execute function body
  85     $4
  86 
  87     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
  88       m4_popdef([ARG_][]arg)
  89     ])
  90 
  91     m4_set_delete(defined_args)
  92   ])
  93 ])
  94 
  95 ###############################################################################
  96 # Check if a list of space-separated words are selected only from a list of
  97 # space-separated legal words. Typical use is to see if a user-specified
  98 # set of words is selected from a set of legal words.
  99 #
 100 # Sets the specified variable to list of non-matching (offending) words, or to
 101 # the empty string if all words are matching the legal set.
 102 #
 103 # $1: result variable name
 104 # $2: list of values to check
 105 # $3: list of legal values
 106 AC_DEFUN([BASIC_GET_NON_MATCHING_VALUES],
 107 [
 108   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 109   # Notice that the original variant fails on SLES 10 and 11
 110   # Some grep versions (at least bsd) behaves strangely on the base case with
 111   # no legal_values, so make it explicit.
 112   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 113   legal_values=`$ECHO $3 | $TR ' ' '\n'`
 114   if test -z "$legal_values"; then
 115     $1="$2"
 116   else
 117     result=`$GREP -Fvx "$legal_values" <<< "$values_to_check" | $GREP -v '^$'`
 118     $1=${result//$'\n'/ }
 119   fi
 120 ])
 121 
 122 ###############################################################################
 123 # Check if a list of space-separated words contains any word(s) from a list of
 124 # space-separated illegal words. Typical use is to see if a user-specified
 125 # set of words contains any from a set of illegal words.
 126 #
 127 # Sets the specified variable to list of matching illegal words, or to
 128 # the empty string if no words are matching the illegal set.
 129 #
 130 # $1: result variable name
 131 # $2: list of values to check
 132 # $3: list of illegal values
 133 AC_DEFUN([BASIC_GET_MATCHING_VALUES],
 134 [
 135   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 136   # Notice that the original variant fails on SLES 10 and 11
 137   # Some grep versions (at least bsd) behaves strangely on the base case with
 138   # no legal_values, so make it explicit.
 139   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 140   illegal_values=`$ECHO $3 | $TR ' ' '\n'`
 141   if test -z "$illegal_values"; then
 142     $1=""
 143   else
 144     result=`$GREP -Fx "$illegal_values" <<< "$values_to_check" | $GREP -v '^$'`
 145     $1=${result//$'\n'/ }
 146   fi
 147 ])
 148 
 149 ###############################################################################
 150 # Sort a space-separated list, and remove duplicates.
 151 #
 152 # Sets the specified variable to the resulting list.
 153 #
 154 # $1: result variable name
 155 # $2: list of values to sort
 156 AC_DEFUN([BASIC_SORT_LIST],
 157 [
 158   values_to_sort=`$ECHO $2 | $TR ' ' '\n'`
 159   result=`$SORT -u <<< "$values_to_sort" | $GREP -v '^$'`
 160   $1=${result//$'\n'/ }
 161 ])
 162 
 163 ###############################################################################
 164 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
 165 # If so, then append $1 to $2 \
 166 # Also set JVM_ARG_OK to true/false depending on outcome.
 167 AC_DEFUN([ADD_JVM_ARG_IF_OK],
 168 [
 169   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
 170   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
 171   OUTPUT=`$3 $1 $USER_BOOT_JDK_OPTIONS -version 2>&1`
 172   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
 173   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
 174   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
 175     $2="[$]$2 $1"
 176     JVM_ARG_OK=true
 177   else
 178     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
 179     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
 180     JVM_ARG_OK=false
 181   fi
 182 ])
 183 
 184 # Appends a string to a path variable, only adding the : when needed.
 185 AC_DEFUN([BASIC_APPEND_TO_PATH],
 186 [
 187   if test "x$2" != x; then
 188     if test "x[$]$1" = x; then
 189       $1="$2"
 190     else
 191       $1="[$]$1:$2"
 192     fi
 193   fi
 194 ])
 195 
 196 # Prepends a string to a path variable, only adding the : when needed.
 197 AC_DEFUN([BASIC_PREPEND_TO_PATH],
 198 [
 199   if test "x$2" != x; then
 200     if test "x[$]$1" = x; then
 201       $1="$2"
 202     else
 203       $1="$2:[$]$1"
 204     fi
 205   fi
 206 ])
 207 
 208 ###############################################################################
 209 # This will make sure the given variable points to a full and proper
 210 # path. This means:
 211 # 1) There will be no spaces in the path. On unix platforms,
 212 #    spaces in the path will result in an error. On Windows,
 213 #    the path will be rewritten using short-style to be space-free.
 214 # 2) The path will be absolute, and it will be in unix-style (on
 215 #     cygwin).
 216 # $1: The name of the variable to fix
 217 AC_DEFUN([BASIC_FIXUP_PATH],
 218 [
 219   # Only process if variable expands to non-empty
 220 
 221   if test "x[$]$1" != x; then
 222     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 223       BASIC_FIXUP_PATH_CYGWIN($1)
 224     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 225       BASIC_FIXUP_PATH_MSYS($1)
 226     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 227       BASIC_FIXUP_PATH_WSL($1)
 228     else
 229       # We're on a unix platform. Hooray! :)
 230       path="[$]$1"
 231       has_space=`$ECHO "$path" | $GREP " "`
 232       if test "x$has_space" != x; then
 233         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
 234         AC_MSG_ERROR([Spaces are not allowed in this path.])
 235       fi
 236 
 237       # Use eval to expand a potential ~
 238       eval path="$path"
 239       if test ! -f "$path" && test ! -d "$path"; then
 240         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 241       fi
 242 
 243       if test -d "$path"; then
 244         $1="`cd "$path"; $THEPWDCMD -L`"
 245       else
 246         dir="`$DIRNAME "$path"`"
 247         base="`$BASENAME "$path"`"
 248         $1="`cd "$dir"; $THEPWDCMD -L`/$base"
 249       fi
 250     fi
 251   fi
 252 ])
 253 
 254 ###############################################################################
 255 # This will make sure the given variable points to a executable
 256 # with a full and proper path. This means:
 257 # 1) There will be no spaces in the path. On unix platforms,
 258 #    spaces in the path will result in an error. On Windows,
 259 #    the path will be rewritten using short-style to be space-free.
 260 # 2) The path will be absolute, and it will be in unix-style (on
 261 #     cygwin).
 262 # Any arguments given to the executable is preserved.
 263 # If the input variable does not have a directory specification, then
 264 # it need to be in the PATH.
 265 # $1: The name of the variable to fix
 266 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 267 [
 268   # Only process if variable expands to non-empty
 269 
 270   if test "x[$]$1" != x; then
 271     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 272       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 273     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 274       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 275     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 276       BASIC_FIXUP_EXECUTABLE_WSL($1)
 277     else
 278       # We're on a unix platform. Hooray! :)
 279       # First separate the path from the arguments. This will split at the first
 280       # space.
 281       complete="[$]$1"
 282       path="${complete%% *}"
 283       tmp="$complete EOL"
 284       arguments="${tmp#* }"
 285 
 286       # Cannot rely on the command "which" here since it doesn't always work.
 287       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 288       if test -z "$is_absolute_path"; then
 289         # Path to executable is not absolute. Find it.
 290         IFS_save="$IFS"
 291         IFS=:
 292         for p in $PATH; do
 293           if test -f "$p/$path" && test -x "$p/$path"; then
 294             new_path="$p/$path"
 295             break
 296           fi
 297         done
 298         IFS="$IFS_save"
 299       else
 300         # This is an absolute path, we can use it without further modifications.
 301         new_path="$path"
 302       fi
 303 
 304       if test "x$new_path" = x; then
 305         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 306         has_space=`$ECHO "$complete" | $GREP " "`
 307         if test "x$has_space" != x; then
 308           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 309         fi
 310         AC_MSG_ERROR([Cannot locate the the path of $1])
 311       fi
 312     fi
 313 
 314     # Now join together the path and the arguments once again
 315     if test "x$arguments" != xEOL; then
 316       new_complete="$new_path ${arguments% *}"
 317     else
 318       new_complete="$new_path"
 319     fi
 320 
 321     if test "x$complete" != "x$new_complete"; then
 322       $1="$new_complete"
 323       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 324     fi
 325   fi
 326 ])
 327 
 328 ###############################################################################
 329 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 330 [
 331   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 332     # Follow a chain of symbolic links. Use readlink
 333     # where it exists, else fall back to horribly
 334     # complicated shell code.
 335     if test "x$READLINK_TESTED" != yes; then
 336       # On MacOSX there is a readlink tool with a different
 337       # purpose than the GNU readlink tool. Check the found readlink.
 338       READLINK_ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 339       # If READLINK_ISGNU is empty, then it's a non-GNU readlink. Don't use it.
 340       READLINK_TESTED=yes
 341     fi
 342 
 343     if test "x$READLINK" != x && test "x$READLINK_ISGNU" != x; then
 344       $1=`$READLINK -f [$]$1`
 345     else
 346       # Save the current directory for restoring afterwards
 347       STARTDIR=$PWD
 348       COUNTER=0
 349       sym_link_dir=`$DIRNAME [$]$1`
 350       sym_link_file=`$BASENAME [$]$1`
 351       cd $sym_link_dir
 352       # Use -P flag to resolve symlinks in directories.
 353       cd `$THEPWDCMD -P`
 354       sym_link_dir=`$THEPWDCMD -P`
 355       # Resolve file symlinks
 356       while test $COUNTER -lt 20; do
 357         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 358         if test "x$ISLINK" == x; then
 359           # This is not a symbolic link! We are done!
 360           break
 361         fi
 362         # Again resolve directory symlinks since the target of the just found
 363         # link could be in a different directory
 364         cd `$DIRNAME $ISLINK`
 365         sym_link_dir=`$THEPWDCMD -P`
 366         sym_link_file=`$BASENAME $ISLINK`
 367         let COUNTER=COUNTER+1
 368       done
 369       cd $STARTDIR
 370       $1=$sym_link_dir/$sym_link_file
 371     fi
 372   fi
 373 ])
 374 
 375 ###############################################################################
 376 # Register a --with argument but mark it as deprecated
 377 # $1: The name of the with argument to deprecate, not including --with-
 378 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 379 [
 380   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 381       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 382       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 383 ])
 384 
 385 ###############################################################################
 386 # Register a --enable argument but mark it as deprecated
 387 # $1: The name of the with argument to deprecate, not including --enable-
 388 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 389 # $3: Messages to user.
 390 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 391 [
 392   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 393       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 394   if test "x$enable_$2" != x; then
 395     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 396 
 397     if test "x$3" != x; then
 398       AC_MSG_WARN([$3])
 399     fi
 400 
 401   fi
 402 ])
 403 
 404 ###############################################################################
 405 AC_DEFUN_ONCE([BASIC_INIT],
 406 [
 407   # Save the original command line. This is passed to us by the wrapper configure script.
 408   AC_SUBST(CONFIGURE_COMMAND_LINE)
 409   # Save the path variable before it gets changed
 410   ORIGINAL_PATH="$PATH"
 411   AC_SUBST(ORIGINAL_PATH)
 412   DATE_WHEN_CONFIGURED=`LANG=C date`
 413   AC_SUBST(DATE_WHEN_CONFIGURED)
 414   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 415 ])
 416 
 417 ###############################################################################
 418 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 419 # $1: variable to check
 420 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 421 [
 422   if test "x[$]$1" = x; then
 423     AC_MSG_ERROR([Could not find required tool for $1])
 424   fi
 425 ])
 426 
 427 ###############################################################################
 428 # Check that there are no unprocessed overridden variables left.
 429 # If so, they are an incorrect argument and we will exit with an error.
 430 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 431 [
 432   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 433     # Replace the separating ! with spaces before presenting for end user.
 434     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 435     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 436   fi
 437 ])
 438 
 439 ###############################################################################
 440 # Setup a tool for the given variable. If correctly specified by the user,
 441 # use that value, otherwise search for the tool using the supplied code snippet.
 442 # $1: variable to set
 443 # $2: code snippet to call to look for the tool
 444 # $3: code snippet to call if variable was used to find tool
 445 AC_DEFUN([BASIC_SETUP_TOOL],
 446 [
 447   # Publish this variable in the help.
 448   AC_ARG_VAR($1, [Override default value for $1])
 449 
 450   if [[ -z "${$1+x}" ]]; then
 451     # The variable is not set by user, try to locate tool using the code snippet
 452     $2
 453   else
 454     # The variable is set, but is it from the command line or the environment?
 455 
 456     # Try to remove the string !$1! from our list.
 457     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 458     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 459       # If it failed, the variable was not from the command line. Ignore it,
 460       # but warn the user (except for BASH, which is always set by the calling BASH).
 461       if test "x$1" != xBASH; then
 462         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 463       fi
 464       # Try to locate tool using the code snippet
 465       $2
 466     else
 467       # If it succeeded, then it was overridden by the user. We will use it
 468       # for the tool.
 469 
 470       # First remove it from the list of overridden variables, so we can test
 471       # for unknown variables in the end.
 472       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 473 
 474       # Check if we try to supply an empty value
 475       if test "x[$]$1" = x; then
 476         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 477         AC_MSG_CHECKING([for $1])
 478         AC_MSG_RESULT([disabled])
 479       else
 480         # Check if the provided tool contains a complete path.
 481         tool_specified="[$]$1"
 482         tool_basename="${tool_specified##*/}"
 483         if test "x$tool_basename" = "x$tool_specified"; then
 484           # A command without a complete path is provided, search $PATH.
 485           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 486           AC_PATH_PROG($1, $tool_basename)
 487           if test "x[$]$1" = x; then
 488             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 489           fi
 490         else
 491           # Otherwise we believe it is a complete path. Use it as it is.
 492           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 493           AC_MSG_CHECKING([for $1])
 494           if test ! -x "$tool_specified"; then
 495             AC_MSG_RESULT([not found])
 496             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 497           fi
 498           AC_MSG_RESULT([$tool_specified])
 499         fi
 500       fi
 501     fi
 502     $3
 503   fi
 504 ])
 505 
 506 ###############################################################################
 507 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 508 # $1: variable to set
 509 # $2: executable name (or list of names) to look for
 510 # $3: [path]
 511 AC_DEFUN([BASIC_PATH_PROGS],
 512 [
 513   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
 514 ])
 515 
 516 ###############################################################################
 517 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 518 # $1: variable to set
 519 # $2: executable name (or list of names) to look for
 520 AC_DEFUN([BASIC_CHECK_TOOLS],
 521 [
 522   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 523 ])
 524 
 525 ###############################################################################
 526 # Like BASIC_PATH_PROGS but fails if no tool was found.
 527 # $1: variable to set
 528 # $2: executable name (or list of names) to look for
 529 # $3: [path]
 530 AC_DEFUN([BASIC_REQUIRE_PROGS],
 531 [
 532   BASIC_PATH_PROGS($1, $2, , $3)
 533   BASIC_CHECK_NONEMPTY($1)
 534 ])
 535 
 536 ###############################################################################
 537 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 538 # $1: variable to set
 539 # $2: autoconf macro to call to look for the special tool
 540 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 541 [
 542   BASIC_SETUP_TOOL($1, [$2])
 543   BASIC_CHECK_NONEMPTY($1)
 544 ])
 545 
 546 ###############################################################################
 547 # Setup the most fundamental tools that relies on not much else to set up,
 548 # but is used by much of the early bootstrap code.
 549 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 550 [
 551   # Start with tools that do not need have cross compilation support
 552   # and can be expected to be found in the default PATH. These tools are
 553   # used by configure.
 554 
 555   # First are all the simple required tools.
 556   BASIC_REQUIRE_PROGS(BASENAME, basename)
 557   BASIC_REQUIRE_PROGS(BASH, bash)
 558   BASIC_REQUIRE_PROGS(CAT, cat)
 559   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 560   BASIC_REQUIRE_PROGS(CMP, cmp)
 561   BASIC_REQUIRE_PROGS(COMM, comm)
 562   BASIC_REQUIRE_PROGS(CP, cp)
 563   BASIC_REQUIRE_PROGS(CUT, cut)
 564   BASIC_REQUIRE_PROGS(DATE, date)
 565   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 566   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 567   BASIC_REQUIRE_PROGS(ECHO, echo)
 568   BASIC_REQUIRE_PROGS(EXPR, expr)
 569   BASIC_REQUIRE_PROGS(FILE, file)
 570   BASIC_REQUIRE_PROGS(FIND, find)
 571   BASIC_REQUIRE_PROGS(HEAD, head)
 572   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
 573   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
 574   BASIC_REQUIRE_PROGS(LN, ln)
 575   BASIC_REQUIRE_PROGS(LS, ls)
 576   # gmkdir is known to be safe for concurrent invocations with -p flag.
 577   BASIC_REQUIRE_PROGS(MKDIR, [gmkdir mkdir])
 578   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 579   BASIC_REQUIRE_PROGS(MV, mv)
 580   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 581   BASIC_REQUIRE_PROGS(PRINTF, printf)
 582   BASIC_REQUIRE_PROGS(READLINK, [greadlink readlink])
 583   BASIC_REQUIRE_PROGS(RM, rm)
 584   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 585   BASIC_REQUIRE_PROGS(SH, sh)
 586   BASIC_REQUIRE_PROGS(SORT, sort)
 587   BASIC_REQUIRE_PROGS(TAIL, tail)
 588   BASIC_REQUIRE_PROGS(TAR, gtar tar)
 589   BASIC_REQUIRE_PROGS(TEE, tee)
 590   BASIC_REQUIRE_PROGS(TOUCH, touch)
 591   BASIC_REQUIRE_PROGS(TR, tr)
 592   BASIC_REQUIRE_PROGS(UNAME, uname)
 593   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 594   BASIC_REQUIRE_PROGS(WC, wc)
 595   BASIC_REQUIRE_PROGS(WHICH, which)
 596   BASIC_REQUIRE_PROGS(XARGS, xargs)
 597 
 598   # Then required tools that require some special treatment.
 599   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 600   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 601   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 602   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 603   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 604 
 605   # Always force rm.
 606   RM="$RM -f"
 607 
 608   # pwd behaves differently on various platforms and some don't support the -L flag.
 609   # Always use the bash builtin pwd to get uniform behavior.
 610   THEPWDCMD=pwd
 611 
 612   # These are not required on all platforms
 613   BASIC_PATH_PROGS(CYGPATH, cygpath)
 614   BASIC_PATH_PROGS(WSLPATH, wslpath)
 615   BASIC_PATH_PROGS(DF, df)
 616   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 617   BASIC_PATH_PROGS(NICE, nice)
 618   BASIC_PATH_PROGS(PANDOC, pandoc)
 619 
 620   BASIC_PATH_PROGS(CMD, [cmd.exe /mnt/c/Windows/System32/cmd.exe])
 621 ])
 622 
 623 ###############################################################################
 624 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 625 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 626 [
 627   # Save the current directory this script was started from
 628   CURDIR="$PWD"
 629 
 630   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 631   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 632   # was not available at that time.
 633   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 634   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 635     ORIGINAL_PATH="$REWRITTEN_PATH"
 636     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 637   fi
 638 
 639   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 640     PATH_SEP=";"
 641     BASIC_CHECK_PATHS_WINDOWS
 642   else
 643     PATH_SEP=":"
 644         EXECUTABLE_SUFFIX=""
 645   fi
 646   AC_SUBST(PATH_SEP)
 647   AC_SUBST(EXECUTABLE_SUFFIX)
 648 
 649   # We get the top-level directory from the supporting wrappers.
 650   AC_MSG_CHECKING([for top-level directory])
 651   AC_MSG_RESULT([$TOPDIR])
 652   AC_SUBST(TOPDIR)
 653 
 654   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 655   BASIC_FIXUP_PATH(CURDIR)
 656   BASIC_FIXUP_PATH(TOPDIR)
 657 
 658   # Locate the directory of this script.
 659   AUTOCONF_DIR=$TOPDIR/make/autoconf
 660 
 661   # Setup username (for use in adhoc version strings etc)
 662   # Outer [ ] to quote m4.
 663   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
 664   AC_SUBST(USERNAME)
 665 ])
 666 
 667 ###############################################################################
 668 # Evaluates platform specific overrides for devkit variables.
 669 # $1: Name of variable
 670 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 671 [
 672   if test "x[$]$1" = x; then
 673     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 674   fi
 675 ])
 676 
 677 ###############################################################################
 678 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 679 [
 680   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 681       [use this devkit for compilers, tools and resources])])
 682 
 683   if test "x$with_devkit" = xyes; then
 684     AC_MSG_ERROR([--with-devkit must have a value])
 685   elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
 686     BASIC_FIXUP_PATH([with_devkit])
 687     DEVKIT_ROOT="$with_devkit"
 688     # Check for a meta data info file in the root of the devkit
 689     if test -f "$DEVKIT_ROOT/devkit.info"; then
 690       . $DEVKIT_ROOT/devkit.info
 691       # This potentially sets the following:
 692       # A descriptive name of the devkit
 693       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 694       # Corresponds to --with-extra-path
 695       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 696       # Corresponds to --with-toolchain-path
 697       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 698       # Corresponds to --with-sysroot
 699       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 700 
 701       # Identifies the Visual Studio version in the devkit
 702       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 703       # The Visual Studio include environment variable
 704       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 705       # The Visual Studio lib environment variable
 706       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 707       # Corresponds to --with-msvcr-dll
 708       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 709       # Corresponds to --with-msvcp-dll
 710       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 711       # Corresponds to --with-ucrt-dll-dir
 712       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_UCRT_DLL_DIR])
 713     fi
 714 
 715     AC_MSG_CHECKING([for devkit])
 716     if test "x$DEVKIT_NAME" != x; then
 717       AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 718     else
 719       AC_MSG_RESULT([$DEVKIT_ROOT])
 720     fi
 721 
 722     BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 723 
 724     # Fallback default of just /bin if DEVKIT_PATH is not defined
 725     if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 726       DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 727     fi
 728     BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 729 
 730     # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 731     # places for backwards compatiblity.
 732     if test "x$DEVKIT_SYSROOT" != x; then
 733       SYSROOT="$DEVKIT_SYSROOT"
 734     elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 735       SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 736     elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 737       SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 738     fi
 739 
 740     if test "x$DEVKIT_ROOT" != x; then
 741       DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
 742       if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 743         DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
 744       fi
 745       AC_SUBST(DEVKIT_LIB_DIR)
 746     fi
 747   fi
 748 
 749   # You can force the sysroot if the sysroot encoded into the compiler tools
 750   # is not correct.
 751   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 752       [alias for --with-sysroot for backwards compatability])],
 753       [SYSROOT=$with_sys_root]
 754   )
 755 
 756   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 757       [use this directory as sysroot])],
 758       [SYSROOT=$with_sysroot]
 759   )
 760 
 761   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 762       [alias for --with-toolchain-path for backwards compatibility])],
 763       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 764   )
 765 
 766   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 767       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 768       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 769   )
 770 
 771   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 772       [prepend these directories to the default path])],
 773       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 774   )
 775 
 776   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 777     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 778     # If not, detect if Xcode is installed by running xcodebuild -version
 779     # if no Xcode installed, xcodebuild exits with 1
 780     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 781     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 782       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 783       # fall back on the stub binary in /usr/bin/xcodebuild
 784       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 785     else
 786       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 787       # when only the command line tools are installed there are no SDKs, so headers
 788       # are copied into the system frameworks
 789       XCODEBUILD=
 790       AC_SUBST(XCODEBUILD)
 791     fi
 792 
 793     AC_MSG_CHECKING([for sdk name])
 794     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 795         [use the platform SDK of the given name. @<:@macosx@:>@])],
 796         [SDKNAME=$with_sdk_name]
 797     )
 798     AC_MSG_RESULT([$SDKNAME])
 799 
 800     # if toolchain path is specified then don't rely on system headers, they may not compile
 801     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 802     test -z "$TOOLCHAIN_PATH" && \
 803       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 804 
 805     if test -z "$SYSROOT"; then
 806       if test -n "$XCODEBUILD"; then
 807         # if we don't have system headers, use default SDK name (last resort)
 808         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 809           SDKNAME=${SDKNAME:-macosx}
 810         fi
 811 
 812         if test -n "$SDKNAME"; then
 813           # Call xcodebuild to determine SYSROOT
 814           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
 815         fi
 816       else
 817         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 818           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 819         fi
 820       fi
 821     else
 822       # warn user if --with-sdk-name was also set
 823       if test -n "$with_sdk_name"; then
 824         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 825       fi
 826     fi
 827 
 828     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 829       # If no system framework headers, then SYSROOT must be set, or we won't build
 830       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 831     fi
 832 
 833     # Perform a basic sanity test
 834     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 835       if test -z "$SYSROOT"; then
 836         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 837       else
 838         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 839       fi
 840     fi
 841 
 842     # set SDKROOT too, Xcode tools will pick it up
 843     SDKROOT="$SYSROOT"
 844     AC_SUBST(SDKROOT)
 845   fi
 846 
 847   # Prepend the extra path to the global path
 848   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 849 
 850   AC_MSG_CHECKING([for sysroot])
 851   AC_MSG_RESULT([$SYSROOT])
 852   AC_MSG_CHECKING([for toolchain path])
 853   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 854   AC_MSG_CHECKING([for extra path])
 855   AC_MSG_RESULT([$EXTRA_PATH])
 856 ])
 857 
 858 ###############################################################################
 859 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 860 [
 861 
 862   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 863       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 864       [ CONF_NAME=${with_conf_name} ])
 865 
 866   # Test from where we are running configure, in or outside of src root.
 867   AC_MSG_CHECKING([where to store configuration])
 868   if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
 869       || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
 870       || test "x$CURDIR" = "x$TOPDIR/make" ; then
 871     # We are running configure from the src root.
 872     # Create a default ./build/target-variant-debuglevel output root.
 873     if test "x${CONF_NAME}" = x; then
 874       AC_MSG_RESULT([in default location])
 875       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
 876     else
 877       AC_MSG_RESULT([in build directory with custom name])
 878     fi
 879 
 880     if test "x$CUSTOM_ROOT" != x; then
 881       OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
 882     else
 883       OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
 884     fi
 885     $MKDIR -p "$OUTPUTDIR"
 886     if test ! -d "$OUTPUTDIR"; then
 887       AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
 888     fi
 889   else
 890     # We are running configure from outside of the src dir.
 891     # Then use the current directory as output dir!
 892     # If configuration is situated in normal build directory, just use the build
 893     # directory name as configuration name, otherwise use the complete path.
 894     if test "x${CONF_NAME}" = x; then
 895       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
 896     fi
 897     OUTPUTDIR="$CURDIR"
 898     AC_MSG_RESULT([in current directory])
 899 
 900     # WARNING: This might be a bad thing to do. You need to be sure you want to
 901     # have a configuration in this directory. Do some sanity checks!
 902 
 903     if test ! -e "$OUTPUTDIR/spec.gmk"; then
 904       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 905       # other files
 906       files_present=`$LS $OUTPUTDIR`
 907       # Configure has already touched config.log and confdefs.h in the current dir when this check
 908       # is performed.
 909       filtered_files=`$ECHO "$files_present" \
 910           | $SED -e 's/config.log//g' \
 911               -e 's/configure.log//g' \
 912               -e 's/confdefs.h//g' \
 913               -e 's/configure-support//g' \
 914               -e 's/ //g' \
 915           | $TR -d '\n'`
 916       if test "x$filtered_files" != x; then
 917         AC_MSG_NOTICE([Current directory is $CURDIR.])
 918         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 919         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 920         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 921         AC_MSG_NOTICE([seriously mess up just about everything.])
 922         AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
 923         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 924         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 925       fi
 926     fi
 927   fi
 928   AC_MSG_CHECKING([what configuration name to use])
 929   AC_MSG_RESULT([$CONF_NAME])
 930 
 931   BASIC_FIXUP_PATH(OUTPUTDIR)
 932 
 933   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
 934   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 935 
 936   SPEC="$OUTPUTDIR/spec.gmk"
 937   AC_SUBST(SPEC)
 938   AC_SUBST(CONF_NAME)
 939   AC_SUBST(OUTPUTDIR)
 940   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 941 
 942   # The spec.gmk file contains all variables for the make system.
 943   AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 944   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 945   AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 946   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
 947   AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
 948   # The compare.sh is used to compare the build output to other builds.
 949   AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 950   # The generated Makefile knows where the spec.gmk is and where the source is.
 951   # You can run make from the OUTPUTDIR, or from the top-level Makefile
 952   # which will look for generated configurations
 953   AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
 954 ])
 955 
 956 #%%% Simple tools %%%
 957 
 958 ###############################################################################
 959 # Check if we have found a usable version of make
 960 # $1: the path to a potential make binary (or empty)
 961 # $2: the description on how we found this
 962 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 963 [
 964   MAKE_CANDIDATE="$1"
 965   DESCRIPTION="$2"
 966 
 967   # On Cygwin, we require a newer version of make than on other platforms
 968   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 969     MAKE_VERSION_EXPR="-e 4\."
 970     MAKE_REQUIRED_VERSION="4.0"
 971    else
 972     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 973     MAKE_REQUIRED_VERSION="3.81"
 974   fi
 975 
 976   if test "x$MAKE_CANDIDATE" != x; then
 977     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 978     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 979     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 980     if test "x$IS_GNU_MAKE" = x; then
 981       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 982     else
 983       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 984       if test "x$IS_MODERN_MAKE" = x; then
 985         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 986       else
 987         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 988           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 989             MAKE_EXPECTED_ENV='cygwin'
 990           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 991             MAKE_EXPECTED_ENV='msys'
 992           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
 993             MAKE_EXPECTED_ENV='x86_64-pc-linux-gnu'
 994           else
 995             AC_MSG_ERROR([Unknown Windows environment])
 996           fi
 997           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 998           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 999         else
1000           # Not relevant for non-Windows
1001           IS_MAKE_CORRECT_ENV=true
1002         fi
1003         if test "x$IS_MAKE_CORRECT_ENV" = x; then
1004           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
1005         else
1006           FOUND_MAKE=$MAKE_CANDIDATE
1007           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
1008         fi
1009       fi
1010     fi
1011   fi
1012 ])
1013 
1014 ###############################################################################
1015 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
1016 [
1017   # Check if make supports the output sync option and if so, setup using it.
1018   AC_MSG_CHECKING([if make --output-sync is supported])
1019   if $MAKE --version -O > /dev/null 2>&1; then
1020     OUTPUT_SYNC_SUPPORTED=true
1021     AC_MSG_RESULT([yes])
1022     AC_MSG_CHECKING([for output-sync value])
1023     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
1024       [set make output sync type if supported by make. @<:@recurse@:>@])],
1025       [OUTPUT_SYNC=$with_output_sync])
1026     if test "x$OUTPUT_SYNC" = "x"; then
1027       OUTPUT_SYNC=none
1028     fi
1029     AC_MSG_RESULT([$OUTPUT_SYNC])
1030     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
1031       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
1032     fi
1033   else
1034     OUTPUT_SYNC_SUPPORTED=false
1035     AC_MSG_RESULT([no])
1036   fi
1037   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
1038   AC_SUBST(OUTPUT_SYNC)
1039 ])
1040 
1041 ###############################################################################
1042 # Goes looking for a usable version of GNU make.
1043 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
1044 [
1045   BASIC_SETUP_TOOL([MAKE],
1046   [
1047     # Try our hardest to locate a correct version of GNU make
1048     AC_PATH_PROGS(CHECK_GMAKE, gmake)
1049     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
1050 
1051     if test "x$FOUND_MAKE" = x; then
1052       AC_PATH_PROGS(CHECK_MAKE, make)
1053       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
1054     fi
1055 
1056     if test "x$FOUND_MAKE" = x; then
1057       if test "x$TOOLCHAIN_PATH" != x; then
1058         # We have a toolchain path, check that as well before giving up.
1059         OLD_PATH=$PATH
1060         PATH=$TOOLCHAIN_PATH:$PATH
1061         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
1062         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
1063         if test "x$FOUND_MAKE" = x; then
1064           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
1065           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
1066         fi
1067         PATH=$OLD_PATH
1068       fi
1069     fi
1070 
1071     if test "x$FOUND_MAKE" = x; then
1072       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
1073     fi
1074   ],[
1075     # If MAKE was set by user, verify the version
1076     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
1077     if test "x$FOUND_MAKE" = x; then
1078       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
1079     fi
1080   ])
1081 
1082   MAKE=$FOUND_MAKE
1083   AC_SUBST(MAKE)
1084   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
1085 
1086   BASIC_CHECK_MAKE_OUTPUT_SYNC
1087 ])
1088 
1089 ###############################################################################
1090 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
1091 [
1092   # Test if find supports -delete
1093   AC_MSG_CHECKING([if find supports -delete])
1094   FIND_DELETE="-delete"
1095 
1096   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
1097 
1098   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
1099 
1100   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
1101   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1102     # No, it does not.
1103     $RM $DELETEDIR/TestIfFindSupportsDelete
1104     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1105       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1106       FIND_DELETE="-print | $XARGS $RM"
1107     else
1108       FIND_DELETE="-exec $RM \{\} \+"
1109     fi
1110     AC_MSG_RESULT([no])
1111   else
1112     AC_MSG_RESULT([yes])
1113   fi
1114   $RMDIR $DELETEDIR
1115   AC_SUBST(FIND_DELETE)
1116 ])
1117 
1118 ###############################################################################
1119 AC_DEFUN([BASIC_CHECK_TAR],
1120 [
1121   # Test which kind of tar was found
1122   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1123     TAR_TYPE="gnu"
1124   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1125     TAR_TYPE="bsd"
1126   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1127     TAR_TYPE="bsd"
1128   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1129     TAR_TYPE="solaris"
1130   fi
1131   AC_MSG_CHECKING([what type of tar was found])
1132   AC_MSG_RESULT([$TAR_TYPE])
1133 
1134   TAR_CREATE_FILE_PARAM=""
1135 
1136   if test "x$TAR_TYPE" = "xgnu"; then
1137     TAR_INCLUDE_PARAM="T"
1138     TAR_SUPPORTS_TRANSFORM="true"
1139     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1140       # When using gnu tar for Solaris targets, need to use compatibility mode
1141       TAR_CREATE_EXTRA_PARAM="--format=ustar"
1142     fi
1143   else
1144     TAR_INCLUDE_PARAM="I"
1145     TAR_SUPPORTS_TRANSFORM="false"
1146   fi
1147   AC_SUBST(TAR_TYPE)
1148   AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1149   AC_SUBST(TAR_INCLUDE_PARAM)
1150   AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1151 ])
1152 
1153 ###############################################################################
1154 AC_DEFUN([BASIC_CHECK_GREP],
1155 [
1156   # Test that grep supports -Fx with a list of pattern which includes null pattern.
1157   # This is a problem for the grep resident on AIX.
1158   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1159   # Multiple subsequent spaces..
1160   STACK_SPACES='aaa   bbb   ccc'
1161   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1162   # patterns in it.
1163   STACK_LIST=${STACK_SPACES// /$'\n'}
1164   NEEDLE_SPACES='ccc bbb aaa'
1165   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1166   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1167   if test "x$RESULT" == "x"; then
1168     AC_MSG_RESULT([yes])
1169   else
1170     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1171       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1172     fi
1173     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1174   fi
1175 ])
1176 
1177 ###############################################################################
1178 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1179 [
1180   BASIC_CHECK_GNU_MAKE
1181 
1182   BASIC_CHECK_FIND_DELETE
1183   BASIC_CHECK_TAR
1184   BASIC_CHECK_GREP
1185 
1186   # These tools might not be installed by default,
1187   # need hint on how to install them.
1188   BASIC_REQUIRE_PROGS(UNZIP, unzip)
1189   # Since zip uses "ZIP" as a environment variable for passing options, we need
1190   # to name our variable differently, hence ZIPEXE.
1191   BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1192 
1193   # Non-required basic tools
1194 
1195   BASIC_PATH_PROGS(LDD, ldd)
1196   if test "x$LDD" = "x"; then
1197     # List shared lib dependencies is used for
1198     # debug output and checking for forbidden dependencies.
1199     # We can build without it.
1200     LDD="true"
1201   fi
1202   BASIC_PATH_PROGS(READELF, [greadelf readelf])
1203   BASIC_PATH_PROGS(DOT, dot)
1204   BASIC_PATH_PROGS(HG, hg)
1205   BASIC_PATH_PROGS(GIT, git)
1206   BASIC_PATH_PROGS(STAT, stat)
1207   BASIC_PATH_PROGS(TIME, time)
1208   BASIC_PATH_PROGS(FLOCK, flock)
1209   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1210   # be in the user path.
1211   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1212   BASIC_PATH_PROGS(PATCH, [gpatch patch])
1213   # Check if it's GNU time
1214   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1215   if test "x$IS_GNU_TIME" != x; then
1216     IS_GNU_TIME=yes
1217   else
1218     IS_GNU_TIME=no
1219   fi
1220   AC_SUBST(IS_GNU_TIME)
1221 
1222   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1223     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1224     BASIC_REQUIRE_PROGS(MIG, mig)
1225     BASIC_REQUIRE_PROGS(XATTR, xattr)
1226     BASIC_PATH_PROGS(CODESIGN, codesign)
1227     if test "x$CODESIGN" != "x"; then
1228       # Verify that the openjdk_codesign certificate is present
1229       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1230       $RM codesign-testfile
1231       $TOUCH codesign-testfile
1232       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1233       $RM codesign-testfile
1234       if test "x$CODESIGN" = x; then
1235         AC_MSG_RESULT([no])
1236       else
1237         AC_MSG_RESULT([yes])
1238       fi
1239     fi
1240     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1241   elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1242     BASIC_REQUIRE_PROGS(ELFEDIT, elfedit)
1243   fi
1244 ])
1245 
1246 ###############################################################################
1247 # Check if build directory is on local disk. If not possible to determine,
1248 # we prefer to claim it's local.
1249 # Argument 1: directory to test
1250 # Argument 2: what to do if it is on local disk
1251 # Argument 3: what to do otherwise (remote disk or failure)
1252 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1253 [
1254   # df -l lists only local disks; if the given directory is not found then
1255   # a non-zero exit code is given
1256   if test "x$DF" = x; then
1257     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1258       # msys does not have df; use Windows "net use" instead.
1259       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1260       if test "x$IS_NETWORK_DISK" = x; then
1261         $2
1262       else
1263         $3
1264       fi
1265     else
1266       # No df here, say it's local
1267       $2
1268     fi
1269   else
1270     # JDK-8189619
1271     # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1272     # is the same. On older AIXes we just continue to live with a "not local build" warning.
1273     if test "x$OPENJDK_TARGET_OS" = xaix; then
1274       DF_LOCAL_ONLY_OPTION='-T local'
1275     else
1276       DF_LOCAL_ONLY_OPTION='-l'
1277     fi
1278     if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1279       $2
1280     else
1281       $3
1282     fi
1283   fi
1284 ])
1285 
1286 ###############################################################################
1287 # Check that source files have basic read permissions set. This might
1288 # not be the case in cygwin in certain conditions.
1289 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1290 [
1291   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1292     file_to_test="$TOPDIR/LICENSE"
1293     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1294       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1295     fi
1296   fi
1297 ])
1298 
1299 ###############################################################################
1300 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1301 [
1302   AC_MSG_CHECKING([if build directory is on local disk])
1303   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1304       [OUTPUT_DIR_IS_LOCAL="yes"],
1305       [OUTPUT_DIR_IS_LOCAL="no"])
1306   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1307 
1308   BASIC_CHECK_SRC_PERMS
1309 
1310   # Check if the user has any old-style ALT_ variables set.
1311   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1312 
1313   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1314   # Since we can't properly handle the dependencies for this, warn the user about the situation
1315   if test -e $OUTPUTDIR/spec.gmk; then
1316     IS_RECONFIGURE=yes
1317   else
1318     IS_RECONFIGURE=no
1319   fi
1320 ])
1321 
1322 ###############################################################################
1323 # Check for support for specific options in bash
1324 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1325 [
1326   # Check bash version
1327   # Extra [ ] to stop m4 mangling
1328   [ BASH_VER=`$BASH --version | $SED -n  -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1329   AC_MSG_CHECKING([bash version])
1330   AC_MSG_RESULT([$BASH_VER])
1331 
1332   BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1333   BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1334   if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1335     AC_MSG_ERROR([bash version 3.2 or better is required])
1336   fi
1337 
1338   # Test if bash supports pipefail.
1339   AC_MSG_CHECKING([if bash supports pipefail])
1340   if ${BASH} -c 'set -o pipefail'; then
1341     BASH_ARGS="$BASH_ARGS -o pipefail"
1342     AC_MSG_RESULT([yes])
1343   else
1344     AC_MSG_RESULT([no])
1345   fi
1346 
1347   AC_MSG_CHECKING([if bash supports errexit (-e)])
1348   if ${BASH} -e -c 'true'; then
1349     BASH_ARGS="$BASH_ARGS -e"
1350     AC_MSG_RESULT([yes])
1351   else
1352     AC_MSG_RESULT([no])
1353   fi
1354 
1355   AC_SUBST(BASH_ARGS)
1356 ])
1357 
1358 ################################################################################
1359 #
1360 # Default make target
1361 #
1362 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1363 [
1364   AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1365       [set the default make target @<:@exploded-image@:>@])])
1366   if test "x$with_default_make_target" = "x" \
1367       || test "x$with_default_make_target" = "xyes"; then
1368     DEFAULT_MAKE_TARGET="exploded-image"
1369   elif test "x$with_default_make_target" = "xno"; then
1370     AC_MSG_ERROR([--without-default-make-target is not a valid option])
1371   else
1372     DEFAULT_MAKE_TARGET="$with_default_make_target"
1373   fi
1374 
1375   AC_SUBST(DEFAULT_MAKE_TARGET)
1376 ])
1377 
1378 ###############################################################################
1379 # Setup the default value for LOG=
1380 #
1381 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_LOG],
1382 [
1383   AC_ARG_WITH(log, [AS_HELP_STRING([--with-log],
1384       [[default vaue for make LOG argument [warn]]])])
1385   AC_MSG_CHECKING([for default LOG value])
1386   if test "x$with_log" = x; then
1387     DEFAULT_LOG=""
1388   else
1389     # Syntax for valid LOG options is a bit too complex for it to be worth
1390     # implementing a test for correctness in configure. Just accept it.
1391     DEFAULT_LOG=$with_log
1392   fi
1393   AC_MSG_RESULT([$DEFAULT_LOG])
1394   AC_SUBST(DEFAULT_LOG)
1395 ])
1396 
1397 ###############################################################################
1398 # Code to run after AC_OUTPUT
1399 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1400 [
1401   # Try to move config.log (generated by autoconf) to the configure-support directory.
1402   if test -e ./config.log; then
1403     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1404   fi
1405 
1406   # Rotate our log file (configure.log)
1407   if test -e "$OUTPUTDIR/configure.log.old"; then
1408     $RM -f "$OUTPUTDIR/configure.log.old"
1409   fi
1410   if test -e "$OUTPUTDIR/configure.log"; then
1411     $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1412   fi
1413 
1414   # Move configure.log from current directory to the build output root
1415   if test -e ./configure.log; then
1416     $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1417   fi
1418 
1419   # Make the compare script executable
1420   $CHMOD +x $OUTPUTDIR/compare.sh
1421 ])