1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 #
  28 # Setup flags for C/C++ compiler
  29 #
  30 
  31 ###############################################################################
  32 #
  33 # How to compile shared libraries.
  34 #
  35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
  36 [
  37   if test "x$TOOLCHAIN_TYPE" = xgcc; then
  38     C_FLAG_REORDER=''
  39 
  40     # Default works for linux, might work on other platforms as well.
  41     SHARED_LIBRARY_FLAGS='-shared'
  42     SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
  43     SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
  44     SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
  45     SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
  46 
  47   elif test "x$TOOLCHAIN_TYPE" = xclang; then
  48     C_FLAG_REORDER=''
  49 
  50     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
  51       # Linking is different on MacOSX
  52       SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
  53       SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
  54       SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
  55       SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
  56       SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
  57 
  58     else
  59       # Default works for linux, might work on other platforms as well.
  60       SHARED_LIBRARY_FLAGS='-shared'
  61       SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
  62       SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
  63       SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
  64 
  65       # arm specific settings
  66       if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
  67         # '-Wl,-z,origin' isn't used on arm.
  68         SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
  69       else
  70         SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
  71       fi
  72     fi
  73 
  74   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
  75     C_FLAG_REORDER='-xF'
  76     SHARED_LIBRARY_FLAGS="-G"
  77     SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
  78     SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
  79     SET_SHARED_LIBRARY_NAME='-h [$]1'
  80     SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
  81 
  82   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
  83     C_FLAG_REORDER=''
  84     SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
  85     SET_EXECUTABLE_ORIGIN=""
  86     SET_SHARED_LIBRARY_ORIGIN=''
  87     SET_SHARED_LIBRARY_NAME=''
  88     SET_SHARED_LIBRARY_MAPFILE=''
  89 
  90   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
  91     C_FLAG_REORDER=''
  92     SHARED_LIBRARY_FLAGS="-dll"
  93     SET_EXECUTABLE_ORIGIN=''
  94     SET_SHARED_LIBRARY_ORIGIN=''
  95     SET_SHARED_LIBRARY_NAME=''
  96     SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
  97   fi
  98 
  99   AC_SUBST(C_FLAG_REORDER)
 100   AC_SUBST(SET_EXECUTABLE_ORIGIN)
 101   AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
 102   AC_SUBST(SET_SHARED_LIBRARY_NAME)
 103   AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
 104   AC_SUBST(SHARED_LIBRARY_FLAGS)
 105 ])
 106 
 107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
 108 [
 109   # By default don't set any specific assembler debug
 110   # info flags for toolchains unless we know they work.
 111   # See JDK-8207057.
 112   ASFLAGS_DEBUG_SYMBOLS=""
 113   # Debug symbols
 114   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 115     CFLAGS_DEBUG_SYMBOLS="-g"
 116     ASFLAGS_DEBUG_SYMBOLS="-g"
 117   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 118     CFLAGS_DEBUG_SYMBOLS="-g"
 119     ASFLAGS_DEBUG_SYMBOLS="-g"
 120   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 121     # -g0 enables debug symbols without disabling inlining.
 122     CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
 123   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 124     CFLAGS_DEBUG_SYMBOLS="-g"
 125   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 126     CFLAGS_DEBUG_SYMBOLS="-Z7 -d2Zi+"
 127   fi
 128 
 129   AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
 130   AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
 131 ])
 132 
 133 AC_DEFUN([FLAGS_SETUP_WARNINGS],
 134 [
 135   AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
 136       [do not consider native warnings to be an error @<:@enabled@:>@])])
 137 
 138   # Set default value.
 139   if test "x$TOOLCHAIN_TYPE" = xxlc; then
 140     WARNINGS_AS_ERRORS=false
 141   else
 142     WARNINGS_AS_ERRORS=true
 143   fi
 144 
 145   AC_MSG_CHECKING([if native warnings are errors])
 146   if test "x$enable_warnings_as_errors" = "xyes"; then
 147     AC_MSG_RESULT([yes (explicitly set)])
 148     WARNINGS_AS_ERRORS=true
 149   elif test "x$enable_warnings_as_errors" = "xno"; then
 150     AC_MSG_RESULT([no (explicitly set)])
 151     WARNINGS_AS_ERRORS=false
 152   elif test "x$enable_warnings_as_errors" = "x"; then
 153     AC_MSG_RESULT([${WARNINGS_AS_ERRORS} (default)])
 154   else
 155     AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
 156   fi
 157 
 158   AC_SUBST(WARNINGS_AS_ERRORS)
 159 
 160   case "${TOOLCHAIN_TYPE}" in
 161     microsoft)
 162       DISABLE_WARNING_PREFIX="-wd"
 163       CFLAGS_WARNINGS_ARE_ERRORS="-WX"
 164 
 165       WARNINGS_ENABLE_ALL="-W3"
 166       DISABLED_WARNINGS="4800"
 167       ;;
 168 
 169     solstudio)
 170       DISABLE_WARNING_PREFIX="-erroff="
 171       CFLAGS_WARNINGS_ARE_ERRORS="-errwarn=%all"
 172 
 173       WARNINGS_ENABLE_ALL_CFLAGS="-v"
 174       WARNINGS_ENABLE_ALL_CXXFLAGS="+w"
 175 
 176       DISABLED_WARNINGS_C=""
 177       DISABLED_WARNINGS_CXX=""
 178       ;;
 179 
 180     gcc)
 181       DISABLE_WARNING_PREFIX="-Wno-"
 182       CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
 183 
 184       # Additional warnings that are not activated by -Wall and -Wextra
 185       WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare \
 186           -Wunused-function -Wundef -Wunused-value -Wreturn-type"
 187       WARNINGS_ENABLE_ADDITIONAL_CXX="-Woverloaded-virtual -Wreorder"
 188       WARNINGS_ENABLE_ALL_CFLAGS="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
 189       WARNINGS_ENABLE_ALL_CXXFLAGS="$WARNINGS_ENABLE_ALL_CFLAGS $WARNINGS_ENABLE_ADDITIONAL_CXX"
 190 
 191       DISABLED_WARNINGS="unused-parameter unused"
 192 
 193       # Repeate the check for the BUILD_CC and BUILD_CXX. Need to also reset
 194       # CFLAGS since any target specific flags will likely not work with the
 195       # build compiler
 196       CC_OLD="$CC"
 197       CXX_OLD="$CXX"
 198       CC="$BUILD_CC"
 199       CXX="$BUILD_CXX"
 200       CFLAGS_OLD="$CFLAGS"
 201       CFLAGS=""
 202       BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
 203       CC="$CC_OLD"
 204       CXX="$CXX_OLD"
 205       CFLAGS="$CFLAGS_OLD"
 206       ;;
 207 
 208     clang)
 209       DISABLE_WARNING_PREFIX="-Wno-"
 210       CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
 211 
 212       # Additional warnings that are not activated by -Wall and -Wextra
 213       WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare -Wreorder \
 214           -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual"
 215       WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
 216 
 217       DISABLED_WARNINGS="unused-parameter unused"
 218 
 219       if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 220         # missing-method-return-type triggers in JavaNativeFoundation framework
 221         DISABLED_WARNINGS="$DISABLED_WARNINGS missing-method-return-type"
 222       fi
 223 
 224       ;;
 225 
 226     xlc)
 227       DISABLE_WARNING_PREFIX="-qsuppress="
 228       CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
 229 
 230       # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
 231       WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
 232       DISABLED_WARNINGS=""
 233       ;;
 234   esac
 235   AC_SUBST(DISABLE_WARNING_PREFIX)
 236   AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
 237   AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
 238   AC_SUBST(DISABLED_WARNINGS)
 239   AC_SUBST(DISABLED_WARNINGS_C)
 240   AC_SUBST(DISABLED_WARNINGS_CXX)
 241 ])
 242 
 243 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
 244 [
 245   # bounds, memory and behavior checking options
 246   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 247     case $DEBUG_LEVEL in
 248     release )
 249       # no adjustment
 250       ;;
 251     fastdebug )
 252       # no adjustment
 253       ;;
 254     slowdebug )
 255       # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
 256       # get's added conditionally on whether we produce debug symbols or not.
 257       # This is most likely not really correct.
 258 
 259       # Add runtime stack smashing and undefined behavior checks.
 260       CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
 261       CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
 262 
 263       JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
 264       ;;
 265     esac
 266   fi
 267 ])
 268 
 269 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
 270 [
 271   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 272     CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
 273 
 274     C_O_FLAG_HIGHEST_JVM="-xO4"
 275     C_O_FLAG_DEBUG_JVM=""
 276     C_O_FLAG_SIZE=""
 277     C_O_FLAG_DEBUG=""
 278     C_O_FLAG_NONE=""
 279     if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 280       C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
 281       C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
 282       C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
 283     elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 284       C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
 285           -xprefetch=auto,explicit $CC_HIGHEST"
 286       C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
 287       C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
 288     fi
 289   elif test "x$TOOLCHAIN_TYPE" = xgcc; then
 290     C_O_FLAG_HIGHEST_JVM="-O3"
 291     C_O_FLAG_HIGHEST="-O3"
 292     C_O_FLAG_HI="-O3"
 293     C_O_FLAG_NORM="-O2"
 294     C_O_FLAG_SIZE="-Os"
 295     C_O_FLAG_DEBUG="-O0"
 296     C_O_FLAG_DEBUG_JVM="-O0"
 297     C_O_FLAG_NONE="-O0"
 298   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 299     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 300       # On MacOSX we optimize for size, something
 301       # we should do for all platforms?
 302       C_O_FLAG_HIGHEST_JVM="-Os"
 303       C_O_FLAG_HIGHEST="-Os"
 304       C_O_FLAG_HI="-Os"
 305       C_O_FLAG_NORM="-Os"
 306       C_O_FLAG_DEBUG_JVM=""
 307     else
 308       C_O_FLAG_HIGHEST_JVM="-O3"
 309       C_O_FLAG_HIGHEST="-O3"
 310       C_O_FLAG_HI="-O3"
 311       C_O_FLAG_NORM="-O2"
 312       C_O_FLAG_DEBUG_JVM="-O0"
 313     fi
 314     C_O_FLAG_SIZE="-Os"
 315     C_O_FLAG_DEBUG="-O0"
 316     C_O_FLAG_NONE="-O0"
 317   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 318     C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
 319     C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
 320     C_O_FLAG_HI="-O3 -qinline -qinlglue"
 321     C_O_FLAG_NORM="-O2"
 322     C_O_FLAG_DEBUG="-qnoopt"
 323     # FIXME: Value below not verified.
 324     C_O_FLAG_DEBUG_JVM=""
 325     C_O_FLAG_NONE="-qnoopt"
 326   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 327     C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
 328     C_O_FLAG_HIGHEST="-O2"
 329     C_O_FLAG_HI="-O1"
 330     C_O_FLAG_NORM="-O1"
 331     C_O_FLAG_DEBUG="-Od"
 332     C_O_FLAG_DEBUG_JVM=""
 333     C_O_FLAG_NONE="-Od"
 334     C_O_FLAG_SIZE="-Os"
 335   fi
 336 
 337   # Now copy to C++ flags
 338   CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
 339   CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
 340   CXX_O_FLAG_HI="$C_O_FLAG_HI"
 341   CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
 342   CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
 343   CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
 344   CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
 345   CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
 346 
 347   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 348     # In solstudio, also add this to C (but not C++) flags...
 349     C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
 350   fi
 351 
 352   # Adjust optimization flags according to debug level.
 353   case $DEBUG_LEVEL in
 354     release )
 355       # no adjustment
 356       ;;
 357     fastdebug )
 358       # Not quite so much optimization
 359       C_O_FLAG_HI="$C_O_FLAG_NORM"
 360       CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
 361       ;;
 362     slowdebug )
 363       # Disable optimization
 364       C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
 365       C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
 366       C_O_FLAG_HI="$C_O_FLAG_DEBUG"
 367       C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
 368       C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
 369       CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
 370       CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
 371       CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
 372       CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
 373       CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
 374       ;;
 375   esac
 376 
 377   AC_SUBST(C_O_FLAG_HIGHEST_JVM)
 378   AC_SUBST(C_O_FLAG_HIGHEST)
 379   AC_SUBST(C_O_FLAG_HI)
 380   AC_SUBST(C_O_FLAG_NORM)
 381   AC_SUBST(C_O_FLAG_NONE)
 382   AC_SUBST(C_O_FLAG_SIZE)
 383   AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
 384   AC_SUBST(CXX_O_FLAG_HIGHEST)
 385   AC_SUBST(CXX_O_FLAG_HI)
 386   AC_SUBST(CXX_O_FLAG_NORM)
 387   AC_SUBST(CXX_O_FLAG_NONE)
 388   AC_SUBST(CXX_O_FLAG_SIZE)
 389 ])
 390 
 391 AC_DEFUN([FLAGS_SETUP_CFLAGS],
 392 [
 393   ### CFLAGS
 394 
 395   FLAGS_SETUP_CFLAGS_HELPER
 396 
 397   FLAGS_OS=$OPENJDK_TARGET_OS
 398   FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
 399   FLAGS_CPU=$OPENJDK_TARGET_CPU
 400   FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
 401   FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
 402   FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
 403   FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
 404   FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
 405 
 406   FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
 407 
 408   FLAGS_OS=$OPENJDK_BUILD_OS
 409   FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
 410   FLAGS_CPU=$OPENJDK_BUILD_CPU
 411   FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
 412   FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
 413   FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
 414   FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
 415   FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
 416 
 417   FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
 418 
 419   COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
 420   # Check that the compiler supports -ffp-contract=off flag
 421   # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
 422   # otherwise.
 423   # These flags are required for GCC-based builds of
 424   # fdlibm with optimization without losing precision.
 425   # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
 426   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 427     FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
 428         IF_TRUE: [FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
 429         IF_FALSE: [FDLIBM_CFLAGS=""])
 430   fi
 431   AC_SUBST(FDLIBM_CFLAGS)
 432 ])
 433 
 434 ################################################################################
 435 # platform independent
 436 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
 437 [
 438   #### OS DEFINES, these should be independent on toolchain
 439   if test "x$OPENJDK_TARGET_OS" = xlinux; then
 440     CFLAGS_OS_DEF_JVM="-DLINUX"
 441     CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
 442   elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
 443     CFLAGS_OS_DEF_JVM="-DSOLARIS"
 444     CFLAGS_OS_DEF_JDK="-D__solaris__"
 445   elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
 446     CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
 447     CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
 448   elif test "x$OPENJDK_TARGET_OS" = xaix; then
 449     CFLAGS_OS_DEF_JVM="-DAIX"
 450   elif test "x$OPENJDK_TARGET_OS" = xbsd; then
 451     CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
 452   elif test "x$OPENJDK_TARGET_OS" = xwindows; then
 453     CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
 454   fi
 455 
 456   CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
 457 
 458   #### GLOBAL DEFINES
 459   # Set some common defines. These works for all compilers, but assume
 460   # -D is universally accepted.
 461 
 462   # Always enable optional macros for VM.
 463   ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 464 
 465   # Setup some hard coded includes
 466   ALWAYS_CFLAGS_JDK=" \
 467       -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
 468       -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
 469       -I${TOPDIR}/src/java.base/share/native/libjava \
 470       -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
 471       -I${TOPDIR}/src/hotspot/share/include \
 472       -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
 473 
 474   ###############################################################################
 475 
 476   # Adjust flags according to debug level.
 477   # Setup debug/release defines
 478   if test "x$DEBUG_LEVEL" = xrelease; then
 479     DEBUG_CFLAGS_JDK="-DNDEBUG"
 480     if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 481       DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
 482     fi
 483   else
 484     DEBUG_CFLAGS_JDK="-DDEBUG"
 485 
 486     if test "x$TOOLCHAIN_TYPE" = xxlc; then
 487       # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
 488       # Hotspot now overflows its 64K TOC (currently only for debug),
 489       # so for debug we build with '-qpic=large -bbigtoc'.
 490       DEBUG_CFLAGS_JVM="-qpic=large"
 491     fi
 492   fi
 493 
 494   if test "x$DEBUG_LEVEL" != xrelease; then
 495     DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
 496     DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
 497   fi
 498 
 499   #### TOOLCHAIN DEFINES
 500 
 501   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 502     ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
 503   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 504     ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
 505   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 506     ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
 507     ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
 508     ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
 509   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 510     ALWAYS_DEFINES_JVM="-D_REENTRANT"
 511     ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
 512   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 513     ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
 514         -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
 515     ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
 516   fi
 517 
 518   ###############################################################################
 519   #
 520   #
 521   # CFLAGS BASIC
 522   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 523     # COMMON to gcc and clang
 524     TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
 525         -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
 526   fi
 527 
 528   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 529     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new"
 530     TOOLCHAIN_CFLAGS_JDK="-pipe"
 531     TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX (but since this gives *worse* performance, use no-strict-aliasing everywhere!)
 532 
 533     CXXSTD_CXXFLAG="-std=gnu++98"
 534     FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$CXXSTD_CXXFLAG -Werror],
 535                                                  IF_FALSE: [CXXSTD_CXXFLAG=""])
 536     TOOLCHAIN_CFLAGS_JDK_CXXONLY="$CXXSTD_CXXFLAG"
 537     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM $CXXSTD_CXXFLAG"
 538     ADLC_CXXFLAG="$CXXSTD_CXXFLAG"
 539 
 540 
 541   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 542     # Restrict the debug information created by Clang to avoid
 543     # too big object files and speed the build up a little bit
 544     # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
 545     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
 546 
 547     # In principle the stack alignment below is cpu- and ABI-dependent and
 548     # should agree with values of StackAlignmentInBytes in various
 549     # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
 550     # works for all platforms.
 551     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
 552 
 553     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 554       TOOLCHAIN_CFLAGS_JDK="-pipe"
 555       TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
 556     fi
 557   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 558     TOOLCHAIN_FLAGS="-errtags -errfmt"
 559     TOOLCHAIN_CFLAGS="-errshort=tags"
 560 
 561     TOOLCHAIN_CFLAGS_JDK="-mt $TOOLCHAIN_FLAGS"
 562     TOOLCHAIN_CFLAGS_JDK_CONLY="-std=c99 -xCC -W0,-noglobal $TOOLCHAIN_CFLAGS" # C only
 563     TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
 564     TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
 565         -library=stlport4 -mt -features=no%except $TOOLCHAIN_FLAGS"
 566     if test "x$DEBUG_LEVEL" = xslowdebug; then
 567       # Previously -g was used instead of -g0 for slowdebug; this is equivalent
 568       # to setting +d.
 569       TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
 570     fi
 571 
 572   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 573     # Suggested additions: -qsrcmsg to get improved error reporting
 574     TOOLCHAIN_CFLAGS_JDK="-qchars=signed -qfullpath -qsaveopt"  # add on both CFLAGS
 575     TOOLCHAIN_CFLAGS_JVM="-qtune=balanced \
 576         -qalias=noansi -qstrict -qtls=default -qlanglvl=c99vla \
 577         -qlanglvl=noredefmac -qnortti -qnoeh -qignerrno"
 578   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 579     TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
 580     TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
 581   fi
 582 
 583   # CFLAGS WARNINGS STUFF
 584   # Set JVM_CFLAGS warning handling
 585   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 586     WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
 587     WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
 588     WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
 589 
 590   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 591     WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
 592 
 593   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 594     WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
 595     WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
 596     WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
 597 
 598   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 599     WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
 600 
 601   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 602     WARNING_CFLAGS=""  # currently left empty
 603   fi
 604 
 605   # Set some additional per-OS defines.
 606 
 607   # Additional macosx handling
 608   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 609     OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
 610         -mmacosx-version-min=$MACOSX_VERSION_MIN"
 611 
 612     if test -n "$MACOSX_VERSION_MAX"; then
 613         OS_CFLAGS="$OS_CFLAGS \
 614             -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
 615     fi
 616   fi
 617 
 618   # Where does this really belong??
 619   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 620     PICFLAG="-fPIC"
 621   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 622     PICFLAG="-KPIC"
 623   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 624     # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
 625     # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
 626     # will have to patch this single instruction with a call to some out-of-order code which
 627     # does the load from the TOC. This is of course slower, and we also would have
 628     # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
 629     # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
 630     # can be patched directly by the linker and does not require a jump to out-of-order code.
 631     #
 632     # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
 633     # for all libjvm variants (both gtest and normal) but no other binaries. So, build
 634     # libjvm with -qpic=large and link with -bbigtoc.
 635     JVM_PICFLAG="-qpic=large"
 636     JDK_PICFLAG="-qpic"
 637   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 638     PICFLAG=""
 639   fi
 640 
 641   if test "x$TOOLCHAIN_TYPE" != xxlc; then
 642     JVM_PICFLAG="$PICFLAG"
 643     JDK_PICFLAG="$PICFLAG"
 644   fi
 645 
 646   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 647     # Linking is different on MacOSX
 648     JDK_PICFLAG=''
 649     if test "x$STATIC_BUILD" = xtrue; then
 650       JVM_PICFLAG=""
 651     fi
 652   fi
 653 
 654   # Optional POSIX functionality needed by the JVM
 655   #
 656   # Check if clock_gettime is available and in which library. This indicates
 657   # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
 658   # don't let it update LIBS.
 659   save_LIBS="$LIBS"
 660   AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
 661   if test "x$LIBS" = "x-lrt "; then
 662     CLOCK_GETTIME_IN_LIBRT=true
 663   fi
 664   LIBS="$save_LIBS"
 665 
 666   if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
 667     OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
 668     if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
 669       OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
 670     fi
 671   fi
 672 
 673   # EXPORT
 674   AC_SUBST(ADLC_CXXFLAG)
 675 ])
 676 
 677 ################################################################################
 678 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
 679 #      conditionals against.
 680 # $2 - Optional prefix for each variable defined.
 681 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
 682 [
 683   #### CPU DEFINES, these should (in theory) be independent on toolchain
 684 
 685   # Setup target CPU
 686   # Setup endianness
 687   if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 688     $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
 689   fi
 690   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 691     # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
 692     #   Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
 693     if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 694       $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
 695     else
 696       $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
 697     fi
 698   else
 699     if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 700       $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
 701     else
 702       $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
 703     fi
 704   fi
 705 
 706   # setup CPU bit size
 707   $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
 708       -D$FLAGS_CPU_LEGACY"
 709 
 710   if test "x$FLAGS_CPU_BITS" = x64; then
 711     # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
 712     # unpack200.exe.
 713     if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
 714       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
 715     fi
 716     if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
 717       # Solaris does not have _LP64=1 in the old build.
 718       # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
 719       $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
 720     fi
 721   fi
 722 
 723   # toolchain dependend, per-cpu
 724   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 725     if test "x$FLAGS_CPU_ARCH" = xx86; then
 726       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
 727     fi
 728   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 729     if test "x$FLAGS_CPU" = xx86_64; then
 730       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
 731     else
 732       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
 733     fi
 734   fi
 735 
 736   # CFLAGS PER CPU
 737   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 738     # COMMON to gcc and clang
 739     if test "x$FLAGS_CPU" = xx86; then
 740       # Force compatibility with i586 on 32 bit intel platforms.
 741       $1_CFLAGS_CPU="-march=i586"
 742     fi
 743   fi
 744 
 745   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 746     if test "x$FLAGS_CPU" = xarm; then
 747       # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
 748       $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
 749       $1_CFLAGS_CPU_JVM="-DARM"
 750     elif test "x$FLAGS_CPU_ARCH" = xppc; then
 751       $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
 752       if test "x$FLAGS_CPU" = xppc64; then
 753         # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
 754         # Use ppc64 instructions, but schedule for power5
 755         $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
 756       elif test "x$FLAGS_CPU" = xppc64le; then
 757         # Little endian machine uses ELFv2 ABI.
 758         # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
 759         $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
 760       fi
 761     elif test "x$FLAGS_CPU" = xs390x; then
 762       $1_CFLAGS_CPU="-mbackchain -march=z10"
 763     fi
 764 
 765     if test "x$FLAGS_CPU_ARCH" != xarm &&  test "x$FLAGS_CPU_ARCH" != xppc; then
 766       # for all archs except arm and ppc, prevent gcc to omit frame pointer
 767       $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
 768     fi
 769 
 770   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 771     if test "x$FLAGS_OS" = xlinux; then
 772       # ppc test not really needed for clang
 773       if test "x$FLAGS_CPU_ARCH" != xarm &&  test "x$FLAGS_CPU_ARCH" != xppc; then
 774         # for all archs except arm and ppc, prevent gcc to omit frame pointer
 775         $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
 776       fi
 777     fi
 778 
 779   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 780     if test "x$FLAGS_CPU" = xx86_64; then
 781       # NOTE: -xregs=no%frameptr is supposed to be default on x64
 782       $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
 783     elif test "x$FLAGS_CPU" = xsparcv9; then
 784       $1_CFLAGS_CPU_JVM="-xarch=sparc"
 785       $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
 786     fi
 787 
 788   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 789     if test "x$FLAGS_CPU" = xppc64; then
 790       $1_CFLAGS_CPU_JVM="-qarch=ppc64"
 791     fi
 792 
 793   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 794     if test "x$FLAGS_CPU" = xx86; then
 795       $1_CFLAGS_CPU_JVM="-arch:IA32"
 796     elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 797       if test "x$DEBUG_LEVEL" != xrelease; then
 798         # NOTE: This is probably redundant; -homeparams is default on
 799         # non-release builds.
 800         $1_CFLAGS_CPU_JVM="-homeparams"
 801       fi
 802     fi
 803   fi
 804 
 805   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 806     TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: 6, PREFIX: $2, IF_AT_LEAST: FLAGS_SETUP_GCC6_COMPILER_FLAGS($1))
 807     $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
 808 
 809     $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
 810   fi
 811 
 812   # EXPORT to API
 813   CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM $TOOLCHAIN_CFLAGS_JVM \
 814       $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
 815       $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG"
 816 
 817   CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
 818       $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
 819       $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK"
 820 
 821   # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
 822   # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
 823   # change in the future.)
 824 
 825   CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY  \
 826       $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
 827   CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
 828       $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
 829 
 830   $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
 831   $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
 832 
 833   $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
 834 
 835   $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK}"
 836   $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK}"
 837   $2CFLAGS_JDKLIB="${$2CFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
 838   $2CXXFLAGS_JDKLIB="${$2CXXFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
 839 
 840   AC_SUBST($2JVM_CFLAGS)
 841   AC_SUBST($2CFLAGS_JDKLIB)
 842   AC_SUBST($2CFLAGS_JDKEXE)
 843   AC_SUBST($2CXXFLAGS_JDKLIB)
 844   AC_SUBST($2CXXFLAGS_JDKEXE)
 845 ])
 846 
 847 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
 848 # Arguments:
 849 # $1 - Prefix for each variable defined.
 850 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
 851 [
 852   # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
 853   # runs afoul of the more aggressive versions of these optimisations.
 854   # Notably, value range propagation now assumes that the this pointer of C++
 855   # member functions is non-null.
 856   NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
 857   dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
 858   dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG -Werror],
 859   dnl                                        IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
 860   NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
 861   dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
 862   dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG -Werror],
 863   dnl                                        IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
 864   AC_MSG_NOTICE([GCC >= 6 detected; adding ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} and ${NO_LIFETIME_DSE_CFLAG}])
 865   $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
 866 ])
 867 
 868 # Documentation on common flags used for solstudio in HIGHEST.
 869 #
 870 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
 871 #          done with care, there are some assumptions below that need to
 872 #          be understood about the use of pointers, and IEEE behavior.
 873 #
 874 # -fns: Use non-standard floating point mode (not IEEE 754)
 875 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
 876 # -fsingle: Use single precision floating point with 'float'
 877 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
 878 #   (Source with excessing pointer casting and data access with mixed
 879 #    pointer types are not recommended)
 880 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
 881 #   (If you expect perfect errno behavior, do not use this)
 882 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
 883 # -xrestrict: Pointer parameters to functions do not overlap
 884 #   (Similar to -xalias_level=basic usage, but less obvious sometimes.
 885 #    If you pass in multiple pointers to the same data, do not use this)
 886 # -xlibmil: Inline some library routines
 887 #   (If you expect perfect errno behavior, do not use this)
 888 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
 889 #   (If you expect perfect errno behavior, do not use this)
 890 #  Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
--- EOF ---