1 #
   2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 AC_DEFUN([BPERF_CHECK_CORES],
  27 [
  28   AC_MSG_CHECKING([for number of cores])
  29   NUM_CORES=1
  30   FOUND_CORES=no
  31 
  32   if test -f /proc/cpuinfo; then
  33     # Looks like a Linux (or cygwin) system
  34     NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`
  35     FOUND_CORES=yes
  36   elif test -x /usr/sbin/psrinfo; then
  37     # Looks like a Solaris system
  38     NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
  39     FOUND_CORES=yes
  40   elif test -x /usr/sbin/system_profiler; then
  41     # Looks like a MacOSX system
  42     NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`
  43     FOUND_CORES=yes
  44   elif test -x /sbin/sysctl; then
  45     # Looks like a BSD system
  46     NUM_CORES=`/sbin/sysctl -n hw.ncpu`
  47     FOUND_CORES=yes
  48   elif test "x$OPENJDK_BUILD_OS" = xaix ; then
  49     NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`
  50     FOUND_CORES=yes
  51   elif test -n "$NUMBER_OF_PROCESSORS"; then
  52     # On windows, look in the env
  53     NUM_CORES=$NUMBER_OF_PROCESSORS
  54     FOUND_CORES=yes
  55   fi
  56 
  57   if test "x$FOUND_CORES" = xyes; then
  58     AC_MSG_RESULT([$NUM_CORES])
  59   else
  60     AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
  61     AC_MSG_WARN([This will disable all parallelism from build!])
  62   fi
  63 ])
  64 
  65 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
  66 [
  67   AC_MSG_CHECKING([for memory size])
  68   # Default to 1024 MB
  69   MEMORY_SIZE=1024
  70   FOUND_MEM=no
  71 
  72   if test -f /proc/meminfo; then
  73     # Looks like a Linux (or cygwin) system
  74     MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
  75     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
  76     FOUND_MEM=yes
  77   elif test -x /usr/sbin/prtconf; then
  78     # Looks like a Solaris or AIX system
  79     MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
  80     FOUND_MEM=yes
  81   elif test -x /usr/sbin/system_profiler; then
  82     # Looks like a MacOSX system
  83     MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`
  84     MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
  85     FOUND_MEM=yes
  86   elif test -x /sbin/sysctl; then
  87     # Looks like a BSD system
  88     MEMORY_SIZE=`/sbin/sysctl -n hw.physmem`
  89     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
  90     FOUND_MEM=yes
  91   elif test "x$OPENJDK_BUILD_OS" = xwindows; then
  92     # Windows, but without cygwin
  93     MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
  94     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
  95     FOUND_MEM=yes
  96   fi
  97 
  98   if test "x$FOUND_MEM" = xyes; then
  99     AC_MSG_RESULT([$MEMORY_SIZE MB])
 100   else
 101     AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
 102     AC_MSG_WARN([This might seriously impact build performance!])
 103   fi
 104 ])
 105 
 106 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
 107 [
 108   # How many cores do we have on this build system?
 109   AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
 110       [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
 111   if test "x$with_num_cores" = x; then
 112     # The number of cores were not specified, try to probe them.
 113     BPERF_CHECK_CORES
 114   else
 115     NUM_CORES=$with_num_cores
 116   fi
 117   AC_SUBST(NUM_CORES)
 118 ])
 119 
 120 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
 121 [
 122   # How much memory do we have on this build system?
 123   AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
 124       [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
 125   if test "x$with_memory_size" = x; then
 126     # The memory size was not specified, try to probe it.
 127     BPERF_CHECK_MEMORY_SIZE
 128   else
 129     MEMORY_SIZE=$with_memory_size
 130   fi
 131   AC_SUBST(MEMORY_SIZE)
 132 ])
 133 
 134 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
 135 [
 136   # Provide a decent default number of parallel jobs for make depending on
 137   # number of cores, amount of memory and machine architecture.
 138   AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
 139       [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
 140   if test "x$with_jobs" = x; then
 141     # Number of jobs was not specified, calculate.
 142     AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
 143     # Approximate memory in GB.
 144     memory_gb=`expr $MEMORY_SIZE / 1024`
 145     # Pick the lowest of memory in gb and number of cores.
 146     if test "$memory_gb" -lt "$NUM_CORES"; then
 147       JOBS="$memory_gb"
 148     else
 149       JOBS="$NUM_CORES"
 150     fi
 151     if test "$JOBS" -eq "0"; then
 152       JOBS=1
 153     fi
 154     AC_MSG_RESULT([$JOBS])
 155   else
 156     JOBS=$with_jobs
 157   fi
 158   AC_SUBST(JOBS)
 159 ])
 160 
 161 AC_DEFUN_ONCE([BPERF_SETUP_TEST_JOBS],
 162 [
 163   # The number of test jobs will be chosen automatically if TEST_JOBS is 0
 164   AC_ARG_WITH(test-jobs, [AS_HELP_STRING([--with-test-jobs],
 165       [number of parallel tests jobs to run @<:@based on build jobs@:>@])])
 166   if test "x$with_test_jobs" = x; then
 167       TEST_JOBS=0
 168   else
 169       TEST_JOBS=$with_test_jobs
 170   fi
 171   AC_SUBST(TEST_JOBS)
 172 ])
 173 
 174 AC_DEFUN([BPERF_SETUP_CCACHE],
 175 [
 176   AC_ARG_ENABLE([ccache],
 177       [AS_HELP_STRING([--enable-ccache],
 178       [enable using ccache to speed up recompilations @<:@disabled@:>@])])
 179 
 180   CCACHE=
 181   CCACHE_STATUS=
 182   AC_MSG_CHECKING([is ccache enabled])
 183   if test "x$enable_ccache" = xyes; then
 184     if test "x$TOOLCHAIN_TYPE" = "xgcc" -o "x$TOOLCHAIN_TYPE" = "xclang"; then
 185       AC_MSG_RESULT([yes])
 186       OLD_PATH="$PATH"
 187       if test "x$TOOLCHAIN_PATH" != x; then
 188         PATH=$TOOLCHAIN_PATH:$PATH
 189       fi
 190       BASIC_REQUIRE_PROGS(CCACHE, ccache)
 191       PATH="$OLD_PATH"
 192       CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
 193       CCACHE_STATUS="Active ($CCACHE_VERSION)"
 194     else
 195       AC_MSG_RESULT([no])
 196       AC_MSG_WARN([ccache is not supported with toolchain type $TOOLCHAIN_TYPE])
 197     fi
 198   elif test "x$enable_ccache" = xno; then
 199     AC_MSG_RESULT([no, explicitly disabled])
 200     CCACHE_STATUS="Disabled"
 201   elif test "x$enable_ccache" = x; then
 202     AC_MSG_RESULT([no])
 203   else
 204     AC_MSG_RESULT([unknown])
 205     AC_MSG_ERROR([--enable-ccache does not accept any parameters])
 206   fi
 207   AC_SUBST(CCACHE)
 208 
 209   AC_ARG_WITH([ccache-dir],
 210       [AS_HELP_STRING([--with-ccache-dir],
 211       [where to store ccache files @<:@~/.ccache@:>@])])
 212 
 213   if test "x$with_ccache_dir" != x; then
 214     # When using a non home ccache directory, assume the use is to share ccache files
 215     # with other users. Thus change the umask.
 216     SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
 217     if test "x$CCACHE" = x; then
 218       AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
 219     fi
 220   fi
 221 
 222   if test "x$CCACHE" != x; then
 223     BPERF_SETUP_CCACHE_USAGE
 224   fi
 225 ])
 226 
 227 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
 228 [
 229   if test "x$CCACHE" != x; then
 230     if test "x$USE_PRECOMPILED_HEADER" = "x1"; then
 231       HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
 232           $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
 233       if test "x$HAS_BAD_CCACHE" != "x"; then
 234         AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
 235       fi
 236       AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
 237       CCACHE_PRECOMP_FLAG="-fpch-preprocess"
 238       PUSHED_FLAGS="$CXXFLAGS"
 239       CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
 240       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
 241       CXXFLAGS="$PUSHED_FLAGS"
 242       if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
 243         AC_MSG_RESULT([yes])
 244         CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
 245         AC_SUBST(CFLAGS_CCACHE)
 246         CCACHE_SLOPPINESS=pch_defines,time_macros
 247       else
 248         AC_MSG_RESULT([no])
 249         AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
 250       fi
 251     fi
 252 
 253     CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
 254         CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
 255 
 256     if test "x$SET_CCACHE_DIR" != x; then
 257       mkdir -p $CCACHE_DIR > /dev/null 2>&1
 258       chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
 259     fi
 260   fi
 261 ])
 262 
 263 ################################################################################
 264 #
 265 # Runs icecc-create-env once and prints the error if it fails
 266 #
 267 # $1: arguments to icecc-create-env
 268 # $2: log file
 269 #
 270 AC_DEFUN([BPERF_RUN_ICECC_CREATE_ENV],
 271 [
 272   cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
 273       && ${ICECC_CREATE_ENV} $1 > $2 2>&1
 274   if test "$?" != "0"; then
 275     AC_MSG_NOTICE([icecc-create-env output:])
 276     cat $2
 277     AC_MSG_ERROR([Failed to create icecc compiler environment])
 278   fi
 279 ])
 280 
 281 ################################################################################
 282 #
 283 # Optionally enable distributed compilation of native code using icecc/icecream
 284 #
 285 AC_DEFUN([BPERF_SETUP_ICECC],
 286 [
 287   AC_ARG_ENABLE([icecc], [AS_HELP_STRING([--enable-icecc],
 288       [enable distribted compilation of native code using icecc/icecream @<:@disabled@:>@])])
 289 
 290   if test "x${enable_icecc}" = "xyes"; then
 291     BASIC_REQUIRE_PROGS(ICECC_CMD, icecc)
 292     old_path="$PATH"
 293 
 294     # Look for icecc-create-env in some known places
 295     PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
 296     BASIC_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
 297     # Use icecc-create-env to create a minimal compilation environment that can
 298     # be sent to the other hosts in the icecream cluster.
 299     icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
 300     ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
 301     # Older versions of icecc does not have the --gcc parameter
 302     if ${ICECC_CREATE_ENV} | $GREP -q -e --gcc; then
 303       icecc_gcc_arg="--gcc"
 304     fi
 305     if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
 306       BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${CC} ${CXX}], \
 307           ${icecc_create_env_log})
 308     elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
 309       # For clang, the icecc compilerwrapper is needed. It usually resides next
 310       # to icecc-create-env.
 311       BASIC_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
 312       BPERF_RUN_ICECC_CREATE_ENV([--clang ${CC} ${ICECC_WRAPPER}], ${icecc_create_env_log})
 313     else
 314       AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
 315     fi
 316     PATH="$old_path"
 317     # The bundle with the compiler gets a name based on checksums. Parse log file
 318     # to find it.
 319     ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
 320     ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
 321     if test ! -f ${ICECC_ENV_BUNDLE}; then
 322       AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
 323     fi
 324     AC_MSG_CHECKING([for icecc build environment for target compiler])
 325     AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
 326     ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
 327 
 328     if test "x${COMPILE_TYPE}" = "xcross"; then
 329       # If cross compiling, create a separate env package for the build compiler
 330       # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
 331       icecc_create_env_log_build="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env_build.log"
 332       if test "x${BUILD_CC##*/}" = "xgcc" ||  test "x${BUILD_CC##*/}" = "xcc"; then
 333         BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${BUILD_CC} ${BUILD_CXX}], \
 334             ${icecc_create_env_log_build})
 335       elif test "x${BUILD_CC##*/}" = "xclang"; then
 336         BPERF_RUN_ICECC_CREATE_ENV([--clang ${BUILD_CC} ${ICECC_WRAPPER}], ${icecc_create_env_log_build})
 337       else
 338         AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
 339       fi
 340       ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log_build}`"
 341       ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
 342       if test ! -f ${ICECC_ENV_BUNDLE}; then
 343         AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
 344       fi
 345       AC_MSG_CHECKING([for icecc build environment for build compiler])
 346       AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
 347       BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
 348           ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
 349     else
 350       BUILD_ICECC="${ICECC}"
 351     fi
 352     AC_SUBST(ICECC)
 353     AC_SUBST(BUILD_ICECC)
 354   fi
 355 ])
 356 
 357 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
 358 [
 359 
 360   ###############################################################################
 361   #
 362   # Can the C/C++ compiler use precompiled headers?
 363   #
 364   AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
 365       [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
 366       [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
 367 
 368   USE_PRECOMPILED_HEADER=1
 369   AC_MSG_CHECKING([If precompiled header is enabled])
 370   if test "x$ENABLE_PRECOMPH" = xno; then
 371     AC_MSG_RESULT([no, forced])
 372     USE_PRECOMPILED_HEADER=0
 373   elif test "x$ICECC" != "x"; then
 374     AC_MSG_RESULT([no, does not work effectively with icecc])
 375     USE_PRECOMPILED_HEADER=0
 376   else
 377     AC_MSG_RESULT([yes])
 378   fi
 379 
 380   if test "x$ENABLE_PRECOMPH" = xyes; then
 381     # Check that the compiler actually supports precomp headers.
 382     if test "x$TOOLCHAIN_TYPE" = xgcc; then
 383       AC_MSG_CHECKING([that precompiled headers work])
 384       echo "int alfa();" > conftest.h
 385       $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 386       if test ! -f conftest.hpp.gch; then
 387         USE_PRECOMPILED_HEADER=0
 388         AC_MSG_RESULT([no])
 389       else
 390         AC_MSG_RESULT([yes])
 391       fi
 392       rm -f conftest.h conftest.hpp.gch
 393     fi
 394   fi
 395 
 396   AC_SUBST(USE_PRECOMPILED_HEADER)
 397 ])
 398 
 399 
 400 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
 401 [
 402   AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
 403       [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
 404 
 405   if test "x$with_sjavac_server_java" != x; then
 406     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
 407     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
 408     if test "x$FOUND_VERSION" = x; then
 409       AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
 410     fi
 411   else
 412     SJAVAC_SERVER_JAVA="$JAVA"
 413   fi
 414   AC_SUBST(SJAVAC_SERVER_JAVA)
 415 
 416   if test "$MEMORY_SIZE" -gt "3000"; then
 417     ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
 418     if test "$JVM_ARG_OK" = true; then
 419       JVM_64BIT=true
 420       JVM_ARG_OK=false
 421     fi
 422   fi
 423 
 424   MX_VALUE=`expr $MEMORY_SIZE / 2`
 425   if test "$JVM_64BIT" = true; then
 426     # Set ms lower than mx since more than one instance of the server might
 427     # get launched at the same time before they figure out which instance won.
 428     MS_VALUE=512
 429     if test "$MX_VALUE" -gt "2048"; then
 430       MX_VALUE=2048
 431     fi
 432   else
 433     MS_VALUE=256
 434     if test "$MX_VALUE" -gt "1500"; then
 435       MX_VALUE=1500
 436     fi
 437   fi
 438   if test "$MX_VALUE" -lt "512"; then
 439     MX_VALUE=512
 440   fi
 441   ADD_JVM_ARG_IF_OK([-Xms${MS_VALUE}M -Xmx${MX_VALUE}M],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
 442   AC_SUBST(SJAVAC_SERVER_JAVA_FLAGS)
 443 
 444   AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
 445       [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
 446       [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC="no"])
 447   if test "x$JVM_ARG_OK" = "xfalse"; then
 448     AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling sjavac])
 449     ENABLE_SJAVAC="no"
 450   fi
 451   AC_MSG_CHECKING([whether to use sjavac])
 452   AC_MSG_RESULT([$ENABLE_SJAVAC])
 453   AC_SUBST(ENABLE_SJAVAC)
 454 
 455   AC_ARG_ENABLE([javac-server], [AS_HELP_STRING([--disable-javac-server],
 456       [disable javac server @<:@enabled@:>@])],
 457       [ENABLE_JAVAC_SERVER="${enableval}"], [ENABLE_JAVAC_SERVER="yes"])
 458   if test "x$JVM_ARG_OK" = "xfalse"; then
 459     AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling javac server])
 460     ENABLE_JAVAC_SERVER="no"
 461   fi
 462   AC_MSG_CHECKING([whether to use javac server])
 463   AC_MSG_RESULT([$ENABLE_JAVAC_SERVER])
 464   AC_SUBST(ENABLE_JAVAC_SERVER)
 465 
 466   if test "x$ENABLE_JAVAC_SERVER" = "xyes" || "x$ENABLE_SJAVAC" = "xyes"; then
 467     # When using a server javac, the small client instances do not need much
 468     # resources.
 469     JAVA_FLAGS_JAVAC="$JAVA_FLAGS_SMALL"
 470   fi
 471 ])