1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN_ONCE([FLAGS_SETUP_INIT_FLAGS],
27 [
28 # Option used to tell the compiler whether to create 32- or 64-bit executables
29 if test "x$TOOLCHAIN_TYPE" = xxlc; then
30 COMPILER_TARGET_BITS_FLAG="-q"
31 else
32 COMPILER_TARGET_BITS_FLAG="-m"
33 fi
34 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
35
36 # FIXME: figure out if we should select AR flags depending on OS or toolchain.
37 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
38 ARFLAGS="-r"
39 elif test "x$OPENJDK_TARGET_OS" = xaix; then
40 ARFLAGS="-X64"
41 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
42 # lib.exe is used as AR to create static libraries.
43 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
44 else
45 ARFLAGS=""
46 fi
47 AC_SUBST(ARFLAGS)
48
49 ## Setup strip.
50 # FIXME: should this really be per platform, or should it be per toolchain type?
51 # strip is not provided by clang or solstudio; so guessing platform makes most sense.
52 # FIXME: we should really only export STRIPFLAGS from here, not POST_STRIP_CMD.
53 if test "x$OPENJDK_TARGET_OS" = xlinux; then
54 STRIPFLAGS="-g"
55 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
56 STRIPFLAGS="-x"
57 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
58 STRIPFLAGS="-S"
59 elif test "x$OPENJDK_TARGET_OS" = xaix; then
60 STRIPFLAGS="-X32_64"
61 fi
62
63 if test "x$OPENJDK_TARGET_OS" != xwindows; then
64 POST_STRIP_CMD="$STRIP $STRIPFLAGS"
65 fi
66 AC_SUBST(POST_STRIP_CMD)
67
68 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
69 # FIXME: break out into MCSFLAGS
70 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
71 fi
72 AC_SUBST(POST_MCS_CMD)
73
74 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
75 CC_OUT_OPTION=-Fo
76 EXE_OUT_OPTION=-out:
77 LD_OUT_OPTION=-out:
78 AR_OUT_OPTION=-out:
79 else
80 # The option used to specify the target .o,.a or .so file.
81 # When compiling, how to specify the to be created object file.
82 CC_OUT_OPTION='-o$(SPACE)'
83 # When linking, how to specify the to be created executable.
84 EXE_OUT_OPTION='-o$(SPACE)'
85 # When linking, how to specify the to be created dynamically linkable library.
86 LD_OUT_OPTION='-o$(SPACE)'
87 # When archiving, how to specify the to be create static archive for object files.
88 AR_OUT_OPTION='rcs$(SPACE)'
89 fi
90 AC_SUBST(CC_OUT_OPTION)
91 AC_SUBST(EXE_OUT_OPTION)
92 AC_SUBST(LD_OUT_OPTION)
93 AC_SUBST(AR_OUT_OPTION)
94
95 # On Windows, we need to set RC flags.
96 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
97 RC_FLAGS="-nologo -l0x409"
98 if test "x$VARIANT" = xOPT; then
99 RC_FLAGS="$RC_FLAGS -DNDEBUG"
100 fi
101
102 # The version variables used to create RC_FLAGS may be overridden
103 # in a custom configure script, or possibly the command line.
104 # Let those variables be expanded at make time in spec.gmk.
105 # The \$ are escaped to the shell, and the $(...) variables
106 # are evaluated by make.
107 RC_FLAGS="$RC_FLAGS \
108 -D\"JDK_BUILD_ID=\$(FULL_VERSION)\" \
109 -D\"JDK_COMPANY=\$(COMPANY_NAME)\" \
110 -D\"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
111 -D\"JDK_VER=\$(JDK_MINOR_VERSION).\$(JDK_MICRO_VERSION).\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0).\$(COOKED_BUILD_NUMBER)\" \
112 -D\"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
113 -D\"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(JDK_MINOR_VERSION) \$(JDK_UPDATE_META_TAG)\" \
114 -D\"JDK_FVER=\$(JDK_MINOR_VERSION),\$(JDK_MICRO_VERSION),\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0),\$(COOKED_BUILD_NUMBER)\""
115 fi
116 AC_SUBST(RC_FLAGS)
117
118 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
119 # silence copyright notice and other headers.
120 COMMON_CCXXFLAGS="$COMMON_CCXXFLAGS -nologo"
121 fi
122
123 if test "x$SYSROOT" != "x"; then
124 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
125 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
126 # Solaris Studio does not have a concept of sysroot. Instead we must
127 # make sure the default include and lib dirs are appended to each
128 # compile and link command line.
129 SYSROOT_CFLAGS="-I$SYSROOT/usr/include"
130 SYSROOT_LDFLAGS="-L$SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
131 -L$SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR \
132 -L$SYSROOT/usr/ccs/lib$OPENJDK_TARGET_CPU_ISADIR"
133 fi
134 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
135 # Apple only wants -isysroot <path>, but we also need -iframework<path>/System/Library/Frameworks
136 SYSROOT_CFLAGS="-isysroot \"$SYSROOT\" -iframework\"$SYSROOT/System/Library/Frameworks\""
137 SYSROOT_LDFLAGS=$SYSROOT_CFLAGS
138 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
139 SYSROOT_CFLAGS="--sysroot=$SYSROOT"
140 SYSROOT_LDFLAGS="--sysroot=$SYSROOT"
141 elif test "x$TOOLCHAIN_TYPE" = xclang; then
142 SYSROOT_CFLAGS="-isysroot \"$SYSROOT\""
143 SYSROOT_LDFLAGS="-isysroot \"$SYSROOT\""
144 fi
145 # Propagate the sysroot args to hotspot
146 LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $SYSROOT_CFLAGS"
147 LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $SYSROOT_CFLAGS"
148 LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $SYSROOT_LDFLAGS"
149 fi
150
151 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
152 # set this here so it doesn't have to be peppered throughout the forest
153 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
154 SYSROOT_CFLAGS="$SYSROOT_CFLAGS -F\"$SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks\""
155 SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS -F\"$SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks\""
156 fi
157
158 AC_SUBST(SYSROOT_CFLAGS)
159 AC_SUBST(SYSROOT_LDFLAGS)
160 ])
161
162 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_LIBS],
163 [
164 ###############################################################################
165 #
166 # How to compile shared libraries.
167 #
168
169 if test "x$TOOLCHAIN_TYPE" = xgcc; then
170 PICFLAG="-fPIC"
171 C_FLAG_REORDER=''
172 CXX_FLAG_REORDER=''
173
174 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
175 # Linking is different on MacOSX
176 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
177 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
178 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
179 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
180 SET_SHARED_LIBRARY_MAPFILE=''
181 else
182 # Default works for linux, might work on other platforms as well.
183 SHARED_LIBRARY_FLAGS='-shared'
184 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
185 SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
186 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
187 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
188 fi
189 elif test "x$TOOLCHAIN_TYPE" = xclang; then
190 PICFLAG=''
191 C_FLAG_REORDER=''
192 CXX_FLAG_REORDER=''
193
194 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
195 # Linking is different on MacOSX
196 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
197 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
198 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
199 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
200 SET_SHARED_LIBRARY_MAPFILE=''
201 else
202 # Default works for linux, might work on other platforms as well.
203 SHARED_LIBRARY_FLAGS='-shared'
204 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
205 SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
206 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
207 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
208 fi
209 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
210 PICFLAG="-KPIC"
211 C_FLAG_REORDER='-xF'
212 CXX_FLAG_REORDER='-xF'
213 SHARED_LIBRARY_FLAGS="-G"
214 SET_EXECUTABLE_ORIGIN='-R\$$$$ORIGIN[$]1'
215 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
216 SET_SHARED_LIBRARY_NAME=''
217 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
218 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
219 PICFLAG="-qpic=large"
220 C_FLAG_REORDER=''
221 CXX_FLAG_REORDER=''
222 SHARED_LIBRARY_FLAGS="-qmkshrobj"
223 SET_EXECUTABLE_ORIGIN=""
224 SET_SHARED_LIBRARY_ORIGIN=''
225 SET_SHARED_LIBRARY_NAME=''
226 SET_SHARED_LIBRARY_MAPFILE=''
227 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
228 PICFLAG=""
229 C_FLAG_REORDER=''
230 CXX_FLAG_REORDER=''
231 SHARED_LIBRARY_FLAGS="-LD"
232 SET_EXECUTABLE_ORIGIN=''
233 SET_SHARED_LIBRARY_ORIGIN=''
234 SET_SHARED_LIBRARY_NAME=''
235 SET_SHARED_LIBRARY_MAPFILE=''
236 fi
237
238 AC_SUBST(C_FLAG_REORDER)
239 AC_SUBST(CXX_FLAG_REORDER)
240 AC_SUBST(SET_EXECUTABLE_ORIGIN)
241 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
242 AC_SUBST(SET_SHARED_LIBRARY_NAME)
243 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
244
245 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
246 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
247 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
248 CFLAGS_JDKLIB_EXTRA='-xstrconst'
249 fi
250 # The (cross) compiler is now configured, we can now test capabilities
251 # of the target platform.
252 ])
253
254 # Documentation on common flags used for solstudio in HIGHEST.
255 #
256 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
257 # done with care, there are some assumptions below that need to
258 # be understood about the use of pointers, and IEEE behavior.
259 #
260 # -fns: Use non-standard floating point mode (not IEEE 754)
261 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
262 # -fsingle: Use single precision floating point with 'float'
263 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
264 # (Source with excessing pointer casting and data access with mixed
265 # pointer types are not recommended)
266 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
267 # (If you expect perfect errno behavior, do not use this)
268 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
269 # -xrestrict: Pointer parameters to functions do not overlap
270 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
271 # If you pass in multiple pointers to the same data, do not use this)
272 # -xlibmil: Inline some library routines
273 # (If you expect perfect errno behavior, do not use this)
274 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
275 # (If you expect perfect errno behavior, do not use this)
276 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
277
278 # FIXME: this will never happen since sparc != sparcv9, ie 32 bit, which we don't build anymore.
279 # Bug?
280 #if test "x$OPENJDK_TARGET_CPU" = xsparc; then
281 # CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
282 # CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
283 #fi
284
285 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
286 [
287
288 ###############################################################################
289 #
290 # Setup the opt flags for different compilers
291 # and different operating systems.
292 #
293
294 # FIXME: this was indirectly the old default, but just inherited.
295 # if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
296 # C_FLAG_DEPS="-MMD -MF"
297 # fi
298
299 # Generate make dependency files
300 if test "x$TOOLCHAIN_TYPE" = xgcc; then
301 C_FLAG_DEPS="-MMD -MF"
302 elif test "x$TOOLCHAIN_TYPE" = xclang; then
303 C_FLAG_DEPS="-MMD -MF"
304 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
305 C_FLAG_DEPS="-xMMD -xMF"
306 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
307 C_FLAG_DEPS="-qmakedep=gcc -MF"
308 fi
309 CXX_FLAG_DEPS="$C_FLAG_DEPS"
310 AC_SUBST(C_FLAG_DEPS)
311 AC_SUBST(CXX_FLAG_DEPS)
312
313 # Debug symbols
314 if test "x$TOOLCHAIN_TYPE" = xgcc; then
315 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
316 # reduce from default "-g2" option to save space
317 CFLAGS_DEBUG_SYMBOLS="-g1"
318 CXXFLAGS_DEBUG_SYMBOLS="-g1"
319 else
320 CFLAGS_DEBUG_SYMBOLS="-g"
321 CXXFLAGS_DEBUG_SYMBOLS="-g"
322 fi
323 elif test "x$TOOLCHAIN_TYPE" = xclang; then
324 CFLAGS_DEBUG_SYMBOLS="-g"
325 CXXFLAGS_DEBUG_SYMBOLS="-g"
326 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
327 CFLAGS_DEBUG_SYMBOLS="-g -xs"
328 # FIXME: likely a bug, this disables debug symbols rather than enables them
329 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
330 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
331 CFLAGS_DEBUG_SYMBOLS="-g"
332 CXXFLAGS_DEBUG_SYMBOLS="-g"
333 fi
334 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
335 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
336
337 # bounds, memory and behavior checking options
338 if test "x$TOOLCHAIN_TYPE" = xgcc; then
339 case $DEBUG_LEVEL in
340 release )
341 # no adjustment
342 ;;
343 fastdebug )
344 # no adjustment
345 ;;
346 slowdebug )
347 # Add runtime stack smashing and undefined behavior checks
348 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
349 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
350 ;;
351 esac
352 fi
353 AC_SUBST(CFLAGS_DEBUG_OPTIONS)
354 AC_SUBST(CXXFLAGS_DEBUG_OPTIONS)
355
356 # Optimization levels
357 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
358 CC_HIGHEST="$CC_HIGHEST -fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
359
360 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
361 # FIXME: seems we always set -xregs=no%frameptr; put it elsewhere more global?
362 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xalias_level=basic -xregs=no%frameptr"
363 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
364 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
365 C_O_FLAG_DEBUG="-xregs=no%frameptr"
366 C_O_FLAG_NONE="-xregs=no%frameptr"
367 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
368 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
369 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
370 CXX_O_FLAG_DEBUG="-xregs=no%frameptr"
371 CXX_O_FLAG_NONE="-xregs=no%frameptr"
372 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
373 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
374 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
375 fi
376 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
377 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xalias_level=basic -xprefetch=auto,explicit -xchip=ultra"
378 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
379 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
380 C_O_FLAG_DEBUG=""
381 C_O_FLAG_NONE=""
382 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
383 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
384 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
385 C_O_FLAG_DEBUG=""
386 CXX_O_FLAG_NONE=""
387 fi
388 else
389 # The remaining toolchains share opt flags between CC and CXX;
390 # setup for C and duplicate afterwards.
391 if test "x$TOOLCHAIN_TYPE" = xgcc; then
392 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
393 # On MacOSX we optimize for size, something
394 # we should do for all platforms?
395 C_O_FLAG_HIGHEST="-Os"
396 C_O_FLAG_HI="-Os"
397 C_O_FLAG_NORM="-Os"
398 else
399 C_O_FLAG_HIGHEST="-O3"
400 C_O_FLAG_HI="-O3"
401 C_O_FLAG_NORM="-O2"
402 fi
403 C_O_FLAG_DEBUG="-O0"
404 C_O_FLAG_NONE="-O0"
405 elif test "x$TOOLCHAIN_TYPE" = xclang; then
406 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
407 # On MacOSX we optimize for size, something
408 # we should do for all platforms?
409 C_O_FLAG_HIGHEST="-Os"
410 C_O_FLAG_HI="-Os"
411 C_O_FLAG_NORM="-Os"
412 else
413 C_O_FLAG_HIGHEST="-O3"
414 C_O_FLAG_HI="-O3"
415 C_O_FLAG_NORM="-O2"
416 fi
417 C_O_FLAG_DEBUG="-O0"
418 C_O_FLAG_NONE="-O0"
419 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
420 C_O_FLAG_HIGHEST="-O3"
421 C_O_FLAG_HI="-O3 -qstrict"
422 C_O_FLAG_NORM="-O2"
423 C_O_FLAG_DEBUG="-qnoopt"
424 C_O_FLAG_NONE="-qnoop"
425 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
426 C_O_FLAG_HIGHEST="-O2"
427 C_O_FLAG_HI="-O1"
428 C_O_FLAG_NORM="-O1"
429 C_O_FLAG_DEBUG="-Od"
430 C_O_FLAG_NONE="-Od"
431 fi
432 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
433 CXX_O_FLAG_HI="$C_O_FLAG_HI"
434 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
435 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
436 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
437 fi
438
439 # Adjust optimization flags according to debug level.
440 case $DEBUG_LEVEL in
441 release )
442 # no adjustment
443 ;;
444 fastdebug )
445 # Not quite so much optimization
446 C_O_FLAG_HI="$C_O_FLAG_NORM"
447 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
448 ;;
449 slowdebug )
450 # Disable optimization
451 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
452 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
453 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
454 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
455 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
456 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
457 ;;
458 esac
459
460 AC_SUBST(C_O_FLAG_HIGHEST)
461 AC_SUBST(C_O_FLAG_HI)
462 AC_SUBST(C_O_FLAG_NORM)
463 AC_SUBST(C_O_FLAG_DEBUG)
464 AC_SUBST(C_O_FLAG_NONE)
465 AC_SUBST(CXX_O_FLAG_HIGHEST)
466 AC_SUBST(CXX_O_FLAG_HI)
467 AC_SUBST(CXX_O_FLAG_NORM)
468 AC_SUBST(CXX_O_FLAG_DEBUG)
469 AC_SUBST(CXX_O_FLAG_NONE)
470 ])
471
472 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK],
473 [
474 # Special extras...
475 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
476 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
477 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
478 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
479 fi
480 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
481 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
482 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
483 CFLAGS_JDK="${CFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
484 CXXFLAGS_JDK="${CXXFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
485 fi
486
487 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
488 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
489 fi
490
491 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
492 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
493 fi
494
495 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
496 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
497 fi
498
499 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
500 [extra flags to be used when compiling jdk c-files])])
501
502 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
503 [extra flags to be used when compiling jdk c++-files])])
504
505 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
506 [extra flags to be used when linking jdk])])
507
508 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
509 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
510 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
511
512 # Hotspot needs these set in their legacy form
513 LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $with_extra_cflags"
514 LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $with_extra_cxxflags"
515 LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $with_extra_ldflags"
516
517 AC_SUBST(LEGACY_EXTRA_CFLAGS)
518 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
519 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
520
521 ###############################################################################
522 #
523 # Now setup the CFLAGS and LDFLAGS for the JDK build.
524 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
525 #
526
527 # Setup compiler/platform specific flags into
528 # CFLAGS_JDK - C Compiler flags
529 # CXXFLAGS_JDK - C++ Compiler flags
530 # COMMON_CCXXFLAGS_JDK - common to C and C++
531 if test "x$TOOLCHAIN_TYPE" = xgcc; then
532 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2 \
533 -pipe -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
534 case $OPENJDK_TARGET_CPU_ARCH in
535 arm )
536 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
537 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
538 ;;
539 ppc )
540 # on ppc we don't prevent gcc to omit frame pointer but do prevent strict aliasing
541 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
542 ;;
543 * )
544 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer"
545 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
546 ;;
547 esac
548 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
549 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
550 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
551 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
552 fi
553
554 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
555 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
556 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
557 CFLAGS_JDK="$CFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
558 CXXFLAGS_JDK="$CXXFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
559 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
560 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK \
561 -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
562 -DWIN32_LEAN_AND_MEAN \
563 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
564 -DWIN32 -DIAL"
565 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
566 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_AMD64_ -Damd64"
567 else
568 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_X86_ -Dx86"
569 fi
570 # If building with Visual Studio 2010, we can still use _STATIC_CPPLIB to
571 # avoid bundling msvcpNNN.dll. Doesn't work with newer versions of visual
572 # studio.
573 if test "x$TOOLCHAIN_VERSION" = "x2010"; then
574 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK \
575 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB"
576 fi
577 fi
578
579 ###############################################################################
580
581 # Adjust flags according to debug level.
582 case $DEBUG_LEVEL in
583 fastdebug | slowdebug )
584 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS $CFLAGS_DEBUG_OPTIONS"
585 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS $CXXFLAGS_DEBUG_OPTIONS"
586 JAVAC_FLAGS="$JAVAC_FLAGS -g"
587 ;;
588 release )
589 ;;
590 * )
591 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
592 ;;
593 esac
594
595 # Setup LP64
596 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK $ADD_LP64"
597
598 # Set some common defines. These works for all compilers, but assume
599 # -D is universally accepted.
600
601 # Setup endianness
602 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
603 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
604 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
605 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
606 # Note: -Dmacro is the same as #define macro 1
607 # -Dmacro= is the same as #define macro
608 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
609 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
610 else
611 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
612 fi
613 else
614 # Same goes for _BIG_ENDIAN. Do we really need to set *ENDIAN on Solaris if they
615 # are defined in the system?
616 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
617 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN="
618 else
619 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN"
620 fi
621 fi
622
623 # Setup target OS define. Use OS target name but in upper case.
624 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
625 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
626
627 # Setup target CPU
628 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
629
630 # Setup debug/release defines
631 if test "x$DEBUG_LEVEL" = xrelease; then
632 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DNDEBUG"
633 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
634 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DTRIMMED"
635 fi
636 else
637 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DDEBUG"
638 fi
639
640 # Setup release name
641 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DRELEASE='\"\$(RELEASE)\"'"
642
643
644 # Set some additional per-OS defines.
645 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
646 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
647 elif test "x$OPENJDK_TARGET_OS" = xaix; then
648 # FIXME: PPC64 should not be here.
649 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DPPC64"
650 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
651 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE"
652 fi
653
654 # Additional macosx handling
655 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
656 # Setting these parameters makes it an error to link to macosx APIs that are
657 # newer than the given OS version and makes the linked binaries compatible
658 # even if built on a newer version of the OS.
659 # The expected format is X.Y.Z
660 MACOSX_VERSION_MIN=10.7.0
661 AC_SUBST(MACOSX_VERSION_MIN)
662
663 # The macro takes the version with no dots, ex: 1070
664 # Let the flags variables get resolved in make for easier override on make
665 # command line.
666 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
667 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
668 fi
669
670 # Setup some hard coded includes
671 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK \
672 -I${JDK_TOPDIR}/src/java.base/share/native/include \
673 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_TARGET_OS/native/include \
674 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/include"
675
676 # The shared libraries are compiled using the picflag.
677 CFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
678 CXXFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA"
679
680 # Executable flags
681 CFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
682 CXXFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
683
684 AC_SUBST(CFLAGS_JDKLIB)
685 AC_SUBST(CFLAGS_JDKEXE)
686 AC_SUBST(CXXFLAGS_JDKLIB)
687 AC_SUBST(CXXFLAGS_JDKEXE)
688
689 # Flags for compiling test libraries
690 CFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
691 CXXFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA"
692
693 # Flags for compiling test executables
694 CFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
695 CXXFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
696
697 AC_SUBST(CFLAGS_TESTLIB)
698 AC_SUBST(CFLAGS_TESTEXE)
699 AC_SUBST(CXXFLAGS_TESTLIB)
700 AC_SUBST(CXXFLAGS_TESTEXE)
701
702 # Setup LDFLAGS et al.
703 #
704
705 # Now this is odd. The JDK native libraries have to link against libjvm.so
706 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
707 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
708 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
709 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
710 # libraries will link to whatever is in memory. Yuck.
711 #
712 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
713 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
714 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
715 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
716 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
717 fi
718 # TODO: make -debug optional "--disable-full-debug-symbols"
719 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
720 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
721 # If this is a --hash-style=gnu system, use --hash-style=both, why?
722 # We have previously set HAS_GNU_HASH if this is the case
723 if test -n "$HAS_GNU_HASH"; then
724 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both"
725 fi
726 if test "x$OPENJDK_TARGET_OS" = xlinux; then
727 # And since we now know that the linker is gnu, then add -z defs, to forbid
728 # undefined symbols in object files.
729 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
730 case $DEBUG_LEVEL in
731 release )
732 # tell linker to optimize libraries.
733 # Should this be supplied to the OSS linker as well?
734 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
735 ;;
736 slowdebug )
737 if test "x$HAS_LINKER_NOW" = "xtrue"; then
738 # do relocations at load
739 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_NOW_FLAG"
740 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_NOW_FLAG"
741 fi
742 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
743 # mark relocations read only
744 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
745 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
746 fi
747 ;;
748 fastdebug )
749 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
750 # mark relocations read only
751 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
752 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
753 fi
754 ;;
755 * )
756 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
757 ;;
758 esac
759 fi
760 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
761 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
762 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
763 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
764 LDFLAGS_JDK="${LDFLAGS_JDK} -brtl -bnolibpath -liconv -bexpall -bernotok"
765 fi
766
767 # Customize LDFLAGS for executables
768
769 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
770
771 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
772 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
773 LDFLAGS_STACK_SIZE=1048576
774 else
775 LDFLAGS_STACK_SIZE=327680
776 fi
777 LDFLAGS_JDKEXE="${LDFLAGS_JDKEXE} /STACK:$LDFLAGS_STACK_SIZE"
778 elif test "x$OPENJDK_TARGET_OS" = xlinux; then
779 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
780 fi
781
782 # Customize LDFLAGS for libs
783 LDFLAGS_JDKLIB="${LDFLAGS_JDK}"
784
785 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
786 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -dll -libpath:${OUTPUT_ROOT}/support/modules_libs/java.base"
787 LDFLAGS_JDKLIB_SUFFIX=""
788 else
789 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} ${SHARED_LIBRARY_FLAGS} \
790 -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}"
791
792 # On some platforms (mac) the linker warns about non existing -L dirs.
793 # Add server first if available. Linking aginst client does not always produce the same results.
794 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
795 # Default to server for other variants.
796 if test "x$JVM_VARIANT_SERVER" = xtrue; then
797 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/server"
798 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
799 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/client"
800 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
801 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
802 else
803 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/server"
804 fi
805
806 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
807 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
808 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
809 fi
810 fi
811
812 AC_SUBST(LDFLAGS_JDKLIB)
813 AC_SUBST(LDFLAGS_JDKEXE)
814 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
815 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
816 AC_SUBST(LDFLAGS_CXX_JDK)
817
818 LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
819 LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE"
820 LDFLAGS_TESTLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX"
821 LDFLAGS_TESTEXE_SUFFIX="$LDFLAGS_JDKEXE_SUFFIX"
822
823 AC_SUBST(LDFLAGS_TESTLIB)
824 AC_SUBST(LDFLAGS_TESTEXE)
825 AC_SUBST(LDFLAGS_TESTLIB_SUFFIX)
826 AC_SUBST(LDFLAGS_TESTEXE_SUFFIX)
827 ])
828
829 # FLAGS_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
830 # [RUN-IF-FALSE])
831 # ------------------------------------------------------------
832 # Check that the c and c++ compilers support an argument
833 AC_DEFUN([FLAGS_COMPILER_CHECK_ARGUMENTS],
834 [
835 AC_MSG_CHECKING([if compiler supports "$1"])
836 supports=yes
837
838 saved_cflags="$CFLAGS"
839 CFLAGS="$CFLAGS $1"
840 AC_LANG_PUSH([C])
841 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
842 [supports=no])
843 AC_LANG_POP([C])
844 CFLAGS="$saved_cflags"
845
846 saved_cxxflags="$CXXFLAGS"
847 CXXFLAGS="$CXXFLAG $1"
848 AC_LANG_PUSH([C++])
849 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
850 [supports=no])
851 AC_LANG_POP([C++])
852 CXXFLAGS="$saved_cxxflags"
853
854 AC_MSG_RESULT([$supports])
855 if test "x$supports" = "xyes" ; then
856 m4_ifval([$2], [$2], [:])
857 else
858 m4_ifval([$3], [$3], [:])
859 fi
860 ])
861
862 # FLAGS_LINKER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
863 # [RUN-IF-FALSE])
864 # ------------------------------------------------------------
865 # Check that the linker support an argument
866 AC_DEFUN([FLAGS_LINKER_CHECK_ARGUMENTS],
867 [
868 AC_MSG_CHECKING([if linker supports "$1"])
869 supports=yes
870
871 saved_ldflags="$LDFLAGS"
872 LDFLAGS="$LDFLAGS $1"
873 AC_LANG_PUSH([C])
874 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
875 [], [supports=no])
876 AC_LANG_POP([C])
877 LDFLAGS="$saved_ldflags"
878
879 AC_MSG_RESULT([$supports])
880 if test "x$supports" = "xyes" ; then
881 m4_ifval([$2], [$2], [:])
882 else
883 m4_ifval([$3], [$3], [:])
884 fi
885 ])
886
887 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_MISC],
888 [
889 # Some Zero and Shark settings.
890 # ZERO_ARCHFLAG tells the compiler which mode to build for
891 case "${OPENJDK_TARGET_CPU}" in
892 s390)
893 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}31"
894 ;;
895 *)
896 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
897 esac
898 FLAGS_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
899 AC_SUBST(ZERO_ARCHFLAG)
900
901 # Check that the compiler supports -mX (or -qX on AIX) flags
902 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
903 FLAGS_COMPILER_CHECK_ARGUMENTS([${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
904 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
905 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
906 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
907
908 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
909 [do not consider native warnings to be an error @<:@enabled@:>@])])
910
911 AC_MSG_CHECKING([if native warnings are errors])
912 if test "x$enable_warnings_as_errors" = "xyes"; then
913 AC_MSG_RESULT([yes (explicitely set)])
914 WARNINGS_AS_ERRORS=true
915 elif test "x$enable_warnings_as_errors" = "xno"; then
916 AC_MSG_RESULT([no])
917 WARNINGS_AS_ERRORS=false
918 elif test "x$enable_warnings_as_errors" = "x"; then
919 AC_MSG_RESULT([yes (default)])
920 WARNINGS_AS_ERRORS=true
921 else
922 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
923 fi
924 AC_SUBST(WARNINGS_AS_ERRORS)
925
926 case "${TOOLCHAIN_TYPE}" in
927 microsoft)
928 DISABLE_WARNING_PREFIX="-wd"
929 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
930 ;;
931 solstudio)
932 DISABLE_WARNING_PREFIX="-erroff="
933 CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
934 ;;
935 gcc)
936 # Prior to gcc 4.4, a -Wno-X where X is unknown for that version of gcc will cause an error
937 FLAGS_COMPILER_CHECK_ARGUMENTS([-Wno-this-is-a-warning-that-do-not-exist],
938 [GCC_CAN_DISABLE_WARNINGS=true],
939 [GCC_CAN_DISABLE_WARNINGS=false]
940 )
941 if test "x$GCC_CAN_DISABLE_WARNINGS" = "xtrue"; then
942 DISABLE_WARNING_PREFIX="-Wno-"
943 else
944 DISABLE_WARNING_PREFIX=
945 fi
946 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
947 ;;
948 clang)
949 DISABLE_WARNING_PREFIX="-Wno-"
950 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
951 ;;
952 esac
953 AC_SUBST(DISABLE_WARNING_PREFIX)
954 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
955 ])