1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # All valid JVM features, regardless of platform
  27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
  28     graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc zgc nmt cds \
  29     static-build link-time-opt aot jfr"
  30 
  31 # Deprecated JVM features (these are ignored, but with a warning)
  32 DEPRECATED_JVM_FEATURES="trace"
  33 
  34 # All valid JVM variants
  35 VALID_JVM_VARIANTS="server client minimal core zero custom"
  36 
  37 ###############################################################################
  38 # Check if the specified JVM variant should be built. To be used in shell if
  39 # constructs, like this:
  40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
  41 #
  42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
  43 
  44 # Definition kept in one line to allow inlining in if statements.
  45 # Additional [] needed to keep m4 from mangling shell constructs.
  46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
  47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
  48 
  49 ###############################################################################
  50 # Check if the specified JVM features are explicitly enabled. To be used in
  51 # shell if constructs, like this:
  52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
  53 #
  54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
  55 
  56 # Definition kept in one line to allow inlining in if statements.
  57 # Additional [] needed to keep m4 from mangling shell constructs.
  58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
  59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
  60 
  61 ###############################################################################
  62 # Check which variants of the JVM that we want to build. Available variants are:
  63 #   server: normal interpreter, and a tiered C1/C2 compiler
  64 #   client: normal interpreter, and C1 (no C2 compiler)
  65 #   minimal: reduced form of client with optional features stripped out
  66 #   core: normal interpreter only, no compiler
  67 #   zero: C++ based interpreter only, no compiler
  68 #   custom: baseline JVM with no default features
  69 #
  70 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
  71 [
  72   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  73       [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
  74 
  75   SETUP_HOTSPOT_TARGET_CPU_PORT
  76 
  77   if test "x$with_jvm_variants" = x; then
  78     with_jvm_variants="server"
  79   fi
  80   JVM_VARIANTS_OPT="$with_jvm_variants"
  81 
  82   # Has the user listed more than one variant?
  83   # Additional [] needed to keep m4 from mangling shell constructs.
  84   if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
  85     BUILDING_MULTIPLE_JVM_VARIANTS=true
  86   else
  87     BUILDING_MULTIPLE_JVM_VARIANTS=false
  88   fi
  89   # Replace the commas with AND for use in the build directory name.
  90   JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
  91 
  92   AC_MSG_CHECKING([which variants of the JVM to build])
  93   # JVM_VARIANTS is a space-separated list.
  94   # Also use minimal, not minimal1 (which is kept for backwards compatibility).
  95   JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
  96   AC_MSG_RESULT([$JVM_VARIANTS])
  97 
  98   # Check that the selected variants are valid
  99   BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
 100   if test "x$INVALID_VARIANTS" != x; then
 101     AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
 102     AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
 103     AC_MSG_ERROR([Cannot continue])
 104   fi
 105 
 106   # All "special" variants share the same output directory ("server")
 107   VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
 108   BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
 109   if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
 110     AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
 111   fi
 112 
 113   # The "main" variant is the one used by other libs to link against during the
 114   # build.
 115   if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
 116     MAIN_VARIANT_PRIO_ORDER="server client minimal"
 117     for variant in $MAIN_VARIANT_PRIO_ORDER; do
 118       if HOTSPOT_CHECK_JVM_VARIANT($variant); then
 119         JVM_VARIANT_MAIN="$variant"
 120         break
 121       fi
 122     done
 123   else
 124     JVM_VARIANT_MAIN="$JVM_VARIANTS"
 125   fi
 126 
 127   AC_SUBST(JVM_VARIANTS)
 128   AC_SUBST(VALID_JVM_VARIANTS)
 129   AC_SUBST(JVM_VARIANT_MAIN)
 130 
 131   if HOTSPOT_CHECK_JVM_VARIANT(zero); then
 132     # zero behaves as a platform and rewrites these values. This is really weird. :(
 133     # We are guaranteed that we do not build any other variants when building zero.
 134     HOTSPOT_TARGET_CPU=zero
 135     HOTSPOT_TARGET_CPU_ARCH=zero
 136   fi
 137 ])
 138 
 139 ###############################################################################
 140 # Check if dtrace should be enabled and has all prerequisites present.
 141 #
 142 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
 143 [
 144   # Test for dtrace dependencies
 145   AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
 146       [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
 147       are present.])])
 148 
 149   DTRACE_DEP_MISSING=false
 150 
 151   AC_MSG_CHECKING([for dtrace tool])
 152   if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
 153     AC_MSG_RESULT([$DTRACE])
 154   else
 155     AC_MSG_RESULT([not found, cannot build dtrace])
 156     DTRACE_DEP_MISSING=true
 157   fi
 158 
 159   AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
 160   if test "x$DTRACE_HEADERS_OK" != "xyes"; then
 161     DTRACE_DEP_MISSING=true
 162   fi
 163 
 164   AC_MSG_CHECKING([if dtrace should be built])
 165   if test "x$enable_dtrace" = "xyes"; then
 166     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 167       AC_MSG_RESULT([no, missing dependencies])
 168       HELP_MSG_MISSING_DEPENDENCY([dtrace])
 169       AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
 170     else
 171       INCLUDE_DTRACE=true
 172       AC_MSG_RESULT([yes, forced])
 173     fi
 174   elif test "x$enable_dtrace" = "xno"; then
 175     INCLUDE_DTRACE=false
 176     AC_MSG_RESULT([no, forced])
 177   elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
 178     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 179       INCLUDE_DTRACE=false
 180       AC_MSG_RESULT([no, missing dependencies])
 181     else
 182       INCLUDE_DTRACE=true
 183       AC_MSG_RESULT([yes, dependencies present])
 184     fi
 185   else
 186     AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
 187   fi
 188 ])
 189 
 190 ################################################################################
 191 # Check if AOT should be enabled
 192 #
 193 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
 194 [
 195   AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
 196       [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
 197 
 198   if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
 199     ENABLE_AOT="true"
 200   elif test "x$enable_aot" = "xyes"; then
 201     ENABLE_AOT="true"
 202   elif test "x$enable_aot" = "xno"; then
 203     ENABLE_AOT="false"
 204   else
 205     AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
 206   fi
 207 
 208   if test "x$ENABLE_AOT" = "xtrue"; then
 209     # Only enable AOT on X64 platforms.
 210     if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 211       if test -e "${TOPDIR}/src/jdk.aot"; then
 212         if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
 213           ENABLE_AOT="true"
 214         else
 215           ENABLE_AOT="false"
 216           if test "x$enable_aot" = "xyes"; then
 217             AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
 218           fi
 219         fi
 220       else
 221         ENABLE_AOT="false"
 222         if test "x$enable_aot" = "xyes"; then
 223           AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
 224         fi
 225       fi
 226     else
 227       ENABLE_AOT="false"
 228       if test "x$enable_aot" = "xyes"; then
 229         AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
 230       fi
 231     fi
 232   fi
 233 
 234   AC_SUBST(ENABLE_AOT)
 235 ])
 236 
 237 ################################################################################
 238 # Allow to disable CDS
 239 #
 240 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
 241 [
 242   AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
 243       [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
 244 
 245   if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
 246     ENABLE_CDS="true"
 247   elif test "x$enable_cds" = "xyes"; then
 248     ENABLE_CDS="true"
 249   elif test "x$enable_cds" = "xno"; then
 250     ENABLE_CDS="false"
 251   else
 252     AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
 253   fi
 254 
 255   # Disable CDS on AIX.
 256   if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 257     ENABLE_CDS="false"
 258     if test "x$enable_cds" = "xyes"; then
 259       AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
 260     fi
 261   fi
 262 
 263   AC_SUBST(ENABLE_CDS)
 264 ])
 265 
 266 ###############################################################################
 267 # Set up all JVM features for each JVM variant.
 268 #
 269 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
 270 [
 271   # Prettify the VALID_JVM_FEATURES string
 272   BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
 273 
 274   # The user can in some cases supply additional jvm features. For the custom
 275   # variant, this defines the entire variant.
 276   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
 277       [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
 278   if test "x$with_jvm_features" != x; then
 279     AC_MSG_CHECKING([user specified JVM feature list])
 280     USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
 281     AC_MSG_RESULT([$user_jvm_feature_list])
 282     # These features will be added to all variant defaults
 283     JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
 284     # These features will be removed from all variant defaults
 285     DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
 286 
 287     # Verify that the user has provided valid features
 288     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
 289     if test "x$INVALID_FEATURES" != x; then
 290       AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
 291       AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
 292       AC_MSG_ERROR([Cannot continue])
 293     fi
 294 
 295     # Check if the user has provided deprecated features
 296     BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
 297     if test "x$DEPRECATED_FEATURES" != x; then
 298       AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
 299       # Filter out deprecated features
 300       BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
 301       BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
 302     fi
 303 
 304   fi
 305 
 306   # Override hotspot cpu definitions for ARM platforms
 307   if test "x$OPENJDK_TARGET_CPU" = xarm; then
 308     HOTSPOT_TARGET_CPU=arm_32
 309     HOTSPOT_TARGET_CPU_DEFINE="ARM32"
 310   elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 311     HOTSPOT_TARGET_CPU=arm_64
 312     HOTSPOT_TARGET_CPU_ARCH=arm
 313   fi
 314 
 315   # Verify that dependencies are met for explicitly set features.
 316   if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
 317     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
 318   fi
 319 
 320   if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
 321     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
 322   fi
 323 
 324   if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
 325     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
 326   fi
 327 
 328   if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
 329     AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
 330   fi
 331 
 332   # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
 333   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 334     if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
 335       NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
 336     fi
 337   fi
 338 
 339   # Only enable ZGC on Linux x86_64
 340   AC_MSG_CHECKING([if zgc should be built])
 341   if HOTSPOT_CHECK_JVM_FEATURE(zgc); then
 342     if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
 343       AC_MSG_RESULT([yes])
 344     else
 345       DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
 346       AC_MSG_RESULT([no, platform not supported])
 347     fi
 348   else
 349     AC_MSG_RESULT([no])
 350   fi
 351 
 352   # Turn on additional features based on other parts of configure
 353   if test "x$INCLUDE_DTRACE" = "xtrue"; then
 354     JVM_FEATURES="$JVM_FEATURES dtrace"
 355   else
 356     if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
 357       AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
 358     fi
 359   fi
 360 
 361   if test "x$STATIC_BUILD" = "xtrue"; then
 362     JVM_FEATURES="$JVM_FEATURES static-build"
 363   else
 364     if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
 365       AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
 366     fi
 367   fi
 368 
 369   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 370     if HOTSPOT_CHECK_JVM_FEATURE(zero); then
 371       AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
 372     fi
 373   fi
 374 
 375   AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
 376   # Check if jvmci is diabled
 377   DISABLE_JVMCI=`$ECHO $DISABLED_JVM_FEATURES | $GREP jvmci`
 378   if test "x$DISABLE_JVMCI" = "xjvmci"; then
 379     AC_MSG_RESULT([no, forced])
 380     JVM_FEATURES_jvmci=""
 381     INCLUDE_JVMCI="false"
 382   else
 383     # Only enable jvmci on x86_64, sparcv9 and aarch64
 384     if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 385        test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
 386        test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 387       AC_MSG_RESULT([yes])
 388       JVM_FEATURES_jvmci="jvmci"
 389       INCLUDE_JVMCI="true"
 390     else
 391       AC_MSG_RESULT([no])
 392       JVM_FEATURES_jvmci=""
 393       INCLUDE_JVMCI="false"
 394       if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
 395         AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
 396       fi
 397     fi
 398   fi
 399 
 400   AC_SUBST(INCLUDE_JVMCI)
 401 
 402   AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
 403   # Check if graal is diabled
 404   DISABLE_GRAAL=`$ECHO $DISABLED_JVM_FEATURES | $GREP graal`
 405   if test "x$DISABLE_GRAAL" = "xgraal"; then
 406     AC_MSG_RESULT([no, forced])
 407     JVM_FEATURES_graal=""
 408     INCLUDE_GRAAL="false"
 409   else
 410     if HOTSPOT_CHECK_JVM_FEATURE(graal); then
 411       AC_MSG_RESULT([yes, forced])
 412       if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
 413         AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
 414       fi
 415       JVM_FEATURES_graal="graal"
 416       INCLUDE_GRAAL="true"
 417     else
 418       # By default enable graal build on x64 or where AOT is available.
 419       # graal build requires jvmci.
 420       if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
 421           (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 422            test "x$ENABLE_AOT" = "xtrue") ; then
 423         AC_MSG_RESULT([yes])
 424         JVM_FEATURES_graal="graal"
 425         INCLUDE_GRAAL="true"
 426       else
 427         AC_MSG_RESULT([no])
 428         JVM_FEATURES_graal=""
 429         INCLUDE_GRAAL="false"
 430       fi
 431     fi
 432   fi
 433 
 434   AC_SUBST(INCLUDE_GRAAL)
 435 
 436   # Disable aot with '--with-jvm-features=-aot'
 437   DISABLE_AOT=`$ECHO $DISABLED_JVM_FEATURES | $GREP aot`
 438   if test "x$DISABLE_AOT" = "xaot"; then
 439     ENABLE_AOT="false"
 440   fi
 441 
 442   AC_MSG_CHECKING([if aot should be enabled])
 443   if test "x$ENABLE_AOT" = "xtrue"; then
 444     if test "x$JVM_FEATURES_graal" != "xgraal"; then
 445       if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
 446         AC_MSG_RESULT([yes, forced])
 447         AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
 448       else
 449         AC_MSG_RESULT([no])
 450       fi
 451       JVM_FEATURES_aot=""
 452       ENABLE_AOT="false"
 453     else
 454       if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
 455         AC_MSG_RESULT([yes, forced])
 456       else
 457         AC_MSG_RESULT([yes])
 458       fi
 459       JVM_FEATURES_aot="aot"
 460     fi
 461   else
 462     if test "x$enable_aot" = "xno" || "x$DISABLE_AOT" = "xaot"; then
 463       AC_MSG_RESULT([no, forced])
 464     else
 465       AC_MSG_RESULT([no])
 466     fi
 467     JVM_FEATURES_aot=""
 468     if HOTSPOT_CHECK_JVM_FEATURE(aot); then
 469       AC_MSG_ERROR([To enable aot, you must use --enable-aot])
 470     fi
 471   fi
 472 
 473   AC_SUBST(ENABLE_AOT)
 474 
 475   if test "x$OPENJDK_TARGET_CPU" = xarm ; then
 476     # Default to use link time optimizations on minimal on arm
 477     JVM_FEATURES_link_time_opt="link-time-opt"
 478   else
 479     JVM_FEATURES_link_time_opt=""
 480   fi
 481 
 482   # All variants but minimal (and custom) get these features
 483   NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc jni-check jvmti management nmt services vm-structs"
 484 
 485   AC_MSG_CHECKING([if cds should be enabled])
 486   if test "x$ENABLE_CDS" = "xtrue"; then
 487     if test "x$enable_cds" = "xyes"; then
 488       AC_MSG_RESULT([yes, forced])
 489     else
 490       AC_MSG_RESULT([yes])
 491     fi
 492     NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
 493   else
 494     if test "x$enable_cds" = "xno"; then
 495       AC_MSG_RESULT([no, forced])
 496     else
 497       AC_MSG_RESULT([no])
 498     fi
 499   fi
 500 
 501   # Enable features depending on variant.
 502   JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
 503   JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
 504   JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
 505   JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
 506   JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
 507   JVM_FEATURES_custom="$JVM_FEATURES"
 508 
 509   AC_SUBST(JVM_FEATURES_server)
 510   AC_SUBST(JVM_FEATURES_client)
 511   AC_SUBST(JVM_FEATURES_core)
 512   AC_SUBST(JVM_FEATURES_minimal)
 513   AC_SUBST(JVM_FEATURES_zero)
 514   AC_SUBST(JVM_FEATURES_custom)
 515 
 516   # Used for verification of Makefiles by check-jvm-feature
 517   AC_SUBST(VALID_JVM_FEATURES)
 518 
 519   # We don't support --with-jvm-interpreter anymore, use zero instead.
 520   BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
 521 ])
 522 
 523 ###############################################################################
 524 # Finalize JVM features once all setup is complete, including custom setup.
 525 #
 526 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
 527 [
 528   for variant in $JVM_VARIANTS; do
 529     AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
 530     features_var_name=JVM_FEATURES_$variant
 531     JVM_FEATURES_FOR_VARIANT=${!features_var_name}
 532 
 533     # Filter out user-requested disabled features
 534     BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
 535 
 536     # Keep feature lists sorted and free of duplicates
 537     BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
 538 
 539     # Update real feature set variable
 540     eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
 541     AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
 542 
 543     # Verify that we have at least one gc selected
 544     GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
 545     if test "x$GC_FEATURES" = x; then
 546       AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
 547     fi
 548 
 549     # Validate features (for configure script errors, not user errors)
 550     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
 551     if test "x$INVALID_FEATURES" != x; then
 552       AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
 553     fi
 554   done
 555 ])
 556 
 557 ################################################################################
 558 #
 559 # Specify which sources will be used to build the 64-bit ARM port
 560 #
 561 # --with-cpu-port=arm64   will use hotspot/src/cpu/arm
 562 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
 563 #
 564 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
 565 [
 566   AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
 567       [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
 568 
 569   if test "x$with_cpu_port" != x; then
 570     if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
 571       AC_MSG_ERROR([--with-cpu-port only available on aarch64])
 572     fi
 573     if test "x$with_cpu_port" != xarm64 && \
 574         test "x$with_cpu_port" != xaarch64; then
 575       AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
 576     fi
 577     HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
 578   fi
 579 ])
 580 
 581 
 582 ################################################################################
 583 # Check if gtest should be built
 584 #
 585 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
 586 [
 587   AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
 588       [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
 589 
 590   if test -e "${TOPDIR}/test/hotspot/gtest"; then
 591     GTEST_DIR_EXISTS="true"
 592   else
 593     GTEST_DIR_EXISTS="false"
 594   fi
 595 
 596   AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
 597   if test "x$enable_hotspot_gtest" = "xyes"; then
 598     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 599       AC_MSG_RESULT([yes, forced])
 600       BUILD_GTEST="true"
 601     else
 602       AC_MSG_ERROR([Cannot build gtest without the test source])
 603     fi
 604   elif test "x$enable_hotspot_gtest" = "xno"; then
 605     AC_MSG_RESULT([no, forced])
 606     BUILD_GTEST="false"
 607   elif test "x$enable_hotspot_gtest" = "x"; then
 608     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 609       AC_MSG_RESULT([yes])
 610       BUILD_GTEST="true"
 611     else
 612       AC_MSG_RESULT([no])
 613       BUILD_GTEST="false"
 614     fi
 615   else
 616     AC_MSG_ERROR([--enable-gtest must be either yes or no])
 617   fi
 618 
 619   AC_SUBST(BUILD_GTEST)
 620 ])