1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64*x32)
34 VAR_CPU=x32
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=32
37 VAR_CPU_ENDIAN=little
38 ;;
39 x86_64)
40 VAR_CPU=x86_64
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=64
43 VAR_CPU_ENDIAN=little
44 ;;
45 i?86)
46 VAR_CPU=x86
47 VAR_CPU_ARCH=x86
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 alpha*)
52 VAR_CPU=alpha
53 VAR_CPU_ARCH=alpha
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 arm*)
58 VAR_CPU=arm
59 VAR_CPU_ARCH=arm
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=little
62 ;;
63 aarch64)
64 VAR_CPU=aarch64
65 VAR_CPU_ARCH=aarch64
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=little
68 ;;
69 ia64)
70 VAR_CPU=ia64
71 VAR_CPU_ARCH=ia64
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 m68k)
76 VAR_CPU=m68k
77 VAR_CPU_ARCH=m68k
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 mips)
82 VAR_CPU=mips
83 VAR_CPU_ARCH=mips
84 VAR_CPU_BITS=32
85 VAR_CPU_ENDIAN=big
86 ;;
87 mipsel)
88 VAR_CPU=mipsel
89 VAR_CPU_ARCH=mipsel
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=little
92 ;;
93 mips64)
94 VAR_CPU=mips64
95 VAR_CPU_ARCH=mips64
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 mips64el)
100 VAR_CPU=mips64el
101 VAR_CPU_ARCH=mips64el
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=little
104 ;;
105 powerpc)
106 VAR_CPU=ppc
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=32
109 VAR_CPU_ENDIAN=big
110 ;;
111 powerpc64)
112 VAR_CPU=ppc64
113 VAR_CPU_ARCH=ppc
114 VAR_CPU_BITS=64
115 VAR_CPU_ENDIAN=big
116 ;;
117 powerpc64le)
118 VAR_CPU=ppc64le
119 VAR_CPU_ARCH=ppc
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=little
122 ;;
123 s390)
124 VAR_CPU=s390
125 VAR_CPU_ARCH=s390
126 VAR_CPU_BITS=32
127 VAR_CPU_ENDIAN=big
128 ;;
129 s390x)
130 VAR_CPU=s390x
131 VAR_CPU_ARCH=s390
132 VAR_CPU_BITS=64
133 VAR_CPU_ENDIAN=big
134 ;;
135 sh*eb)
136 VAR_CPU=sh
137 VAR_CPU_ARCH=sh
138 VAR_CPU_BITS=32
139 VAR_CPU_ENDIAN=big
140 ;;
141 sh*)
142 VAR_CPU=sh
143 VAR_CPU_ARCH=sh
144 VAR_CPU_BITS=32
145 VAR_CPU_ENDIAN=little
146 ;;
147 sparc)
148 VAR_CPU=sparc
149 VAR_CPU_ARCH=sparc
150 VAR_CPU_BITS=32
151 VAR_CPU_ENDIAN=big
152 ;;
153 sparcv9|sparc64)
154 VAR_CPU=sparcv9
155 VAR_CPU_ARCH=sparc
156 VAR_CPU_BITS=64
157 VAR_CPU_ENDIAN=big
158 ;;
159 *)
160 AC_MSG_ERROR([unsupported cpu $1])
161 ;;
162 esac
163 ])
164
165 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
166 # Converts autoconf style OS name to OpenJDK style, into
167 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
168 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
169 [
170 case "$1" in
171 *linux*)
172 VAR_OS=linux
173 VAR_OS_TYPE=unix
174 ;;
175 *solaris*)
176 VAR_OS=solaris
177 VAR_OS_TYPE=unix
178 ;;
179 *darwin*)
180 VAR_OS=macosx
181 VAR_OS_TYPE=unix
182 ;;
183 *bsd*)
184 VAR_OS=bsd
185 VAR_OS_TYPE=unix
186 ;;
187 *cygwin*)
188 VAR_OS=windows
189 VAR_OS_ENV=windows.cygwin
190 ;;
191 *mingw*)
192 VAR_OS=windows
193 VAR_OS_ENV=windows.msys
194 ;;
195 *aix*)
196 VAR_OS=aix
197 VAR_OS_TYPE=unix
198 ;;
199 *)
200 AC_MSG_ERROR([unsupported operating system $1])
201 ;;
202 esac
203 ])
204
205 # Expects $host_os $host_cpu $build_os and $build_cpu
206 # and $with_target_bits to have been setup!
207 #
208 # Translate the standard triplet(quadruplet) definition
209 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
210 # OPENJDK_BUILD_OS, etc.
211 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
212 [
213 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
214 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
215 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
216 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
217 OPENJDK_TARGET_AUTOCONF_NAME="$host"
218 OPENJDK_BUILD_AUTOCONF_NAME="$build"
219 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
220 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
221
222 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
223 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
224 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
225 # ..and setup our own variables. (Do this explicitly to facilitate searching)
226 OPENJDK_BUILD_OS="$VAR_OS"
227 if test "x$VAR_OS_TYPE" != x; then
228 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
229 else
230 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
231 fi
232 if test "x$VAR_OS_ENV" != x; then
233 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
234 else
235 OPENJDK_BUILD_OS_ENV="$VAR_OS"
236 fi
237 OPENJDK_BUILD_CPU="$VAR_CPU"
238 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
239 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
240 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
241 AC_SUBST(OPENJDK_BUILD_OS)
242 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
243 AC_SUBST(OPENJDK_BUILD_OS_ENV)
244 AC_SUBST(OPENJDK_BUILD_CPU)
245 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
246 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
247 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
248
249 AC_MSG_CHECKING([openjdk-build os-cpu])
250 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
251
252 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
253 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
254 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
255 # ... and setup our own variables. (Do this explicitly to facilitate searching)
256 OPENJDK_TARGET_OS="$VAR_OS"
257 if test "x$VAR_OS_TYPE" != x; then
258 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
259 else
260 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
261 fi
262 if test "x$VAR_OS_ENV" != x; then
263 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
264 else
265 OPENJDK_TARGET_OS_ENV="$VAR_OS"
266 fi
267 OPENJDK_TARGET_CPU="$VAR_CPU"
268 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
269 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
270 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
271 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
272
273 AC_SUBST(OPENJDK_TARGET_OS)
274 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
275 AC_SUBST(OPENJDK_TARGET_OS_ENV)
276 AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
277 AC_SUBST(OPENJDK_TARGET_CPU)
278 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
279 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
280 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
281
282 AC_MSG_CHECKING([openjdk-target os-cpu])
283 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
284 ])
285
286 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
287 # accordingly. Must be done after setting up build and target system, but before
288 # doing anything else with these values.
289 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
290 [
291 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
292 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
293
294 # We have three types of compiles:
295 # native == normal compilation, target system == build system
296 # cross == traditional cross compilation, target system != build system; special toolchain needed
297 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
298 #
299 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
300 # We're doing a proper cross-compilation
301 COMPILE_TYPE="cross"
302 else
303 COMPILE_TYPE="native"
304 fi
305
306 if test "x$with_target_bits" != x; then
307 if test "x$COMPILE_TYPE" = "xcross"; then
308 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
309 fi
310
311 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
312 # A reduced build is requested
313 COMPILE_TYPE="reduced"
314 OPENJDK_TARGET_CPU_BITS=32
315 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
316 OPENJDK_TARGET_CPU=x86
317 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
318 OPENJDK_TARGET_CPU=sparc
319 else
320 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
321 fi
322 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
323 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
324 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
325 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
326 else
327 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
328 fi
329 fi
330 AC_SUBST(COMPILE_TYPE)
331
332 AC_MSG_CHECKING([compilation type])
333 AC_MSG_RESULT([$COMPILE_TYPE])
334 ])
335
336 # Setup the legacy variables, for controlling the old makefiles.
337 #
338 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
339 [
340 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
341 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
342 ])
343
344 # $1 - Either TARGET or BUILD to setup the variables for.
345 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
346 [
347 # Also store the legacy naming of the cpu.
348 # Ie i586 and amd64 instead of x86 and x86_64
349 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
350 if test "x$OPENJDK_$1_CPU" = xx86; then
351 OPENJDK_$1_CPU_LEGACY="i586"
352 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
353 # On all platforms except MacOSX replace x86_64 with amd64.
354 OPENJDK_$1_CPU_LEGACY="amd64"
355 elif test "x$OPENJDK_$1_CPU" = xalpha; then
356 # Avoid name collisions with variables named alpha
357 OPENJDK_$1_CPU_LEGACY="_alpha_"
358 elif test "x$OPENJDK_$1_CPU" = xsh; then
359 # Avoid name collisions with variables named sh
360 OPENJDK_$1_CPU_LEGACY="_sh_"
361 fi
362 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
363
364 # And the second legacy naming of the cpu.
365 # Ie i386 and amd64 instead of x86 and x86_64.
366 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
367 if test "x$OPENJDK_$1_CPU" = xx86; then
368 OPENJDK_$1_CPU_LEGACY_LIB="i386"
369 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
370 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
371 fi
372 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
373
374 # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
375 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
376 # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
377 OPENJDK_$1_CPU_ISADIR=""
378 if test "x$OPENJDK_$1_OS" = xsolaris; then
379 if test "x$OPENJDK_$1_CPU" = xx86_64; then
380 OPENJDK_$1_CPU_ISADIR="/amd64"
381 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
382 OPENJDK_$1_CPU_ISADIR="/sparcv9"
383 fi
384 fi
385 AC_SUBST(OPENJDK_$1_CPU_ISADIR)
386
387 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
388 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
389 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
390 # On linux only, we replace x86 with i386.
391 OPENJDK_$1_CPU_OSARCH="i386"
392 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
393 # On all platforms except macosx, we replace x86_64 with amd64.
394 OPENJDK_$1_CPU_OSARCH="amd64"
395 fi
396 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
397
398 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
399 if test "x$OPENJDK_$1_CPU" = xx86; then
400 OPENJDK_$1_CPU_JLI="i386"
401 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
402 # On all platforms except macosx, we replace x86_64 with amd64.
403 OPENJDK_$1_CPU_JLI="amd64"
404 fi
405
406 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
407 # Macosx is osx and x86_64 is x64
408 if test "x$OPENJDK_$1_OS" = xmacosx; then
409 OPENJDK_$1_OS_BUNDLE="osx"
410 else
411 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
412 fi
413 if test "x$OPENJDK_$1_CPU" = xx86_64; then
414 OPENJDK_$1_CPU_BUNDLE="x64"
415 else
416 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
417 fi
418 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
419 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
420
421 if test "x$COMPILE_TYPE" = "xcross"; then
422 # FIXME: ... or should this include reduced builds..?
423 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
424 else
425 DEFINE_CROSS_COMPILE_ARCH=""
426 fi
427 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
428
429 # Convert openjdk platform names to hotspot names
430
431 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
432 if test "x$OPENJDK_$1_OS" = xmacosx; then
433 HOTSPOT_$1_OS=bsd
434 fi
435 AC_SUBST(HOTSPOT_$1_OS)
436
437 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
438 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
439 HOTSPOT_$1_OS_TYPE=posix
440 fi
441 AC_SUBST(HOTSPOT_$1_OS_TYPE)
442
443 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
444 if test "x$OPENJDK_$1_CPU" = xx86; then
445 HOTSPOT_$1_CPU=x86_32
446 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
447 HOTSPOT_$1_CPU=sparc
448 elif test "x$OPENJDK_$1_CPU" = xppc64; then
449 HOTSPOT_$1_CPU=ppc_64
450 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
451 HOTSPOT_$1_CPU=ppc_64
452 fi
453 AC_SUBST(HOTSPOT_$1_CPU)
454
455 # This is identical with OPENJDK_*, but define anyway for consistency.
456 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
457 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
458
459 # Setup HOTSPOT_$1_CPU_DEFINE
460 if test "x$OPENJDK_$1_CPU" = xx86; then
461 HOTSPOT_$1_CPU_DEFINE=IA32
462 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
463 HOTSPOT_$1_CPU_DEFINE=AMD64
464 elif test "x$OPENJDK_$1_CPU" = xx32; then
465 HOTSPOT_$1_CPU_DEFINE=X32
466 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
467 HOTSPOT_$1_CPU_DEFINE=SPARC
468 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
469 HOTSPOT_$1_CPU_DEFINE=AARCH64
470 elif test "x$OPENJDK_$1_CPU" = xppc64; then
471 HOTSPOT_$1_CPU_DEFINE=PPC64
472 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
473 HOTSPOT_$1_CPU_DEFINE=PPC64
474
475 # The cpu defines below are for zero, we don't support them directly.
476 elif test "x$OPENJDK_$1_CPU" = xsparc; then
477 HOTSPOT_$1_CPU_DEFINE=SPARC
478 elif test "x$OPENJDK_$1_CPU" = xppc; then
479 HOTSPOT_$1_CPU_DEFINE=PPC32
480 elif test "x$OPENJDK_$1_CPU" = xs390; then
481 HOTSPOT_$1_CPU_DEFINE=S390
482 elif test "x$OPENJDK_$1_CPU" = xs390x; then
483 HOTSPOT_$1_CPU_DEFINE=S390
484 elif test "x$OPENJDK_$1_CPU" != x; then
485 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
486 fi
487 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
488
489 # For historical reasons, the OS include directories have odd names.
490 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
491 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
492 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
493 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
494 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
495 fi
496 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
497 ])
498
499 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
500 [
501 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
502 RELEASE_FILE_OS_NAME=SunOS
503 fi
504 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
505 RELEASE_FILE_OS_NAME=Linux
506 fi
507 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
508 RELEASE_FILE_OS_NAME=Windows
509 fi
510 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
511 RELEASE_FILE_OS_NAME="Darwin"
512 fi
513 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
514 RELEASE_FILE_OS_NAME="AIX"
515 fi
516 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
517
518 AC_SUBST(RELEASE_FILE_OS_NAME)
519 AC_SUBST(RELEASE_FILE_OS_ARCH)
520 ])
521
522 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
523 [
524 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
525 OPENJDK_MODULE_TARGET_OS_NAME="macos"
526 else
527 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
528 fi
529
530 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
531 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
532 else
533 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
534 fi
535
536 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
537 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
538 ])
539
540 #%%% Build and target systems %%%
541 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
542 [
543 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
544 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
545 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
546 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
547 # to use the configure naming style.
548 AC_CANONICAL_BUILD
549 AC_CANONICAL_HOST
550 AC_CANONICAL_TARGET
551
552 PLATFORM_EXTRACT_TARGET_AND_BUILD
553 PLATFORM_SETUP_TARGET_CPU_BITS
554 PLATFORM_SET_MODULE_TARGET_OS_VALUES
555 PLATFORM_SET_RELEASE_FILE_OS_VALUES
556 PLATFORM_SETUP_LEGACY_VARS
557 ])
558
559 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
560 [
561 ###############################################################################
562
563 # Note that this is the build platform OS version!
564
565 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
566 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
567 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
568 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
569 AC_SUBST(OS_VERSION_MAJOR)
570 AC_SUBST(OS_VERSION_MINOR)
571 AC_SUBST(OS_VERSION_MICRO)
572 ])
573
574 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
575 [
576 ###############################################################################
577 #
578 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
579 # (The JVM can use 32 or 64 bit Java pointers but that decision
580 # is made at runtime.)
581 #
582
583 # Make compilation sanity check
584 AC_CHECK_HEADERS([stdio.h], , [
585 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
586 if test "x$COMPILE_TYPE" = xreduced; then
587 HELP_MSG_MISSING_DEPENDENCY([reduced])
588 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
589 elif test "x$COMPILE_TYPE" = xcross; then
590 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
591 fi
592 AC_MSG_ERROR([Cannot continue.])
593 ])
594
595 AC_CHECK_SIZEOF([int *], [1111])
596
597 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
598 if test "x$ac_cv_sizeof_int_p" = x; then
599 # The test failed, lets stick to the assumed value.
600 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
601 else
602 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
603
604 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
605 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
606 if test "x$COMPILE_TYPE" = xreduced; then
607 HELP_MSG_MISSING_DEPENDENCY([reduced])
608 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
609 elif test "x$COMPILE_TYPE" = xcross; then
610 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
611 fi
612 AC_MSG_ERROR([Cannot continue.])
613 fi
614 fi
615
616 AC_MSG_CHECKING([for target address size])
617 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
618 ])
619
620 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
621 [
622 ###############################################################################
623 #
624 # Is the target little of big endian?
625 #
626 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
627
628 if test "x$ENDIAN" = xuniversal_endianness; then
629 AC_MSG_ERROR([Building with both big and little endianness is not supported])
630 fi
631 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
632 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
633 fi
634 ])