1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x[$]$1" = x; then
50 $1="$2"
51 else
52 $1="[$]$1:$2"
53 fi
54 ])
55
56 # This will make sure the given variable points to a full and proper
57 # path. This means:
58 # 1) There will be no spaces in the path. On posix platforms,
59 # spaces in the path will result in an error. On Windows,
60 # the path will be rewritten using short-style to be space-free.
61 # 2) The path will be absolute, and it will be in unix-style (on
62 # cygwin).
63 # $1: The name of the variable to fix
64 AC_DEFUN([BASIC_FIXUP_PATH],
65 [
66 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
67 BASIC_FIXUP_PATH_CYGWIN($1)
68 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
69 BASIC_FIXUP_PATH_MSYS($1)
70 else
71 # We're on a posix platform. Hooray! :)
72 path="[$]$1"
73 has_space=`$ECHO "$path" | $GREP " "`
74 if test "x$has_space" != x; then
75 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
76 AC_MSG_ERROR([Spaces are not allowed in this path.])
77 fi
78
79 # Use eval to expand a potential ~
80 eval path="$path"
81 if test ! -f "$path" && test ! -d "$path"; then
82 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
83 fi
84
85 $1="`cd "$path"; $THEPWDCMD -L`"
86 fi
87 ])
88
89 # This will make sure the given variable points to a executable
90 # with a full and proper path. This means:
91 # 1) There will be no spaces in the path. On posix platforms,
92 # spaces in the path will result in an error. On Windows,
93 # the path will be rewritten using short-style to be space-free.
94 # 2) The path will be absolute, and it will be in unix-style (on
95 # cygwin).
96 # Any arguments given to the executable is preserved.
97 # If the input variable does not have a directory specification, then
98 # it need to be in the PATH.
99 # $1: The name of the variable to fix
100 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
101 [
102 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
103 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
104 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
105 BASIC_FIXUP_EXECUTABLE_MSYS($1)
106 else
107 # We're on a posix platform. Hooray! :)
108 # First separate the path from the arguments. This will split at the first
109 # space.
110 complete="[$]$1"
111 path="${complete%% *}"
112 tmp="$complete EOL"
113 arguments="${tmp#* }"
114
115 # Cannot rely on the command "which" here since it doesn't always work.
116 is_absolute_path=`$ECHO "$path" | $GREP ^/`
117 if test -z "$is_absolute_path"; then
118 # Path to executable is not absolute. Find it.
119 IFS_save="$IFS"
120 IFS=:
121 for p in $PATH; do
122 if test -f "$p/$path" && test -x "$p/$path"; then
123 new_path="$p/$path"
124 break
125 fi
126 done
127 IFS="$IFS_save"
128 else
129 new_path="$path"
130 fi
131
132 if test "x$new_path" = x; then
133 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
134 has_space=`$ECHO "$complete" | $GREP " "`
135 if test "x$has_space" != x; then
136 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
137 fi
138 AC_MSG_ERROR([Cannot locate the the path of $1])
139 fi
140 fi
141
142 # Now join together the path and the arguments once again
143 if test "x$arguments" != xEOL; then
144 new_complete="$new_path ${arguments% *}"
145 else
146 new_complete="$new_path"
147 fi
148
149 if test "x$complete" != "x$new_complete"; then
150 $1="$new_complete"
151 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
152 fi
153 ])
154
155 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
156 [
157 if test "x$OPENJDK_BUILD_OS" != xwindows; then
158 # Follow a chain of symbolic links. Use readlink
159 # where it exists, else fall back to horribly
160 # complicated shell code.
161 if test "x$READLINK_TESTED" != yes; then
162 # On MacOSX there is a readlink tool with a different
163 # purpose than the GNU readlink tool. Check the found readlink.
164 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
165 if test "x$ISGNU" = x; then
166 # A readlink that we do not know how to use.
167 # Are there other non-GNU readlinks out there?
168 READLINK_TESTED=yes
169 READLINK=
170 fi
171 fi
172
173 if test "x$READLINK" != x; then
174 $1=`$READLINK -f [$]$1`
175 else
176 # Save the current directory for restoring afterwards
177 STARTDIR=$PWD
178 COUNTER=0
179 sym_link_dir=`$DIRNAME [$]$1`
180 sym_link_file=`$BASENAME [$]$1`
181 cd $sym_link_dir
182 # Use -P flag to resolve symlinks in directories.
183 cd `$THEPWDCMD -P`
184 sym_link_dir=`$THEPWDCMD -P`
185 # Resolve file symlinks
186 while test $COUNTER -lt 20; do
187 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
188 if test "x$ISLINK" == x; then
189 # This is not a symbolic link! We are done!
190 break
191 fi
192 # Again resolve directory symlinks since the target of the just found
193 # link could be in a different directory
194 cd `$DIRNAME $ISLINK`
195 sym_link_dir=`$THEPWDCMD -P`
196 sym_link_file=`$BASENAME $ISLINK`
197 let COUNTER=COUNTER+1
198 done
199 cd $STARTDIR
200 $1=$sym_link_dir/$sym_link_file
201 fi
202 fi
203 ])
204
205 # Register a --with argument but mark it as deprecated
206 # $1: The name of the with argument to deprecate, not including --with-
207 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
208 [
209 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
210 [Deprecated. Option is kept for backwards compatibility and is ignored])],
211 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
212 ])
213
214 # Register a --enable argument but mark it as deprecated
215 # $1: The name of the with argument to deprecate, not including --enable-
216 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
217 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
218 [
219 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
220 [Deprecated. Option is kept for backwards compatibility and is ignored])])
221 if test "x$enable_$2" != x; then
222 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
223 fi
224 ])
225
226 AC_DEFUN_ONCE([BASIC_INIT],
227 [
228 # Save the original command line. This is passed to us by the wrapper configure script.
229 AC_SUBST(CONFIGURE_COMMAND_LINE)
230 DATE_WHEN_CONFIGURED=`LANG=C date`
231 AC_SUBST(DATE_WHEN_CONFIGURED)
232 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
233 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
234 ])
235
236 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
237 # $1: variable to check
238 AC_DEFUN([BASIC_CHECK_NONEMPTY],
239 [
240 if test "x[$]$1" = x; then
241 AC_MSG_ERROR([Could not find required tool for $1])
242 fi
243 ])
244
245 # Check that there are no unprocessed overridden variables left.
246 # If so, they are an incorrect argument and we will exit with an error.
247 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
248 [
249 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
250 # Replace the separating ! with spaces before presenting for end user.
251 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
252 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
253 fi
254 ])
255
256 # Setup a tool for the given variable. If correctly specified by the user,
257 # use that value, otherwise search for the tool using the supplied code snippet.
258 # $1: variable to set
259 # $2: code snippet to call to look for the tool
260 AC_DEFUN([BASIC_SETUP_TOOL],
261 [
262 # Publish this variable in the help.
263 AC_ARG_VAR($1, [Override default value for $1])
264
265 if test "x[$]$1" = x; then
266 # The variable is not set by user, try to locate tool using the code snippet
267 $2
268 else
269 # The variable is set, but is it from the command line or the environment?
270
271 # Try to remove the string !$1! from our list.
272 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
273 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
274 # If it failed, the variable was not from the command line. Ignore it,
275 # but warn the user (except for BASH, which is always set by the calling BASH).
276 if test "x$1" != xBASH; then
277 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
278 fi
279 # Try to locate tool using the code snippet
280 $2
281 else
282 # If it succeeded, then it was overridden by the user. We will use it
283 # for the tool.
284
285 # First remove it from the list of overridden variables, so we can test
286 # for unknown variables in the end.
287 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
288
289 # Check if the provided tool contains a complete path.
290 tool_specified="[$]$1"
291 tool_basename="${tool_specified##*/}"
292 if test "x$tool_basename" = "x$tool_specified"; then
293 # A command without a complete path is provided, search $PATH.
294 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
295 AC_PATH_PROG($1, $tool_basename)
296 if test "x[$]$1" = x; then
297 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
298 fi
299 else
300 # Otherwise we believe it is a complete path. Use it as it is.
301 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
302 AC_MSG_CHECKING([for $1])
303 if test ! -x "$tool_specified"; then
304 AC_MSG_RESULT([not found])
305 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
306 fi
307 AC_MSG_RESULT([$tool_specified])
308 fi
309 fi
310 fi
311 ])
312
313 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
314 # $1: variable to set
315 # $2: executable name (or list of names) to look for
316 AC_DEFUN([BASIC_PATH_PROGS],
317 [
318 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
319 ])
320
321 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
322 # $1: variable to set
323 # $2: executable name (or list of names) to look for
324 AC_DEFUN([BASIC_CHECK_TOOLS],
325 [
326 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
327 ])
328
329 # Like BASIC_PATH_PROGS but fails if no tool was found.
330 # $1: variable to set
331 # $2: executable name (or list of names) to look for
332 AC_DEFUN([BASIC_REQUIRE_PROGS],
333 [
334 BASIC_PATH_PROGS($1, $2)
335 BASIC_CHECK_NONEMPTY($1)
336 ])
337
338 # Like BASIC_SETUP_TOOL but fails if no tool was found.
339 # $1: variable to set
340 # $2: autoconf macro to call to look for the special tool
341 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
342 [
343 BASIC_SETUP_TOOL($1, [$2])
344 BASIC_CHECK_NONEMPTY($1)
345 ])
346
347 # Setup the most fundamental tools that relies on not much else to set up,
348 # but is used by much of the early bootstrap code.
349 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
350 [
351 # Start with tools that do not need have cross compilation support
352 # and can be expected to be found in the default PATH. These tools are
353 # used by configure. Nor are these tools expected to be found in the
354 # devkit from the builddeps server either, since they are
355 # needed to download the devkit.
356
357 # First are all the simple required tools.
358 BASIC_REQUIRE_PROGS(BASENAME, basename)
359 BASIC_REQUIRE_PROGS(BASH, bash)
360 BASIC_REQUIRE_PROGS(CAT, cat)
361 BASIC_REQUIRE_PROGS(CHMOD, chmod)
362 BASIC_REQUIRE_PROGS(CMP, cmp)
363 BASIC_REQUIRE_PROGS(COMM, comm)
364 BASIC_REQUIRE_PROGS(CP, cp)
365 BASIC_REQUIRE_PROGS(CPIO, cpio)
366 BASIC_REQUIRE_PROGS(CUT, cut)
367 BASIC_REQUIRE_PROGS(DATE, date)
368 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
369 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
370 BASIC_REQUIRE_PROGS(ECHO, echo)
371 BASIC_REQUIRE_PROGS(EXPR, expr)
372 BASIC_REQUIRE_PROGS(FILE, file)
373 BASIC_REQUIRE_PROGS(FIND, find)
374 BASIC_REQUIRE_PROGS(HEAD, head)
375 BASIC_REQUIRE_PROGS(LN, ln)
376 BASIC_REQUIRE_PROGS(LS, ls)
377 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
378 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
379 BASIC_REQUIRE_PROGS(MV, mv)
380 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
381 BASIC_REQUIRE_PROGS(PRINTF, printf)
382 BASIC_REQUIRE_PROGS(RM, rm)
383 BASIC_REQUIRE_PROGS(SH, sh)
384 BASIC_REQUIRE_PROGS(SORT, sort)
385 BASIC_REQUIRE_PROGS(TAIL, tail)
386 BASIC_REQUIRE_PROGS(TAR, tar)
387 BASIC_REQUIRE_PROGS(TEE, tee)
388 BASIC_REQUIRE_PROGS(TOUCH, touch)
389 BASIC_REQUIRE_PROGS(TR, tr)
390 BASIC_REQUIRE_PROGS(UNAME, uname)
391 BASIC_REQUIRE_PROGS(UNIQ, uniq)
392 BASIC_REQUIRE_PROGS(WC, wc)
393 BASIC_REQUIRE_PROGS(WHICH, which)
394 BASIC_REQUIRE_PROGS(XARGS, xargs)
395
396 # Then required tools that require some special treatment.
397 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
398 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
399 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
400 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
401 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
402
403 # Always force rm.
404 RM="$RM -f"
405
406 # pwd behaves differently on various platforms and some don't support the -L flag.
407 # Always use the bash builtin pwd to get uniform behavior.
408 THEPWDCMD=pwd
409
410 # These are not required on all platforms
411 BASIC_PATH_PROGS(CYGPATH, cygpath)
412 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
413 BASIC_PATH_PROGS(DF, df)
414 BASIC_PATH_PROGS(SETFILE, SetFile)
415 ])
416
417 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
418 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
419 [
420 # Locate the directory of this script.
421 SCRIPT="[$]0"
422 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`
423
424 # Where is the source? It is located two levels above the configure script.
425 CURDIR="$PWD"
426 cd "$AUTOCONF_DIR/../.."
427 SRC_ROOT="`$THEPWDCMD -L`"
428
429 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
430 PATH_SEP=";"
431 BASIC_CHECK_PATHS_WINDOWS
432 else
433 PATH_SEP=":"
434 fi
435
436 AC_SUBST(SRC_ROOT)
437 AC_SUBST(PATH_SEP)
438 cd "$CURDIR"
439
440 BASIC_FIXUP_PATH(SRC_ROOT)
441 BASIC_FIXUP_PATH(CURDIR)
442
443 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
444 # Add extra search paths on solaris for utilities like ar and as etc...
445 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
446 fi
447
448 # You can force the sys-root if the sys-root encoded into the cross compiler tools
449 # is not correct.
450 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
451 [pass this sys-root to the compilers and tools (for cross-compiling)])])
452
453 if test "x$with_sys_root" != x; then
454 SYS_ROOT=$with_sys_root
455 else
456 SYS_ROOT=/
457 fi
458 AC_SUBST(SYS_ROOT)
459
460 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
461 [search this directory for compilers and tools (for cross-compiling)])],
462 [TOOLS_DIR=$with_tools_dir]
463 )
464
465 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
466 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
467 [
468 if test "x$with_sys_root" != x; then
469 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
470 fi
471 BASIC_FIXUP_PATH([with_devkit])
472 BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)
473 if test -d "$with_devkit/$host_alias/libc"; then
474 SYS_ROOT=$with_devkit/$host_alias/libc
475 elif test -d "$with_devkit/$host/sys-root"; then
476 SYS_ROOT=$with_devkit/$host/sys-root
477 fi
478 ])
479 ])
480
481 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
482 [
483
484 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
485 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
486 [ CONF_NAME=${with_conf_name} ])
487
488 # Test from where we are running configure, in or outside of src root.
489 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
490 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
491 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
492 # We are running configure from the src root.
493 # Create a default ./build/target-variant-debuglevel output root.
494 if test "x${CONF_NAME}" = x; then
495 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
496 fi
497 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
498 $MKDIR -p "$OUTPUT_ROOT"
499 if test ! -d "$OUTPUT_ROOT"; then
500 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
501 fi
502 else
503 # We are running configure from outside of the src dir.
504 # Then use the current directory as output dir!
505 # If configuration is situated in normal build directory, just use the build
506 # directory name as configuration name, otherwise use the complete path.
507 if test "x${CONF_NAME}" = x; then
508 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
509 fi
510 OUTPUT_ROOT="$CURDIR"
511
512 # WARNING: This might be a bad thing to do. You need to be sure you want to
513 # have a configuration in this directory. Do some sanity checks!
514
515 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
516 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
517 # other files
518 files_present=`$LS $OUTPUT_ROOT`
519 # Configure has already touched config.log and confdefs.h in the current dir when this check
520 # is performed.
521 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
522 | $TR -d '\n'`
523 if test "x$filtered_files" != x; then
524 AC_MSG_NOTICE([Current directory is $CURDIR.])
525 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
526 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
527 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
528 AC_MSG_NOTICE([seriously mess up just about everything.])
529 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
530 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
531 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
532 fi
533 fi
534 fi
535 AC_MSG_CHECKING([what configuration name to use])
536 AC_MSG_RESULT([$CONF_NAME])
537
538 BASIC_FIXUP_PATH(OUTPUT_ROOT)
539
540 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
541 AC_SUBST(CONF_NAME, $CONF_NAME)
542 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
543
544 # Most of the probed defines are put into config.h
545 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
546 # The spec.gmk file contains all variables for the make system.
547 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
548 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
549 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
550 # The bootcycle-spec.gmk file contains support for boot cycle builds.
551 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
552 # The compare.sh is used to compare the build output to other builds.
553 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
554 # Spec.sh is currently used by compare-objects.sh
555 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
556 # The generated Makefile knows where the spec.gmk is and where the source is.
557 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
558 # which will look for generated configurations
559 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
560
561 # Save the arguments given to us
562 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
563 ])
564
565 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
566 [
567 # Setup default logging of stdout and stderr to build.log in the output root.
568 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
569 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
570 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
571 AC_SUBST(BUILD_LOG)
572 AC_SUBST(BUILD_LOG_PREVIOUS)
573 AC_SUBST(BUILD_LOG_WRAPPER)
574 ])
575
576
577 #%%% Simple tools %%%
578
579 # Check if we have found a usable version of make
580 # $1: the path to a potential make binary (or empty)
581 # $2: the description on how we found this
582 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
583 [
584 MAKE_CANDIDATE="$1"
585 DESCRIPTION="$2"
586 if test "x$MAKE_CANDIDATE" != x; then
587 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
588 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
589 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
590 if test "x$IS_GNU_MAKE" = x; then
591 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
592 else
593 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
594 if test "x$IS_MODERN_MAKE" = x; then
595 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
596 else
597 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
598 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
599 MAKE_EXPECTED_ENV='cygwin'
600 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
601 MAKE_EXPECTED_ENV='msys'
602 else
603 AC_MSG_ERROR([Unknown Windows environment])
604 fi
605 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
606 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
607 else
608 # Not relevant for non-Windows
609 IS_MAKE_CORRECT_ENV=true
610 fi
611 if test "x$IS_MAKE_CORRECT_ENV" = x; then
612 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
613 else
614 FOUND_MAKE=$MAKE_CANDIDATE
615 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
616 fi
617 fi
618 fi
619 fi
620 ])
621
622 # Goes looking for a usable version of GNU make.
623 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
624 [
625 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
626 if test "x$MAKE" != x; then
627 # User has supplied a make, test it.
628 if test ! -f "$MAKE"; then
629 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
630 fi
631 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
632 if test "x$FOUND_MAKE" = x; then
633 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
634 fi
635 else
636 # Try our hardest to locate a correct version of GNU make
637 AC_PATH_PROGS(CHECK_GMAKE, gmake)
638 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
639
640 if test "x$FOUND_MAKE" = x; then
641 AC_PATH_PROGS(CHECK_MAKE, make)
642 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
643 fi
644
645 if test "x$FOUND_MAKE" = x; then
646 if test "x$TOOLS_DIR" != x; then
647 # We have a tools-dir, check that as well before giving up.
648 OLD_PATH=$PATH
649 PATH=$TOOLS_DIR:$PATH
650 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
651 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
652 if test "x$FOUND_MAKE" = x; then
653 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
654 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
655 fi
656 PATH=$OLD_PATH
657 fi
658 fi
659
660 if test "x$FOUND_MAKE" = x; then
661 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
662 fi
663 fi
664
665 MAKE=$FOUND_MAKE
666 AC_SUBST(MAKE)
667 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
668 ])
669
670 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
671 [
672 # Test if find supports -delete
673 AC_MSG_CHECKING([if find supports -delete])
674 FIND_DELETE="-delete"
675
676 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
677
678 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
679
680 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
681 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
682 # No, it does not.
683 rm $DELETEDIR/TestIfFindSupportsDelete
684 FIND_DELETE="-exec rm \{\} \+"
685 AC_MSG_RESULT([no])
686 else
687 AC_MSG_RESULT([yes])
688 fi
689 rmdir $DELETEDIR
690 AC_SUBST(FIND_DELETE)
691 ])
692
693 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
694 [
695 BASIC_CHECK_GNU_MAKE
696
697 BASIC_CHECK_FIND_DELETE
698
699 # These tools might not be installed by default,
700 # need hint on how to install them.
701 BASIC_REQUIRE_PROGS(UNZIP, unzip)
702 BASIC_REQUIRE_PROGS(ZIP, zip)
703
704 # Non-required basic tools
705
706 BASIC_PATH_PROGS(LDD, ldd)
707 if test "x$LDD" = "x"; then
708 # List shared lib dependencies is used for
709 # debug output and checking for forbidden dependencies.
710 # We can build without it.
711 LDD="true"
712 fi
713 BASIC_PATH_PROGS(OTOOL, otool)
714 if test "x$OTOOL" = "x"; then
715 OTOOL="true"
716 fi
717 BASIC_PATH_PROGS(READELF, [greadelf readelf])
718 BASIC_PATH_PROGS(HG, hg)
719 BASIC_PATH_PROGS(STAT, stat)
720 BASIC_PATH_PROGS(TIME, time)
721 # Check if it's GNU time
722 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
723 if test "x$IS_GNU_TIME" != x; then
724 IS_GNU_TIME=yes
725 else
726 IS_GNU_TIME=no
727 fi
728 AC_SUBST(IS_GNU_TIME)
729
730 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
731 BASIC_REQUIRE_PROGS(COMM, comm)
732 fi
733
734 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
735 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
736 BASIC_REQUIRE_PROGS(XATTR, xattr)
737 BASIC_PATH_PROGS(CODESIGN, codesign)
738 if test "x$CODESIGN" != "x"; then
739 # Verify that the openjdk_codesign certificate is present
740 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
741 rm -f codesign-testfile
742 touch codesign-testfile
743 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
744 rm -f codesign-testfile
745 if test "x$CODESIGN" = x; then
746 AC_MSG_RESULT([no])
747 else
748 AC_MSG_RESULT([yes])
749 fi
750 fi
751 fi
752 ])
753
754 # Check if build directory is on local disk. If not possible to determine,
755 # we prefer to claim it's local.
756 # Argument 1: directory to test
757 # Argument 2: what to do if it is on local disk
758 # Argument 3: what to do otherwise (remote disk or failure)
759 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
760 [
761 # df -l lists only local disks; if the given directory is not found then
762 # a non-zero exit code is given
763 if test "x$DF" = x; then
764 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
765 # msys does not have df; use Windows "net use" instead.
766 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
767 if test "x$IS_NETWORK_DISK" = x; then
768 $2
769 else
770 $3
771 fi
772 else
773 # No df here, say it's local
774 $2
775 fi
776 else
777 if $DF -l $1 > /dev/null 2>&1; then
778 $2
779 else
780 $3
781 fi
782 fi
783 ])
784
785 # Check that source files have basic read permissions set. This might
786 # not be the case in cygwin in certain conditions.
787 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
788 [
789 if test x"$OPENJDK_BUILD_OS" = xwindows; then
790 file_to_test="$SRC_ROOT/LICENSE"
791 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
792 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
793 fi
794 fi
795 ])
796
797 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
798 [
799 # Did user specify any unknown variables?
800 BASIC_CHECK_LEFTOVER_OVERRIDDEN
801
802 AC_MSG_CHECKING([if build directory is on local disk])
803 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
804 [OUTPUT_DIR_IS_LOCAL="yes"],
805 [OUTPUT_DIR_IS_LOCAL="no"])
806 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
807
808 BASIC_CHECK_SRC_PERMS
809
810 # Check if the user has any old-style ALT_ variables set.
811 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
812
813 # Before generating output files, test if they exist. If they do, this is a reconfigure.
814 # Since we can't properly handle the dependencies for this, warn the user about the situation
815 if test -e $OUTPUT_ROOT/spec.gmk; then
816 IS_RECONFIGURE=yes
817 else
818 IS_RECONFIGURE=no
819 fi
820 ])