1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Create a function/macro that takes a series of named arguments. The call is
27 # similar to AC_DEFUN, but the setup of the function looks like this:
28 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
29 # ... do something
30 # AC_MSG_NOTICE([Value of BAR is ARG_BAR])
31 # ])
32 # A star (*) in front of a named argument means that it is required and it's
33 # presence will be verified. To pass e.g. the first value as a normal indexed
34 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
35 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
36 # "ARG_FOO".
37 #
38 # The generated function can be called like this:
39 # MYFUNC(FOO: [foo-val],
40 # BAR: [
41 # $ECHO hello world
42 # ])
43 # Note that the argument value must start on the same line as the argument name.
44 #
45 # Argument 1: Name of the function to define
46 # Argument 2: List of legal named arguments, with a * prefix for required arguments
47 # Argument 3: Argument array to treat as named, typically $@
48 # Argument 4: The main function body
49 AC_DEFUN([BASIC_DEFUN_NAMED],
50 [
51 AC_DEFUN($1, [
52 m4_foreach(arg, m4_split($2), [
53 m4_if(m4_bregexp(arg, [^\*]), -1,
54 [
55 m4_set_add(legal_named_args, arg)
56 ],
57 [
58 m4_set_add(legal_named_args, m4_substr(arg, 1))
59 m4_set_add(required_named_args, m4_substr(arg, 1))
60 ]
61 )
62 ])
63
64 m4_foreach([arg], [$3], [
65 m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
66 m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
67 m4_set_remove(required_named_args, arg_name)
68 m4_set_remove(legal_named_args, arg_name)
69 m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
70 m4_set_add(defined_args, arg_name)
71 m4_undefine([arg_name])
72 ])
73 m4_set_empty(required_named_args, [], [
74 AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
75 ])
76 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
77 m4_pushdef([ARG_][]arg, [])
78 m4_set_add(defined_args, arg)
79 ])
80 m4_set_delete(legal_named_args)
81 m4_set_delete(required_named_args)
82
83 # Execute function body
84 $4
85
86 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
87 m4_popdef([ARG_][]arg)
88 ])
89
90 m4_set_delete(defined_args)
91 ])
92 ])
93
94 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
95 # If so, then append $1 to $2 \
96 # Also set JVM_ARG_OK to true/false depending on outcome.
97 AC_DEFUN([ADD_JVM_ARG_IF_OK],
98 [
99 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
100 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
101 OUTPUT=`$3 $1 -version 2>&1`
102 FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
103 FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
104 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
105 $2="[$]$2 $1"
106 JVM_ARG_OK=true
107 else
108 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
109 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
110 JVM_ARG_OK=false
111 fi
112 ])
113
114 # Appends a string to a path variable, only adding the : when needed.
115 AC_DEFUN([BASIC_APPEND_TO_PATH],
116 [
117 if test "x$2" != x; then
118 if test "x[$]$1" = x; then
119 $1="$2"
120 else
121 $1="[$]$1:$2"
122 fi
123 fi
124 ])
125
126 # Prepends a string to a path variable, only adding the : when needed.
127 AC_DEFUN([BASIC_PREPEND_TO_PATH],
128 [
129 if test "x$2" != x; then
130 if test "x[$]$1" = x; then
131 $1="$2"
132 else
133 $1="$2:[$]$1"
134 fi
135 fi
136 ])
137
138 # This will make sure the given variable points to a full and proper
139 # path. This means:
140 # 1) There will be no spaces in the path. On unix platforms,
141 # spaces in the path will result in an error. On Windows,
142 # the path will be rewritten using short-style to be space-free.
143 # 2) The path will be absolute, and it will be in unix-style (on
144 # cygwin).
145 # $1: The name of the variable to fix
146 AC_DEFUN([BASIC_FIXUP_PATH],
147 [
148 # Only process if variable expands to non-empty
149
150 if test "x[$]$1" != x; then
151 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
152 BASIC_FIXUP_PATH_CYGWIN($1)
153 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
154 BASIC_FIXUP_PATH_MSYS($1)
155 else
156 # We're on a unix platform. Hooray! :)
157 path="[$]$1"
158 has_space=`$ECHO "$path" | $GREP " "`
159 if test "x$has_space" != x; then
160 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
161 AC_MSG_ERROR([Spaces are not allowed in this path.])
162 fi
163
164 # Use eval to expand a potential ~
165 eval path="$path"
166 if test ! -f "$path" && test ! -d "$path"; then
167 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
168 fi
169
170 if test -d "$path"; then
171 $1="`cd "$path"; $THEPWDCMD -L`"
172 else
173 dir="`$DIRNAME "$path"`"
174 base="`$BASENAME "$path"`"
175 $1="`cd "$dir"; $THEPWDCMD -L`/$base"
176 fi
177 fi
178 fi
179 ])
180
181 # This will make sure the given variable points to a executable
182 # with a full and proper path. This means:
183 # 1) There will be no spaces in the path. On unix platforms,
184 # spaces in the path will result in an error. On Windows,
185 # the path will be rewritten using short-style to be space-free.
186 # 2) The path will be absolute, and it will be in unix-style (on
187 # cygwin).
188 # Any arguments given to the executable is preserved.
189 # If the input variable does not have a directory specification, then
190 # it need to be in the PATH.
191 # $1: The name of the variable to fix
192 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
193 [
194 # Only process if variable expands to non-empty
195
196 if test "x[$]$1" != x; then
197 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
198 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
199 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
200 BASIC_FIXUP_EXECUTABLE_MSYS($1)
201 else
202 # We're on a unix platform. Hooray! :)
203 # First separate the path from the arguments. This will split at the first
204 # space.
205 complete="[$]$1"
206 path="${complete%% *}"
207 tmp="$complete EOL"
208 arguments="${tmp#* }"
209
210 # Cannot rely on the command "which" here since it doesn't always work.
211 is_absolute_path=`$ECHO "$path" | $GREP ^/`
212 if test -z "$is_absolute_path"; then
213 # Path to executable is not absolute. Find it.
214 IFS_save="$IFS"
215 IFS=:
216 for p in $PATH; do
217 if test -f "$p/$path" && test -x "$p/$path"; then
218 new_path="$p/$path"
219 break
220 fi
221 done
222 IFS="$IFS_save"
223 else
224 # This is an absolute path, we can use it without further modifications.
225 new_path="$path"
226 fi
227
228 if test "x$new_path" = x; then
229 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
230 has_space=`$ECHO "$complete" | $GREP " "`
231 if test "x$has_space" != x; then
232 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
233 fi
234 AC_MSG_ERROR([Cannot locate the the path of $1])
235 fi
236 fi
237
238 # Now join together the path and the arguments once again
239 if test "x$arguments" != xEOL; then
240 new_complete="$new_path ${arguments% *}"
241 else
242 new_complete="$new_path"
243 fi
244
245 if test "x$complete" != "x$new_complete"; then
246 $1="$new_complete"
247 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
248 fi
249 fi
250 ])
251
252 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
253 [
254 if test "x$OPENJDK_BUILD_OS" != xwindows; then
255 # Follow a chain of symbolic links. Use readlink
256 # where it exists, else fall back to horribly
257 # complicated shell code.
258 if test "x$READLINK_TESTED" != yes; then
259 # On MacOSX there is a readlink tool with a different
260 # purpose than the GNU readlink tool. Check the found readlink.
261 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
262 if test "x$ISGNU" = x; then
263 # A readlink that we do not know how to use.
264 # Are there other non-GNU readlinks out there?
265 READLINK_TESTED=yes
266 READLINK=
267 fi
268 fi
269
270 if test "x$READLINK" != x; then
271 $1=`$READLINK -f [$]$1`
272 else
273 # Save the current directory for restoring afterwards
274 STARTDIR=$PWD
275 COUNTER=0
276 sym_link_dir=`$DIRNAME [$]$1`
277 sym_link_file=`$BASENAME [$]$1`
278 cd $sym_link_dir
279 # Use -P flag to resolve symlinks in directories.
280 cd `$THEPWDCMD -P`
281 sym_link_dir=`$THEPWDCMD -P`
282 # Resolve file symlinks
283 while test $COUNTER -lt 20; do
284 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
285 if test "x$ISLINK" == x; then
286 # This is not a symbolic link! We are done!
287 break
288 fi
289 # Again resolve directory symlinks since the target of the just found
290 # link could be in a different directory
291 cd `$DIRNAME $ISLINK`
292 sym_link_dir=`$THEPWDCMD -P`
293 sym_link_file=`$BASENAME $ISLINK`
294 let COUNTER=COUNTER+1
295 done
296 cd $STARTDIR
297 $1=$sym_link_dir/$sym_link_file
298 fi
299 fi
300 ])
301
302 # Register a --with argument but mark it as deprecated
303 # $1: The name of the with argument to deprecate, not including --with-
304 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
305 [
306 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
307 [Deprecated. Option is kept for backwards compatibility and is ignored])],
308 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
309 ])
310
311 # Register a --enable argument but mark it as deprecated
312 # $1: The name of the with argument to deprecate, not including --enable-
313 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
314 # $3: Messages to user.
315 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
316 [
317 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
318 [Deprecated. Option is kept for backwards compatibility and is ignored])])
319 if test "x$enable_$2" != x; then
320 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
321
322 if test "x$3" != x; then
323 AC_MSG_WARN([$3])
324 fi
325
326 fi
327 ])
328
329 AC_DEFUN_ONCE([BASIC_INIT],
330 [
331 # Save the original command line. This is passed to us by the wrapper configure script.
332 AC_SUBST(CONFIGURE_COMMAND_LINE)
333 # Save the path variable before it gets changed
334 ORIGINAL_PATH="$PATH"
335 AC_SUBST(ORIGINAL_PATH)
336 DATE_WHEN_CONFIGURED=`LANG=C date`
337 AC_SUBST(DATE_WHEN_CONFIGURED)
338 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
339 ])
340
341 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
342 # $1: variable to check
343 AC_DEFUN([BASIC_CHECK_NONEMPTY],
344 [
345 if test "x[$]$1" = x; then
346 AC_MSG_ERROR([Could not find required tool for $1])
347 fi
348 ])
349
350 # Check that there are no unprocessed overridden variables left.
351 # If so, they are an incorrect argument and we will exit with an error.
352 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
353 [
354 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
355 # Replace the separating ! with spaces before presenting for end user.
356 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
357 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
358 fi
359 ])
360
361 # Setup a tool for the given variable. If correctly specified by the user,
362 # use that value, otherwise search for the tool using the supplied code snippet.
363 # $1: variable to set
364 # $2: code snippet to call to look for the tool
365 # $3: code snippet to call if variable was used to find tool
366 AC_DEFUN([BASIC_SETUP_TOOL],
367 [
368 # Publish this variable in the help.
369 AC_ARG_VAR($1, [Override default value for $1])
370
371 if [[ -z "${$1+x}" ]]; then
372 # The variable is not set by user, try to locate tool using the code snippet
373 $2
374 else
375 # The variable is set, but is it from the command line or the environment?
376
377 # Try to remove the string !$1! from our list.
378 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
379 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
380 # If it failed, the variable was not from the command line. Ignore it,
381 # but warn the user (except for BASH, which is always set by the calling BASH).
382 if test "x$1" != xBASH; then
383 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
384 fi
385 # Try to locate tool using the code snippet
386 $2
387 else
388 # If it succeeded, then it was overridden by the user. We will use it
389 # for the tool.
390
391 # First remove it from the list of overridden variables, so we can test
392 # for unknown variables in the end.
393 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
394
395 # Check if we try to supply an empty value
396 if test "x[$]$1" = x; then
397 AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
398 AC_MSG_CHECKING([for $1])
399 AC_MSG_RESULT([disabled])
400 else
401 # Check if the provided tool contains a complete path.
402 tool_specified="[$]$1"
403 tool_basename="${tool_specified##*/}"
404 if test "x$tool_basename" = "x$tool_specified"; then
405 # A command without a complete path is provided, search $PATH.
406 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
407 AC_PATH_PROG($1, $tool_basename)
408 if test "x[$]$1" = x; then
409 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
410 fi
411 else
412 # Otherwise we believe it is a complete path. Use it as it is.
413 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
414 AC_MSG_CHECKING([for $1])
415 if test ! -x "$tool_specified"; then
416 AC_MSG_RESULT([not found])
417 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
418 fi
419 AC_MSG_RESULT([$tool_specified])
420 fi
421 fi
422 fi
423 $3
424 fi
425 ])
426
427 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
428 # $1: variable to set
429 # $2: executable name (or list of names) to look for
430 # $3: [path]
431 AC_DEFUN([BASIC_PATH_PROGS],
432 [
433 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
434 ])
435
436 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
437 # $1: variable to set
438 # $2: executable name (or list of names) to look for
439 AC_DEFUN([BASIC_CHECK_TOOLS],
440 [
441 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
442 ])
443
444 # Like BASIC_PATH_PROGS but fails if no tool was found.
445 # $1: variable to set
446 # $2: executable name (or list of names) to look for
447 # $3: [path]
448 AC_DEFUN([BASIC_REQUIRE_PROGS],
449 [
450 BASIC_PATH_PROGS($1, $2, , $3)
451 BASIC_CHECK_NONEMPTY($1)
452 ])
453
454 # Like BASIC_SETUP_TOOL but fails if no tool was found.
455 # $1: variable to set
456 # $2: autoconf macro to call to look for the special tool
457 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
458 [
459 BASIC_SETUP_TOOL($1, [$2])
460 BASIC_CHECK_NONEMPTY($1)
461 ])
462
463 # Setup the most fundamental tools that relies on not much else to set up,
464 # but is used by much of the early bootstrap code.
465 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
466 [
467 # Start with tools that do not need have cross compilation support
468 # and can be expected to be found in the default PATH. These tools are
469 # used by configure.
470
471 # First are all the simple required tools.
472 BASIC_REQUIRE_PROGS(BASENAME, basename)
473 BASIC_REQUIRE_PROGS(BASH, bash)
474 BASIC_REQUIRE_PROGS(CAT, cat)
475 BASIC_REQUIRE_PROGS(CHMOD, chmod)
476 BASIC_REQUIRE_PROGS(CMP, cmp)
477 BASIC_REQUIRE_PROGS(COMM, comm)
478 BASIC_REQUIRE_PROGS(CP, cp)
479 BASIC_REQUIRE_PROGS(CUT, cut)
480 BASIC_REQUIRE_PROGS(DATE, date)
481 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
482 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
483 BASIC_REQUIRE_PROGS(ECHO, echo)
484 BASIC_REQUIRE_PROGS(EXPR, expr)
485 BASIC_REQUIRE_PROGS(FILE, file)
486 BASIC_REQUIRE_PROGS(FIND, find)
487 BASIC_REQUIRE_PROGS(HEAD, head)
488 BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
489 BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
490 BASIC_REQUIRE_PROGS(LN, ln)
491 BASIC_REQUIRE_PROGS(LS, ls)
492 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
493 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
494 BASIC_REQUIRE_PROGS(MV, mv)
495 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
496 BASIC_REQUIRE_PROGS(PRINTF, printf)
497 BASIC_REQUIRE_PROGS(RM, rm)
498 BASIC_REQUIRE_PROGS(RMDIR, rmdir)
499 BASIC_REQUIRE_PROGS(SH, sh)
500 BASIC_REQUIRE_PROGS(SORT, sort)
501 BASIC_REQUIRE_PROGS(TAIL, tail)
502 BASIC_REQUIRE_PROGS(TAR, gtar tar)
503 BASIC_REQUIRE_PROGS(TEE, tee)
504 BASIC_REQUIRE_PROGS(TOUCH, touch)
505 BASIC_REQUIRE_PROGS(TR, tr)
506 BASIC_REQUIRE_PROGS(UNAME, uname)
507 BASIC_REQUIRE_PROGS(UNIQ, uniq)
508 BASIC_REQUIRE_PROGS(WC, wc)
509 BASIC_REQUIRE_PROGS(WHICH, which)
510 BASIC_REQUIRE_PROGS(XARGS, xargs)
511
512 # Then required tools that require some special treatment.
513 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
514 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
515 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
516 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
517 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
518
519 # Always force rm.
520 RM="$RM -f"
521
522 # pwd behaves differently on various platforms and some don't support the -L flag.
523 # Always use the bash builtin pwd to get uniform behavior.
524 THEPWDCMD=pwd
525
526 # These are not required on all platforms
527 BASIC_PATH_PROGS(CYGPATH, cygpath)
528 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
529 BASIC_PATH_PROGS(DF, df)
530 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
531 BASIC_PATH_PROGS(NICE, nice)
532 BASIC_PATH_PROGS(PANDOC, pandoc)
533 ])
534
535 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
536 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
537 [
538 # Save the current directory this script was started from
539 CURDIR="$PWD"
540
541 # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
542 # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
543 # was not available at that time.
544 REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
545 if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
546 ORIGINAL_PATH="$REWRITTEN_PATH"
547 AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
548 fi
549
550 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
551 PATH_SEP=";"
552 BASIC_CHECK_PATHS_WINDOWS
553 else
554 PATH_SEP=":"
555 fi
556 AC_SUBST(PATH_SEP)
557
558 # We get the top-level directory from the supporting wrappers.
559 AC_MSG_CHECKING([for top-level directory])
560 AC_MSG_RESULT([$TOPDIR])
561 AC_SUBST(TOPDIR)
562
563 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
564 BASIC_FIXUP_PATH(CURDIR)
565 BASIC_FIXUP_PATH(TOPDIR)
566
567 # Locate the directory of this script.
568 AUTOCONF_DIR=$TOPDIR/make/autoconf
569
570 # Setup username (for use in adhoc version strings etc)
571 # Outer [ ] to quote m4.
572 [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
573 AC_SUBST(USERNAME)
574 ])
575
576 # Evaluates platform specific overrides for devkit variables.
577 # $1: Name of variable
578 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
579 [
580 if test "x[$]$1" = x; then
581 eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
582 fi
583 ])
584
585 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
586 [
587 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
588 [use this devkit for compilers, tools and resources])])
589
590 if test "x$with_devkit" = xyes; then
591 AC_MSG_ERROR([--with-devkit must have a value])
592 elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
593 BASIC_FIXUP_PATH([with_devkit])
594 DEVKIT_ROOT="$with_devkit"
595 # Check for a meta data info file in the root of the devkit
596 if test -f "$DEVKIT_ROOT/devkit.info"; then
597 . $DEVKIT_ROOT/devkit.info
598 # This potentially sets the following:
599 # A descriptive name of the devkit
600 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
601 # Corresponds to --with-extra-path
602 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
603 # Corresponds to --with-toolchain-path
604 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
605 # Corresponds to --with-sysroot
606 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
607
608 # Identifies the Visual Studio version in the devkit
609 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
610 # The Visual Studio include environment variable
611 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
612 # The Visual Studio lib environment variable
613 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
614 # Corresponds to --with-msvcr-dll
615 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
616 # Corresponds to --with-msvcp-dll
617 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
618 fi
619
620 AC_MSG_CHECKING([for devkit])
621 if test "x$DEVKIT_NAME" != x; then
622 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
623 else
624 AC_MSG_RESULT([$DEVKIT_ROOT])
625 fi
626
627 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
628
629 # Fallback default of just /bin if DEVKIT_PATH is not defined
630 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
631 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
632 fi
633 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
634
635 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
636 # places for backwards compatiblity.
637 if test "x$DEVKIT_SYSROOT" != x; then
638 SYSROOT="$DEVKIT_SYSROOT"
639 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
640 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
641 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
642 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
643 fi
644
645 if test "x$DEVKIT_ROOT" != x; then
646 DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
647 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
648 DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
649 fi
650 AC_SUBST(DEVKIT_LIB_DIR)
651 fi
652 fi
653
654 # You can force the sysroot if the sysroot encoded into the compiler tools
655 # is not correct.
656 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
657 [alias for --with-sysroot for backwards compatability])],
658 [SYSROOT=$with_sys_root]
659 )
660
661 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
662 [use this directory as sysroot])],
663 [SYSROOT=$with_sysroot]
664 )
665
666 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
667 [alias for --with-toolchain-path for backwards compatibility])],
668 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
669 )
670
671 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
672 [prepend these directories when searching for toolchain binaries (compilers etc)])],
673 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
674 )
675
676 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
677 [prepend these directories to the default path])],
678 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
679 )
680
681 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
682 # If a devkit has been supplied, find xcodebuild in the toolchain_path.
683 # If not, detect if Xcode is installed by running xcodebuild -version
684 # if no Xcode installed, xcodebuild exits with 1
685 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
686 if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
687 # We need to use xcodebuild in the toolchain dir provided by the user, this will
688 # fall back on the stub binary in /usr/bin/xcodebuild
689 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
690 else
691 # this should result in SYSROOT being empty, unless --with-sysroot is provided
692 # when only the command line tools are installed there are no SDKs, so headers
693 # are copied into the system frameworks
694 XCODEBUILD=
695 AC_SUBST(XCODEBUILD)
696 fi
697
698 AC_MSG_CHECKING([for sdk name])
699 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
700 [use the platform SDK of the given name. @<:@macosx@:>@])],
701 [SDKNAME=$with_sdk_name]
702 )
703 AC_MSG_RESULT([$SDKNAME])
704
705 # if toolchain path is specified then don't rely on system headers, they may not compile
706 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
707 test -z "$TOOLCHAIN_PATH" && \
708 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
709
710 if test -z "$SYSROOT"; then
711 if test -n "$XCODEBUILD"; then
712 # if we don't have system headers, use default SDK name (last resort)
713 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
714 SDKNAME=${SDKNAME:-macosx}
715 fi
716
717 if test -n "$SDKNAME"; then
718 # Call xcodebuild to determine SYSROOT
719 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
720 fi
721 else
722 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
723 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
724 fi
725 fi
726 else
727 # warn user if --with-sdk-name was also set
728 if test -n "$with_sdk_name"; then
729 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
730 fi
731 fi
732
733 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
734 # If no system framework headers, then SYSROOT must be set, or we won't build
735 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
736 fi
737
738 # Perform a basic sanity test
739 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
740 if test -z "$SYSROOT"; then
741 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
742 else
743 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
744 fi
745 fi
746
747 # set SDKROOT too, Xcode tools will pick it up
748 SDKROOT="$SYSROOT"
749 AC_SUBST(SDKROOT)
750 fi
751
752 # Prepend the extra path to the global path
753 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
754
755 AC_MSG_CHECKING([for sysroot])
756 AC_MSG_RESULT([$SYSROOT])
757 AC_MSG_CHECKING([for toolchain path])
758 AC_MSG_RESULT([$TOOLCHAIN_PATH])
759 AC_MSG_CHECKING([for extra path])
760 AC_MSG_RESULT([$EXTRA_PATH])
761 ])
762
763 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
764 [
765
766 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
767 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
768 [ CONF_NAME=${with_conf_name} ])
769
770 # Test from where we are running configure, in or outside of src root.
771 AC_MSG_CHECKING([where to store configuration])
772 if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
773 || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
774 || test "x$CURDIR" = "x$TOPDIR/make" ; then
775 # We are running configure from the src root.
776 # Create a default ./build/target-variant-debuglevel output root.
777 if test "x${CONF_NAME}" = x; then
778 AC_MSG_RESULT([in default location])
779 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
780 else
781 AC_MSG_RESULT([in build directory with custom name])
782 fi
783
784 if test "x$CUSTOM_ROOT" != x; then
785 OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
786 else
787 OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
788 fi
789 $MKDIR -p "$OUTPUTDIR"
790 if test ! -d "$OUTPUTDIR"; then
791 AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
792 fi
793 else
794 # We are running configure from outside of the src dir.
795 # Then use the current directory as output dir!
796 # If configuration is situated in normal build directory, just use the build
797 # directory name as configuration name, otherwise use the complete path.
798 if test "x${CONF_NAME}" = x; then
799 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
800 fi
801 OUTPUTDIR="$CURDIR"
802 AC_MSG_RESULT([in current directory])
803
804 # WARNING: This might be a bad thing to do. You need to be sure you want to
805 # have a configuration in this directory. Do some sanity checks!
806
807 if test ! -e "$OUTPUTDIR/spec.gmk"; then
808 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
809 # other files
810 files_present=`$LS $OUTPUTDIR`
811 # Configure has already touched config.log and confdefs.h in the current dir when this check
812 # is performed.
813 filtered_files=`$ECHO "$files_present" \
814 | $SED -e 's/config.log//g' \
815 -e 's/configure.log//g' \
816 -e 's/confdefs.h//g' \
817 -e 's/configure-support//g' \
818 -e 's/ //g' \
819 | $TR -d '\n'`
820 if test "x$filtered_files" != x; then
821 AC_MSG_NOTICE([Current directory is $CURDIR.])
822 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
823 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
824 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
825 AC_MSG_NOTICE([seriously mess up just about everything.])
826 AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
827 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
828 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
829 fi
830 fi
831 fi
832 AC_MSG_CHECKING([what configuration name to use])
833 AC_MSG_RESULT([$CONF_NAME])
834
835 BASIC_FIXUP_PATH(OUTPUTDIR)
836
837 CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
838 $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
839
840 SPEC="$OUTPUTDIR/spec.gmk"
841 AC_SUBST(SPEC)
842 AC_SUBST(CONF_NAME)
843 AC_SUBST(OUTPUTDIR)
844 AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
845
846 # The spec.gmk file contains all variables for the make system.
847 AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
848 # The bootcycle-spec.gmk file contains support for boot cycle builds.
849 AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
850 # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
851 AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
852 # The compare.sh is used to compare the build output to other builds.
853 AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
854 # The generated Makefile knows where the spec.gmk is and where the source is.
855 # You can run make from the OUTPUTDIR, or from the top-level Makefile
856 # which will look for generated configurations
857 AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
858 ])
859
860 #%%% Simple tools %%%
861
862 # Check if we have found a usable version of make
863 # $1: the path to a potential make binary (or empty)
864 # $2: the description on how we found this
865 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
866 [
867 MAKE_CANDIDATE="$1"
868 DESCRIPTION="$2"
869
870 # On Cygwin, we require a newer version of make than on other platforms
871 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
872 MAKE_VERSION_EXPR="-e 4\."
873 MAKE_REQUIRED_VERSION="4.0"
874 else
875 MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
876 MAKE_REQUIRED_VERSION="3.81"
877 fi
878
879 if test "x$MAKE_CANDIDATE" != x; then
880 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
881 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
882 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
883 if test "x$IS_GNU_MAKE" = x; then
884 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
885 else
886 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
887 if test "x$IS_MODERN_MAKE" = x; then
888 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
889 else
890 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
891 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
892 MAKE_EXPECTED_ENV='cygwin'
893 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
894 MAKE_EXPECTED_ENV='msys'
895 else
896 AC_MSG_ERROR([Unknown Windows environment])
897 fi
898 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
899 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
900 else
901 # Not relevant for non-Windows
902 IS_MAKE_CORRECT_ENV=true
903 fi
904 if test "x$IS_MAKE_CORRECT_ENV" = x; then
905 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
906 else
907 FOUND_MAKE=$MAKE_CANDIDATE
908 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
909 fi
910 fi
911 fi
912 fi
913 ])
914
915 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
916 [
917 # Check if make supports the output sync option and if so, setup using it.
918 AC_MSG_CHECKING([if make --output-sync is supported])
919 if $MAKE --version -O > /dev/null 2>&1; then
920 OUTPUT_SYNC_SUPPORTED=true
921 AC_MSG_RESULT([yes])
922 AC_MSG_CHECKING([for output-sync value])
923 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
924 [set make output sync type if supported by make. @<:@recurse@:>@])],
925 [OUTPUT_SYNC=$with_output_sync])
926 if test "x$OUTPUT_SYNC" = "x"; then
927 OUTPUT_SYNC=none
928 fi
929 AC_MSG_RESULT([$OUTPUT_SYNC])
930 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
931 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
932 fi
933 else
934 OUTPUT_SYNC_SUPPORTED=false
935 AC_MSG_RESULT([no])
936 fi
937 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
938 AC_SUBST(OUTPUT_SYNC)
939 ])
940
941 # Goes looking for a usable version of GNU make.
942 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
943 [
944 BASIC_SETUP_TOOL([MAKE],
945 [
946 # Try our hardest to locate a correct version of GNU make
947 AC_PATH_PROGS(CHECK_GMAKE, gmake)
948 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
949
950 if test "x$FOUND_MAKE" = x; then
951 AC_PATH_PROGS(CHECK_MAKE, make)
952 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
953 fi
954
955 if test "x$FOUND_MAKE" = x; then
956 if test "x$TOOLCHAIN_PATH" != x; then
957 # We have a toolchain path, check that as well before giving up.
958 OLD_PATH=$PATH
959 PATH=$TOOLCHAIN_PATH:$PATH
960 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
961 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
962 if test "x$FOUND_MAKE" = x; then
963 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
964 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
965 fi
966 PATH=$OLD_PATH
967 fi
968 fi
969
970 if test "x$FOUND_MAKE" = x; then
971 AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
972 fi
973 ],[
974 # If MAKE was set by user, verify the version
975 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
976 if test "x$FOUND_MAKE" = x; then
977 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
978 fi
979 ])
980
981 MAKE=$FOUND_MAKE
982 AC_SUBST(MAKE)
983 AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
984
985 BASIC_CHECK_MAKE_OUTPUT_SYNC
986 ])
987
988 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
989 [
990 # Test if find supports -delete
991 AC_MSG_CHECKING([if find supports -delete])
992 FIND_DELETE="-delete"
993
994 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
995
996 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
997
998 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
999 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1000 # No, it does not.
1001 $RM $DELETEDIR/TestIfFindSupportsDelete
1002 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1003 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1004 FIND_DELETE="-print | $XARGS $RM"
1005 else
1006 FIND_DELETE="-exec $RM \{\} \+"
1007 fi
1008 AC_MSG_RESULT([no])
1009 else
1010 AC_MSG_RESULT([yes])
1011 fi
1012 $RMDIR $DELETEDIR
1013 AC_SUBST(FIND_DELETE)
1014 ])
1015
1016 AC_DEFUN([BASIC_CHECK_TAR],
1017 [
1018 # Test which kind of tar was found
1019 if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1020 TAR_TYPE="gnu"
1021 elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1022 TAR_TYPE="bsd"
1023 elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1024 TAR_TYPE="bsd"
1025 elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1026 TAR_TYPE="solaris"
1027 fi
1028 AC_MSG_CHECKING([what type of tar was found])
1029 AC_MSG_RESULT([$TAR_TYPE])
1030
1031 TAR_CREATE_FILE_PARAM=""
1032
1033 if test "x$TAR_TYPE" = "xgnu"; then
1034 TAR_INCLUDE_PARAM="T"
1035 TAR_SUPPORTS_TRANSFORM="true"
1036 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1037 # When using gnu tar for Solaris targets, need to use compatibility mode
1038 TAR_CREATE_EXTRA_PARAM="--format=ustar"
1039 fi
1040 else
1041 TAR_INCLUDE_PARAM="I"
1042 TAR_SUPPORTS_TRANSFORM="false"
1043 fi
1044 AC_SUBST(TAR_TYPE)
1045 AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1046 AC_SUBST(TAR_INCLUDE_PARAM)
1047 AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1048 ])
1049
1050 AC_DEFUN([BASIC_CHECK_GREP],
1051 [
1052 # Test that grep supports -Fx with a list of pattern which includes null pattern.
1053 # This is a problem for the grep resident on AIX.
1054 AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1055 # Multiple subsequent spaces..
1056 STACK_SPACES='aaa bbb ccc'
1057 # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1058 # patterns in it.
1059 STACK_LIST=${STACK_SPACES// /$'\n'}
1060 NEEDLE_SPACES='ccc bbb aaa'
1061 NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1062 RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1063 if test "x$RESULT" == "x"; then
1064 AC_MSG_RESULT([yes])
1065 else
1066 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1067 ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1068 fi
1069 AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1070 fi
1071 ])
1072
1073 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1074 [
1075 BASIC_CHECK_GNU_MAKE
1076
1077 BASIC_CHECK_FIND_DELETE
1078 BASIC_CHECK_TAR
1079 BASIC_CHECK_GREP
1080
1081 # These tools might not be installed by default,
1082 # need hint on how to install them.
1083 BASIC_REQUIRE_PROGS(UNZIP, unzip)
1084 # Since zip uses "ZIP" as a environment variable for passing options, we need
1085 # to name our variable differently, hence ZIPEXE.
1086 BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1087
1088 # Non-required basic tools
1089
1090 BASIC_PATH_PROGS(LDD, ldd)
1091 if test "x$LDD" = "x"; then
1092 # List shared lib dependencies is used for
1093 # debug output and checking for forbidden dependencies.
1094 # We can build without it.
1095 LDD="true"
1096 fi
1097 BASIC_PATH_PROGS(READELF, [greadelf readelf])
1098 BASIC_PATH_PROGS(DOT, dot)
1099 BASIC_PATH_PROGS(HG, hg)
1100 BASIC_PATH_PROGS(STAT, stat)
1101 BASIC_PATH_PROGS(TIME, time)
1102 BASIC_PATH_PROGS(FLOCK, flock)
1103 # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1104 # be in the user path.
1105 BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1106 BASIC_PATH_PROGS(PATCH, [gpatch patch])
1107 # Check if it's GNU time
1108 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1109 if test "x$IS_GNU_TIME" != x; then
1110 IS_GNU_TIME=yes
1111 else
1112 IS_GNU_TIME=no
1113 fi
1114 AC_SUBST(IS_GNU_TIME)
1115
1116 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1117 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1118 BASIC_REQUIRE_PROGS(XATTR, xattr)
1119 BASIC_PATH_PROGS(CODESIGN, codesign)
1120 if test "x$CODESIGN" != "x"; then
1121 # Verify that the openjdk_codesign certificate is present
1122 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1123 $RM codesign-testfile
1124 $TOUCH codesign-testfile
1125 $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1126 $RM codesign-testfile
1127 if test "x$CODESIGN" = x; then
1128 AC_MSG_RESULT([no])
1129 else
1130 AC_MSG_RESULT([yes])
1131 fi
1132 fi
1133 BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1134 fi
1135 ])
1136
1137 # Check if build directory is on local disk. If not possible to determine,
1138 # we prefer to claim it's local.
1139 # Argument 1: directory to test
1140 # Argument 2: what to do if it is on local disk
1141 # Argument 3: what to do otherwise (remote disk or failure)
1142 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1143 [
1144 # df -l lists only local disks; if the given directory is not found then
1145 # a non-zero exit code is given
1146 if test "x$DF" = x; then
1147 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1148 # msys does not have df; use Windows "net use" instead.
1149 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1150 if test "x$IS_NETWORK_DISK" = x; then
1151 $2
1152 else
1153 $3
1154 fi
1155 else
1156 # No df here, say it's local
1157 $2
1158 fi
1159 else
1160 # JDK-8189619
1161 # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1162 # is the same. On older AIXes we just continue to live with a "not local build" warning.
1163 if test "x$OPENJDK_TARGET_OS" = xaix; then
1164 DF_LOCAL_ONLY_OPTION='-T local'
1165 else
1166 DF_LOCAL_ONLY_OPTION='-l'
1167 fi
1168 if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1169 $2
1170 else
1171 $3
1172 fi
1173 fi
1174 ])
1175
1176 # Check that source files have basic read permissions set. This might
1177 # not be the case in cygwin in certain conditions.
1178 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1179 [
1180 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1181 file_to_test="$TOPDIR/LICENSE"
1182 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1183 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1184 fi
1185 fi
1186 ])
1187
1188 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1189 [
1190 AC_MSG_CHECKING([if build directory is on local disk])
1191 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1192 [OUTPUT_DIR_IS_LOCAL="yes"],
1193 [OUTPUT_DIR_IS_LOCAL="no"])
1194 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1195
1196 BASIC_CHECK_SRC_PERMS
1197
1198 # Check if the user has any old-style ALT_ variables set.
1199 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1200
1201 # Before generating output files, test if they exist. If they do, this is a reconfigure.
1202 # Since we can't properly handle the dependencies for this, warn the user about the situation
1203 if test -e $OUTPUTDIR/spec.gmk; then
1204 IS_RECONFIGURE=yes
1205 else
1206 IS_RECONFIGURE=no
1207 fi
1208 ])
1209
1210 # Check for support for specific options in bash
1211 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1212 [
1213 # Check bash version
1214 # Extra [ ] to stop m4 mangling
1215 [ BASH_VER=`$BASH --version | $SED -n -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1216 AC_MSG_CHECKING([bash version])
1217 AC_MSG_RESULT([$BASH_VER])
1218
1219 BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1220 BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1221 if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1222 AC_MSG_ERROR([bash version 3.2 or better is required])
1223 fi
1224
1225 # Test if bash supports pipefail.
1226 AC_MSG_CHECKING([if bash supports pipefail])
1227 if ${BASH} -c 'set -o pipefail'; then
1228 BASH_ARGS="$BASH_ARGS -o pipefail"
1229 AC_MSG_RESULT([yes])
1230 else
1231 AC_MSG_RESULT([no])
1232 fi
1233
1234 AC_MSG_CHECKING([if bash supports errexit (-e)])
1235 if ${BASH} -e -c 'true'; then
1236 BASH_ARGS="$BASH_ARGS -e"
1237 AC_MSG_RESULT([yes])
1238 else
1239 AC_MSG_RESULT([no])
1240 fi
1241
1242 AC_SUBST(BASH_ARGS)
1243 ])
1244
1245 ################################################################################
1246 #
1247 # Default make target
1248 #
1249 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1250 [
1251 AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1252 [set the default make target @<:@exploded-image@:>@])])
1253 if test "x$with_default_make_target" = "x" \
1254 || test "x$with_default_make_target" = "xyes"; then
1255 DEFAULT_MAKE_TARGET="exploded-image"
1256 elif test "x$with_default_make_target" = "xno"; then
1257 AC_MSG_ERROR([--without-default-make-target is not a valid option])
1258 else
1259 DEFAULT_MAKE_TARGET="$with_default_make_target"
1260 fi
1261
1262 AC_SUBST(DEFAULT_MAKE_TARGET)
1263 ])
1264
1265 # Code to run after AC_OUTPUT
1266 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1267 [
1268 # Try to move config.log (generated by autoconf) to the configure-support directory.
1269 if test -e ./config.log; then
1270 $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1271 fi
1272
1273 # Rotate our log file (configure.log)
1274 if test -e "$OUTPUTDIR/configure.log.old"; then
1275 $RM -f "$OUTPUTDIR/configure.log.old"
1276 fi
1277 if test -e "$OUTPUTDIR/configure.log"; then
1278 $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1279 fi
1280
1281 # Move configure.log from current directory to the build output root
1282 if test -e ./configure.log; then
1283 $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1284 fi
1285
1286 # Make the compare script executable
1287 $CHMOD +x $OUTPUTDIR/compare.sh
1288 ])