1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
34
35
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
38
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
45
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
52
53 # Setup a number of variables describing how native output files are
54 # named on this platform/toolchain.
55 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
56 [
57 # Define filename patterns
58 if test "x$OPENJDK_TARGET_OS" = xwindows; then
59 LIBRARY_PREFIX=
60 SHARED_LIBRARY_SUFFIX='.dll'
61 STATIC_LIBRARY_SUFFIX='.lib'
62 SHARED_LIBRARY='[$]1.dll'
63 STATIC_LIBRARY='[$]1.lib'
64 OBJ_SUFFIX='.obj'
65 EXE_SUFFIX='.exe'
66 else
67 LIBRARY_PREFIX=lib
68 SHARED_LIBRARY_SUFFIX='.so'
69 STATIC_LIBRARY_SUFFIX='.a'
70 SHARED_LIBRARY='lib[$]1.so'
71 STATIC_LIBRARY='lib[$]1.a'
72 OBJ_SUFFIX='.o'
73 EXE_SUFFIX=''
74 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
75 SHARED_LIBRARY='lib[$]1.dylib'
76 SHARED_LIBRARY_SUFFIX='.dylib'
77 fi
78 fi
79
80 AC_SUBST(LIBRARY_PREFIX)
81 AC_SUBST(SHARED_LIBRARY_SUFFIX)
82 AC_SUBST(STATIC_LIBRARY_SUFFIX)
83 AC_SUBST(SHARED_LIBRARY)
84 AC_SUBST(STATIC_LIBRARY)
85 AC_SUBST(OBJ_SUFFIX)
86 AC_SUBST(EXE_SUFFIX)
87 ])
88
89 # Determine which toolchain type to use, and make sure it is valid for this
90 # platform. Setup various information about the selected toolchain.
91 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
92 [
93 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
94 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
95
96 # Use indirect variable referencing
97 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
98 VALID_TOOLCHAINS=${!toolchain_var_name}
99
100 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
101 # On Mac OS X, default toolchain to clang after Xcode 5
102 XCODE_VERSION_OUTPUT=`xcodebuild -version 2>&1 | $HEAD -n 1`
103 $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
104 if test $? -ne 0; then
105 AC_MSG_ERROR([Failed to determine Xcode version.])
106 fi
107 XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
108 $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
109 $CUT -f 1 -d .`
110 AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
111 if test $XCODE_MAJOR_VERSION -ge 5; then
112 DEFAULT_TOOLCHAIN="clang"
113 else
114 DEFAULT_TOOLCHAIN="gcc"
115 fi
116 else
117 # First toolchain type in the list is the default
118 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
119 fi
120
121 if test "x$with_toolchain_type" = xlist; then
122 # List all toolchains
123 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
124 for toolchain in $VALID_TOOLCHAINS; do
125 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
126 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
127 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
128 done
129
130 exit 0
131 elif test "x$with_toolchain_type" != x; then
132 # User override; check that it is valid
133 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
134 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
135 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
136 AC_MSG_ERROR([Cannot continue.])
137 fi
138 TOOLCHAIN_TYPE=$with_toolchain_type
139 else
140 # No flag given, use default
141 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
142 fi
143 AC_SUBST(TOOLCHAIN_TYPE)
144
145 TOOLCHAIN_CC_BINARY_clang="clang"
146 TOOLCHAIN_CC_BINARY_gcc="gcc"
147 TOOLCHAIN_CC_BINARY_microsoft="cl"
148 TOOLCHAIN_CC_BINARY_solstudio="cc"
149 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
150
151 TOOLCHAIN_CXX_BINARY_clang="clang++"
152 TOOLCHAIN_CXX_BINARY_gcc="g++"
153 TOOLCHAIN_CXX_BINARY_microsoft="cl"
154 TOOLCHAIN_CXX_BINARY_solstudio="CC"
155 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
156
157 # Use indirect variable referencing
158 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
159 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
160 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
161 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
162 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
163 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
164
165 TOOLCHAIN_SETUP_FILENAME_PATTERNS
166
167 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
168 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
169 else
170 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
171 fi
172 ])
173
174 # Before we start detecting the toolchain executables, we might need some
175 # special setup, e.g. additional paths etc.
176 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
177 [
178 # FIXME: Is this needed?
179 AC_LANG(C++)
180
181 # Store the CFLAGS etc passed to the configure script.
182 ORG_CFLAGS="$CFLAGS"
183 ORG_CXXFLAGS="$CXXFLAGS"
184 ORG_OBJCFLAGS="$OBJCFLAGS"
185
186 # On Windows, we need to detect the visual studio installation first.
187 # This will change the PATH, but we need to keep that new PATH even
188 # after toolchain detection is done, since the compiler (on x86) uses
189 # it for DLL resolution in runtime.
190 if test "x$OPENJDK_BUILD_OS" = "xwindows" && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
191 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
192 # Reset path to VS_PATH. It will include everything that was on PATH at the time we
193 # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
194 PATH="$VS_PATH"
195 # The microsoft toolchain also requires INCLUDE and LIB to be set.
196 export INCLUDE="$VS_INCLUDE"
197 export LIB="$VS_LIB"
198 fi
199
200 # autoconf magic only relies on PATH, so update it if tools dir is specified
201 OLD_PATH="$PATH"
202
203 # For solaris we really need solaris tools, and not the GNU equivalent.
204 # The build tools on Solaris reside in /usr/ccs (C Compilation System),
205 # so add that to path before starting to probe.
206 # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.
207 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
208 PATH="/usr/ccs/bin:$PATH"
209 fi
210
211 # Finally add TOOLS_DIR at the beginning, to allow --with-tools-dir to
212 # override all other locations.
213 if test "x$TOOLS_DIR" != x; then
214 PATH=$TOOLS_DIR:$PATH
215 fi
216
217 # If a devkit is found on the builddeps server, then prepend its path to the
218 # PATH variable. If there are cross compilers available in the devkit, these
219 # will be found by AC_PROG_CC et al.
220 DEVKIT=
221 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
222 [
223 # Found devkit
224 PATH="$DEVKIT/bin:$PATH"
225 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
226 if test "x$x_includes" = "xNONE"; then
227 x_includes="$SYS_ROOT/usr/include/X11"
228 fi
229 if test "x$x_libraries" = "xNONE"; then
230 x_libraries="$SYS_ROOT/usr/lib"
231 fi
232 ],
233 [])
234 ])
235
236 # Restore path, etc
237 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
238 [
239 # Restore old path.
240 PATH="$OLD_PATH"
241
242 # Restore the flags to the user specified values.
243 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
244 CFLAGS="$ORG_CFLAGS"
245 CXXFLAGS="$ORG_CXXFLAGS"
246 OBJCFLAGS="$ORG_OBJCFLAGS"
247 ])
248
249 # Check if a compiler is of the toolchain type we expect, and save the version
250 # information from it. If the compiler does not match the expected type,
251 # this function will abort using AC_MSG_ERROR. If it matches, the version will
252 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
253 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
254 #
255 # $1 = compiler to test (CC or CXX)
256 # $2 = human readable name of compiler (C or C++)
257 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
258 [
259 COMPILER=[$]$1
260 COMPILER_NAME=$2
261
262 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
263 # cc -V output typically looks like
264 # cc: Sun C 5.12 Linux_i386 2011/11/16
265 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
266 # Check that this is likely to be the Solaris Studio cc.
267 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
268 if test $? -ne 0; then
269 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
270 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
271 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
272 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
273 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
274 fi
275 # Remove usage instructions (if present), and
276 # collapse compiler output into a single line
277 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
278 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
279 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
280 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
281 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
282 # xlc -qversion output typically looks like
283 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
284 # Version: 11.01.0000.0015
285 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
286 # Check that this is likely to be the IBM XL C compiler.
287 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
288 if test $? -ne 0; then
289 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
290 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
291 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
292 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
293 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
294 fi
295 # Collapse compiler output into a single line
296 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
297 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
298 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
299 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
300 # There is no specific version flag, but all output starts with a version string.
301 # First line typically looks something like:
302 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
303 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
304 # Check that this is likely to be Microsoft CL.EXE.
305 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
306 if test $? -ne 0; then
307 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
308 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
309 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
310 fi
311 # Collapse compiler output into a single line
312 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
313 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
314 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
315 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
316 # gcc --version output typically looks like
317 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
318 # Copyright (C) 2013 Free Software Foundation, Inc.
319 # This is free software; see the source for copying conditions. There is NO
320 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
321 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
322 # Check that this is likely to be GCC.
323 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
324 if test $? -ne 0; then
325 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
326 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
327 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
328 fi
329 # Remove Copyright and legalese from version string, and
330 # collapse into a single line
331 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
332 $SED -e 's/ *Copyright .*//'`
333 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
334 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
335 elif test "x$TOOLCHAIN_TYPE" = xclang; then
336 # clang --version output typically looks like
337 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
338 # clang version 3.3 (tags/RELEASE_33/final)
339 # or
340 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
341 # Target: x86_64-pc-linux-gnu
342 # Thread model: posix
343 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
344 # Check that this is likely to be clang
345 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
346 if test $? -ne 0; then
347 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
348 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
349 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
350 fi
351 # Collapse compiler output into a single line
352 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
353 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
354 $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
355 else
356 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
357 fi
358 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
359 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
360 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
361 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
362
363 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
364 ])
365
366 # Try to locate the given C or C++ compiler in the path, or otherwise.
367 #
368 # $1 = compiler to test (CC or CXX)
369 # $2 = human readable name of compiler (C or C++)
370 # $3 = list of compiler names to search for
371 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
372 [
373 COMPILER_NAME=$2
374 SEARCH_LIST="$3"
375
376 if test "x[$]$1" != x; then
377 # User has supplied compiler name already, always let that override.
378 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
379 if test "x`basename [$]$1`" = "x[$]$1"; then
380 # A command without a complete path is provided, search $PATH.
381
382 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
383 if test "x$POTENTIAL_$1" != x; then
384 $1=$POTENTIAL_$1
385 else
386 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
387 fi
388 else
389 # Otherwise it might already be a complete path
390 if test ! -x "[$]$1"; then
391 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
392 fi
393 fi
394 else
395 # No user supplied value. Locate compiler ourselves.
396
397 # If we are cross compiling, assume cross compilation tools follows the
398 # cross compilation standard where they are prefixed with the autoconf
399 # standard name for the target. For example the binary
400 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
401 # If we are not cross compiling, then the default compiler name will be
402 # used.
403
404 $1=
405 # If TOOLS_DIR is set, check for all compiler names in there first
406 # before checking the rest of the PATH.
407 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
408 # step, this should not be necessary.
409 if test -n "$TOOLS_DIR"; then
410 PATH_save="$PATH"
411 PATH="$TOOLS_DIR"
412 AC_PATH_PROGS(TOOLS_DIR_$1, $SEARCH_LIST)
413 $1=$TOOLS_DIR_$1
414 PATH="$PATH_save"
415 fi
416
417 # AC_PATH_PROGS can't be run multiple times with the same variable,
418 # so create a new name for this run.
419 if test "x[$]$1" = x; then
420 AC_PATH_PROGS(POTENTIAL_$1, $SEARCH_LIST)
421 $1=$POTENTIAL_$1
422 fi
423
424 if test "x[$]$1" = x; then
425 HELP_MSG_MISSING_DEPENDENCY([devkit])
426 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
427 fi
428 fi
429
430 # Now we have a compiler binary in $1. Make sure it's okay.
431 BASIC_FIXUP_EXECUTABLE($1)
432 TEST_COMPILER="[$]$1"
433 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
434 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
435 if test "x$OPENJDK_BUILD_OS" != xaix; then
436 # FIXME: This test should not be needed anymore; we don't do that for any platform.
437 AC_MSG_CHECKING([resolved symbolic links for $1])
438 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
439 AC_MSG_RESULT([$TEST_COMPILER])
440 fi
441 AC_MSG_CHECKING([if $1 is disguised ccache])
442
443 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
444 if test "x$COMPILER_BASENAME" = "xccache"; then
445 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
446 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
447 # We want to control ccache invocation ourselves, so ignore this cc and try
448 # searching again.
449
450 # Remove the path to the fake ccache cc from the PATH
451 RETRY_COMPILER_SAVED_PATH="$PATH"
452 COMPILER_DIRNAME=`$DIRNAME [$]$1`
453 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
454
455 # Try again looking for our compiler
456 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
457 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
458 PATH="$RETRY_COMPILER_SAVED_PATH"
459
460 AC_MSG_CHECKING([for resolved symbolic links for $1])
461 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
462 AC_MSG_RESULT([$PROPER_COMPILER_$1])
463 $1="$PROPER_COMPILER_$1"
464 else
465 AC_MSG_RESULT([no, keeping $1])
466 fi
467
468 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
469 ])
470
471 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
472 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
473 # archiver (AR). Verify that the compilers are correct according to the
474 # toolchain type.
475 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
476 [
477 #
478 # Setup the compilers (CC and CXX)
479 #
480 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
481 # Now that we have resolved CC ourself, let autoconf have its go at it
482 AC_PROG_CC([$CC])
483
484 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
485 # Now that we have resolved CXX ourself, let autoconf have its go at it
486 AC_PROG_CXX([$CXX])
487
488 #
489 # Setup the preprocessor (CPP and CXXCPP)
490 #
491 AC_PROG_CPP
492 BASIC_FIXUP_EXECUTABLE(CPP)
493 AC_PROG_CXXCPP
494 BASIC_FIXUP_EXECUTABLE(CXXCPP)
495
496 #
497 # Setup the linker (LD)
498 #
499 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
500 # In the Microsoft toolchain we have a separate LD command "link".
501 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
502 # a cygwin program for something completely different.
503 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
504 BASIC_FIXUP_EXECUTABLE(LD)
505 # Verify that we indeed succeeded with this trick.
506 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
507 "$LD" --version > /dev/null
508 if test $? -eq 0 ; then
509 AC_MSG_RESULT([no])
510 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
511 else
512 AC_MSG_RESULT([yes])
513 fi
514 LDCXX="$LD"
515 else
516 # All other toolchains use the compiler to link.
517 LD="$CC"
518 LDCXX="$CXX"
519 fi
520 AC_SUBST(LD)
521 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
522 AC_SUBST(LDCXX)
523
524 #
525 # Setup the assembler (AS)
526 #
527 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
528 # FIXME: should this really be solaris, or solstudio?
529 BASIC_PATH_PROGS(AS, as)
530 BASIC_FIXUP_EXECUTABLE(AS)
531 else
532 # FIXME: is this correct for microsoft?
533 AS="$CC -c"
534 fi
535 AC_SUBST(AS)
536
537 #
538 # Setup the archiver (AR)
539 #
540 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
541 # The corresponding ar tool is lib.exe (used to create static libraries)
542 AC_CHECK_PROG([AR], [lib],[lib],,,)
543 else
544 BASIC_CHECK_TOOLS(AR, ar)
545 fi
546 BASIC_FIXUP_EXECUTABLE(AR)
547 ])
548
549 # Setup additional tools that is considered a part of the toolchain, but not the
550 # core part. Many of these are highly platform-specific and do not exist,
551 # and/or are not needed on all platforms.
552 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
553 [
554 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
555 AC_PROG_OBJC
556 BASIC_FIXUP_EXECUTABLE(OBJC)
557 BASIC_PATH_PROGS(LIPO, lipo)
558 BASIC_FIXUP_EXECUTABLE(LIPO)
559 else
560 OBJC=
561 fi
562
563 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
564 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
565 BASIC_FIXUP_EXECUTABLE(MT)
566 # Setup the resource compiler (RC)
567 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
568 BASIC_FIXUP_EXECUTABLE(RC)
569 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
570 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
571 fi
572
573 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
574 BASIC_PATH_PROGS(STRIP, strip)
575 BASIC_FIXUP_EXECUTABLE(STRIP)
576 BASIC_PATH_PROGS(NM, nm)
577 BASIC_FIXUP_EXECUTABLE(NM)
578 BASIC_PATH_PROGS(GNM, gnm)
579 BASIC_FIXUP_EXECUTABLE(GNM)
580
581 BASIC_PATH_PROGS(MCS, mcs)
582 BASIC_FIXUP_EXECUTABLE(MCS)
583 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
584 # FIXME: we should unify this with the solaris case above.
585 BASIC_CHECK_TOOLS(STRIP, strip)
586 BASIC_FIXUP_EXECUTABLE(STRIP)
587 BASIC_CHECK_TOOLS(NM, nm)
588 BASIC_FIXUP_EXECUTABLE(NM)
589 GNM="$NM"
590 AC_SUBST(GNM)
591 fi
592
593 # objcopy is used for moving debug symbols to separate files when
594 # full debug symbols are enabled.
595 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
596 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
597 # Only call fixup if objcopy was found.
598 if test -n "$OBJCOPY"; then
599 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
600 fi
601 fi
602
603 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
604 if test "x$OBJDUMP" != x; then
605 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
606 # bails if argument is missing.
607 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
608 fi
609 ])
610
611 # Setup the build tools (i.e, the compiler and linker used to build programs
612 # that should be run on the build platform, not the target platform, as a build
613 # helper). Since the non-cross-compile case uses the normal, target compilers
614 # for this, we can only do this after these have been setup.
615 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
616 [
617 if test "x$COMPILE_TYPE" = "xcross"; then
618 # Now we need to find a C/C++ compiler that can build executables for the
619 # build platform. We can't use the AC_PROG_CC macro, since it can only be
620 # used once. Also, we need to do this without adding a tools dir to the
621 # path, otherwise we might pick up cross-compilers which don't use standard
622 # naming.
623
624 # FIXME: we should list the discovered compilers as an exclude pattern!
625 # If we do that, we can do this detection before POST_DETECTION, and still
626 # find the build compilers in the tools dir, if needed.
627 BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
628 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
629 BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
630 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
631 BASIC_PATH_PROGS(BUILD_LD, ld)
632 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
633 else
634 # If we are not cross compiling, use the normal target compilers for
635 # building the build platform executables.
636 BUILD_CC="$CC"
637 BUILD_CXX="$CXX"
638 BUILD_LD="$LD"
639 fi
640
641 AC_SUBST(BUILD_CC)
642 AC_SUBST(BUILD_CXX)
643 AC_SUBST(BUILD_LD)
644 ])
645
646 # Setup legacy variables that are still needed as alternative ways to refer to
647 # parts of the toolchain.
648 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
649 [
650 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
651 # For hotspot, we need these in Windows mixed path,
652 # so rewrite them all. Need added .exe suffix.
653 HOTSPOT_CXX="$CXX.exe"
654 HOTSPOT_LD="$LD.exe"
655 HOTSPOT_MT="$MT.exe"
656 HOTSPOT_RC="$RC.exe"
657 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
658 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
659 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
660 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
661 AC_SUBST(HOTSPOT_MT)
662 AC_SUBST(HOTSPOT_RC)
663 else
664 HOTSPOT_CXX="$CXX"
665 HOTSPOT_LD="$LD"
666 fi
667 AC_SUBST(HOTSPOT_CXX)
668 AC_SUBST(HOTSPOT_LD)
669
670 if test "x$TOOLCHAIN_TYPE" = xclang; then
671 USE_CLANG=true
672 fi
673 AC_SUBST(USE_CLANG)
674
675 # LDEXE is the linker to use, when creating executables. Not really used.
676 # FIXME: These should just be removed!
677 LDEXE="$LD"
678 LDEXECXX="$LDCXX"
679 AC_SUBST(LDEXE)
680 AC_SUBST(LDEXECXX)
681 ])
682
683 # Do some additional checks on the detected tools.
684 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
685 [
686 # The package path is used only on macosx?
687 # FIXME: clean this up, and/or move it elsewhere.
688 PACKAGE_PATH=/opt/local
689 AC_SUBST(PACKAGE_PATH)
690
691 # Check for extra potential brokenness.
692 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
693 # On Windows, double-check that we got the right compiler.
694 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
695 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
696 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
697 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
698 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
699 fi
700 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
701 if test "x$COMPILER_CPU_TEST" != "xx64"; then
702 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
703 fi
704 fi
705 fi
706
707 if test "x$TOOLCHAIN_TYPE" = xgcc; then
708 # If this is a --hash-style=gnu system, use --hash-style=both, why?
709 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
710 # This is later checked when setting flags.
711 fi
712
713 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
714 # in executable.'
715 USING_BROKEN_SUSE_LD=no
716 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
717 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
718 echo "SUNWprivate_1.1 { local: *; };" > version-script.map
719 echo "int main() { }" > main.c
720 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
721 AC_MSG_RESULT(no)
722 USING_BROKEN_SUSE_LD=no
723 else
724 AC_MSG_RESULT(yes)
725 USING_BROKEN_SUSE_LD=yes
726 fi
727 rm -rf version-script.map main.c a.out
728 fi
729 AC_SUBST(USING_BROKEN_SUSE_LD)
730 ])
731
732 # Setup the JTReg Regression Test Harness.
733 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
734 [
735 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
736 [Regression Test Harness @<:@probed@:>@])],
737 [],
738 [with_jtreg=no])
739
740 if test "x$with_jtreg" = xno; then
741 # jtreg disabled
742 AC_MSG_CHECKING([for jtreg])
743 AC_MSG_RESULT(no)
744 else
745 if test "x$with_jtreg" != xyes; then
746 # with path specified.
747 JT_HOME="$with_jtreg"
748 fi
749
750 if test "x$JT_HOME" != x; then
751 AC_MSG_CHECKING([for jtreg])
752
753 # use JT_HOME enviroment var.
754 BASIC_FIXUP_PATH([JT_HOME])
755
756 # jtreg win32 script works for everybody
757 JTREGEXE="$JT_HOME/win32/bin/jtreg"
758
759 if test ! -f "$JTREGEXE"; then
760 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
761 fi
762
763 AC_MSG_RESULT($JTREGEXE)
764 else
765 # try to find jtreg on path
766 BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
767 JT_HOME="`$DIRNAME $JTREGEXE`"
768 fi
769 fi
770
771 AC_SUBST(JT_HOME)
772 AC_SUBST(JTREGEXE)
773 ])