1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # All valid JVM features, regardless of platform
  27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
  28     graal vm-structs jni-check services management all-gcs nmt cds \
  29     static-build link-time-opt aot"
  30 
  31 # All valid JVM variants
  32 VALID_JVM_VARIANTS="server client minimal core zero custom"
  33 
  34 ###############################################################################
  35 # Check if the specified JVM variant should be built. To be used in shell if
  36 # constructs, like this:
  37 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
  38 #
  39 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
  40 
  41 # Definition kept in one line to allow inlining in if statements.
  42 # Additional [] needed to keep m4 from mangling shell constructs.
  43 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
  44 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
  45 
  46 ###############################################################################
  47 # Check if the specified JVM features are explicitly enabled. To be used in
  48 # shell if constructs, like this:
  49 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
  50 #
  51 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
  52 
  53 # Definition kept in one line to allow inlining in if statements.
  54 # Additional [] needed to keep m4 from mangling shell constructs.
  55 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
  56 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
  57 
  58 ###############################################################################
  59 # Check which variants of the JVM that we want to build. Available variants are:
  60 #   server: normal interpreter, and a tiered C1/C2 compiler
  61 #   client: normal interpreter, and C1 (no C2 compiler)
  62 #   minimal: reduced form of client with optional features stripped out
  63 #   core: normal interpreter only, no compiler
  64 #   zero: C++ based interpreter only, no compiler
  65 #   custom: baseline JVM with no default features
  66 #
  67 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
  68 [
  69   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  70       [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
  71 
  72   SETUP_HOTSPOT_TARGET_CPU_PORT
  73 
  74   if test "x$with_jvm_variants" = x; then
  75     with_jvm_variants="server"
  76   fi
  77   JVM_VARIANTS_OPT="$with_jvm_variants"
  78 
  79   # Has the user listed more than one variant?
  80   # Additional [] needed to keep m4 from mangling shell constructs.
  81   if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
  82     BUILDING_MULTIPLE_JVM_VARIANTS=true
  83   else
  84     BUILDING_MULTIPLE_JVM_VARIANTS=false
  85   fi
  86   # Replace the commas with AND for use in the build directory name.
  87   JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
  88 
  89   AC_MSG_CHECKING([which variants of the JVM to build])
  90   # JVM_VARIANTS is a space-separated list.
  91   # Also use minimal, not minimal1 (which is kept for backwards compatibility).
  92   JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
  93   AC_MSG_RESULT([$JVM_VARIANTS])
  94 
  95   # Check that the selected variants are valid
  96 
  97   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
  98   # Notice that the original variant failes on SLES 10 and 11
  99   NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
 100   STACK=${JVM_VARIANTS// /$'\n'}
 101   INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 102   if test "x$INVALID_VARIANTS" != x; then
 103     AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
 104     AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
 105   fi
 106 
 107   # All "special" variants share the same output directory ("server")
 108   VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
 109   NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
 110   STACK=${JVM_VARIANTS// /$'\n'}
 111   INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 112   if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
 113     AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
 114   fi
 115 
 116   # The "main" variant is the one used by other libs to link against during the
 117   # build.
 118   if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
 119     MAIN_VARIANT_PRIO_ORDER="server client minimal"
 120     for variant in $MAIN_VARIANT_PRIO_ORDER; do
 121       if HOTSPOT_CHECK_JVM_VARIANT($variant); then
 122         JVM_VARIANT_MAIN="$variant"
 123         break
 124       fi
 125     done
 126   else
 127     JVM_VARIANT_MAIN="$JVM_VARIANTS"
 128   fi
 129 
 130   AC_SUBST(JVM_VARIANTS)
 131   AC_SUBST(VALID_JVM_VARIANTS)
 132   AC_SUBST(JVM_VARIANT_MAIN)
 133 
 134   if HOTSPOT_CHECK_JVM_VARIANT(zero); then
 135     # zero behaves as a platform and rewrites these values. This is really weird. :(
 136     # We are guaranteed that we do not build any other variants when building zero.
 137     HOTSPOT_TARGET_CPU=zero
 138     HOTSPOT_TARGET_CPU_ARCH=zero
 139   fi
 140 ])
 141 
 142 ###############################################################################
 143 # Check if dtrace should be enabled and has all prerequisites present.
 144 #
 145 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
 146 [
 147   # Test for dtrace dependencies
 148   AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
 149       [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
 150       are present.])])
 151 
 152   DTRACE_DEP_MISSING=false
 153 
 154   AC_MSG_CHECKING([for dtrace tool])
 155   if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
 156     AC_MSG_RESULT([$DTRACE])
 157   else
 158     AC_MSG_RESULT([not found, cannot build dtrace])
 159     DTRACE_DEP_MISSING=true
 160   fi
 161 
 162   AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
 163   if test "x$DTRACE_HEADERS_OK" != "xyes"; then
 164     DTRACE_DEP_MISSING=true
 165   fi
 166 
 167   AC_MSG_CHECKING([if dtrace should be built])
 168   if test "x$enable_dtrace" = "xyes"; then
 169     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 170       AC_MSG_RESULT([no, missing dependencies])
 171       HELP_MSG_MISSING_DEPENDENCY([dtrace])
 172       AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
 173     else
 174       INCLUDE_DTRACE=true
 175       AC_MSG_RESULT([yes, forced])
 176     fi
 177   elif test "x$enable_dtrace" = "xno"; then
 178     INCLUDE_DTRACE=false
 179     AC_MSG_RESULT([no, forced])
 180   elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
 181     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 182       INCLUDE_DTRACE=false
 183       AC_MSG_RESULT([no, missing dependencies])
 184     else
 185       INCLUDE_DTRACE=true
 186       AC_MSG_RESULT([yes, dependencies present])
 187     fi
 188   else
 189     AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
 190   fi
 191 ])
 192 
 193 ################################################################################
 194 # Check if AOT should be enabled
 195 #
 196 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
 197 [
 198   AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
 199       [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
 200 
 201   if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
 202     ENABLE_AOT="true"
 203   elif test "x$enable_aot" = "xyes"; then
 204     ENABLE_AOT="true"
 205   elif test "x$enable_aot" = "xno"; then
 206     ENABLE_AOT="false"
 207     AC_MSG_CHECKING([if aot should be enabled])
 208     AC_MSG_RESULT([no, forced])
 209   else
 210     AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
 211   fi
 212 
 213   if test "x$ENABLE_AOT" = "xtrue"; then
 214     # Only enable AOT on X64 platforms.
 215     if test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
 216       if test -e "${TOPDIR}/src/jdk.aot"; then
 217         if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
 218           ENABLE_AOT="true"
 219         else
 220           ENABLE_AOT="false"
 221           if test "x$enable_aot" = "xyes"; then
 222             AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
 223           fi
 224         fi
 225       else
 226         ENABLE_AOT="false"
 227         if test "x$enable_aot" = "xyes"; then
 228           AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
 229         fi
 230       fi
 231     else
 232       ENABLE_AOT="false"
 233       if test "x$enable_aot" = "xyes"; then
 234         AC_MSG_ERROR([AOT is currently only supported on x86_64. Remove --enable-aot.])
 235       fi
 236     fi
 237   fi
 238 
 239   AC_SUBST(ENABLE_AOT)
 240 ])
 241 
 242 ################################################################################
 243 # Allow to disable CDS
 244 #
 245 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
 246 [
 247   AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no@:>@],
 248       [enable class data sharing feature in non-minimal VM. Default is yes.])])
 249 
 250   if test "x$enable_cds" = "x" || test "x$enable_cds" = "xyes"; then
 251     ENABLE_CDS="true"
 252   elif test "x$enable_cds" = "xno"; then
 253     ENABLE_CDS="false"
 254   else
 255     AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
 256   fi
 257 
 258   AC_SUBST(ENABLE_CDS)
 259 ])
 260 
 261 ###############################################################################
 262 # Set up all JVM features for each JVM variant.
 263 #
 264 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
 265 [
 266   # The user can in some cases supply additional jvm features. For the custom
 267   # variant, this defines the entire variant.
 268   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
 269       [additional JVM features to enable (separated by comma),  use '--help' to show possible values @<:@none@:>@])])
 270   if test "x$with_jvm_features" != x; then
 271     AC_MSG_CHECKING([additional JVM features])
 272     JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
 273     AC_MSG_RESULT([$JVM_FEATURES])
 274   fi
 275 
 276   # Override hotspot cpu definitions for ARM platforms
 277   if test "x$OPENJDK_TARGET_CPU" = xarm; then
 278     HOTSPOT_TARGET_CPU=arm_32
 279     HOTSPOT_TARGET_CPU_DEFINE="ARM32"
 280   elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 281     HOTSPOT_TARGET_CPU=arm_64
 282     HOTSPOT_TARGET_CPU_ARCH=arm
 283   fi
 284 
 285   # Verify that dependencies are met for explicitly set features.
 286   if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
 287     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
 288   fi
 289 
 290   if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
 291     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
 292   fi
 293 
 294   if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
 295     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
 296   fi
 297 
 298   if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
 299     AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
 300   fi
 301 
 302   if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
 303     AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
 304   fi
 305 
 306   # Turn on additional features based on other parts of configure
 307   if test "x$INCLUDE_DTRACE" = "xtrue"; then
 308     JVM_FEATURES="$JVM_FEATURES dtrace"
 309   else
 310     if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
 311       AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
 312     fi
 313   fi
 314 
 315   if test "x$STATIC_BUILD" = "xtrue"; then
 316     JVM_FEATURES="$JVM_FEATURES static-build"
 317   else
 318     if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
 319       AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
 320     fi
 321   fi
 322 
 323   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 324     if HOTSPOT_CHECK_JVM_FEATURE(zero); then
 325       AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
 326     fi
 327   fi
 328 
 329   # Only enable jvmci on x86_64, sparcv9 and aarch64.
 330   if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 331      test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
 332      test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 333     JVM_FEATURES_jvmci="jvmci"
 334   else
 335     JVM_FEATURES_jvmci=""
 336   fi
 337 
 338   AC_MSG_CHECKING([if jdk.internal.vm.compiler should be built])
 339   if HOTSPOT_CHECK_JVM_FEATURE(graal); then
 340     AC_MSG_RESULT([yes, forced])
 341     if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
 342       AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
 343     fi
 344     INCLUDE_GRAAL="true"
 345   else
 346     # By default enable graal build on x64 or where AOT is available.
 347     # graal build requires jvmci.
 348     if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
 349         (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 350          test "x$ENABLE_AOT" = "xtrue") ; then
 351       AC_MSG_RESULT([yes])
 352       JVM_FEATURES_graal="graal"
 353       INCLUDE_GRAAL="true"
 354     else
 355       AC_MSG_RESULT([no])
 356       JVM_FEATURES_graal=""
 357       INCLUDE_GRAAL="false"
 358     fi
 359   fi
 360 
 361   AC_SUBST(INCLUDE_GRAAL)
 362 
 363   AC_MSG_CHECKING([if aot should be enabled])
 364   if test "x$ENABLE_AOT" = "xtrue"; then
 365     if test "x$enable_aot" = "xyes"; then
 366       AC_MSG_RESULT([yes, forced])
 367     else
 368       AC_MSG_RESULT([yes])
 369     fi
 370     JVM_FEATURES_aot="aot"
 371   else
 372     if test "x$enable_aot" = "xno"; then
 373       AC_MSG_RESULT([no, forced])
 374     else
 375       AC_MSG_RESULT([no])
 376     fi
 377     JVM_FEATURES_aot=""
 378   fi
 379 
 380   if test "x$OPENJDK_TARGET_CPU" = xarm ; then
 381     # Default to use link time optimizations on minimal on arm
 382     JVM_FEATURES_link_time_opt="link-time-opt"
 383   else
 384     JVM_FEATURES_link_time_opt=""
 385   fi
 386 
 387   # All variants but minimal (and custom) get these features
 388   NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti vm-structs jni-check services management all-gcs nmt"
 389   if test "x$ENABLE_CDS" = "xtrue"; then
 390     NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
 391   fi
 392 
 393   # Enable features depending on variant.
 394   JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
 395   JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
 396   JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
 397   JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES $JVM_FEATURES_link_time_opt"
 398   JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
 399   JVM_FEATURES_custom="$JVM_FEATURES"
 400 
 401   AC_SUBST(JVM_FEATURES_server)
 402   AC_SUBST(JVM_FEATURES_client)
 403   AC_SUBST(JVM_FEATURES_core)
 404   AC_SUBST(JVM_FEATURES_minimal)
 405   AC_SUBST(JVM_FEATURES_zero)
 406   AC_SUBST(JVM_FEATURES_custom)
 407 
 408   # Used for verification of Makefiles by check-jvm-feature
 409   AC_SUBST(VALID_JVM_FEATURES)
 410 
 411   # We don't support --with-jvm-interpreter anymore, use zero instead.
 412   BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
 413 ])
 414 
 415 ###############################################################################
 416 # Validate JVM features once all setup is complete, including custom setup.
 417 #
 418 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
 419 [
 420   # Keep feature lists sorted and free of duplicates
 421   JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
 422   JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
 423   JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
 424   JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
 425   JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
 426   JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
 427 
 428   # Validate features
 429   for variant in $JVM_VARIANTS; do
 430     AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
 431     features_var_name=JVM_FEATURES_$variant
 432     JVM_FEATURES_TO_TEST=${!features_var_name}
 433     AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
 434     NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
 435     STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
 436     INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 437     if test "x$INVALID_FEATURES" != x; then
 438       AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
 439     fi
 440   done
 441 ])
 442 
 443 ################################################################################
 444 #
 445 # Specify which sources will be used to build the 64-bit ARM port
 446 #
 447 # --with-cpu-port=arm64   will use hotspot/src/cpu/arm
 448 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
 449 #
 450 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
 451 [
 452   AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
 453       [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
 454 
 455   if test "x$with_cpu_port" != x; then
 456     if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
 457       AC_MSG_ERROR([--with-cpu-port only available on aarch64])
 458     fi
 459     if test "x$with_cpu_port" != xarm64 && \
 460         test "x$with_cpu_port" != xaarch64; then
 461       AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
 462     fi
 463     HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
 464   fi
 465 ])
 466 
 467 
 468 ################################################################################
 469 # Check if gtest should be built
 470 #
 471 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
 472 [
 473   AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
 474       [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
 475 
 476   if test -e "${TOPDIR}/test/hotspot/gtest"; then
 477     GTEST_DIR_EXISTS="true"
 478   else
 479     GTEST_DIR_EXISTS="false"
 480   fi
 481 
 482   AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
 483   if test "x$enable_hotspot_gtest" = "xyes"; then
 484     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 485       AC_MSG_RESULT([yes, forced])
 486       BUILD_GTEST="true"
 487     else
 488       AC_MSG_ERROR([Cannot build gtest without the test source])
 489     fi
 490   elif test "x$enable_hotspot_gtest" = "xno"; then
 491     AC_MSG_RESULT([no, forced])
 492     BUILD_GTEST="false"
 493   elif test "x$enable_hotspot_gtest" = "x"; then
 494     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 495       AC_MSG_RESULT([yes])
 496       BUILD_GTEST="true"
 497     else
 498       AC_MSG_RESULT([no])
 499       BUILD_GTEST="false"
 500     fi
 501   else
 502     AC_MSG_ERROR([--enable-gtest must be either yes or no])
 503   fi
 504 
 505   AC_SUBST(BUILD_GTEST)
 506 ])