1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x$2" != x; then
50 if test "x[$]$1" = x; then
51 $1="$2"
52 else
53 $1="[$]$1:$2"
54 fi
55 fi
56 ])
57
58 # Prepends a string to a path variable, only adding the : when needed.
59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
60 [
61 if test "x$2" != x; then
62 if test "x[$]$1" = x; then
63 $1="$2"
64 else
65 $1="$2:[$]$1"
66 fi
67 fi
68 ])
69
70 # This will make sure the given variable points to a full and proper
71 # path. This means:
72 # 1) There will be no spaces in the path. On unix platforms,
73 # spaces in the path will result in an error. On Windows,
74 # the path will be rewritten using short-style to be space-free.
75 # 2) The path will be absolute, and it will be in unix-style (on
76 # cygwin).
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_PATH],
79 [
80 # Only process if variable expands to non-empty
81
82 if test "x[$]$1" != x; then
83 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
84 BASIC_FIXUP_PATH_CYGWIN($1)
85 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
86 BASIC_FIXUP_PATH_MSYS($1)
87 else
88 # We're on a unix platform. Hooray! :)
89 path="[$]$1"
90 has_space=`$ECHO "$path" | $GREP " "`
91 if test "x$has_space" != x; then
92 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
93 AC_MSG_ERROR([Spaces are not allowed in this path.])
94 fi
95
96 # Use eval to expand a potential ~
97 eval path="$path"
98 if test ! -f "$path" && test ! -d "$path"; then
99 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
100 fi
101
102 if test -d "$path"; then
103 $1="`cd "$path"; $THEPWDCMD -L`"
104 else
105 dir="`$DIRNAME "$path"`"
106 base="`$BASENAME "$path"`"
107 $1="`cd "$dir"; $THEPWDCMD -L`/$base"
108 fi
109 fi
110 fi
111 ])
112
113 # This will make sure the given variable points to a executable
114 # with a full and proper path. This means:
115 # 1) There will be no spaces in the path. On unix platforms,
116 # spaces in the path will result in an error. On Windows,
117 # the path will be rewritten using short-style to be space-free.
118 # 2) The path will be absolute, and it will be in unix-style (on
119 # cygwin).
120 # Any arguments given to the executable is preserved.
121 # If the input variable does not have a directory specification, then
122 # it need to be in the PATH.
123 # $1: The name of the variable to fix
124 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
125 [
126 # Only process if variable expands to non-empty
127
128 if test "x[$]$1" != x; then
129 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
130 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
131 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
132 BASIC_FIXUP_EXECUTABLE_MSYS($1)
133 else
134 # We're on a unix platform. Hooray! :)
135 # First separate the path from the arguments. This will split at the first
136 # space.
137 complete="[$]$1"
138 path="${complete%% *}"
139 tmp="$complete EOL"
140 arguments="${tmp#* }"
141
142 # Cannot rely on the command "which" here since it doesn't always work.
143 is_absolute_path=`$ECHO "$path" | $GREP ^/`
144 if test -z "$is_absolute_path"; then
145 # Path to executable is not absolute. Find it.
146 IFS_save="$IFS"
147 IFS=:
148 for p in $PATH; do
149 if test -f "$p/$path" && test -x "$p/$path"; then
150 new_path="$p/$path"
151 break
152 fi
153 done
154 IFS="$IFS_save"
155 else
156 # This is an absolute path, we can use it without further modifications.
157 new_path="$path"
158 fi
159
160 if test "x$new_path" = x; then
161 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
162 has_space=`$ECHO "$complete" | $GREP " "`
163 if test "x$has_space" != x; then
164 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
165 fi
166 AC_MSG_ERROR([Cannot locate the the path of $1])
167 fi
168 fi
169
170 # Now join together the path and the arguments once again
171 if test "x$arguments" != xEOL; then
172 new_complete="$new_path ${arguments% *}"
173 else
174 new_complete="$new_path"
175 fi
176
177 if test "x$complete" != "x$new_complete"; then
178 $1="$new_complete"
179 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
180 fi
181 fi
182 ])
183
184 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
185 [
186 if test "x$OPENJDK_BUILD_OS" != xwindows; then
187 # Follow a chain of symbolic links. Use readlink
188 # where it exists, else fall back to horribly
189 # complicated shell code.
190 if test "x$READLINK_TESTED" != yes; then
191 # On MacOSX there is a readlink tool with a different
192 # purpose than the GNU readlink tool. Check the found readlink.
193 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
194 if test "x$ISGNU" = x; then
195 # A readlink that we do not know how to use.
196 # Are there other non-GNU readlinks out there?
197 READLINK_TESTED=yes
198 READLINK=
199 fi
200 fi
201
202 if test "x$READLINK" != x; then
203 $1=`$READLINK -f [$]$1`
204 else
205 # Save the current directory for restoring afterwards
206 STARTDIR=$PWD
207 COUNTER=0
208 sym_link_dir=`$DIRNAME [$]$1`
209 sym_link_file=`$BASENAME [$]$1`
210 cd $sym_link_dir
211 # Use -P flag to resolve symlinks in directories.
212 cd `$THEPWDCMD -P`
213 sym_link_dir=`$THEPWDCMD -P`
214 # Resolve file symlinks
215 while test $COUNTER -lt 20; do
216 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
217 if test "x$ISLINK" == x; then
218 # This is not a symbolic link! We are done!
219 break
220 fi
221 # Again resolve directory symlinks since the target of the just found
222 # link could be in a different directory
223 cd `$DIRNAME $ISLINK`
224 sym_link_dir=`$THEPWDCMD -P`
225 sym_link_file=`$BASENAME $ISLINK`
226 let COUNTER=COUNTER+1
227 done
228 cd $STARTDIR
229 $1=$sym_link_dir/$sym_link_file
230 fi
231 fi
232 ])
233
234 # Register a --with argument but mark it as deprecated
235 # $1: The name of the with argument to deprecate, not including --with-
236 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
237 [
238 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
239 [Deprecated. Option is kept for backwards compatibility and is ignored])],
240 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
241 ])
242
243 # Register a --enable argument but mark it as deprecated
244 # $1: The name of the with argument to deprecate, not including --enable-
245 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
246 # $3: Messages to user.
247 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
248 [
249 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
250 [Deprecated. Option is kept for backwards compatibility and is ignored])])
251 if test "x$enable_$2" != x; then
252 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
253
254 if test "x$3" != x; then
255 AC_MSG_WARN([$3])
256 fi
257
258 fi
259 ])
260
261 AC_DEFUN_ONCE([BASIC_INIT],
262 [
263 # Save the original command line. This is passed to us by the wrapper configure script.
264 AC_SUBST(CONFIGURE_COMMAND_LINE)
265 # Save the path variable before it gets changed
266 ORIGINAL_PATH="$PATH"
267 AC_SUBST(ORIGINAL_PATH)
268 DATE_WHEN_CONFIGURED=`LANG=C date`
269 AC_SUBST(DATE_WHEN_CONFIGURED)
270 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
271 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
272 ])
273
274 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
275 # $1: variable to check
276 AC_DEFUN([BASIC_CHECK_NONEMPTY],
277 [
278 if test "x[$]$1" = x; then
279 AC_MSG_ERROR([Could not find required tool for $1])
280 fi
281 ])
282
283 # Check that there are no unprocessed overridden variables left.
284 # If so, they are an incorrect argument and we will exit with an error.
285 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
286 [
287 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
288 # Replace the separating ! with spaces before presenting for end user.
289 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
290 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
291 fi
292 ])
293
294 # Setup a tool for the given variable. If correctly specified by the user,
295 # use that value, otherwise search for the tool using the supplied code snippet.
296 # $1: variable to set
297 # $2: code snippet to call to look for the tool
298 # $3: code snippet to call if variable was used to find tool
299 AC_DEFUN([BASIC_SETUP_TOOL],
300 [
301 # Publish this variable in the help.
302 AC_ARG_VAR($1, [Override default value for $1])
303
304 if [[ -z "${$1+x}" ]]; then
305 # The variable is not set by user, try to locate tool using the code snippet
306 $2
307 else
308 # The variable is set, but is it from the command line or the environment?
309
310 # Try to remove the string !$1! from our list.
311 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
312 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
313 # If it failed, the variable was not from the command line. Ignore it,
314 # but warn the user (except for BASH, which is always set by the calling BASH).
315 if test "x$1" != xBASH; then
316 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
317 fi
318 # Try to locate tool using the code snippet
319 $2
320 else
321 # If it succeeded, then it was overridden by the user. We will use it
322 # for the tool.
323
324 # First remove it from the list of overridden variables, so we can test
325 # for unknown variables in the end.
326 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
327
328 # Check if we try to supply an empty value
329 if test "x[$]$1" = x; then
330 AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
331 AC_MSG_CHECKING([for $1])
332 AC_MSG_RESULT([disabled])
333 else
334 # Check if the provided tool contains a complete path.
335 tool_specified="[$]$1"
336 tool_basename="${tool_specified##*/}"
337 if test "x$tool_basename" = "x$tool_specified"; then
338 # A command without a complete path is provided, search $PATH.
339 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
340 AC_PATH_PROG($1, $tool_basename)
341 if test "x[$]$1" = x; then
342 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
343 fi
344 else
345 # Otherwise we believe it is a complete path. Use it as it is.
346 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
347 AC_MSG_CHECKING([for $1])
348 if test ! -x "$tool_specified"; then
349 AC_MSG_RESULT([not found])
350 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
351 fi
352 AC_MSG_RESULT([$tool_specified])
353 fi
354 fi
355 fi
356 $3
357 fi
358 ])
359
360 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
361 # $1: variable to set
362 # $2: executable name (or list of names) to look for
363 AC_DEFUN([BASIC_PATH_PROGS],
364 [
365 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
366 ])
367
368 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
369 # $1: variable to set
370 # $2: executable name (or list of names) to look for
371 AC_DEFUN([BASIC_CHECK_TOOLS],
372 [
373 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
374 ])
375
376 # Like BASIC_PATH_PROGS but fails if no tool was found.
377 # $1: variable to set
378 # $2: executable name (or list of names) to look for
379 AC_DEFUN([BASIC_REQUIRE_PROGS],
380 [
381 BASIC_PATH_PROGS($1, $2)
382 BASIC_CHECK_NONEMPTY($1)
383 ])
384
385 # Like BASIC_SETUP_TOOL but fails if no tool was found.
386 # $1: variable to set
387 # $2: autoconf macro to call to look for the special tool
388 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
389 [
390 BASIC_SETUP_TOOL($1, [$2])
391 BASIC_CHECK_NONEMPTY($1)
392 ])
393
394 # Setup the most fundamental tools that relies on not much else to set up,
395 # but is used by much of the early bootstrap code.
396 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
397 [
398 # Start with tools that do not need have cross compilation support
399 # and can be expected to be found in the default PATH. These tools are
400 # used by configure.
401
402 # First are all the simple required tools.
403 BASIC_REQUIRE_PROGS(BASENAME, basename)
404 BASIC_REQUIRE_PROGS(BASH, bash)
405 BASIC_REQUIRE_PROGS(CAT, cat)
406 BASIC_REQUIRE_PROGS(CHMOD, chmod)
407 BASIC_REQUIRE_PROGS(CMP, cmp)
408 BASIC_REQUIRE_PROGS(COMM, comm)
409 BASIC_REQUIRE_PROGS(CP, cp)
410 BASIC_REQUIRE_PROGS(CUT, cut)
411 BASIC_REQUIRE_PROGS(DATE, date)
412 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
413 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
414 BASIC_REQUIRE_PROGS(ECHO, echo)
415 BASIC_REQUIRE_PROGS(EXPR, expr)
416 BASIC_REQUIRE_PROGS(FILE, file)
417 BASIC_REQUIRE_PROGS(FIND, find)
418 BASIC_REQUIRE_PROGS(HEAD, head)
419 BASIC_REQUIRE_PROGS(LN, ln)
420 BASIC_REQUIRE_PROGS(LS, ls)
421 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
422 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
423 BASIC_REQUIRE_PROGS(MV, mv)
424 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
425 BASIC_REQUIRE_PROGS(PRINTF, printf)
426 BASIC_REQUIRE_PROGS(RM, rm)
427 BASIC_REQUIRE_PROGS(RMDIR, rmdir)
428 BASIC_REQUIRE_PROGS(SH, sh)
429 BASIC_REQUIRE_PROGS(SORT, sort)
430 BASIC_REQUIRE_PROGS(TAIL, tail)
431 BASIC_REQUIRE_PROGS(TAR, tar)
432 BASIC_REQUIRE_PROGS(TEE, tee)
433 BASIC_REQUIRE_PROGS(TOUCH, touch)
434 BASIC_REQUIRE_PROGS(TR, tr)
435 BASIC_REQUIRE_PROGS(UNAME, uname)
436 BASIC_REQUIRE_PROGS(UNIQ, uniq)
437 BASIC_REQUIRE_PROGS(WC, wc)
438 BASIC_REQUIRE_PROGS(WHICH, which)
439 BASIC_REQUIRE_PROGS(XARGS, xargs)
440
441 # Then required tools that require some special treatment.
442 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
443 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
444 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
445 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
446 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
447
448 # Always force rm.
449 RM="$RM -f"
450
451 # pwd behaves differently on various platforms and some don't support the -L flag.
452 # Always use the bash builtin pwd to get uniform behavior.
453 THEPWDCMD=pwd
454
455 # These are not required on all platforms
456 BASIC_PATH_PROGS(CYGPATH, cygpath)
457 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
458 BASIC_PATH_PROGS(DF, df)
459 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
460 BASIC_PATH_PROGS(NICE, nice)
461 ])
462
463 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
464 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
465 [
466 # Save the current directory this script was started from
467 CURDIR="$PWD"
468
469 # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
470 # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
471 # was not available at that time.
472 REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
473 if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
474 ORIGINAL_PATH="$REWRITTEN_PATH"
475 AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
476 fi
477
478 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
479 PATH_SEP=";"
480 BASIC_CHECK_PATHS_WINDOWS
481 else
482 PATH_SEP=":"
483 fi
484 AC_SUBST(PATH_SEP)
485
486 # We get the top-level directory from the supporting wrappers.
487 AC_MSG_CHECKING([for top-level directory])
488 AC_MSG_RESULT([$TOPDIR])
489 AC_SUBST(TOPDIR)
490
491 # Save the original version of TOPDIR for string comparisons
492 ORIGINAL_TOPDIR="$TOPDIR"
493 AC_SUBST(ORIGINAL_TOPDIR)
494
495 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
496 BASIC_FIXUP_PATH(CURDIR)
497 BASIC_FIXUP_PATH(TOPDIR)
498 # SRC_ROOT is a traditional alias for TOPDIR.
499 SRC_ROOT=$TOPDIR
500
501 # Calculate a canonical version of TOPDIR for string comparisons
502 CANONICAL_TOPDIR=$TOPDIR
503 BASIC_REMOVE_SYMBOLIC_LINKS([CANONICAL_TOPDIR])
504 AC_SUBST(CANONICAL_TOPDIR)
505
506 # Locate the directory of this script.
507 AUTOCONF_DIR=$TOPDIR/common/autoconf
508 ])
509
510 # Evaluates platform specific overrides for devkit variables.
511 # $1: Name of variable
512 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
513 [
514 if test "x[$]$1" = x; then
515 eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
516 fi
517 ])
518
519 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
520 [
521 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
522 [use this devkit for compilers, tools and resources])],
523 [
524 BASIC_FIXUP_PATH([with_devkit])
525 DEVKIT_ROOT="$with_devkit"
526 # Check for a meta data info file in the root of the devkit
527 if test -f "$DEVKIT_ROOT/devkit.info"; then
528 . $DEVKIT_ROOT/devkit.info
529 # This potentially sets the following:
530 # A descriptive name of the devkit
531 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
532 # Corresponds to --with-extra-path
533 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
534 # Corresponds to --with-toolchain-path
535 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
536 # Corresponds to --with-sysroot
537 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
538
539 # Identifies the Visual Studio version in the devkit
540 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
541 # The Visual Studio include environment variable
542 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
543 # The Visual Studio lib environment variable
544 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
545 # Corresponds to --with-msvcr-dll
546 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
547 # Corresponds to --with-msvcp-dll
548 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
549 fi
550
551 AC_MSG_CHECKING([for devkit])
552 if test "x$DEVKIT_NAME" != x; then
553 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
554 else
555 AC_MSG_RESULT([$DEVKIT_ROOT])
556 fi
557
558 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
559
560 # Fallback default of just /bin if DEVKIT_PATH is not defined
561 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
562 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
563 fi
564 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
565
566 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
567 # places for backwards compatiblity.
568 if test "x$DEVKIT_SYSROOT" != x; then
569 SYSROOT="$DEVKIT_SYSROOT"
570 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
571 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
572 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
573 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
574 fi
575 ]
576 )
577
578 # You can force the sysroot if the sysroot encoded into the compiler tools
579 # is not correct.
580 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
581 [alias for --with-sysroot for backwards compatability])],
582 [SYSROOT=$with_sys_root]
583 )
584
585 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
586 [use this directory as sysroot])],
587 [SYSROOT=$with_sysroot]
588 )
589
590 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
591 [alias for --with-toolchain-path for backwards compatibility])],
592 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
593 )
594
595 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
596 [prepend these directories when searching for toolchain binaries (compilers etc)])],
597 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
598 )
599
600 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
601 [prepend these directories to the default path])],
602 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
603 )
604
605 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
606 # If a devkit has been supplied, find xcodebuild in the toolchain_path.
607 # If not, detect if Xcode is installed by running xcodebuild -version
608 # if no Xcode installed, xcodebuild exits with 1
609 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
610 if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
611 # We need to use xcodebuild in the toolchain dir provided by the user, this will
612 # fall back on the stub binary in /usr/bin/xcodebuild
613 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
614 else
615 # this should result in SYSROOT being empty, unless --with-sysroot is provided
616 # when only the command line tools are installed there are no SDKs, so headers
617 # are copied into the system frameworks
618 XCODEBUILD=
619 AC_SUBST(XCODEBUILD)
620 fi
621
622 AC_MSG_CHECKING([for sdk name])
623 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
624 [use the platform SDK of the given name. @<:@macosx@:>@])],
625 [SDKNAME=$with_sdk_name]
626 )
627 AC_MSG_RESULT([$SDKNAME])
628
629 # if toolchain path is specified then don't rely on system headers, they may not compile
630 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
631 test -z "$TOOLCHAIN_PATH" && \
632 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
633
634 if test -z "$SYSROOT"; then
635 if test -n "$XCODEBUILD"; then
636 # if we don't have system headers, use default SDK name (last resort)
637 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
638 SDKNAME=${SDKNAME:-macosx}
639 fi
640
641 if test -n "$SDKNAME"; then
642 # Call xcodebuild to determine SYSROOT
643 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | grep '^Path: ' | sed 's/Path: //'`
644 fi
645 else
646 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
647 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
648 fi
649 fi
650 else
651 # warn user if --with-sdk-name was also set
652 if test -n "$with_sdk_name"; then
653 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
654 fi
655 fi
656
657 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
658 # If no system framework headers, then SYSROOT must be set, or we won't build
659 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
660 fi
661
662 # Perform a basic sanity test
663 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
664 if test -z "$SYSROOT"; then
665 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
666 else
667 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
668 fi
669 fi
670
671 # set SDKROOT too, Xcode tools will pick it up
672 AC_SUBST(SDKROOT,$SYSROOT)
673 fi
674
675 # Prepend the extra path to the global path
676 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
677
678 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
679 # Add extra search paths on solaris for utilities like ar and as etc...
680 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
681 fi
682
683 AC_MSG_CHECKING([for sysroot])
684 AC_MSG_RESULT([$SYSROOT])
685 AC_MSG_CHECKING([for toolchain path])
686 AC_MSG_RESULT([$TOOLCHAIN_PATH])
687 AC_MSG_CHECKING([for extra path])
688 AC_MSG_RESULT([$EXTRA_PATH])
689 ])
690
691 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
692 [
693
694 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
695 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
696 [ CONF_NAME=${with_conf_name} ])
697
698 # Test from where we are running configure, in or outside of src root.
699 AC_MSG_CHECKING([where to store configuration])
700 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
701 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
702 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
703 # We are running configure from the src root.
704 # Create a default ./build/target-variant-debuglevel output root.
705 if test "x${CONF_NAME}" = x; then
706 AC_MSG_RESULT([in default location])
707 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
708 else
709 AC_MSG_RESULT([in build directory with custom name])
710 fi
711 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
712 $MKDIR -p "$OUTPUT_ROOT"
713 if test ! -d "$OUTPUT_ROOT"; then
714 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
715 fi
716 else
717 # We are running configure from outside of the src dir.
718 # Then use the current directory as output dir!
719 # If configuration is situated in normal build directory, just use the build
720 # directory name as configuration name, otherwise use the complete path.
721 if test "x${CONF_NAME}" = x; then
722 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
723 fi
724 OUTPUT_ROOT="$CURDIR"
725 AC_MSG_RESULT([in current directory])
726
727 # WARNING: This might be a bad thing to do. You need to be sure you want to
728 # have a configuration in this directory. Do some sanity checks!
729
730 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
731 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
732 # other files
733 files_present=`$LS $OUTPUT_ROOT`
734 # Configure has already touched config.log and confdefs.h in the current dir when this check
735 # is performed.
736 filtered_files=`$ECHO "$files_present" \
737 | $SED -e 's/config.log//g' \
738 -e 's/configure.log//g' \
739 -e 's/confdefs.h//g' \
740 -e 's/ //g' \
741 | $TR -d '\n'`
742 if test "x$filtered_files" != x; then
743 AC_MSG_NOTICE([Current directory is $CURDIR.])
744 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
745 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
746 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
747 AC_MSG_NOTICE([seriously mess up just about everything.])
748 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
749 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
750 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
751 fi
752 fi
753 fi
754 AC_MSG_CHECKING([what configuration name to use])
755 AC_MSG_RESULT([$CONF_NAME])
756
757 BASIC_FIXUP_PATH(OUTPUT_ROOT)
758
759 CONFIGURESUPPORT_OUTPUTDIR="$OUTPUT_ROOT/configure-support"
760 $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
761
762 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
763 AC_SUBST(CONF_NAME, $CONF_NAME)
764 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
765 AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
766
767 # The spec.gmk file contains all variables for the make system.
768 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
769 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
770 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
771 # The bootcycle-spec.gmk file contains support for boot cycle builds.
772 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
773 # The compare.sh is used to compare the build output to other builds.
774 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
775 # The generated Makefile knows where the spec.gmk is and where the source is.
776 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
777 # which will look for generated configurations
778 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
779 ])
780
781 #%%% Simple tools %%%
782
783 # Check if we have found a usable version of make
784 # $1: the path to a potential make binary (or empty)
785 # $2: the description on how we found this
786 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
787 [
788 MAKE_CANDIDATE="$1"
789 DESCRIPTION="$2"
790
791 # On Cygwin, we require a newer version of make than on other platforms
792 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
793 MAKE_VERSION_EXPR="-e 4\."
794 MAKE_REQUIRED_VERSION="4.0"
795 else
796 MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
797 MAKE_REQUIRED_VERSION="3.81"
798 fi
799
800 if test "x$MAKE_CANDIDATE" != x; then
801 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
802 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
803 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
804 if test "x$IS_GNU_MAKE" = x; then
805 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
806 else
807 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
808 if test "x$IS_MODERN_MAKE" = x; then
809 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
810 else
811 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
812 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
813 MAKE_EXPECTED_ENV='cygwin'
814 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
815 MAKE_EXPECTED_ENV='msys'
816 else
817 AC_MSG_ERROR([Unknown Windows environment])
818 fi
819 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
820 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
821 else
822 # Not relevant for non-Windows
823 IS_MAKE_CORRECT_ENV=true
824 fi
825 if test "x$IS_MAKE_CORRECT_ENV" = x; then
826 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
827 else
828 FOUND_MAKE=$MAKE_CANDIDATE
829 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
830 fi
831 fi
832 fi
833 fi
834 ])
835
836 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
837 [
838 # Check if make supports the output sync option and if so, setup using it.
839 AC_MSG_CHECKING([if make --output-sync is supported])
840 if $MAKE --version -O > /dev/null 2>&1; then
841 OUTPUT_SYNC_SUPPORTED=true
842 AC_MSG_RESULT([yes])
843 AC_MSG_CHECKING([for output-sync value])
844 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
845 [set make output sync type if supported by make. @<:@recurse@:>@])],
846 [OUTPUT_SYNC=$with_output_sync])
847 if test "x$OUTPUT_SYNC" = "x"; then
848 OUTPUT_SYNC=none
849 fi
850 AC_MSG_RESULT([$OUTPUT_SYNC])
851 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
852 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
853 fi
854 else
855 OUTPUT_SYNC_SUPPORTED=false
856 AC_MSG_RESULT([no])
857 fi
858 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
859 AC_SUBST(OUTPUT_SYNC)
860 ])
861
862 # Goes looking for a usable version of GNU make.
863 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
864 [
865 BASIC_SETUP_TOOL([MAKE],
866 [
867 # Try our hardest to locate a correct version of GNU make
868 AC_PATH_PROGS(CHECK_GMAKE, gmake)
869 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
870
871 if test "x$FOUND_MAKE" = x; then
872 AC_PATH_PROGS(CHECK_MAKE, make)
873 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
874 fi
875
876 if test "x$FOUND_MAKE" = x; then
877 if test "x$TOOLCHAIN_PATH" != x; then
878 # We have a toolchain path, check that as well before giving up.
879 OLD_PATH=$PATH
880 PATH=$TOOLCHAIN_PATH:$PATH
881 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
882 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
883 if test "x$FOUND_MAKE" = x; then
884 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
885 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
886 fi
887 PATH=$OLD_PATH
888 fi
889 fi
890
891 if test "x$FOUND_MAKE" = x; then
892 AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
893 fi
894 ],[
895 # If MAKE was set by user, verify the version
896 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
897 if test "x$FOUND_MAKE" = x; then
898 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
899 fi
900 ])
901
902 MAKE=$FOUND_MAKE
903 AC_SUBST(MAKE)
904 AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
905
906 BASIC_CHECK_MAKE_OUTPUT_SYNC
907 ])
908
909 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
910 [
911 # Test if find supports -delete
912 AC_MSG_CHECKING([if find supports -delete])
913 FIND_DELETE="-delete"
914
915 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
916
917 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
918
919 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
920 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
921 # No, it does not.
922 rm $DELETEDIR/TestIfFindSupportsDelete
923 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
924 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
925 FIND_DELETE="-print | xargs rm"
926 else
927 FIND_DELETE="-exec rm \{\} \+"
928 fi
929 AC_MSG_RESULT([no])
930 else
931 AC_MSG_RESULT([yes])
932 fi
933 rmdir $DELETEDIR
934 AC_SUBST(FIND_DELETE)
935 ])
936
937 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
938 [
939 BASIC_CHECK_GNU_MAKE
940
941 BASIC_CHECK_FIND_DELETE
942
943 # These tools might not be installed by default,
944 # need hint on how to install them.
945 BASIC_REQUIRE_PROGS(UNZIP, unzip)
946 BASIC_REQUIRE_PROGS(ZIP, zip)
947
948 # Non-required basic tools
949
950 BASIC_PATH_PROGS(LDD, ldd)
951 if test "x$LDD" = "x"; then
952 # List shared lib dependencies is used for
953 # debug output and checking for forbidden dependencies.
954 # We can build without it.
955 LDD="true"
956 fi
957 BASIC_PATH_PROGS(OTOOL, otool)
958 if test "x$OTOOL" = "x"; then
959 OTOOL="true"
960 fi
961 BASIC_PATH_PROGS(READELF, [greadelf readelf])
962 BASIC_PATH_PROGS(HG, hg)
963 BASIC_PATH_PROGS(STAT, stat)
964 BASIC_PATH_PROGS(TIME, time)
965 BASIC_PATH_PROGS(PATCH, [gpatch patch])
966 # Check if it's GNU time
967 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
968 if test "x$IS_GNU_TIME" != x; then
969 IS_GNU_TIME=yes
970 else
971 IS_GNU_TIME=no
972 fi
973 AC_SUBST(IS_GNU_TIME)
974
975 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
976 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
977 BASIC_REQUIRE_PROGS(XATTR, xattr)
978 BASIC_PATH_PROGS(CODESIGN, codesign)
979 if test "x$CODESIGN" != "x"; then
980 # Verify that the openjdk_codesign certificate is present
981 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
982 rm -f codesign-testfile
983 touch codesign-testfile
984 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
985 rm -f codesign-testfile
986 if test "x$CODESIGN" = x; then
987 AC_MSG_RESULT([no])
988 else
989 AC_MSG_RESULT([yes])
990 fi
991 fi
992 BASIC_REQUIRE_PROGS(SETFILE, SetFile)
993 fi
994 ])
995
996 # Check if build directory is on local disk. If not possible to determine,
997 # we prefer to claim it's local.
998 # Argument 1: directory to test
999 # Argument 2: what to do if it is on local disk
1000 # Argument 3: what to do otherwise (remote disk or failure)
1001 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1002 [
1003 # df -l lists only local disks; if the given directory is not found then
1004 # a non-zero exit code is given
1005 if test "x$DF" = x; then
1006 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1007 # msys does not have df; use Windows "net use" instead.
1008 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1009 if test "x$IS_NETWORK_DISK" = x; then
1010 $2
1011 else
1012 $3
1013 fi
1014 else
1015 # No df here, say it's local
1016 $2
1017 fi
1018 else
1019 if $DF -l $1 > /dev/null 2>&1; then
1020 $2
1021 else
1022 $3
1023 fi
1024 fi
1025 ])
1026
1027 # Check that source files have basic read permissions set. This might
1028 # not be the case in cygwin in certain conditions.
1029 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1030 [
1031 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1032 file_to_test="$SRC_ROOT/LICENSE"
1033 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1034 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1035 fi
1036 fi
1037 ])
1038
1039 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1040 [
1041 # Did user specify any unknown variables?
1042 BASIC_CHECK_LEFTOVER_OVERRIDDEN
1043
1044 AC_MSG_CHECKING([if build directory is on local disk])
1045 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
1046 [OUTPUT_DIR_IS_LOCAL="yes"],
1047 [OUTPUT_DIR_IS_LOCAL="no"])
1048 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1049
1050 BASIC_CHECK_SRC_PERMS
1051
1052 # Check if the user has any old-style ALT_ variables set.
1053 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1054
1055 # Before generating output files, test if they exist. If they do, this is a reconfigure.
1056 # Since we can't properly handle the dependencies for this, warn the user about the situation
1057 if test -e $OUTPUT_ROOT/spec.gmk; then
1058 IS_RECONFIGURE=yes
1059 else
1060 IS_RECONFIGURE=no
1061 fi
1062 ])
1063
1064 # Check for support for specific options in bash
1065 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1066 [
1067 # Test if bash supports pipefail.
1068 AC_MSG_CHECKING([if bash supports pipefail])
1069 if ${BASH} -c 'set -o pipefail'; then
1070 BASH_ARGS="$BASH_ARGS -o pipefail"
1071 AC_MSG_RESULT([yes])
1072 else
1073 AC_MSG_RESULT([no])
1074 fi
1075
1076 AC_MSG_CHECKING([if bash supports errexit (-e)])
1077 if ${BASH} -e -c 'true'; then
1078 BASH_ARGS="$BASH_ARGS -e"
1079 AC_MSG_RESULT([yes])
1080 else
1081 AC_MSG_RESULT([no])
1082 fi
1083
1084 AC_SUBST(BASH_ARGS)
1085 ])
1086
1087 ################################################################################
1088 #
1089 # Default make target
1090 #
1091 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1092 [
1093 AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1094 [set the default make target @<:@exploded-image@:>@])])
1095 if test "x$with_default_make_target" = "x" \
1096 || test "x$with_default_make_target" = "xyes"; then
1097 DEFAULT_MAKE_TARGET="exploded-image"
1098 elif test "x$with_default_make_target" = "xno"; then
1099 AC_MSG_ERROR([--without-default-make-target is not a valid option])
1100 else
1101 DEFAULT_MAKE_TARGET="$with_default_make_target"
1102 fi
1103
1104 AC_SUBST(DEFAULT_MAKE_TARGET)
1105 ])
1106
1107 # Code to run after AC_OUTPUT
1108 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1109 [
1110 # Try to move config.log (generated by autoconf) to the configure-support directory.
1111 if test -e ./config.log; then
1112 $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1113 fi
1114
1115 # Rotate our log file (configure.log)
1116 if test -e "$OUTPUT_ROOT/configure.log.old"; then
1117 $RM -f "$OUTPUT_ROOT/configure.log.old"
1118 fi
1119 if test -e "$OUTPUT_ROOT/configure.log"; then
1120 $MV -f "$OUTPUT_ROOT/configure.log" "$OUTPUT_ROOT/configure.log.old" 2> /dev/null
1121 fi
1122
1123 # Move configure.log from current directory to the build output root
1124 if test -e ./configure.log; then
1125 echo found it
1126 $MV -f ./configure.log "$OUTPUT_ROOT/configure.log" 2> /dev/null
1127 fi
1128
1129 # Make the compare script executable
1130 $CHMOD +x $OUTPUT_ROOT/compare.sh
1131 ])