1 #
2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file handles detection of the Boot JDK. The Boot JDK detection
28 # process has been developed as a response to solve a complex real-world
29 # problem. Initially, it was simple, but it has grown as platform after
30 # platform, idiosyncracy after idiosyncracy has been supported.
31 #
32 # The basic idea is this:
33 # 1) You need an acceptable *) JDK to use as a Boot JDK
34 # 2) There are several ways to locate a JDK, that are mostly platform
35 # dependent **)
36 # 3) You can have multiple JDKs installed
37 # 4) If possible, configure should try to dig out an acceptable JDK
38 # automatically, without having to resort to command-line options
39 #
40 # *) acceptable means e.g. JDK7 for building JDK8, a complete JDK (with
41 # javac) and not a JRE, etc.
42 #
43 # **) On Windows we typically use a well-known path.
44 # On MacOSX we typically use the tool java_home.
45 # On Linux we typically find javac in the $PATH, and then follow a
46 # chain of symlinks that often ends up in a real JDK.
47 #
48 # This leads to the code where we check in different ways to locate a
49 # JDK, and if one is found, check if it is acceptable. If not, we print
50 # our reasons for rejecting it (useful when debugging non-working
51 # configure situations) and continue checking the next one.
52 ########################################################################
53
54 # Execute the check given as argument, and verify the result
55 # If the Boot JDK was previously found, do nothing
56 # $1 A command line (typically autoconf macro) to execute
57 AC_DEFUN([BOOTJDK_DO_CHECK],
58 [
59 if test "x$BOOT_JDK_FOUND" = xno; then
60 # Now execute the test
61 $1
62
63 # If previous step claimed to have found a JDK, check it to see if it seems to be valid.
64 if test "x$BOOT_JDK_FOUND" = xmaybe; then
65 # Do we have a bin/java?
66 if test ! -x "$BOOT_JDK/bin/java$EXECUTABLE_SUFFIX"; then
67 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK did not contain bin/java; ignoring])
68 BOOT_JDK_FOUND=no
69 else
70 # Do we have a bin/javac?
71 if test ! -x "$BOOT_JDK/bin/javac$EXECUTABLE_SUFFIX"; then
72 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK did not contain bin/javac; ignoring])
73 AC_MSG_NOTICE([(This might be an JRE instead of an JDK)])
74 BOOT_JDK_FOUND=no
75 else
76 # Oh, this is looking good! We probably have found a proper JDK. Is it the correct version?
77 BOOT_JDK_VERSION=`"$BOOT_JDK/bin/java$EXECUTABLE_SUFFIX" $USER_BOOT_JDK_OPTIONS -version 2>&1 | $HEAD -n 1`
78 if [ [[ "$BOOT_JDK_VERSION" =~ "Picked up" ]] ]; then
79 AC_MSG_NOTICE([You have _JAVA_OPTIONS or JAVA_TOOL_OPTIONS set. This can mess up the build. Please use --with-boot-jdk-jvmargs instead.])
80 AC_MSG_NOTICE([Java reports: "$BOOT_JDK_VERSION".])
81 AC_MSG_ERROR([Cannot continue])
82 fi
83 if [ [[ "$BOOT_JDK_VERSION" =~ "Unrecognized option" ]] ]; then
84 AC_MSG_NOTICE([The specified --with-boot-jdk-jvmargs is invalid for the tested java])
85 AC_MSG_NOTICE([Error message: "$BOOT_JDK_VERSION".])
86 AC_MSG_NOTICE([Please fix arguments, or point to an explicit boot JDK which accept these arguments])
87 AC_MSG_ERROR([Cannot continue])
88 fi
89
90 # Extra M4 quote needed to protect [] in grep expression.
91 [FOUND_CORRECT_VERSION=`$ECHO $BOOT_JDK_VERSION \
92 | $EGREP "\"(${DEFAULT_ACCEPTABLE_BOOT_VERSIONS// /|})([\.+-].*)?\""`]
93 if test "x$FOUND_CORRECT_VERSION" = x; then
94 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK is incorrect JDK version ($BOOT_JDK_VERSION); ignoring])
95 AC_MSG_NOTICE([(Your Boot JDK version must be one of: $DEFAULT_ACCEPTABLE_BOOT_VERSIONS)])
96 BOOT_JDK_FOUND=no
97 else
98 # We're done! :-)
99 BOOT_JDK_FOUND=yes
100 BASIC_FIXUP_PATH(BOOT_JDK)
101 AC_MSG_CHECKING([for Boot JDK])
102 AC_MSG_RESULT([$BOOT_JDK])
103 AC_MSG_CHECKING([Boot JDK version])
104 BOOT_JDK_VERSION=`"$BOOT_JDK/bin/java$EXECUTABLE_SUFFIX" $USER_BOOT_JDK_OPTIONS -version 2>&1 | $TR '\n\r' ' '`
105 AC_MSG_RESULT([$BOOT_JDK_VERSION])
106 fi # end check jdk version
107 fi # end check javac
108 fi # end check java
109 fi # end check boot jdk found
110 fi
111 ])
112
113 # Test: Is bootjdk explicitly set by command line arguments?
114 AC_DEFUN([BOOTJDK_CHECK_ARGUMENTS],
115 [
116 if test "x$with_boot_jdk" != x; then
117 if test -d "$with_boot_jdk"; then
118 BOOT_JDK=$with_boot_jdk
119 BOOT_JDK_FOUND=maybe
120 elif test -f "$with_boot_jdk"; then
121 case "$with_boot_jdk" in
122 *.tar.gz )
123 BOOT_JDK_SUPPORT_DIR=$CONFIGURESUPPORT_OUTPUTDIR/boot-jdk
124 $RM -rf $BOOT_JDK_SUPPORT_DIR
125 $MKDIR -p $BOOT_JDK_SUPPORT_DIR
126 $GUNZIP -c $with_boot_jdk | $TAR xf - -C $BOOT_JDK_SUPPORT_DIR
127
128 # Try to find javac to determine BOOT_JDK path
129 BOOT_JDK_JAVAC_PATH=`$FIND $BOOT_JDK_SUPPORT_DIR | $GREP "/bin/javac"`
130 if test "x$BOOT_JDK_JAVAC_PATH" != x; then
131 BOOT_JDK_FOUND=maybe
132 BOOT_JDK=$($DIRNAME $($DIRNAME $BOOT_JDK_JAVAC_PATH))
133 else
134 BOOT_JDK_FOUND=no
135 fi
136 ;;
137 * )
138 BOOT_JDK_FOUND=no
139 ;;
140 esac
141 else
142 BOOT_JDK_FOUND=no
143 fi
144 AC_MSG_NOTICE([Found potential Boot JDK using configure arguments])
145 fi
146 ])
147
148 # Test: Is $JAVA_HOME set?
149 AC_DEFUN([BOOTJDK_CHECK_JAVA_HOME],
150 [
151 if test "x$JAVA_HOME" != x; then
152 JAVA_HOME_PROCESSED="$JAVA_HOME"
153 BASIC_FIXUP_PATH(JAVA_HOME_PROCESSED)
154 if test ! -d "$JAVA_HOME_PROCESSED"; then
155 AC_MSG_NOTICE([Your JAVA_HOME points to a non-existing directory!])
156 else
157 # Aha, the user has set a JAVA_HOME
158 # let us use that as the Boot JDK.
159 BOOT_JDK="$JAVA_HOME_PROCESSED"
160 BOOT_JDK_FOUND=maybe
161 AC_MSG_NOTICE([Found potential Boot JDK using JAVA_HOME])
162 fi
163 fi
164 ])
165
166 # Test: Is there a java or javac in the PATH, which is a symlink to the JDK?
167 AC_DEFUN([BOOTJDK_CHECK_JAVA_IN_PATH_IS_SYMLINK],
168 [
169 AC_PATH_PROG(JAVAC_CHECK, javac)
170 AC_PATH_PROG(JAVA_CHECK, java)
171 BINARY="$JAVAC_CHECK"
172 if test "x$JAVAC_CHECK" = x; then
173 BINARY="$JAVA_CHECK"
174 fi
175 if test "x$BINARY" != x; then
176 # So there is a java(c) binary, it might be part of a JDK.
177 # Lets find the JDK/JRE directory by following symbolic links.
178 # Linux/GNU systems often have links from /usr/bin/java to
179 # /etc/alternatives/java to the real JDK binary.
180 BASIC_REMOVE_SYMBOLIC_LINKS(BINARY)
181 BOOT_JDK=`dirname "$BINARY"`
182 BOOT_JDK=`cd "$BOOT_JDK/.."; pwd`
183 if test -x "$BOOT_JDK/bin/javac" && test -x "$BOOT_JDK/bin/java"; then
184 # Looks like we found ourselves an JDK
185 BOOT_JDK_FOUND=maybe
186 AC_MSG_NOTICE([Found potential Boot JDK using java(c) in PATH])
187 fi
188 fi
189 ])
190
191 # Test: Is there a /usr/libexec/java_home? (Typically on MacOSX)
192 # $1: Argument to the java_home binary (optional)
193 AC_DEFUN([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME],
194 [
195 if test -x /usr/libexec/java_home; then
196 BOOT_JDK=`/usr/libexec/java_home $1`
197 BOOT_JDK_FOUND=maybe
198 AC_MSG_NOTICE([Found potential Boot JDK using /usr/libexec/java_home $1])
199 fi
200 ])
201
202 # Test: On MacOS X, can we find a boot jdk using /usr/libexec/java_home?
203 AC_DEFUN([BOOTJDK_CHECK_MACOSX_JAVA_LOCATOR],
204 [
205 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
206 # First check at user selected default
207 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME()])
208 # If that did not work out (e.g. too old), try explicit versions instead
209 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME([-v 1.9])])
210 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME([-v 1.8])])
211 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME([-v 1.7])])
212 fi
213 ])
214
215 # Look for a jdk in the given path. If there are multiple, try to select the newest.
216 # If found, set BOOT_JDK and BOOT_JDK_FOUND.
217 # $1 = Path to directory containing jdk installations.
218 # $2 = String to append to the found JDK directory to get the proper JDK home
219 AC_DEFUN([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY],
220 [
221 BOOT_JDK_PREFIX="$1"
222 BOOT_JDK_SUFFIX="$2"
223 ALL_JDKS_FOUND=`$LS "$BOOT_JDK_PREFIX" 2> /dev/null | $SORT -r`
224 if test "x$ALL_JDKS_FOUND" != x; then
225 for JDK_TO_TRY in $ALL_JDKS_FOUND ; do
226 BOOTJDK_DO_CHECK([
227 BOOT_JDK="${BOOT_JDK_PREFIX}/${JDK_TO_TRY}${BOOT_JDK_SUFFIX}"
228 if test -d "$BOOT_JDK"; then
229 BOOT_JDK_FOUND=maybe
230 AC_MSG_NOTICE([Found potential Boot JDK using well-known locations (in $BOOT_JDK_PREFIX/$JDK_TO_TRY)])
231 fi
232 ])
233 done
234 fi
235 ])
236
237 # Call BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY, but use the given
238 # environmental variable as base for where to look.
239 # $1 Name of an environmal variable, assumed to point to the Program Files directory.
240 AC_DEFUN([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY],
241 [
242 if test "x[$]$1" != x; then
243 VIRTUAL_DIR="[$]$1/Java"
244 BASIC_WINDOWS_REWRITE_AS_UNIX_PATH(VIRTUAL_DIR)
245 BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY($VIRTUAL_DIR)
246 fi
247 ])
248
249 # Test: Is there a JDK installed in default, well-known locations?
250 AC_DEFUN([BOOTJDK_CHECK_WELL_KNOWN_LOCATIONS],
251 [
252 if test "x$OPENJDK_TARGET_OS" = xwindows; then
253 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([ProgramW6432])])
254 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([PROGRAMW6432])])
255 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([PROGRAMFILES])])
256 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([ProgramFiles])])
257 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/cygdrive/c/Program Files/Java])])
258 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
259 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/Library/Java/JavaVirtualMachines],[/Contents/Home])])
260 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/System/Library/Java/JavaVirtualMachines],[/Contents/Home])])
261 elif test "x$OPENJDK_TARGET_OS" = xlinux; then
262 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/usr/lib/jvm])])
263 fi
264 ])
265
266 # Check that a command-line tool in the Boot JDK is correct
267 # $1 = name of variable to assign
268 # $2 = name of binary
269 AC_DEFUN([BOOTJDK_CHECK_TOOL_IN_BOOTJDK],
270 [
271 # Use user overridden value if available, otherwise locate tool in the Boot JDK.
272 BASIC_SETUP_TOOL($1,
273 [
274 AC_MSG_CHECKING([for $2 in Boot JDK])
275 $1=$BOOT_JDK/bin/$2
276 if test ! -x [$]$1; then
277 AC_MSG_RESULT(not found)
278 AC_MSG_NOTICE([Your Boot JDK seems broken. This might be fixed by explicitly setting --with-boot-jdk])
279 AC_MSG_ERROR([Could not find $2 in the Boot JDK])
280 fi
281 AC_MSG_RESULT(ok)
282 AC_SUBST($1)
283 ])
284 ])
285
286 ###############################################################################
287 #
288 # We need a Boot JDK to bootstrap the build.
289 #
290
291 AC_DEFUN_ONCE([BOOTJDK_SETUP_BOOT_JDK],
292 [
293 BOOT_JDK_FOUND=no
294 AC_ARG_WITH(boot-jdk, [AS_HELP_STRING([--with-boot-jdk],
295 [path to Boot JDK (used to bootstrap build) @<:@probed@:>@])])
296
297 AC_ARG_WITH(boot-jdk-jvmargs, [AS_HELP_STRING([--with-boot-jdk-jvmargs],
298 [specify additional arguments to be passed to Boot JDK tools @<:@none@:>@])])
299
300 USER_BOOT_JDK_OPTIONS="$with_boot_jdk_jvmargs"
301
302 # We look for the Boot JDK through various means, going from more certain to
303 # more of a guess-work. After each test, BOOT_JDK_FOUND is set to "yes" if
304 # we detected something (if so, the path to the jdk is in BOOT_JDK). But we
305 # must check if this is indeed valid; otherwise we'll continue looking.
306
307 # Test: Is bootjdk explicitly set by command line arguments?
308 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_ARGUMENTS])
309 if test "x$with_boot_jdk" != x && test "x$BOOT_JDK_FOUND" = xno; then
310 # Having specified an argument which is incorrect will produce an instant failure;
311 # we should not go on looking
312 AC_MSG_ERROR([The path given by --with-boot-jdk does not contain a valid Boot JDK])
313 fi
314
315 # Test: On MacOS X, can we find a boot jdk using /usr/libexec/java_home?
316 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_MACOSX_JAVA_LOCATOR])
317
318 # Test: Is $JAVA_HOME set?
319 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_JAVA_HOME])
320
321 # Test: Is there a java or javac in the PATH, which is a symlink to the JDK?
322 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_JAVA_IN_PATH_IS_SYMLINK])
323
324 # Test: Is there a JDK installed in default, well-known locations?
325 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_WELL_KNOWN_LOCATIONS])
326
327 # If we haven't found anything yet, we've truly lost. Give up.
328 if test "x$BOOT_JDK_FOUND" = xno; then
329 HELP_MSG_MISSING_DEPENDENCY([openjdk])
330 AC_MSG_NOTICE([Could not find a valid Boot JDK. $HELP_MSG])
331 AC_MSG_NOTICE([This might be fixed by explicitly setting --with-boot-jdk])
332 AC_MSG_ERROR([Cannot continue])
333 fi
334
335 AC_SUBST(BOOT_JDK)
336
337 # Setup tools from the Boot JDK.
338 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVA, java$EXECUTABLE_SUFFIX)
339 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVAC, javac$EXECUTABLE_SUFFIX)
340 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVADOC, javadoc$EXECUTABLE_SUFFIX)
341 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAR, jar$EXECUTABLE_SUFFIX)
342 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JARSIGNER, jarsigner$EXECUTABLE_SUFFIX)
343
344 # Finally, set some other options...
345
346 # When compiling code to be executed by the Boot JDK, force compatibility with the
347 # oldest supported bootjdk.
348 BOOT_JDK_SOURCETARGET="-source 9 -target 9"
349 AC_SUBST(BOOT_JDK_SOURCETARGET)
350
351 AC_SUBST(JAVAC_FLAGS)
352
353 # Check if the boot jdk is 32 or 64 bit
354 if "$JAVA" -version 2>&1 | $GREP -q "64-Bit"; then
355 BOOT_JDK_BITS="64"
356 else
357 BOOT_JDK_BITS="32"
358 fi
359 AC_MSG_CHECKING([if Boot JDK is 32 or 64 bits])
360 AC_MSG_RESULT([$BOOT_JDK_BITS])
361
362 # Try to enable CDS
363 AC_MSG_CHECKING([for local Boot JDK Class Data Sharing (CDS)])
364 BOOT_JDK_CDS_ARCHIVE=$CONFIGURESUPPORT_OUTPUTDIR/classes.jsa
365 ADD_JVM_ARG_IF_OK([-XX:+UnlockDiagnosticVMOptions -XX:-VerifySharedSpaces -XX:SharedArchiveFile=$BOOT_JDK_CDS_ARCHIVE],boot_jdk_cds_args,[$JAVA])
366
367 if test "x$boot_jdk_cds_args" != x; then
368 # Try creating a CDS archive
369 "$JAVA" $boot_jdk_cds_args -Xshare:dump > /dev/null 2>&1
370 if test $? -eq 0; then
371 BOOTJDK_USE_LOCAL_CDS=true
372 AC_MSG_RESULT([yes, created])
373 else
374 # Generation failed, don't use CDS.
375 BOOTJDK_USE_LOCAL_CDS=false
376 AC_MSG_RESULT([no, creation failed])
377 fi
378 else
379 BOOTJDK_USE_LOCAL_CDS=false
380 AC_MSG_RESULT([no, -XX:SharedArchiveFile not supported])
381 fi
382 ])
383
384 AC_DEFUN_ONCE([BOOTJDK_SETUP_BOOT_JDK_ARGUMENTS],
385 [
386 ##############################################################################
387 #
388 # Specify jvm options for anything that is run with the Boot JDK.
389 # Not all JVM:s accept the same arguments on the command line.
390 #
391 AC_MSG_CHECKING([flags for boot jdk java command] )
392
393 # Force en-US environment
394 ADD_JVM_ARG_IF_OK([-Duser.language=en -Duser.country=US],boot_jdk_jvmargs,[$JAVA])
395
396 if test "x$BOOTJDK_USE_LOCAL_CDS" = xtrue; then
397 # Use our own CDS archive
398 ADD_JVM_ARG_IF_OK([$boot_jdk_cds_args -Xshare:auto],boot_jdk_jvmargs,[$JAVA])
399 else
400 # Otherwise optimistically use the system-wide one, if one is present
401 ADD_JVM_ARG_IF_OK([-Xshare:auto],boot_jdk_jvmargs,[$JAVA])
402 fi
403
404 # Finally append user provided options to allow them to override.
405 ADD_JVM_ARG_IF_OK([$USER_BOOT_JDK_OPTIONS],boot_jdk_jvmargs,[$JAVA])
406
407 AC_MSG_RESULT([$boot_jdk_jvmargs])
408
409 # For now, general JAVA_FLAGS are the same as the boot jdk jvmargs
410 JAVA_FLAGS=$boot_jdk_jvmargs
411 AC_SUBST(JAVA_FLAGS)
412
413 AC_MSG_CHECKING([flags for boot jdk java command for big workloads])
414
415 # Starting amount of heap memory.
416 ADD_JVM_ARG_IF_OK([-Xms64M],boot_jdk_jvmargs_big,[$JAVA])
417 BOOTCYCLE_JVM_ARGS_BIG=-Xms64M
418
419 # Maximum amount of heap memory and stack size.
420 JVM_HEAP_LIMIT_32="768"
421 # Running a 64 bit JVM allows for and requires a bigger heap
422 JVM_HEAP_LIMIT_64="1600"
423 STACK_SIZE_32=768
424 STACK_SIZE_64=1536
425 JVM_HEAP_LIMIT_GLOBAL=`expr $MEMORY_SIZE / 2`
426 if test "$JVM_HEAP_LIMIT_GLOBAL" -lt "$JVM_HEAP_LIMIT_32"; then
427 JVM_HEAP_LIMIT_32=$JVM_HEAP_LIMIT_GLOBAL
428 fi
429 if test "$JVM_HEAP_LIMIT_GLOBAL" -lt "$JVM_HEAP_LIMIT_64"; then
430 JVM_HEAP_LIMIT_64=$JVM_HEAP_LIMIT_GLOBAL
431 fi
432 if test "$JVM_HEAP_LIMIT_GLOBAL" -lt "512"; then
433 JVM_HEAP_LIMIT_32=512
434 JVM_HEAP_LIMIT_64=512
435 fi
436
437 if test "x$BOOT_JDK_BITS" = "x32"; then
438 STACK_SIZE=$STACK_SIZE_32
439 JVM_MAX_HEAP=$JVM_HEAP_LIMIT_32
440 else
441 STACK_SIZE=$STACK_SIZE_64
442 JVM_MAX_HEAP=$JVM_HEAP_LIMIT_64
443 fi
444 ADD_JVM_ARG_IF_OK([-Xmx${JVM_MAX_HEAP}M],boot_jdk_jvmargs_big,[$JAVA])
445 ADD_JVM_ARG_IF_OK([-XX:ThreadStackSize=$STACK_SIZE],boot_jdk_jvmargs_big,[$JAVA])
446
447 AC_MSG_RESULT([$boot_jdk_jvmargs_big])
448
449 JAVA_FLAGS_BIG=$boot_jdk_jvmargs_big
450 AC_SUBST(JAVA_FLAGS_BIG)
451
452 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
453 BOOTCYCLE_MAX_HEAP=$JVM_HEAP_LIMIT_32
454 BOOTCYCLE_STACK_SIZE=$STACK_SIZE_32
455 else
456 BOOTCYCLE_MAX_HEAP=$JVM_HEAP_LIMIT_64
457 BOOTCYCLE_STACK_SIZE=$STACK_SIZE_64
458 fi
459 BOOTCYCLE_JVM_ARGS_BIG="$BOOTCYCLE_JVM_ARGS_BIG -Xmx${BOOTCYCLE_MAX_HEAP}M"
460 BOOTCYCLE_JVM_ARGS_BIG="$BOOTCYCLE_JVM_ARGS_BIG -XX:ThreadStackSize=$BOOTCYCLE_STACK_SIZE"
461 AC_MSG_CHECKING([flags for bootcycle boot jdk java command for big workloads])
462 AC_MSG_RESULT([$BOOTCYCLE_JVM_ARGS_BIG])
463 AC_SUBST(BOOTCYCLE_JVM_ARGS_BIG)
464
465 # By default, the main javac compilations use big
466 JAVA_FLAGS_JAVAC="$JAVA_FLAGS_BIG"
467 AC_SUBST(JAVA_FLAGS_JAVAC)
468
469 AC_MSG_CHECKING([flags for boot jdk java command for small workloads])
470
471 # Use serial gc for small short lived tools if possible
472 ADD_JVM_ARG_IF_OK([-XX:+UseSerialGC],boot_jdk_jvmargs_small,[$JAVA])
473 ADD_JVM_ARG_IF_OK([-Xms32M],boot_jdk_jvmargs_small,[$JAVA])
474 ADD_JVM_ARG_IF_OK([-Xmx512M],boot_jdk_jvmargs_small,[$JAVA])
475 ADD_JVM_ARG_IF_OK([-XX:TieredStopAtLevel=1],boot_jdk_jvmargs_small,[$JAVA])
476
477 AC_MSG_RESULT([$boot_jdk_jvmargs_small])
478
479 JAVA_FLAGS_SMALL=$boot_jdk_jvmargs_small
480 AC_SUBST(JAVA_FLAGS_SMALL)
481
482 JAVA_TOOL_FLAGS_SMALL=""
483 for f in $JAVA_FLAGS_SMALL; do
484 JAVA_TOOL_FLAGS_SMALL="$JAVA_TOOL_FLAGS_SMALL -J$f"
485 done
486 AC_SUBST(JAVA_TOOL_FLAGS_SMALL)
487 ])
488
489 # BUILD_JDK: the location of the latest JDK that can run
490 # on the host system and supports the target class file version
491 # generated in this JDK build. This variable should only be
492 # used after the launchers are built.
493 #
494
495 # Execute the check given as argument, and verify the result.
496 # If the JDK was previously found, do nothing.
497 # $1 A command line (typically autoconf macro) to execute
498 AC_DEFUN([BOOTJDK_CHECK_BUILD_JDK],
499 [
500 if test "x$BUILD_JDK_FOUND" = xno; then
501 # Execute the test
502 $1
503
504 # If previous step claimed to have found a JDK, check it to see if it seems to be valid.
505 if test "x$BUILD_JDK_FOUND" = xmaybe; then
506 # Do we have a bin/java?
507 if test ! -x "$BUILD_JDK/bin/java"; then
508 AC_MSG_NOTICE([Potential Build JDK found at $BUILD_JDK did not contain bin/java; ignoring])
509 BUILD_JDK_FOUND=no
510 elif test ! -x "$BUILD_JDK/bin/jlink"; then
511 AC_MSG_NOTICE([Potential Build JDK found at $BUILD_JDK did not contain bin/jlink; ignoring])
512 BUILD_JDK_FOUND=no
513 elif test ! -x "$BUILD_JDK/bin/jmod"; then
514 AC_MSG_NOTICE([Potential Build JDK found at $BUILD_JDK did not contain bin/jmod; ignoring])
515 BUILD_JDK_FOUND=no
516 elif test ! -x "$BUILD_JDK/bin/javac"; then
517 # Do we have a bin/javac?
518 AC_MSG_NOTICE([Potential Build JDK found at $BUILD_JDK did not contain bin/javac; ignoring])
519 AC_MSG_NOTICE([(This might be a JRE instead of an JDK)])
520 BUILD_JDK_FOUND=no
521 else
522 # Oh, this is looking good! We probably have found a proper JDK. Is it the correct version?
523 BUILD_JDK_VERSION=`"$BUILD_JDK/bin/java" -version 2>&1 | $HEAD -n 1`
524
525 # Extra M4 quote needed to protect [] in grep expression.
526 [FOUND_CORRECT_VERSION=`echo $BUILD_JDK_VERSION | $EGREP "\"$VERSION_FEATURE([\.+-].*)?\""`]
527 if test "x$FOUND_CORRECT_VERSION" = x; then
528 AC_MSG_NOTICE([Potential Build JDK found at $BUILD_JDK is incorrect JDK version ($BUILD_JDK_VERSION); ignoring])
529 AC_MSG_NOTICE([(Your Build JDK must be version $VERSION_FEATURE)])
530 BUILD_JDK_FOUND=no
531 else
532 # We're done!
533 BUILD_JDK_FOUND=yes
534 BASIC_FIXUP_PATH(BUILD_JDK)
535 AC_MSG_CHECKING([for Build JDK])
536 AC_MSG_RESULT([$BUILD_JDK])
537 AC_MSG_CHECKING([Build JDK version])
538 BUILD_JDK_VERSION=`"$BUILD_JDK/bin/java" -version 2>&1 | $TR '\n\r' ' '`
539 AC_MSG_RESULT([$BUILD_JDK_VERSION])
540 fi # end check jdk version
541 fi # end check java
542 fi # end check build jdk found
543 fi
544 ])
545
546 # By default the BUILD_JDK is the JDK_OUTPUTDIR. If the target architecture
547 # is different than the host system doing the build (e.g. cross-compilation),
548 # a special BUILD_JDK is built as part of the build process. An external
549 # prebuilt BUILD_JDK can also be supplied.
550 AC_DEFUN([BOOTJDK_SETUP_BUILD_JDK],
551 [
552 AC_ARG_WITH(build-jdk, [AS_HELP_STRING([--with-build-jdk],
553 [path to JDK of same version as is being built@<:@the newly built JDK@:>@])])
554
555 CREATE_BUILDJDK=false
556 EXTERNAL_BUILDJDK=false
557 BUILD_JDK_FOUND="no"
558 if test "x$with_build_jdk" != "x"; then
559 BOOTJDK_CHECK_BUILD_JDK([
560 if test "x$with_build_jdk" != x; then
561 BUILD_JDK=$with_build_jdk
562 BUILD_JDK_FOUND=maybe
563 AC_MSG_NOTICE([Found potential Build JDK using configure arguments])
564 fi])
565 EXTERNAL_BUILDJDK=true
566 else
567 if test "x$COMPILE_TYPE" = "xcross"; then
568 BUILD_JDK="\$(BUILDJDK_OUTPUTDIR)/jdk"
569 BUILD_JDK_FOUND=yes
570 CREATE_BUILDJDK=true
571 AC_MSG_CHECKING([for Build JDK])
572 AC_MSG_RESULT([yes, will build it for the host platform])
573 else
574 BUILD_JDK="\$(JDK_OUTPUTDIR)"
575 BUILD_JDK_FOUND=yes
576 AC_MSG_CHECKING([for Build JDK])
577 AC_MSG_RESULT([yes, will use output dir])
578 fi
579 fi
580
581 JMOD="$BUILD_JDK/bin/jmod"
582 JLINK="$BUILD_JDK/bin/jlink"
583 AC_SUBST(JMOD)
584 AC_SUBST(JLINK)
585
586 if test "x$BUILD_JDK_FOUND" != "xyes"; then
587 AC_MSG_CHECKING([for Build JDK])
588 AC_MSG_RESULT([no])
589 AC_MSG_ERROR([Could not find a suitable Build JDK])
590 fi
591
592 AC_SUBST(CREATE_BUILDJDK)
593 AC_SUBST(BUILD_JDK)
594 AC_SUBST(EXTERNAL_BUILDJDK)
595 ])