1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 C_FLAG_REORDER=''
39
40 # Default works for linux, might work on other platforms as well.
41 SHARED_LIBRARY_FLAGS='-shared'
42 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
43 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
44 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
45 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
46
47 elif test "x$TOOLCHAIN_TYPE" = xclang; then
48 C_FLAG_REORDER=''
49
50 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
51 # Linking is different on MacOSX
52 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
53 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
54 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
55 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
56 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
57
58 else
59 # Default works for linux, might work on other platforms as well.
60 SHARED_LIBRARY_FLAGS='-shared'
61 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
62 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
63 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
64
65 # arm specific settings
66 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
67 # '-Wl,-z,origin' isn't used on arm.
68 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
69 else
70 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
71 fi
72 fi
73
74 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
75 C_FLAG_REORDER='-xF'
76 SHARED_LIBRARY_FLAGS="-G"
77 SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
78 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
79 SET_SHARED_LIBRARY_NAME='-h [$]1'
80 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
81
82 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
83 C_FLAG_REORDER=''
84 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
85 SET_EXECUTABLE_ORIGIN=""
86 SET_SHARED_LIBRARY_ORIGIN=''
87 SET_SHARED_LIBRARY_NAME=''
88 SET_SHARED_LIBRARY_MAPFILE=''
89
90 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
91 C_FLAG_REORDER=''
92 SHARED_LIBRARY_FLAGS="-dll"
93 SET_EXECUTABLE_ORIGIN=''
94 SET_SHARED_LIBRARY_ORIGIN=''
95 SET_SHARED_LIBRARY_NAME=''
96 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
97 fi
98
99 AC_SUBST(C_FLAG_REORDER)
100 AC_SUBST(SET_EXECUTABLE_ORIGIN)
101 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
102 AC_SUBST(SET_SHARED_LIBRARY_NAME)
103 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
104 AC_SUBST(SHARED_LIBRARY_FLAGS)
105 ])
106
107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
108 [
109 # By default don't set any specific assembler debug
110 # info flags for toolchains unless we know they work.
111 # See JDK-8207057.
112 ASFLAGS_DEBUG_SYMBOLS=""
113 # Debug symbols
114 if test "x$TOOLCHAIN_TYPE" = xgcc; then
115 CFLAGS_DEBUG_SYMBOLS="-g"
116 ASFLAGS_DEBUG_SYMBOLS="-g"
117 elif test "x$TOOLCHAIN_TYPE" = xclang; then
118 CFLAGS_DEBUG_SYMBOLS="-g"
119 ASFLAGS_DEBUG_SYMBOLS="-g"
120 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
121 # -g0 enables debug symbols without disabling inlining.
122 CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
123 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
124 CFLAGS_DEBUG_SYMBOLS="-g"
125 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
126 CFLAGS_DEBUG_SYMBOLS="-Z7 -d2Zi+"
127 fi
128
129 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
130 AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
131 ])
132
133 AC_DEFUN([FLAGS_SETUP_WARNINGS],
134 [
135 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
136 [do not consider native warnings to be an error @<:@enabled@:>@])])
137
138 # Set default value.
139 if test "x$TOOLCHAIN_TYPE" = xxlc; then
140 WARNINGS_AS_ERRORS=false
141 else
142 WARNINGS_AS_ERRORS=true
143 fi
144
145 AC_MSG_CHECKING([if native warnings are errors])
146 if test "x$enable_warnings_as_errors" = "xyes"; then
147 AC_MSG_RESULT([yes (explicitly set)])
148 WARNINGS_AS_ERRORS=true
149 elif test "x$enable_warnings_as_errors" = "xno"; then
150 AC_MSG_RESULT([no (explicitly set)])
151 WARNINGS_AS_ERRORS=false
152 elif test "x$enable_warnings_as_errors" = "x"; then
153 AC_MSG_RESULT([${WARNINGS_AS_ERRORS} (default)])
154 else
155 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
156 fi
157
158 AC_SUBST(WARNINGS_AS_ERRORS)
159
160 case "${TOOLCHAIN_TYPE}" in
161 microsoft)
162 DISABLE_WARNING_PREFIX="-wd"
163 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
164
165 WARNINGS_ENABLE_ALL="-W3"
166 DISABLED_WARNINGS="4800"
167 ;;
168
169 solstudio)
170 DISABLE_WARNING_PREFIX="-erroff="
171 CFLAGS_WARNINGS_ARE_ERRORS="-errwarn=%all"
172
173 WARNINGS_ENABLE_ALL_CFLAGS="-v"
174 WARNINGS_ENABLE_ALL_CXXFLAGS="+w"
175
176 DISABLED_WARNINGS_C=""
177 DISABLED_WARNINGS_CXX=""
178 ;;
179
180 gcc)
181 DISABLE_WARNING_PREFIX="-Wno-"
182 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
183
184 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2"
185 WARNINGS_ENABLE_ADDITIONAL_JVM="-Wpointer-arith -Wsign-compare -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual -Wreorder -Wreturn-type"
186
187 DISABLED_WARNINGS="unused-parameter unused"
188
189 # Repeate the check for the BUILD_CC and BUILD_CXX. Need to also reset
190 # CFLAGS since any target specific flags will likely not work with the
191 # build compiler
192 CC_OLD="$CC"
193 CXX_OLD="$CXX"
194 CC="$BUILD_CC"
195 CXX="$BUILD_CXX"
196 CFLAGS_OLD="$CFLAGS"
197 CFLAGS=""
198 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
199 CC="$CC_OLD"
200 CXX="$CXX_OLD"
201 CFLAGS="$CFLAGS_OLD"
202 ;;
203
204 clang)
205 DISABLE_WARNING_PREFIX="-Wno-"
206 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
207
208 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2"
209 WARNINGS_ENABLE_ADDITIONAL_JVM="-Wpointer-arith -Wsign-compare -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual -Wreorder"
210
211 DISABLED_WARNINGS="unused-parameter unused"
212 ;;
213
214 xlc)
215 DISABLE_WARNING_PREFIX="-qsuppress="
216 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
217
218 # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
219 WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
220 DISABLED_WARNINGS=""
221 ;;
222 esac
223 AC_SUBST(DISABLE_WARNING_PREFIX)
224 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
225 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
226 AC_SUBST(DISABLED_WARNINGS)
227 AC_SUBST(DISABLED_WARNINGS_C)
228 AC_SUBST(DISABLED_WARNINGS_CXX)
229 ])
230
231 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
232 [
233 # bounds, memory and behavior checking options
234 if test "x$TOOLCHAIN_TYPE" = xgcc; then
235 case $DEBUG_LEVEL in
236 release )
237 # no adjustment
238 ;;
239 fastdebug )
240 # no adjustment
241 ;;
242 slowdebug )
243 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
244 # get's added conditionally on whether we produce debug symbols or not.
245 # This is most likely not really correct.
246
247 # Add runtime stack smashing and undefined behavior checks.
248 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
249 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
250
251 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
252 ;;
253 esac
254 fi
255 ])
256
257 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
258 [
259 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
260 CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
261
262 C_O_FLAG_HIGHEST_JVM="-xO4"
263 C_O_FLAG_DEBUG_JVM=""
264 C_O_FLAG_SIZE=""
265 C_O_FLAG_DEBUG=""
266 C_O_FLAG_NONE=""
267 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
268 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
269 C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
270 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
271 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
272 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
273 -xprefetch=auto,explicit $CC_HIGHEST"
274 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
275 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
276 fi
277 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
278 C_O_FLAG_HIGHEST_JVM="-O3"
279 C_O_FLAG_HIGHEST="-O3"
280 C_O_FLAG_HI="-O3"
281 C_O_FLAG_NORM="-O2"
282 C_O_FLAG_SIZE="-Os"
283 C_O_FLAG_DEBUG="-O0"
284 C_O_FLAG_DEBUG_JVM="-O0"
285 C_O_FLAG_NONE="-O0"
286 elif test "x$TOOLCHAIN_TYPE" = xclang; then
287 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
288 # On MacOSX we optimize for size, something
289 # we should do for all platforms?
290 C_O_FLAG_HIGHEST_JVM="-Os"
291 C_O_FLAG_HIGHEST="-Os"
292 C_O_FLAG_HI="-Os"
293 C_O_FLAG_NORM="-Os"
294 C_O_FLAG_DEBUG_JVM=""
295 else
296 C_O_FLAG_HIGHEST_JVM="-O3"
297 C_O_FLAG_HIGHEST="-O3"
298 C_O_FLAG_HI="-O3"
299 C_O_FLAG_NORM="-O2"
300 C_O_FLAG_DEBUG_JVM="-O0"
301 fi
302 C_O_FLAG_SIZE="-Os"
303 C_O_FLAG_DEBUG="-O0"
304 C_O_FLAG_NONE="-O0"
305 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
306 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
307 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
308 C_O_FLAG_HI="-O3 -qinline -qinlglue"
309 C_O_FLAG_NORM="-O2"
310 C_O_FLAG_DEBUG="-qnoopt"
311 # FIXME: Value below not verified.
312 C_O_FLAG_DEBUG_JVM=""
313 C_O_FLAG_NONE="-qnoopt"
314 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
315 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
316 C_O_FLAG_HIGHEST="-O2"
317 C_O_FLAG_HI="-O1"
318 C_O_FLAG_NORM="-O1"
319 C_O_FLAG_DEBUG="-Od"
320 C_O_FLAG_DEBUG_JVM=""
321 C_O_FLAG_NONE="-Od"
322 C_O_FLAG_SIZE="-Os"
323 fi
324
325 # Now copy to C++ flags
326 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
327 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
328 CXX_O_FLAG_HI="$C_O_FLAG_HI"
329 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
330 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
331 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
332 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
333 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
334
335 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
336 # In solstudio, also add this to C (but not C++) flags...
337 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
338 fi
339
340 # Adjust optimization flags according to debug level.
341 case $DEBUG_LEVEL in
342 release )
343 # no adjustment
344 ;;
345 fastdebug )
346 # Not quite so much optimization
347 C_O_FLAG_HI="$C_O_FLAG_NORM"
348 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
349 ;;
350 slowdebug )
351 # Disable optimization
352 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
353 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
354 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
355 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
356 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
357 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
358 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
359 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
360 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
361 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
362 ;;
363 esac
364
365 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
366 AC_SUBST(C_O_FLAG_HIGHEST)
367 AC_SUBST(C_O_FLAG_HI)
368 AC_SUBST(C_O_FLAG_NORM)
369 AC_SUBST(C_O_FLAG_NONE)
370 AC_SUBST(C_O_FLAG_SIZE)
371 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
372 AC_SUBST(CXX_O_FLAG_HIGHEST)
373 AC_SUBST(CXX_O_FLAG_HI)
374 AC_SUBST(CXX_O_FLAG_NORM)
375 AC_SUBST(CXX_O_FLAG_NONE)
376 AC_SUBST(CXX_O_FLAG_SIZE)
377 ])
378
379 AC_DEFUN([FLAGS_SETUP_CFLAGS],
380 [
381 ### CFLAGS
382
383 FLAGS_SETUP_CFLAGS_HELPER
384
385 FLAGS_OS=$OPENJDK_TARGET_OS
386 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
387 FLAGS_CPU=$OPENJDK_TARGET_CPU
388 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
389 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
390 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
391 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
392 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
393
394 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
395
396 FLAGS_OS=$OPENJDK_BUILD_OS
397 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
398 FLAGS_CPU=$OPENJDK_BUILD_CPU
399 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
400 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
401 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
402 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
403 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
404
405 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
406
407 COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
408 # Check that the compiler supports -ffp-contract=off flag
409 # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
410 # otherwise.
411 # These flags are required for GCC-based builds of
412 # fdlibm with optimization without losing precision.
413 # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
414 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
415 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
416 IF_TRUE: [FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
417 IF_FALSE: [FDLIBM_CFLAGS=""])
418 fi
419 AC_SUBST(FDLIBM_CFLAGS)
420 ])
421
422 ################################################################################
423 # platform independent
424 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
425 [
426 #### OS DEFINES, these should be independent on toolchain
427 if test "x$OPENJDK_TARGET_OS" = xlinux; then
428 CFLAGS_OS_DEF_JVM="-DLINUX"
429 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
430 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
431 CFLAGS_OS_DEF_JVM="-DSOLARIS"
432 CFLAGS_OS_DEF_JDK="-D__solaris__"
433 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
434 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
435 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
436 elif test "x$OPENJDK_TARGET_OS" = xaix; then
437 CFLAGS_OS_DEF_JVM="-DAIX"
438 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
439 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
440 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
441 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
442 fi
443
444 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
445
446 #### GLOBAL DEFINES
447 # Set some common defines. These works for all compilers, but assume
448 # -D is universally accepted.
449
450 # Always enable optional macros for VM.
451 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
452
453 # Setup some hard coded includes
454 ALWAYS_CFLAGS_JDK=" \
455 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
456 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
457 -I${TOPDIR}/src/java.base/share/native/libjava \
458 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
459 -I${TOPDIR}/src/hotspot/share/include \
460 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
461
462 ###############################################################################
463
464 # Adjust flags according to debug level.
465 # Setup debug/release defines
466 if test "x$DEBUG_LEVEL" = xrelease; then
467 DEBUG_CFLAGS_JDK="-DNDEBUG"
468 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
469 DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
470 fi
471 else
472 DEBUG_CFLAGS_JDK="-DDEBUG"
473
474 if test "x$TOOLCHAIN_TYPE" = xxlc; then
475 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
476 # Hotspot now overflows its 64K TOC (currently only for debug),
477 # so for debug we build with '-qpic=large -bbigtoc'.
478 DEBUG_CFLAGS_JVM="-qpic=large"
479 fi
480 fi
481
482 if test "x$DEBUG_LEVEL" != xrelease; then
483 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
484 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
485 fi
486
487 #### TOOLCHAIN DEFINES
488
489 if test "x$TOOLCHAIN_TYPE" = xgcc; then
490 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
491 elif test "x$TOOLCHAIN_TYPE" = xclang; then
492 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
493 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
494 ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
495 ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
496 ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
497 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
498 ALWAYS_DEFINES_JVM="-D_REENTRANT"
499 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
500 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
501 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
502 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
503 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
504 fi
505
506 ###############################################################################
507 #
508 #
509 # CFLAGS BASIC
510 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
511 # COMMON to gcc and clang
512 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
513 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
514 fi
515
516 if test "x$TOOLCHAIN_TYPE" = xgcc; then
517 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new"
518 TOOLCHAIN_CFLAGS_JDK="-pipe"
519 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX (but since this gives *worse* performance, use no-strict-aliasing everywhere!)
520
521 CXXSTD_CXXFLAG="-std=gnu++98"
522 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$CXXSTD_CXXFLAG -Werror],
523 IF_FALSE: [CXXSTD_CXXFLAG=""])
524 TOOLCHAIN_CFLAGS_JDK_CXXONLY="$CXXSTD_CXXFLAG"
525 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM $CXXSTD_CXXFLAG"
526 ADLC_CXXFLAG="$CXXSTD_CXXFLAG"
527
528
529 elif test "x$TOOLCHAIN_TYPE" = xclang; then
530 # Restrict the debug information created by Clang to avoid
531 # too big object files and speed the build up a little bit
532 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
533 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
534
535 # In principle the stack alignment below is cpu- and ABI-dependent and
536 # should agree with values of StackAlignmentInBytes in various
537 # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
538 # works for all platforms.
539 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
540
541 if test "x$OPENJDK_TARGET_OS" = xlinux; then
542 TOOLCHAIN_CFLAGS_JDK="-pipe"
543 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
544 fi
545 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
546 TOOLCHAIN_FLAGS="-errtags -errfmt"
547 TOOLCHAIN_CFLAGS="-errshort=tags"
548
549 TOOLCHAIN_CFLAGS_JDK="-mt $TOOLCHAIN_FLAGS"
550 TOOLCHAIN_CFLAGS_JDK_CONLY="-xc99=%none -xCC -Xa -W0,-noglobal $TOOLCHAIN_CFLAGS" # C only
551 TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
552 TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
553 -library=stlport4 -mt -features=no%except $TOOLCHAIN_FLAGS"
554 if test "x$DEBUG_LEVEL" = xslowdebug; then
555 # Previously -g was used instead of -g0 for slowdebug; this is equivalent
556 # to setting +d.
557 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
558 fi
559
560 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
561 # Suggested additions: -qsrcmsg to get improved error reporting
562 TOOLCHAIN_CFLAGS_JDK="-qchars=signed -qfullpath -qsaveopt" # add on both CFLAGS
563 TOOLCHAIN_CFLAGS_JVM="-qtune=balanced \
564 -qalias=noansi -qstrict -qtls=default -qlanglvl=c99vla \
565 -qlanglvl=noredefmac -qnortti -qnoeh -qignerrno"
566 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
567 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
568 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
569 fi
570
571 # CFLAGS WARNINGS STUFF
572 # Set JVM_CFLAGS warning handling
573 if test "x$TOOLCHAIN_TYPE" = xgcc; then
574 WARNING_CFLAGS_JDK="$WARNINGS_ENABLE_ALL"
575 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL $WARNINGS_ENABLE_ADDITIONAL_JVM"
576
577 elif test "x$TOOLCHAIN_TYPE" = xclang; then
578 if test "x$OPENJDK_TARGET_OS" = xlinux; then
579 WARNING_CFLAGS_JDK="$WARNINGS_ENABLE_ALL"
580 else
581 WARNING_CFLAGS_JDK="" # currently left empty
582 fi
583 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL $WARNINGS_ENABLE_ADDITIONAL_JVM"
584
585 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
586 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
587 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
588 WARNING_CFLAGS_JVM="" # currently left empty
589 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
590 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
591 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
592 WARNING_CFLAGS="" # currently left empty
593 fi
594
595 # Set some additional per-OS defines.
596
597 # Additional macosx handling
598 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
599 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
600 -mmacosx-version-min=$MACOSX_VERSION_MIN"
601
602 if test -n "$MACOSX_VERSION_MAX"; then
603 OS_CFLAGS="$OS_CFLAGS \
604 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
605 fi
606 fi
607
608 # Where does this really belong??
609 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
610 PICFLAG="-fPIC"
611 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
612 PICFLAG="-KPIC"
613 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
614 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
615 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
616 # will have to patch this single instruction with a call to some out-of-order code which
617 # does the load from the TOC. This is of course slower, and we also would have
618 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
619 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
620 # can be patched directly by the linker and does not require a jump to out-of-order code.
621 #
622 # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
623 # for all libjvm variants (both gtest and normal) but no other binaries. So, build
624 # libjvm with -qpic=large and link with -bbigtoc.
625 JVM_PICFLAG="-qpic=large"
626 JDK_PICFLAG="-qpic"
627 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
628 PICFLAG=""
629 fi
630
631 if test "x$TOOLCHAIN_TYPE" != xxlc; then
632 JVM_PICFLAG="$PICFLAG"
633 JDK_PICFLAG="$PICFLAG"
634 fi
635
636 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
637 # Linking is different on MacOSX
638 JDK_PICFLAG=''
639 if test "x$STATIC_BUILD" = xtrue; then
640 JVM_PICFLAG=""
641 fi
642 fi
643
644 # Optional POSIX functionality needed by the JVM
645 #
646 # Check if clock_gettime is available and in which library. This indicates
647 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
648 # don't let it update LIBS.
649 save_LIBS="$LIBS"
650 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
651 if test "x$LIBS" = "x-lrt "; then
652 CLOCK_GETTIME_IN_LIBRT=true
653 fi
654 LIBS="$save_LIBS"
655
656 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
657 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
658 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
659 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
660 fi
661 fi
662
663 # EXPORT
664 AC_SUBST(ADLC_CXXFLAG)
665 ])
666
667 ################################################################################
668 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
669 # conditionals against.
670 # $2 - Optional prefix for each variable defined.
671 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
672 [
673 #### CPU DEFINES, these should (in theory) be independent on toolchain
674
675 # Setup target CPU
676 # Setup endianness
677 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
678 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
679 fi
680 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
681 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
682 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
683 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
684 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
685 else
686 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
687 fi
688 else
689 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
690 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
691 else
692 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
693 fi
694 fi
695
696 # setup CPU bit size
697 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
698 -D$FLAGS_CPU_LEGACY"
699
700 if test "x$FLAGS_CPU_BITS" = x64; then
701 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
702 # unpack200.exe.
703 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
704 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
705 fi
706 if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
707 # Solaris does not have _LP64=1 in the old build.
708 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
709 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
710 fi
711 fi
712
713 # toolchain dependend, per-cpu
714 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
715 if test "x$FLAGS_CPU_ARCH" = xx86; then
716 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
717 fi
718 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
719 if test "x$FLAGS_CPU" = xx86_64; then
720 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
721 else
722 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
723 fi
724 fi
725
726 # CFLAGS PER CPU
727 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
728 # COMMON to gcc and clang
729 if test "x$FLAGS_CPU" = xx86; then
730 # Force compatibility with i586 on 32 bit intel platforms.
731 $1_CFLAGS_CPU="-march=i586"
732 fi
733 fi
734
735 if test "x$TOOLCHAIN_TYPE" = xgcc; then
736 if test "x$FLAGS_CPU" = xarm; then
737 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
738 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
739 $1_CFLAGS_CPU_JVM="-DARM"
740 elif test "x$FLAGS_CPU" = xaarch64; then
741 if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
742 $1_CFLAGS_CPU_JVM="-fsigned-char -DARM"
743 fi
744 elif test "x$FLAGS_CPU_ARCH" = xppc; then
745 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
746 if test "x$FLAGS_CPU" = xppc64; then
747 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
748 # Use ppc64 instructions, but schedule for power5
749 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
750 elif test "x$FLAGS_CPU" = xppc64le; then
751 # Little endian machine uses ELFv2 ABI.
752 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
753 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
754 fi
755 elif test "x$FLAGS_CPU" = xs390x; then
756 $1_CFLAGS_CPU="-mbackchain -march=z10"
757 fi
758
759 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
760 # for all archs except arm and ppc, prevent gcc to omit frame pointer
761 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
762 fi
763
764 elif test "x$TOOLCHAIN_TYPE" = xclang; then
765 if test "x$FLAGS_OS" = xlinux; then
766 # ppc test not really needed for clang
767 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
768 # for all archs except arm and ppc, prevent gcc to omit frame pointer
769 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
770 fi
771 fi
772
773 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
774 if test "x$FLAGS_CPU" = xx86_64; then
775 # NOTE: -xregs=no%frameptr is supposed to be default on x64
776 $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
777 elif test "x$FLAGS_CPU" = xsparcv9; then
778 $1_CFLAGS_CPU_JVM="-xarch=sparc"
779 $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
780 fi
781
782 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
783 if test "x$FLAGS_CPU" = xppc64; then
784 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
785 fi
786
787 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
788 if test "x$FLAGS_CPU" = xx86; then
789 $1_CFLAGS_CPU_JVM="-arch:IA32"
790 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
791 if test "x$DEBUG_LEVEL" != xrelease; then
792 # NOTE: This is probably redundant; -homeparams is default on
793 # non-release builds.
794 $1_CFLAGS_CPU_JVM="-homeparams"
795 fi
796 fi
797 fi
798
799 if test "x$TOOLCHAIN_TYPE" = xgcc; then
800 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: 6, PREFIX: $2, IF_AT_LEAST: FLAGS_SETUP_GCC6_COMPILER_FLAGS($1))
801 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
802
803 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
804 fi
805
806 # EXPORT to API
807 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM $TOOLCHAIN_CFLAGS_JVM \
808 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
809 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG"
810
811 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
812 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
813 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK"
814
815 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
816 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
817 # change in the future.)
818
819 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
820 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
821 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
822 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
823
824 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
825 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
826
827 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
828
829 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK}"
830 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK}"
831 $2CFLAGS_JDKLIB="${$2CFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
832 $2CXXFLAGS_JDKLIB="${$2CXXFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
833
834 AC_SUBST($2JVM_CFLAGS)
835 AC_SUBST($2CFLAGS_JDKLIB)
836 AC_SUBST($2CFLAGS_JDKEXE)
837 AC_SUBST($2CXXFLAGS_JDKLIB)
838 AC_SUBST($2CXXFLAGS_JDKEXE)
839 ])
840
841 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
842 # Arguments:
843 # $1 - Prefix for each variable defined.
844 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
845 [
846 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
847 # runs afoul of the more aggressive versions of these optimisations.
848 # Notably, value range propagation now assumes that the this pointer of C++
849 # member functions is non-null.
850 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
851 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
852 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG -Werror],
853 dnl IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
854 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
855 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
856 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG -Werror],
857 dnl IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
858 AC_MSG_NOTICE([GCC >= 6 detected; adding ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} and ${NO_LIFETIME_DSE_CFLAG}])
859 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
860 ])
861
862 # Documentation on common flags used for solstudio in HIGHEST.
863 #
864 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
865 # done with care, there are some assumptions below that need to
866 # be understood about the use of pointers, and IEEE behavior.
867 #
868 # -fns: Use non-standard floating point mode (not IEEE 754)
869 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
870 # -fsingle: Use single precision floating point with 'float'
871 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
872 # (Source with excessing pointer casting and data access with mixed
873 # pointer types are not recommended)
874 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
875 # (If you expect perfect errno behavior, do not use this)
876 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
877 # -xrestrict: Pointer parameters to functions do not overlap
878 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
879 # If you pass in multiple pointers to the same data, do not use this)
880 # -xlibmil: Inline some library routines
881 # (If you expect perfect errno behavior, do not use this)
882 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
883 # (If you expect perfect errno behavior, do not use this)
884 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now