1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 m4_include([flags-cflags.m4])
27 m4_include([flags-ldflags.m4])
28 m4_include([flags-other.m4])
29
30 ################################################################################
31 #
32 # Setup ABI profile (for arm)
33 #
34 AC_DEFUN([FLAGS_SETUP_ABI_PROFILE],
35 [
36 AC_ARG_WITH(abi-profile, [AS_HELP_STRING([--with-abi-profile],
37 [specify ABI profile for ARM builds (arm-vfp-sflt,arm-vfp-hflt,arm-sflt, armv5-vfp-sflt,armv6-vfp-hflt,arm64,aarch64) @<:@toolchain dependent@:>@ ])])
38
39 if test "x$with_abi_profile" != x; then
40 if test "x$OPENJDK_TARGET_CPU" != xarm && \
41 test "x$OPENJDK_TARGET_CPU" != xaarch64; then
42 AC_MSG_ERROR([--with-abi-profile only available on arm/aarch64])
43 fi
44
45 OPENJDK_TARGET_ABI_PROFILE=$with_abi_profile
46 AC_MSG_CHECKING([for ABI profle])
47 AC_MSG_RESULT([$OPENJDK_TARGET_ABI_PROFILE])
48
49 if test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-sflt; then
50 ARM_FLOAT_TYPE=vfp-sflt
51 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
52 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-hflt; then
53 ARM_FLOAT_TYPE=vfp-hflt
54 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
55 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-sflt; then
56 ARM_FLOAT_TYPE=sflt
57 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
58 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv5-vfp-sflt; then
59 ARM_FLOAT_TYPE=vfp-sflt
60 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
61 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv6-vfp-hflt; then
62 ARM_FLOAT_TYPE=vfp-hflt
63 ARM_ARCH_TYPE_FLAGS='-march=armv6 -marm'
64 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm64; then
65 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
66 ARM_FLOAT_TYPE=
67 ARM_ARCH_TYPE_FLAGS=
68 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xaarch64; then
69 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
70 ARM_FLOAT_TYPE=
71 ARM_ARCH_TYPE_FLAGS=
72 else
73 AC_MSG_ERROR([Invalid ABI profile: "$OPENJDK_TARGET_ABI_PROFILE"])
74 fi
75
76 if test "x$ARM_FLOAT_TYPE" = xvfp-sflt; then
77 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=softfp -mfpu=vfp -DFLOAT_ARCH=-vfp-sflt'
78 elif test "x$ARM_FLOAT_TYPE" = xvfp-hflt; then
79 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=hard -mfpu=vfp -DFLOAT_ARCH=-vfp-hflt'
80 elif test "x$ARM_FLOAT_TYPE" = xsflt; then
81 ARM_FLOAT_TYPE_FLAGS='-msoft-float -mfpu=vfp'
82 fi
83 AC_MSG_CHECKING([for $ARM_FLOAT_TYPE floating point flags])
84 AC_MSG_RESULT([$ARM_FLOAT_TYPE_FLAGS])
85
86 AC_MSG_CHECKING([for arch type flags])
87 AC_MSG_RESULT([$ARM_ARCH_TYPE_FLAGS])
88
89 # Now set JDK_ARCH_ABI_PROP_NAME. This is equivalent to the last part of the
90 # autoconf target triplet.
91 [ JDK_ARCH_ABI_PROP_NAME=`$ECHO $OPENJDK_TARGET_AUTOCONF_NAME | $SED -e 's/.*-\([^-]*\)$/\1/'` ]
92 # Sanity check that it is a known ABI.
93 if test "x$JDK_ARCH_ABI_PROP_NAME" != xgnu && \
94 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabi && \
95 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabihf; then
96 AC_MSG_WARN([Unknown autoconf target triplet ABI: "$JDK_ARCH_ABI_PROP_NAME"])
97 fi
98 AC_MSG_CHECKING([for ABI property name])
99 AC_MSG_RESULT([$JDK_ARCH_ABI_PROP_NAME])
100 AC_SUBST(JDK_ARCH_ABI_PROP_NAME)
101 fi
102
103 # When building with an abi profile, the name of that profile is appended on the
104 # bundle platform, which is used in bundle names.
105 if test "x$OPENJDK_TARGET_ABI_PROFILE" != x; then
106 OPENJDK_TARGET_BUNDLE_PLATFORM="$OPENJDK_TARGET_OS_BUNDLE-$OPENJDK_TARGET_ABI_PROFILE"
107 fi
108 ])
109
110 AC_DEFUN([FLAGS_SETUP_MACOSX_VERSION],
111 [
112 # Additional macosx handling
113 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
114 # MACOSX_VERSION_MIN specifies the lowest version of Macosx that the built
115 # binaries should be compatible with, even if compiled on a newer version
116 # of the OS. It currently has a hard coded value. Setting this also limits
117 # exposure to API changes in header files. Bumping this is likely to
118 # require code changes to build.
119 MACOSX_VERSION_MIN=10.9.0
120 MACOSX_VERSION_MIN_NODOTS=${MACOSX_VERSION_MIN//\./}
121
122 AC_SUBST(MACOSX_VERSION_MIN)
123
124 # Setting --with-macosx-version-max=<version> makes it an error to build or
125 # link to macosx APIs that are newer than the given OS version. The expected
126 # format for <version> is either nn.n.n or nn.nn.nn. See /usr/include/AvailabilityMacros.h.
127 AC_ARG_WITH([macosx-version-max], [AS_HELP_STRING([--with-macosx-version-max],
128 [error on use of newer functionality. @<:@macosx@:>@])],
129 [
130 if echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]]\.[[0-9]]\$"; then
131 MACOSX_VERSION_MAX=$with_macosx_version_max
132 elif echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]][[0-9]]\.[[0-9]][[0-9]]\$"; then
133 MACOSX_VERSION_MAX=$with_macosx_version_max
134 elif test "x$with_macosx_version_max" = "xno"; then
135 # Use build system default
136 MACOSX_VERSION_MAX=
137 else
138 AC_MSG_ERROR([osx version format must be nn.n.n or nn.nn.nn])
139 fi
140 ],
141 [MACOSX_VERSION_MAX=]
142 )
143 MACOSX_VERSION_MAX_NODOTS=${MACOSX_VERSION_MAX//\./}
144
145 AC_SUBST(MACOSX_VERSION_MAX)
146 fi
147 ])
148
149 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
150 # corresponding configure arguments instead
151 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
152 [
153 if test "x$CFLAGS" != "x"; then
154 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
155 fi
156
157 if test "x$CXXFLAGS" != "x"; then
158 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
159 fi
160
161 if test "x$LDFLAGS" != "x"; then
162 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
163 fi
164
165 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
166 [extra flags to be used when compiling jdk c-files])])
167
168 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
169 [extra flags to be used when compiling jdk c++-files])])
170
171 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
172 [extra flags to be used when linking jdk])])
173
174 USER_CFLAGS="$with_extra_cflags"
175 USER_CXXFLAGS="$with_extra_cxxflags"
176 USER_LDFLAGS="$with_extra_ldflags"
177 ])
178
179 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
180 # that configure can use them while detecting compilers.
181 # TOOLCHAIN_TYPE is available here.
182 # Param 1 - Optional prefix to all variables. (e.g BUILD_)
183 AC_DEFUN([FLAGS_SETUP_SYSROOT_FLAGS],
184 [
185 if test "x[$]$1SYSROOT" != "x"; then
186 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
187 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
188 # Solaris Studio does not have a concept of sysroot. Instead we must
189 # make sure the default include and lib dirs are appended to each
190 # compile and link command line. Must also add -I-xbuiltin to enable
191 # inlining of system functions and intrinsics.
192 $1SYSROOT_CFLAGS="-I-xbuiltin -I[$]$1SYSROOT/usr/include"
193 $1SYSROOT_LDFLAGS="-L[$]$1SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
194 -L[$]$1SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR"
195 # If the devkit contains the ld linker, make sure we use it.
196 AC_PATH_PROG(SOLARIS_LD, ld, , $DEVKIT_TOOLCHAIN_PATH:$DEVKIT_EXTRA_PATH)
197 # Make sure this ld is runnable.
198 if test -f "$SOLARIS_LD"; then
199 if "$SOLARIS_LD" -V > /dev/null 2> /dev/null; then
200 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -Yl,$(dirname $SOLARIS_LD)"
201 else
202 AC_MSG_WARN([Could not run $SOLARIS_LD found in devkit, reverting to system ld])
203 fi
204 fi
205 fi
206 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
207 $1SYSROOT_CFLAGS="--sysroot=[$]$1SYSROOT"
208 $1SYSROOT_LDFLAGS="--sysroot=[$]$1SYSROOT"
209 elif test "x$TOOLCHAIN_TYPE" = xclang; then
210 $1SYSROOT_CFLAGS="-isysroot [$]$1SYSROOT"
211 $1SYSROOT_LDFLAGS="-isysroot [$]$1SYSROOT"
212 fi
213 fi
214
215 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
216 # We also need -iframework<path>/System/Library/Frameworks
217 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
218 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
219 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
220 # set this here so it doesn't have to be peppered throughout the forest
221 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
222 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
223 fi
224
225 AC_SUBST($1SYSROOT_CFLAGS)
226 AC_SUBST($1SYSROOT_LDFLAGS)
227 ])
228
229 AC_DEFUN_ONCE([FLAGS_PRE_TOOLCHAIN],
230 [
231 # We should always include user supplied flags
232 FLAGS_SETUP_USER_SUPPLIED_FLAGS
233 # The sysroot flags are needed for configure to be able to run the compilers
234 FLAGS_SETUP_SYSROOT_FLAGS
235
236 # For solstudio and xlc, the word size flag is required for correct behavior.
237 # For clang/gcc, the flag is only strictly required for reduced builds, but
238 # set it always where possible (x86, sparc and ppc).
239 if test "x$TOOLCHAIN_TYPE" = xxlc; then
240 MACHINE_FLAG="-q${OPENJDK_TARGET_CPU_BITS}"
241 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
242 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
243 elif test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
244 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86 ||
245 test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc ||
246 test "x$OPENJDK_TARGET_CPU_ARCH" = xppc; then
247 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
248 fi
249 fi
250
251 # FIXME: global flags are not used yet...
252 # The "global" flags will *always* be set. Without them, it is not possible to
253 # get a working compilation.
254 GLOBAL_CFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CFLAGS"
255 GLOBAL_CXXFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CXXFLAGS"
256 GLOBAL_LDFLAGS="$MACHINE_FLAG $SYSROOT_LDFLAGS $USER_LDFLAGS"
257 # FIXME: Don't really know how to do with this, but this was the old behavior
258 GLOBAL_CPPFLAGS="$SYSROOT_CFLAGS"
259 AC_SUBST(GLOBAL_CFLAGS)
260 AC_SUBST(GLOBAL_CXXFLAGS)
261 AC_SUBST(GLOBAL_LDFLAGS)
262 AC_SUBST(GLOBAL_CPPFLAGS)
263
264 # FIXME: For compatilibity, export this as EXTRA_CFLAGS for now.
265 EXTRA_CFLAGS="$MACHINE_FLAG $USER_CFLAGS"
266 EXTRA_CXXFLAGS="$MACHINE_FLAG $USER_CXXFLAGS"
267 EXTRA_LDFLAGS="$MACHINE_FLAG $USER_LDFLAGS"
268
269 AC_SUBST(EXTRA_CFLAGS)
270 AC_SUBST(EXTRA_CXXFLAGS)
271 AC_SUBST(EXTRA_LDFLAGS)
272
273 # For autoconf testing to work, the global flags must also be stored in the
274 # "unnamed" CFLAGS etc.
275 CFLAGS="$GLOBAL_CFLAGS"
276 CXXFLAGS="$GLOBAL_CXXFLAGS"
277 LDFLAGS="$GLOBAL_LDFLAGS"
278 CPPFLAGS="$GLOBAL_CPPFLAGS"
279 ])
280
281 AC_DEFUN([FLAGS_SETUP_TOOLCHAIN_CONTROL],
282 [
283 # COMPILER_TARGET_BITS_FLAG : option for selecting 32- or 64-bit output
284 # COMPILER_COMMAND_FILE_FLAG : option for passing a command file to the compiler
285 # COMPILER_BINDCMD_FILE_FLAG : option for specifying a file which saves the binder
286 # commands produced by the link step (currently AIX only)
287 if test "x$TOOLCHAIN_TYPE" = xxlc; then
288 COMPILER_TARGET_BITS_FLAG="-q"
289 COMPILER_COMMAND_FILE_FLAG="-f"
290 COMPILER_BINDCMD_FILE_FLAG="-bloadmap:"
291 else
292 COMPILER_TARGET_BITS_FLAG="-m"
293 COMPILER_COMMAND_FILE_FLAG="@"
294 COMPILER_BINDCMD_FILE_FLAG=""
295
296 # The solstudio linker does not support @-files.
297 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
298 COMPILER_COMMAND_FILE_FLAG=
299 fi
300
301 # Check if @file is supported by gcc
302 if test "x$TOOLCHAIN_TYPE" = xgcc; then
303 AC_MSG_CHECKING([if @file is supported by gcc])
304 # Extra emtpy "" to prevent ECHO from interpreting '--version' as argument
305 $ECHO "" "--version" > command.file
306 if $CXX @command.file 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
307 AC_MSG_RESULT(yes)
308 COMPILER_COMMAND_FILE_FLAG="@"
309 else
310 AC_MSG_RESULT(no)
311 COMPILER_COMMAND_FILE_FLAG=
312 fi
313 $RM command.file
314 fi
315 fi
316
317 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
318 AC_SUBST(COMPILER_COMMAND_FILE_FLAG)
319 AC_SUBST(COMPILER_BINDCMD_FILE_FLAG)
320
321 # Check that the compiler supports -mX (or -qX on AIX) flags
322 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
323 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
324 IF_TRUE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
325 IF_FALSE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
326 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
327
328 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
329 CC_OUT_OPTION=-Fo
330 LD_OUT_OPTION=-out:
331 AR_OUT_OPTION=-out:
332 else
333 # The option used to specify the target .o,.a or .so file.
334 # When compiling, how to specify the to be created object file.
335 CC_OUT_OPTION='-o$(SPACE)'
336 # When linking, how to specify the output
337 LD_OUT_OPTION='-o$(SPACE)'
338 # When archiving, how to specify the to be create static archive for object files.
339 AR_OUT_OPTION='rcs$(SPACE)'
340 fi
341 AC_SUBST(CC_OUT_OPTION)
342 AC_SUBST(LD_OUT_OPTION)
343 AC_SUBST(AR_OUT_OPTION)
344
345 # Generate make dependency files
346 if test "x$TOOLCHAIN_TYPE" = xgcc; then
347 C_FLAG_DEPS="-MMD -MF"
348 elif test "x$TOOLCHAIN_TYPE" = xclang; then
349 C_FLAG_DEPS="-MMD -MF"
350 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
351 C_FLAG_DEPS="-xMMD -xMF"
352 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
353 C_FLAG_DEPS="-qmakedep=gcc -MF"
354 fi
355 CXX_FLAG_DEPS="$C_FLAG_DEPS"
356 AC_SUBST(C_FLAG_DEPS)
357 AC_SUBST(CXX_FLAG_DEPS)
358 ])
359
360 AC_DEFUN_ONCE([FLAGS_POST_TOOLCHAIN],
361 [
362 FLAGS_SETUP_TOOLCHAIN_CONTROL
363
364 if test "x$BUILD_SYSROOT" != x; then
365 FLAGS_SETUP_SYSROOT_FLAGS([BUILD_])
366 else
367 if test "x$COMPILE_TYPE" != "xcross"; then
368 BUILD_SYSROOT_CFLAGS="$SYSROOT_CFLAGS"
369 BUILD_SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS"
370 fi
371 fi
372 AC_SUBST(BUILD_SYSROOT_CFLAGS)
373 AC_SUBST(BUILD_SYSROOT_LDFLAGS)
374
375 ])
376
377 AC_DEFUN([FLAGS_SETUP_FLAGS],
378 [
379 FLAGS_SETUP_MACOSX_VERSION
380 FLAGS_SETUP_ABI_PROFILE
381
382 FLAGS_SETUP_SHARED_LIBS
383 FLAGS_SETUP_DEBUG_SYMBOLS
384 FLAGS_SETUP_WARNINGS
385 FLAGS_SETUP_QUALITY_CHECKS
386 FLAGS_SETUP_OPTIMIZATION
387
388 FLAGS_SETUP_CFLAGS
389 FLAGS_SETUP_LDFLAGS
390
391 FLAGS_SETUP_ARFLAGS
392 FLAGS_SETUP_STRIPFLAGS
393 FLAGS_SETUP_RCFLAGS
394
395 FLAGS_SETUP_ASFLAGS
396 FLAGS_SETUP_ASFLAGS_CPU_DEP([TARGET])
397 FLAGS_SETUP_ASFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
398 ])
399
400 # FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
401 # IF_FALSE: [RUN-IF-FALSE])
402 # ------------------------------------------------------------
403 # Check that the C compiler supports an argument
404 BASIC_DEFUN_NAMED([FLAGS_C_COMPILER_CHECK_ARGUMENTS],
405 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
406 [
407 AC_MSG_CHECKING([if the C compiler supports "ARG_ARGUMENT"])
408 supports=yes
409
410 saved_cflags="$CFLAGS"
411 CFLAGS="$CFLAGS ARG_ARGUMENT"
412 AC_LANG_PUSH([C])
413 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
414 [supports=no])
415 AC_LANG_POP([C])
416 CFLAGS="$saved_cflags"
417
418 AC_MSG_RESULT([$supports])
419 if test "x$supports" = "xyes" ; then
420 :
421 ARG_IF_TRUE
422 else
423 :
424 ARG_IF_FALSE
425 fi
426 ])
427
428 # FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
429 # IF_FALSE: [RUN-IF-FALSE])
430 # ------------------------------------------------------------
431 # Check that the C++ compiler supports an argument
432 BASIC_DEFUN_NAMED([FLAGS_CXX_COMPILER_CHECK_ARGUMENTS],
433 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
434 [
435 AC_MSG_CHECKING([if the C++ compiler supports "ARG_ARGUMENT"])
436 supports=yes
437
438 saved_cxxflags="$CXXFLAGS"
439 CXXFLAGS="$CXXFLAG ARG_ARGUMENT"
440 AC_LANG_PUSH([C++])
441 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
442 [supports=no])
443 AC_LANG_POP([C++])
444 CXXFLAGS="$saved_cxxflags"
445
446 AC_MSG_RESULT([$supports])
447 if test "x$supports" = "xyes" ; then
448 :
449 ARG_IF_TRUE
450 else
451 :
452 ARG_IF_FALSE
453 fi
454 ])
455
456 # FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
457 # IF_FALSE: [RUN-IF-FALSE])
458 # ------------------------------------------------------------
459 # Check that the C and C++ compilers support an argument
460 BASIC_DEFUN_NAMED([FLAGS_COMPILER_CHECK_ARGUMENTS],
461 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
462 [
463 FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
464 IF_TRUE: [C_COMP_SUPPORTS="yes"],
465 IF_FALSE: [C_COMP_SUPPORTS="no"])
466 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
467 IF_TRUE: [CXX_COMP_SUPPORTS="yes"],
468 IF_FALSE: [CXX_COMP_SUPPORTS="no"])
469
470 AC_MSG_CHECKING([if both compilers support "ARG_ARGUMENT"])
471 supports=no
472 if test "x$C_COMP_SUPPORTS" = "xyes" -a "x$CXX_COMP_SUPPORTS" = "xyes"; then supports=yes; fi
473
474 AC_MSG_RESULT([$supports])
475 if test "x$supports" = "xyes" ; then
476 :
477 ARG_IF_TRUE
478 else
479 :
480 ARG_IF_FALSE
481 fi
482 ])
483
484 # FLAGS_LINKER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
485 # IF_FALSE: [RUN-IF-FALSE])
486 # ------------------------------------------------------------
487 # Check that the linker support an argument
488 BASIC_DEFUN_NAMED([FLAGS_LINKER_CHECK_ARGUMENTS],
489 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
490 [
491 AC_MSG_CHECKING([if linker supports "ARG_ARGUMENT"])
492 supports=yes
493
494 saved_ldflags="$LDFLAGS"
495 LDFLAGS="$LDFLAGS ARG_ARGUMENT"
496 AC_LANG_PUSH([C])
497 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
498 [], [supports=no])
499 AC_LANG_POP([C])
500 LDFLAGS="$saved_ldflags"
501
502 AC_MSG_RESULT([$supports])
503 if test "x$supports" = "xyes" ; then
504 :
505 ARG_IF_TRUE
506 else
507 :
508 ARG_IF_FALSE
509 fi
510 ])