1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Create a function/macro that takes a series of named arguments. The call is
27 # similar to AC_DEFUN, but the setup of the function looks like this:
28 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
29 # ... do something
30 # AC_MSG_NOTICE([Value of BAR is ARG_BAR])
31 # ])
32 # A star (*) in front of a named argument means that it is required and it's
33 # presence will be verified. To pass e.g. the first value as a normal indexed
34 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
35 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
36 # "ARG_FOO".
37 #
38 # The generated function can be called like this:
39 # MYFUNC(FOO: [foo-val], BAR:
40 # [
41 # $ECHO hello world
42 # ])
43 #
44 #
45 # Argument 1: Name of the function to define
46 # Argument 2: List of legal named arguments, with a * prefix for required arguments
47 # Argument 3: Argument array to treat as named, typically $@
48 # Argument 4: The main function body
49 AC_DEFUN([BASIC_DEFUN_NAMED],
50 [
51 AC_DEFUN($1, [
52 m4_foreach(arg, m4_split($2), [
53 m4_if(m4_bregexp(arg, [^\*]), -1,
54 [
55 m4_set_add(legal_named_args, arg)
56 ],
57 [
58 m4_set_add(legal_named_args, m4_substr(arg, 1))
59 m4_set_add(required_named_args, m4_substr(arg, 1))
60 ]
61 )
62 ])
63
64 m4_foreach([arg], [$3], [
65 m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
66 m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
67 m4_set_remove(required_named_args, arg_name)
68 m4_set_remove(legal_named_args, arg_name)
69 m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
70 m4_set_add(defined_args, arg_name)
71 m4_undefine([arg_name])
72 ])
73 m4_set_empty(required_named_args, [], [
74 AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
75 ])
76 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
77 m4_pushdef([ARG_][]arg, [])
78 m4_set_add(defined_args, arg)
79 ])
80 m4_set_delete(legal_named_args)
81 m4_set_delete(required_named_args)
82
83 # Execute function body
84 $4
85
86 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
87 m4_popdef([ARG_][]arg)
88 ])
89
90 m4_set_delete(defined_args)
91 ])
92 ])
93
94 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
95 # If so, then append $1 to $2 \
96 # Also set JVM_ARG_OK to true/false depending on outcome.
97 AC_DEFUN([ADD_JVM_ARG_IF_OK],
98 [
99 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
100 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
101 OUTPUT=`$3 $1 -version 2>&1`
102 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
103 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
104 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
105 $2="[$]$2 $1"
106 JVM_ARG_OK=true
107 else
108 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
109 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
110 JVM_ARG_OK=false
111 fi
112 ])
113
114 # Appends a string to a path variable, only adding the : when needed.
115 AC_DEFUN([BASIC_APPEND_TO_PATH],
116 [
117 if test "x$2" != x; then
118 if test "x[$]$1" = x; then
119 $1="$2"
120 else
121 $1="[$]$1:$2"
122 fi
123 fi
124 ])
125
126 # Prepends a string to a path variable, only adding the : when needed.
127 AC_DEFUN([BASIC_PREPEND_TO_PATH],
128 [
129 if test "x$2" != x; then
130 if test "x[$]$1" = x; then
131 $1="$2"
132 else
133 $1="$2:[$]$1"
134 fi
135 fi
136 ])
137
138 # This will make sure the given variable points to a full and proper
139 # path. This means:
140 # 1) There will be no spaces in the path. On unix platforms,
141 # spaces in the path will result in an error. On Windows,
142 # the path will be rewritten using short-style to be space-free.
143 # 2) The path will be absolute, and it will be in unix-style (on
144 # cygwin).
145 # $1: The name of the variable to fix
146 AC_DEFUN([BASIC_FIXUP_PATH],
147 [
148 # Only process if variable expands to non-empty
149
150 if test "x[$]$1" != x; then
151 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
152 BASIC_FIXUP_PATH_CYGWIN($1)
153 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
154 BASIC_FIXUP_PATH_MSYS($1)
155 else
156 # We're on a unix platform. Hooray! :)
157 path="[$]$1"
158 has_space=`$ECHO "$path" | $GREP " "`
159 if test "x$has_space" != x; then
160 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
161 AC_MSG_ERROR([Spaces are not allowed in this path.])
162 fi
163
164 # Use eval to expand a potential ~
165 eval path="$path"
166 if test ! -f "$path" && test ! -d "$path"; then
167 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
168 fi
169
170 if test -d "$path"; then
171 $1="`cd "$path"; $THEPWDCMD -L`"
172 else
173 dir="`$DIRNAME "$path"`"
174 base="`$BASENAME "$path"`"
175 $1="`cd "$dir"; $THEPWDCMD -L`/$base"
176 fi
177 fi
178 fi
179 ])
180
181 # This will make sure the given variable points to a executable
182 # with a full and proper path. This means:
183 # 1) There will be no spaces in the path. On unix platforms,
184 # spaces in the path will result in an error. On Windows,
185 # the path will be rewritten using short-style to be space-free.
186 # 2) The path will be absolute, and it will be in unix-style (on
187 # cygwin).
188 # Any arguments given to the executable is preserved.
189 # If the input variable does not have a directory specification, then
190 # it need to be in the PATH.
191 # $1: The name of the variable to fix
192 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
193 [
194 # Only process if variable expands to non-empty
195
196 if test "x[$]$1" != x; then
197 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
198 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
199 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
200 BASIC_FIXUP_EXECUTABLE_MSYS($1)
201 else
202 # We're on a unix platform. Hooray! :)
203 # First separate the path from the arguments. This will split at the first
204 # space.
205 complete="[$]$1"
206 path="${complete%% *}"
207 tmp="$complete EOL"
208 arguments="${tmp#* }"
209
210 # Cannot rely on the command "which" here since it doesn't always work.
211 is_absolute_path=`$ECHO "$path" | $GREP ^/`
212 if test -z "$is_absolute_path"; then
213 # Path to executable is not absolute. Find it.
214 IFS_save="$IFS"
215 IFS=:
216 for p in $PATH; do
217 if test -f "$p/$path" && test -x "$p/$path"; then
218 new_path="$p/$path"
219 break
220 fi
221 done
222 IFS="$IFS_save"
223 else
224 # This is an absolute path, we can use it without further modifications.
225 new_path="$path"
226 fi
227
228 if test "x$new_path" = x; then
229 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
230 has_space=`$ECHO "$complete" | $GREP " "`
231 if test "x$has_space" != x; then
232 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
233 fi
234 AC_MSG_ERROR([Cannot locate the the path of $1])
235 fi
236 fi
237
238 # Now join together the path and the arguments once again
239 if test "x$arguments" != xEOL; then
240 new_complete="$new_path ${arguments% *}"
241 else
242 new_complete="$new_path"
243 fi
244
245 if test "x$complete" != "x$new_complete"; then
246 $1="$new_complete"
247 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
248 fi
249 fi
250 ])
251
252 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
253 [
254 if test "x$OPENJDK_BUILD_OS" != xwindows; then
255 # Follow a chain of symbolic links. Use readlink
256 # where it exists, else fall back to horribly
257 # complicated shell code.
258 if test "x$READLINK_TESTED" != yes; then
259 # On MacOSX there is a readlink tool with a different
260 # purpose than the GNU readlink tool. Check the found readlink.
261 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
262 if test "x$ISGNU" = x; then
263 # A readlink that we do not know how to use.
264 # Are there other non-GNU readlinks out there?
265 READLINK_TESTED=yes
266 READLINK=
267 fi
268 fi
269
270 if test "x$READLINK" != x; then
271 $1=`$READLINK -f [$]$1`
272 else
273 # Save the current directory for restoring afterwards
274 STARTDIR=$PWD
275 COUNTER=0
276 sym_link_dir=`$DIRNAME [$]$1`
277 sym_link_file=`$BASENAME [$]$1`
278 cd $sym_link_dir
279 # Use -P flag to resolve symlinks in directories.
280 cd `$THEPWDCMD -P`
281 sym_link_dir=`$THEPWDCMD -P`
282 # Resolve file symlinks
283 while test $COUNTER -lt 20; do
284 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
285 if test "x$ISLINK" == x; then
286 # This is not a symbolic link! We are done!
287 break
288 fi
289 # Again resolve directory symlinks since the target of the just found
290 # link could be in a different directory
291 cd `$DIRNAME $ISLINK`
292 sym_link_dir=`$THEPWDCMD -P`
293 sym_link_file=`$BASENAME $ISLINK`
294 let COUNTER=COUNTER+1
295 done
296 cd $STARTDIR
297 $1=$sym_link_dir/$sym_link_file
298 fi
299 fi
300 ])
301
302 # Register a --with argument but mark it as deprecated
303 # $1: The name of the with argument to deprecate, not including --with-
304 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
305 [
306 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
307 [Deprecated. Option is kept for backwards compatibility and is ignored])],
308 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
309 ])
310
311 # Register a --enable argument but mark it as deprecated
312 # $1: The name of the with argument to deprecate, not including --enable-
313 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
314 # $3: Messages to user.
315 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
316 [
317 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
318 [Deprecated. Option is kept for backwards compatibility and is ignored])])
319 if test "x$enable_$2" != x; then
320 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
321
322 if test "x$3" != x; then
323 AC_MSG_WARN([$3])
324 fi
325
326 fi
327 ])
328
329 AC_DEFUN_ONCE([BASIC_INIT],
330 [
331 # Save the original command line. This is passed to us by the wrapper configure script.
332 AC_SUBST(CONFIGURE_COMMAND_LINE)
333 # Save the path variable before it gets changed
334 ORIGINAL_PATH="$PATH"
335 AC_SUBST(ORIGINAL_PATH)
336 DATE_WHEN_CONFIGURED=`LANG=C date`
337 AC_SUBST(DATE_WHEN_CONFIGURED)
338 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
339 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
340 ])
341
342 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
343 # $1: variable to check
344 AC_DEFUN([BASIC_CHECK_NONEMPTY],
345 [
346 if test "x[$]$1" = x; then
347 AC_MSG_ERROR([Could not find required tool for $1])
348 fi
349 ])
350
351 # Check that there are no unprocessed overridden variables left.
352 # If so, they are an incorrect argument and we will exit with an error.
353 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
354 [
355 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
356 # Replace the separating ! with spaces before presenting for end user.
357 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
358 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
359 fi
360 ])
361
362 # Setup a tool for the given variable. If correctly specified by the user,
363 # use that value, otherwise search for the tool using the supplied code snippet.
364 # $1: variable to set
365 # $2: code snippet to call to look for the tool
366 # $3: code snippet to call if variable was used to find tool
367 AC_DEFUN([BASIC_SETUP_TOOL],
368 [
369 # Publish this variable in the help.
370 AC_ARG_VAR($1, [Override default value for $1])
371
372 if [[ -z "${$1+x}" ]]; then
373 # The variable is not set by user, try to locate tool using the code snippet
374 $2
375 else
376 # The variable is set, but is it from the command line or the environment?
377
378 # Try to remove the string !$1! from our list.
379 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
380 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
381 # If it failed, the variable was not from the command line. Ignore it,
382 # but warn the user (except for BASH, which is always set by the calling BASH).
383 if test "x$1" != xBASH; then
384 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
385 fi
386 # Try to locate tool using the code snippet
387 $2
388 else
389 # If it succeeded, then it was overridden by the user. We will use it
390 # for the tool.
391
392 # First remove it from the list of overridden variables, so we can test
393 # for unknown variables in the end.
394 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
395
396 # Check if we try to supply an empty value
397 if test "x[$]$1" = x; then
398 AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
399 AC_MSG_CHECKING([for $1])
400 AC_MSG_RESULT([disabled])
401 else
402 # Check if the provided tool contains a complete path.
403 tool_specified="[$]$1"
404 tool_basename="${tool_specified##*/}"
405 if test "x$tool_basename" = "x$tool_specified"; then
406 # A command without a complete path is provided, search $PATH.
407 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
408 AC_PATH_PROG($1, $tool_basename)
409 if test "x[$]$1" = x; then
410 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
411 fi
412 else
413 # Otherwise we believe it is a complete path. Use it as it is.
414 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
415 AC_MSG_CHECKING([for $1])
416 if test ! -x "$tool_specified"; then
417 AC_MSG_RESULT([not found])
418 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
419 fi
420 AC_MSG_RESULT([$tool_specified])
421 fi
422 fi
423 fi
424 $3
425 fi
426 ])
427
428 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
429 # $1: variable to set
430 # $2: executable name (or list of names) to look for
431 AC_DEFUN([BASIC_PATH_PROGS],
432 [
433 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
434 ])
435
436 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
437 # $1: variable to set
438 # $2: executable name (or list of names) to look for
439 AC_DEFUN([BASIC_CHECK_TOOLS],
440 [
441 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
442 ])
443
444 # Like BASIC_PATH_PROGS but fails if no tool was found.
445 # $1: variable to set
446 # $2: executable name (or list of names) to look for
447 AC_DEFUN([BASIC_REQUIRE_PROGS],
448 [
449 BASIC_PATH_PROGS($1, $2)
450 BASIC_CHECK_NONEMPTY($1)
451 ])
452
453 # Like BASIC_SETUP_TOOL but fails if no tool was found.
454 # $1: variable to set
455 # $2: autoconf macro to call to look for the special tool
456 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
457 [
458 BASIC_SETUP_TOOL($1, [$2])
459 BASIC_CHECK_NONEMPTY($1)
460 ])
461
462 # Setup the most fundamental tools that relies on not much else to set up,
463 # but is used by much of the early bootstrap code.
464 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
465 [
466 # Start with tools that do not need have cross compilation support
467 # and can be expected to be found in the default PATH. These tools are
468 # used by configure.
469
470 # First are all the simple required tools.
471 BASIC_REQUIRE_PROGS(BASENAME, basename)
472 BASIC_REQUIRE_PROGS(BASH, bash)
473 BASIC_REQUIRE_PROGS(CAT, cat)
474 BASIC_REQUIRE_PROGS(CHMOD, chmod)
475 BASIC_REQUIRE_PROGS(CMP, cmp)
476 BASIC_REQUIRE_PROGS(COMM, comm)
477 BASIC_REQUIRE_PROGS(CP, cp)
478 BASIC_REQUIRE_PROGS(CUT, cut)
479 BASIC_REQUIRE_PROGS(DATE, date)
480 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
481 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
482 BASIC_REQUIRE_PROGS(ECHO, echo)
483 BASIC_REQUIRE_PROGS(EXPR, expr)
484 BASIC_REQUIRE_PROGS(FILE, file)
485 BASIC_REQUIRE_PROGS(FIND, find)
486 BASIC_REQUIRE_PROGS(HEAD, head)
487 BASIC_REQUIRE_PROGS(LN, ln)
488 BASIC_REQUIRE_PROGS(LS, ls)
489 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
490 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
491 BASIC_REQUIRE_PROGS(MV, mv)
492 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
493 BASIC_REQUIRE_PROGS(PRINTF, printf)
494 BASIC_REQUIRE_PROGS(RM, rm)
495 BASIC_REQUIRE_PROGS(RMDIR, rmdir)
496 BASIC_REQUIRE_PROGS(SH, sh)
497 BASIC_REQUIRE_PROGS(SORT, sort)
498 BASIC_REQUIRE_PROGS(TAIL, tail)
499 BASIC_REQUIRE_PROGS(TAR, tar)
500 BASIC_REQUIRE_PROGS(TEE, tee)
501 BASIC_REQUIRE_PROGS(TOUCH, touch)
502 BASIC_REQUIRE_PROGS(TR, tr)
503 BASIC_REQUIRE_PROGS(UNAME, uname)
504 BASIC_REQUIRE_PROGS(UNIQ, uniq)
505 BASIC_REQUIRE_PROGS(WC, wc)
506 BASIC_REQUIRE_PROGS(WHICH, which)
507 BASIC_REQUIRE_PROGS(XARGS, xargs)
508
509 # Then required tools that require some special treatment.
510 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
511 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
512 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
513 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
514 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
515
516 # Always force rm.
517 RM="$RM -f"
518
519 # pwd behaves differently on various platforms and some don't support the -L flag.
520 # Always use the bash builtin pwd to get uniform behavior.
521 THEPWDCMD=pwd
522
523 # These are not required on all platforms
524 BASIC_PATH_PROGS(CYGPATH, cygpath)
525 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
526 BASIC_PATH_PROGS(DF, df)
527 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
528 BASIC_PATH_PROGS(NICE, nice)
529 ])
530
531 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
532 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
533 [
534 # Save the current directory this script was started from
535 CURDIR="$PWD"
536
537 # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
538 # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
539 # was not available at that time.
540 REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
541 if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
542 ORIGINAL_PATH="$REWRITTEN_PATH"
543 AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
544 fi
545
546 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
547 PATH_SEP=";"
548 BASIC_CHECK_PATHS_WINDOWS
549 else
550 PATH_SEP=":"
551 fi
552 AC_SUBST(PATH_SEP)
553
554 # We get the top-level directory from the supporting wrappers.
555 AC_MSG_CHECKING([for top-level directory])
556 AC_MSG_RESULT([$TOPDIR])
557 AC_SUBST(TOPDIR)
558
559 # Save the original version of TOPDIR for string comparisons
560 ORIGINAL_TOPDIR="$TOPDIR"
561 AC_SUBST(ORIGINAL_TOPDIR)
562
563 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
564 BASIC_FIXUP_PATH(CURDIR)
565 BASIC_FIXUP_PATH(TOPDIR)
566 # SRC_ROOT is a traditional alias for TOPDIR.
567 SRC_ROOT=$TOPDIR
568
569 # Calculate a canonical version of TOPDIR for string comparisons
570 CANONICAL_TOPDIR=$TOPDIR
571 BASIC_REMOVE_SYMBOLIC_LINKS([CANONICAL_TOPDIR])
572 AC_SUBST(CANONICAL_TOPDIR)
573
574 # Locate the directory of this script.
575 AUTOCONF_DIR=$TOPDIR/common/autoconf
576
577 # Setup username (for use in adhoc version strings etc)
578 # Outer [ ] to quote m4.
579 [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
580 AC_SUBST(USERNAME)
581 ])
582
583 # Evaluates platform specific overrides for devkit variables.
584 # $1: Name of variable
585 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
586 [
587 if test "x[$]$1" = x; then
588 eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
589 fi
590 ])
591
592 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
593 [
594 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
595 [use this devkit for compilers, tools and resources])],
596 [
597 BASIC_FIXUP_PATH([with_devkit])
598 DEVKIT_ROOT="$with_devkit"
599 # Check for a meta data info file in the root of the devkit
600 if test -f "$DEVKIT_ROOT/devkit.info"; then
601 . $DEVKIT_ROOT/devkit.info
602 # This potentially sets the following:
603 # A descriptive name of the devkit
604 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
605 # Corresponds to --with-extra-path
606 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
607 # Corresponds to --with-toolchain-path
608 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
609 # Corresponds to --with-sysroot
610 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
611
612 # Identifies the Visual Studio version in the devkit
613 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
614 # The Visual Studio include environment variable
615 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
616 # The Visual Studio lib environment variable
617 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
618 # Corresponds to --with-msvcr-dll
619 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
620 # Corresponds to --with-msvcp-dll
621 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
622 fi
623
624 AC_MSG_CHECKING([for devkit])
625 if test "x$DEVKIT_NAME" != x; then
626 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
627 else
628 AC_MSG_RESULT([$DEVKIT_ROOT])
629 fi
630
631 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
632
633 # Fallback default of just /bin if DEVKIT_PATH is not defined
634 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
635 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
636 fi
637 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
638
639 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
640 # places for backwards compatiblity.
641 if test "x$DEVKIT_SYSROOT" != x; then
642 SYSROOT="$DEVKIT_SYSROOT"
643 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
644 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
645 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
646 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
647 fi
648 ]
649 )
650
651 # You can force the sysroot if the sysroot encoded into the compiler tools
652 # is not correct.
653 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
654 [alias for --with-sysroot for backwards compatability])],
655 [SYSROOT=$with_sys_root]
656 )
657
658 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
659 [use this directory as sysroot])],
660 [SYSROOT=$with_sysroot]
661 )
662
663 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
664 [alias for --with-toolchain-path for backwards compatibility])],
665 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
666 )
667
668 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
669 [prepend these directories when searching for toolchain binaries (compilers etc)])],
670 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
671 )
672
673 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
674 [prepend these directories to the default path])],
675 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
676 )
677
678 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
679 # If a devkit has been supplied, find xcodebuild in the toolchain_path.
680 # If not, detect if Xcode is installed by running xcodebuild -version
681 # if no Xcode installed, xcodebuild exits with 1
682 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
683 if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
684 # We need to use xcodebuild in the toolchain dir provided by the user, this will
685 # fall back on the stub binary in /usr/bin/xcodebuild
686 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
687 else
688 # this should result in SYSROOT being empty, unless --with-sysroot is provided
689 # when only the command line tools are installed there are no SDKs, so headers
690 # are copied into the system frameworks
691 XCODEBUILD=
692 AC_SUBST(XCODEBUILD)
693 fi
694
695 AC_MSG_CHECKING([for sdk name])
696 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
697 [use the platform SDK of the given name. @<:@macosx@:>@])],
698 [SDKNAME=$with_sdk_name]
699 )
700 AC_MSG_RESULT([$SDKNAME])
701
702 # if toolchain path is specified then don't rely on system headers, they may not compile
703 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
704 test -z "$TOOLCHAIN_PATH" && \
705 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
706
707 if test -z "$SYSROOT"; then
708 if test -n "$XCODEBUILD"; then
709 # if we don't have system headers, use default SDK name (last resort)
710 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
711 SDKNAME=${SDKNAME:-macosx}
712 fi
713
714 if test -n "$SDKNAME"; then
715 # Call xcodebuild to determine SYSROOT
716 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | grep '^Path: ' | sed 's/Path: //'`
717 fi
718 else
719 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
720 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
721 fi
722 fi
723 else
724 # warn user if --with-sdk-name was also set
725 if test -n "$with_sdk_name"; then
726 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
727 fi
728 fi
729
730 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
731 # If no system framework headers, then SYSROOT must be set, or we won't build
732 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
733 fi
734
735 # Perform a basic sanity test
736 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
737 if test -z "$SYSROOT"; then
738 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
739 else
740 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
741 fi
742 fi
743
744 # set SDKROOT too, Xcode tools will pick it up
745 AC_SUBST(SDKROOT,$SYSROOT)
746 fi
747
748 # Prepend the extra path to the global path
749 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
750
751 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
752 # Add extra search paths on solaris for utilities like ar and as etc...
753 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
754 fi
755
756 AC_MSG_CHECKING([for sysroot])
757 AC_MSG_RESULT([$SYSROOT])
758 AC_MSG_CHECKING([for toolchain path])
759 AC_MSG_RESULT([$TOOLCHAIN_PATH])
760 AC_MSG_CHECKING([for extra path])
761 AC_MSG_RESULT([$EXTRA_PATH])
762 ])
763
764 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
765 [
766
767 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
768 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
769 [ CONF_NAME=${with_conf_name} ])
770
771 # Test from where we are running configure, in or outside of src root.
772 AC_MSG_CHECKING([where to store configuration])
773 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
774 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
775 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
776 # We are running configure from the src root.
777 # Create a default ./build/target-variant-debuglevel output root.
778 if test "x${CONF_NAME}" = x; then
779 AC_MSG_RESULT([in default location])
780 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
781 else
782 AC_MSG_RESULT([in build directory with custom name])
783 fi
784 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
785 $MKDIR -p "$OUTPUT_ROOT"
786 if test ! -d "$OUTPUT_ROOT"; then
787 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
788 fi
789 else
790 # We are running configure from outside of the src dir.
791 # Then use the current directory as output dir!
792 # If configuration is situated in normal build directory, just use the build
793 # directory name as configuration name, otherwise use the complete path.
794 if test "x${CONF_NAME}" = x; then
795 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
796 fi
797 OUTPUT_ROOT="$CURDIR"
798 AC_MSG_RESULT([in current directory])
799
800 # WARNING: This might be a bad thing to do. You need to be sure you want to
801 # have a configuration in this directory. Do some sanity checks!
802
803 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
804 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
805 # other files
806 files_present=`$LS $OUTPUT_ROOT`
807 # Configure has already touched config.log and confdefs.h in the current dir when this check
808 # is performed.
809 filtered_files=`$ECHO "$files_present" \
810 | $SED -e 's/config.log//g' \
811 -e 's/configure.log//g' \
812 -e 's/confdefs.h//g' \
813 -e 's/ //g' \
814 | $TR -d '\n'`
815 if test "x$filtered_files" != x; then
816 AC_MSG_NOTICE([Current directory is $CURDIR.])
817 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
818 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
819 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
820 AC_MSG_NOTICE([seriously mess up just about everything.])
821 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
822 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
823 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
824 fi
825 fi
826 fi
827 AC_MSG_CHECKING([what configuration name to use])
828 AC_MSG_RESULT([$CONF_NAME])
829
830 BASIC_FIXUP_PATH(OUTPUT_ROOT)
831
832 CONFIGURESUPPORT_OUTPUTDIR="$OUTPUT_ROOT/configure-support"
833 $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
834
835 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
836 AC_SUBST(CONF_NAME, $CONF_NAME)
837 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
838 AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
839
840 # The spec.gmk file contains all variables for the make system.
841 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
842 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
843 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
844 # The bootcycle-spec.gmk file contains support for boot cycle builds.
845 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
846 # The compare.sh is used to compare the build output to other builds.
847 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
848 # The generated Makefile knows where the spec.gmk is and where the source is.
849 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
850 # which will look for generated configurations
851 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
852 ])
853
854 #%%% Simple tools %%%
855
856 # Check if we have found a usable version of make
857 # $1: the path to a potential make binary (or empty)
858 # $2: the description on how we found this
859 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
860 [
861 MAKE_CANDIDATE="$1"
862 DESCRIPTION="$2"
863
864 # On Cygwin, we require a newer version of make than on other platforms
865 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
866 MAKE_VERSION_EXPR="-e 4\."
867 MAKE_REQUIRED_VERSION="4.0"
868 else
869 MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
870 MAKE_REQUIRED_VERSION="3.81"
871 fi
872
873 if test "x$MAKE_CANDIDATE" != x; then
874 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
875 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
876 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
877 if test "x$IS_GNU_MAKE" = x; then
878 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
879 else
880 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
881 if test "x$IS_MODERN_MAKE" = x; then
882 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
883 else
884 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
885 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
886 MAKE_EXPECTED_ENV='cygwin'
887 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
888 MAKE_EXPECTED_ENV='msys'
889 else
890 AC_MSG_ERROR([Unknown Windows environment])
891 fi
892 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
893 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
894 else
895 # Not relevant for non-Windows
896 IS_MAKE_CORRECT_ENV=true
897 fi
898 if test "x$IS_MAKE_CORRECT_ENV" = x; then
899 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
900 else
901 FOUND_MAKE=$MAKE_CANDIDATE
902 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
903 fi
904 fi
905 fi
906 fi
907 ])
908
909 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
910 [
911 # Check if make supports the output sync option and if so, setup using it.
912 AC_MSG_CHECKING([if make --output-sync is supported])
913 if $MAKE --version -O > /dev/null 2>&1; then
914 OUTPUT_SYNC_SUPPORTED=true
915 AC_MSG_RESULT([yes])
916 AC_MSG_CHECKING([for output-sync value])
917 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
918 [set make output sync type if supported by make. @<:@recurse@:>@])],
919 [OUTPUT_SYNC=$with_output_sync])
920 if test "x$OUTPUT_SYNC" = "x"; then
921 OUTPUT_SYNC=none
922 fi
923 AC_MSG_RESULT([$OUTPUT_SYNC])
924 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
925 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
926 fi
927 else
928 OUTPUT_SYNC_SUPPORTED=false
929 AC_MSG_RESULT([no])
930 fi
931 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
932 AC_SUBST(OUTPUT_SYNC)
933 ])
934
935 # Goes looking for a usable version of GNU make.
936 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
937 [
938 BASIC_SETUP_TOOL([MAKE],
939 [
940 # Try our hardest to locate a correct version of GNU make
941 AC_PATH_PROGS(CHECK_GMAKE, gmake)
942 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
943
944 if test "x$FOUND_MAKE" = x; then
945 AC_PATH_PROGS(CHECK_MAKE, make)
946 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
947 fi
948
949 if test "x$FOUND_MAKE" = x; then
950 if test "x$TOOLCHAIN_PATH" != x; then
951 # We have a toolchain path, check that as well before giving up.
952 OLD_PATH=$PATH
953 PATH=$TOOLCHAIN_PATH:$PATH
954 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
955 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
956 if test "x$FOUND_MAKE" = x; then
957 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
958 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
959 fi
960 PATH=$OLD_PATH
961 fi
962 fi
963
964 if test "x$FOUND_MAKE" = x; then
965 AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
966 fi
967 ],[
968 # If MAKE was set by user, verify the version
969 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
970 if test "x$FOUND_MAKE" = x; then
971 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
972 fi
973 ])
974
975 MAKE=$FOUND_MAKE
976 AC_SUBST(MAKE)
977 AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
978
979 BASIC_CHECK_MAKE_OUTPUT_SYNC
980 ])
981
982 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
983 [
984 # Test if find supports -delete
985 AC_MSG_CHECKING([if find supports -delete])
986 FIND_DELETE="-delete"
987
988 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
989
990 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
991
992 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
993 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
994 # No, it does not.
995 rm $DELETEDIR/TestIfFindSupportsDelete
996 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
997 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
998 FIND_DELETE="-print | xargs rm"
999 else
1000 FIND_DELETE="-exec rm \{\} \+"
1001 fi
1002 AC_MSG_RESULT([no])
1003 else
1004 AC_MSG_RESULT([yes])
1005 fi
1006 rmdir $DELETEDIR
1007 AC_SUBST(FIND_DELETE)
1008 ])
1009
1010 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1011 [
1012 BASIC_CHECK_GNU_MAKE
1013
1014 BASIC_CHECK_FIND_DELETE
1015
1016 # These tools might not be installed by default,
1017 # need hint on how to install them.
1018 BASIC_REQUIRE_PROGS(UNZIP, unzip)
1019 BASIC_REQUIRE_PROGS(ZIP, zip)
1020
1021 # Non-required basic tools
1022
1023 BASIC_PATH_PROGS(LDD, ldd)
1024 if test "x$LDD" = "x"; then
1025 # List shared lib dependencies is used for
1026 # debug output and checking for forbidden dependencies.
1027 # We can build without it.
1028 LDD="true"
1029 fi
1030 BASIC_PATH_PROGS(OTOOL, otool)
1031 if test "x$OTOOL" = "x"; then
1032 OTOOL="true"
1033 fi
1034 BASIC_PATH_PROGS(READELF, [greadelf readelf])
1035 BASIC_PATH_PROGS(HG, hg)
1036 BASIC_PATH_PROGS(STAT, stat)
1037 BASIC_PATH_PROGS(TIME, time)
1038 BASIC_PATH_PROGS(PATCH, [gpatch patch])
1039 # Check if it's GNU time
1040 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1041 if test "x$IS_GNU_TIME" != x; then
1042 IS_GNU_TIME=yes
1043 else
1044 IS_GNU_TIME=no
1045 fi
1046 AC_SUBST(IS_GNU_TIME)
1047
1048 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1049 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1050 BASIC_REQUIRE_PROGS(XATTR, xattr)
1051 BASIC_PATH_PROGS(CODESIGN, codesign)
1052 if test "x$CODESIGN" != "x"; then
1053 # Verify that the openjdk_codesign certificate is present
1054 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1055 rm -f codesign-testfile
1056 touch codesign-testfile
1057 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1058 rm -f codesign-testfile
1059 if test "x$CODESIGN" = x; then
1060 AC_MSG_RESULT([no])
1061 else
1062 AC_MSG_RESULT([yes])
1063 fi
1064 fi
1065 BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1066 fi
1067 ])
1068
1069 # Check if build directory is on local disk. If not possible to determine,
1070 # we prefer to claim it's local.
1071 # Argument 1: directory to test
1072 # Argument 2: what to do if it is on local disk
1073 # Argument 3: what to do otherwise (remote disk or failure)
1074 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1075 [
1076 # df -l lists only local disks; if the given directory is not found then
1077 # a non-zero exit code is given
1078 if test "x$DF" = x; then
1079 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1080 # msys does not have df; use Windows "net use" instead.
1081 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1082 if test "x$IS_NETWORK_DISK" = x; then
1083 $2
1084 else
1085 $3
1086 fi
1087 else
1088 # No df here, say it's local
1089 $2
1090 fi
1091 else
1092 if $DF -l $1 > /dev/null 2>&1; then
1093 $2
1094 else
1095 $3
1096 fi
1097 fi
1098 ])
1099
1100 # Check that source files have basic read permissions set. This might
1101 # not be the case in cygwin in certain conditions.
1102 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1103 [
1104 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1105 file_to_test="$SRC_ROOT/LICENSE"
1106 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1107 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1108 fi
1109 fi
1110 ])
1111
1112 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1113 [
1114 # Did user specify any unknown variables?
1115 BASIC_CHECK_LEFTOVER_OVERRIDDEN
1116
1117 AC_MSG_CHECKING([if build directory is on local disk])
1118 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
1119 [OUTPUT_DIR_IS_LOCAL="yes"],
1120 [OUTPUT_DIR_IS_LOCAL="no"])
1121 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1122
1123 BASIC_CHECK_SRC_PERMS
1124
1125 # Check if the user has any old-style ALT_ variables set.
1126 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1127
1128 # Before generating output files, test if they exist. If they do, this is a reconfigure.
1129 # Since we can't properly handle the dependencies for this, warn the user about the situation
1130 if test -e $OUTPUT_ROOT/spec.gmk; then
1131 IS_RECONFIGURE=yes
1132 else
1133 IS_RECONFIGURE=no
1134 fi
1135 ])
1136
1137 # Check for support for specific options in bash
1138 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1139 [
1140 # Test if bash supports pipefail.
1141 AC_MSG_CHECKING([if bash supports pipefail])
1142 if ${BASH} -c 'set -o pipefail'; then
1143 BASH_ARGS="$BASH_ARGS -o pipefail"
1144 AC_MSG_RESULT([yes])
1145 else
1146 AC_MSG_RESULT([no])
1147 fi
1148
1149 AC_MSG_CHECKING([if bash supports errexit (-e)])
1150 if ${BASH} -e -c 'true'; then
1151 BASH_ARGS="$BASH_ARGS -e"
1152 AC_MSG_RESULT([yes])
1153 else
1154 AC_MSG_RESULT([no])
1155 fi
1156
1157 AC_SUBST(BASH_ARGS)
1158 ])
1159
1160 ################################################################################
1161 #
1162 # Default make target
1163 #
1164 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1165 [
1166 AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1167 [set the default make target @<:@exploded-image@:>@])])
1168 if test "x$with_default_make_target" = "x" \
1169 || test "x$with_default_make_target" = "xyes"; then
1170 DEFAULT_MAKE_TARGET="exploded-image"
1171 elif test "x$with_default_make_target" = "xno"; then
1172 AC_MSG_ERROR([--without-default-make-target is not a valid option])
1173 else
1174 DEFAULT_MAKE_TARGET="$with_default_make_target"
1175 fi
1176
1177 AC_SUBST(DEFAULT_MAKE_TARGET)
1178 ])
1179
1180 # Code to run after AC_OUTPUT
1181 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1182 [
1183 # Try to move config.log (generated by autoconf) to the configure-support directory.
1184 if test -e ./config.log; then
1185 $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1186 fi
1187
1188 # Rotate our log file (configure.log)
1189 if test -e "$OUTPUT_ROOT/configure.log.old"; then
1190 $RM -f "$OUTPUT_ROOT/configure.log.old"
1191 fi
1192 if test -e "$OUTPUT_ROOT/configure.log"; then
1193 $MV -f "$OUTPUT_ROOT/configure.log" "$OUTPUT_ROOT/configure.log.old" 2> /dev/null
1194 fi
1195
1196 # Move configure.log from current directory to the build output root
1197 if test -e ./configure.log; then
1198 $MV -f ./configure.log "$OUTPUT_ROOT/configure.log" 2> /dev/null
1199 fi
1200
1201 # Make the compare script executable
1202 $CHMOD +x $OUTPUT_ROOT/compare.sh
1203 ])