1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ########################################################################
  27 # This file is responsible for detecting, verifying and setting up the 
  28 # toolchain, i.e. the compiler, linker and related utilities. It will setup 
  29 # proper paths to the binaries, but it will not setup any flags.
  30 #
  31 # The binaries used is determined by the toolchain type, which is the family of 
  32 # compilers and related tools that are used.
  33 ########################################################################
  34 
  35 
  36 # All valid toolchains, regardless of platform (used by help.m4)
  37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
  38 
  39 # These toolchains are valid on different platforms
  40 VALID_TOOLCHAINS_linux="gcc clang"
  41 VALID_TOOLCHAINS_solaris="solstudio"
  42 VALID_TOOLCHAINS_macosx="gcc clang"
  43 VALID_TOOLCHAINS_aix="xlc"
  44 VALID_TOOLCHAINS_windows="microsoft"
  45 
  46 # Toolchain descriptions
  47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
  48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
  49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
  50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
  51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
  52 
  53 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
  54 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
  55 # $1 - optional variable prefix for compiler and version variables (BUILD_)
  56 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
  57 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
  58 [
  59   if test "x$CC_VERSION" != "x$CXX_VERSION"; then
  60     AC_MSG_WARN([C and C++ compiler has different version numbers, $CC_VERSION vs $CXX_VERSION.])
  61     AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
  62   fi
  63 
  64   # We only check CC_VERSION since we assume CXX_VERSION is equal.
  65   if [ [[ "$CC_VERSION" =~ (.*\.){3} ]] ]; then
  66     AC_MSG_WARN([C compiler version number has more than three parts (X.Y.Z): $CC_VERSION. Comparisons might be wrong.])
  67   fi
  68 
  69   if [ [[  "$CC_VERSION" =~ [0-9]{6} ]] ]; then
  70     AC_MSG_WARN([C compiler version number has a part larger than 99999: $CC_VERSION. Comparisons might be wrong.])
  71   fi
  72 
  73   $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$CC_VERSION"`
  74 ])
  75 
  76 # Check if the configured compiler (C and C++) is of a specific version or
  77 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
  78 #
  79 # Arguments:
  80 #   $1:   The version string to check against the found version
  81 #   $2:   block to run if the compiler is at least this version (>=)
  82 #   $3:   block to run if the compiler is older than this version (<)
  83 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
  84 [
  85   REFERENCE_VERSION=$1
  86 
  87   if [ [[ "$REFERENCE_VERSION" =~ (.*\.){3} ]] ]; then
  88     AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only three parts (X.Y.Z) is supported])
  89   fi
  90 
  91   if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
  92     AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only parts < 99999 is supported])
  93   fi
  94 
  95   # Version comparison method inspired by http://stackoverflow.com/a/24067243
  96   COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$REFERENCE_VERSION"`
  97 
  98   if test $COMPARABLE_ACTUAL_VERSION -ge $COMPARABLE_REFERENCE_VERSION ; then
  99     m4_ifval([$2], [$2], [:])
 100   else
 101     m4_ifval([$3], [$3], [:])
 102   fi
 103 ])
 104 
 105 
 106 # Setup a number of variables describing how native output files are
 107 # named on this platform/toolchain.
 108 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
 109 [
 110   # Define filename patterns
 111   if test "x$OPENJDK_TARGET_OS" = xwindows; then
 112     LIBRARY_PREFIX=
 113     SHARED_LIBRARY_SUFFIX='.dll'
 114     STATIC_LIBRARY_SUFFIX='.lib'
 115     SHARED_LIBRARY='[$]1.dll'
 116     STATIC_LIBRARY='[$]1.lib'
 117     OBJ_SUFFIX='.obj'
 118     EXE_SUFFIX='.exe'
 119   else
 120     LIBRARY_PREFIX=lib
 121     SHARED_LIBRARY_SUFFIX='.so'
 122     STATIC_LIBRARY_SUFFIX='.a'
 123     SHARED_LIBRARY='lib[$]1.so'
 124     STATIC_LIBRARY='lib[$]1.a'
 125     OBJ_SUFFIX='.o'
 126     EXE_SUFFIX=''
 127     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 128       SHARED_LIBRARY='lib[$]1.dylib'
 129       SHARED_LIBRARY_SUFFIX='.dylib'
 130     fi
 131   fi
 132 
 133   AC_SUBST(LIBRARY_PREFIX)
 134   AC_SUBST(SHARED_LIBRARY_SUFFIX)
 135   AC_SUBST(STATIC_LIBRARY_SUFFIX)
 136   AC_SUBST(SHARED_LIBRARY)
 137   AC_SUBST(STATIC_LIBRARY)
 138   AC_SUBST(OBJ_SUFFIX)
 139   AC_SUBST(EXE_SUFFIX)  
 140 ])
 141 
 142 # Determine which toolchain type to use, and make sure it is valid for this
 143 # platform. Setup various information about the selected toolchain.
 144 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
 145 [
 146   AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
 147       [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
 148 
 149   # Use indirect variable referencing
 150   toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
 151   VALID_TOOLCHAINS=${!toolchain_var_name}
 152   # First toolchain type in the list is the default
 153   DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
 154 
 155   if test "x$with_toolchain_type" = xlist; then
 156     # List all toolchains
 157     AC_MSG_NOTICE([The following toolchains are valid on this platform:])
 158     for toolchain in $VALID_TOOLCHAINS; do
 159       toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
 160       TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
 161       $PRINTF "  %-10s  %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
 162     done
 163     
 164     exit 0
 165   elif test "x$with_toolchain_type" != x; then
 166     # User override; check that it is valid
 167     if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
 168       AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
 169       AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
 170       AC_MSG_ERROR([Cannot continue.])
 171     fi
 172     TOOLCHAIN_TYPE=$with_toolchain_type
 173   else
 174     # No flag given, use default
 175     TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
 176   fi
 177   AC_SUBST(TOOLCHAIN_TYPE)
 178 
 179   TOOLCHAIN_CC_BINARY_clang="clang"
 180   TOOLCHAIN_CC_BINARY_gcc="gcc"
 181   TOOLCHAIN_CC_BINARY_microsoft="cl"
 182   TOOLCHAIN_CC_BINARY_solstudio="cc"
 183   TOOLCHAIN_CC_BINARY_xlc="xlc_r"
 184 
 185   TOOLCHAIN_CXX_BINARY_clang="clang++"
 186   TOOLCHAIN_CXX_BINARY_gcc="g++"
 187   TOOLCHAIN_CXX_BINARY_microsoft="cl"
 188   TOOLCHAIN_CXX_BINARY_solstudio="CC"
 189   TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
 190 
 191   # Use indirect variable referencing
 192   toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
 193   TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
 194   toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
 195   TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
 196   toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
 197   TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
 198 
 199   TOOLCHAIN_SETUP_FILENAME_PATTERNS
 200 
 201   if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
 202     AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
 203   else
 204     AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
 205   fi 
 206 ])
 207 
 208 # Before we start detecting the toolchain executables, we might need some 
 209 # special setup, e.g. additional paths etc.
 210 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
 211 [
 212   # FIXME: Is this needed?
 213   AC_LANG(C++)
 214 
 215   # Store the CFLAGS etal passed to the configure script.
 216   ORG_CFLAGS="$CFLAGS"
 217   ORG_CXXFLAGS="$CXXFLAGS"
 218   ORG_OBJCFLAGS="$OBJCFLAGS"
 219 
 220   # autoconf magic only relies on PATH, so update it if tools dir is specified
 221   OLD_PATH="$PATH"
 222 
 223   # On Windows, we need to detect the visual studio installation first.
 224   # This will change the PATH, but we need to keep that new PATH even 
 225   # after toolchain detection is done, since the compiler (on x86) uses
 226   # it for DLL resolution in runtime.
 227   if test "x$OPENJDK_BUILD_OS" = "xwindows" \
 228       && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
 229     TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
 230     # Reset path to VS_PATH. It will include everything that was on PATH at the time we
 231     # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
 232     PATH="$VS_PATH"
 233     # The microsoft toolchain also requires INCLUDE and LIB to be set.
 234     export INCLUDE="$VS_INCLUDE"
 235     export LIB="$VS_LIB"
 236   fi
 237 
 238   # Before we locate the compilers, we need to sanitize the Xcode build environment
 239   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 240     # determine path to Xcode developer directory
 241     # can be empty in which case all the tools will rely on a sane Xcode 4 installation
 242     SET_DEVELOPER_DIR=
 243 
 244     if test -n "$XCODE_PATH"; then
 245       DEVELOPER_DIR="$XCODE_PATH"/Contents/Developer
 246     fi
 247 
 248     # DEVELOPER_DIR could also be provided directly
 249     AC_MSG_CHECKING([Determining if we need to set DEVELOPER_DIR])
 250     if test -n "$DEVELOPER_DIR"; then
 251       if test ! -d "$DEVELOPER_DIR"; then
 252         AC_MSG_ERROR([Xcode Developer path does not exist: $DEVELOPER_DIR, please provide a path to the Xcode 4 application bundle using --with-xcode-path])
 253       fi
 254       if test ! -f "$DEVELOPER_DIR"/usr/bin/xcodebuild; then
 255         AC_MSG_ERROR([Xcode Developer path is not valid: $DEVELOPER_DIR, it must point to Contents/Developer inside an Xcode application bundle])
 256       fi
 257       # make it visible to all the tools immediately
 258       export DEVELOPER_DIR
 259       SET_DEVELOPER_DIR="export DEVELOPER_DIR := $DEVELOPER_DIR"
 260       AC_MSG_RESULT([yes ($DEVELOPER_DIR)])
 261     else
 262       AC_MSG_RESULT([no])
 263     fi
 264     AC_SUBST(SET_DEVELOPER_DIR)
 265 
 266     AC_PATH_PROG(XCODEBUILD, xcodebuild)
 267     if test -z "$XCODEBUILD"; then
 268       AC_MSG_ERROR([The xcodebuild tool was not found, the Xcode command line tools are required to build on Mac OS X])
 269     fi
 270 
 271     # Fail-fast: verify we're building on Xcode 4, we cannot build with Xcode 5 or later
 272     XCODE_VERSION=`$XCODEBUILD -version | grep '^Xcode ' | sed 's/Xcode //'`
 273     XC_VERSION_PARTS=( ${XCODE_VERSION//./ } )
 274     if test ! "${XC_VERSION_PARTS[[0]]}" = "4"; then
 275       AC_MSG_ERROR([Xcode 4 is required to build JDK 8, the version found was $XCODE_VERSION. Use --with-xcode-path to specify the location of Xcode 4 or make Xcode 4 active by using xcode-select.])
 276     fi
 277 
 278     # Some versions of Xcode 5 command line tools install gcc and g++ as symlinks to
 279     # clang and clang++, which will break the build. So handle that here if we need to.
 280     if test -L "/usr/bin/gcc" -o -L "/usr/bin/g++"; then
 281       # use xcrun to find the real gcc and add it's directory to PATH
 282       # then autoconf magic will find it
 283       AC_MSG_NOTICE([Found gcc symlinks to clang in /usr/bin, adding path to real gcc to PATH])
 284       XCODE_BIN_PATH=$(dirname `xcrun -find gcc`)
 285       PATH="$XCODE_BIN_PATH":$PATH
 286     fi
 287 
 288     # Determine appropriate SDKPATH, don't use SDKROOT as it interferes with the stub tools
 289     AC_MSG_CHECKING([Determining Xcode SDK path])
 290     # allow SDKNAME to be set to override the default SDK selection
 291     SDKPATH=`"$XCODEBUILD" -sdk ${SDKNAME:-macosx} -version | grep '^Path: ' | sed 's/Path: //'`
 292     if test -n "$SDKPATH"; then
 293       AC_MSG_RESULT([$SDKPATH])
 294     else
 295       AC_MSG_RESULT([(none, will use system headers and frameworks)])
 296     fi
 297     AC_SUBST(SDKPATH)
 298 
 299     # Perform a basic sanity test
 300     if test ! -f "$SDKPATH/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 301       AC_MSG_ERROR([Unable to find required framework headers, provide a valid path to Xcode 4 using --with-xcode-path])
 302     fi
 303 
 304     # if SDKPATH is non-empty then we need to add -isysroot and -iframework for gcc and g++
 305     if test -n "$SDKPATH"; then
 306       # We need -isysroot <path> and -iframework<path>/System/Library/Frameworks
 307       CFLAGS_JDK="${CFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
 308       CXXFLAGS_JDK="${CXXFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
 309       LDFLAGS_JDK="${LDFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
 310     fi
 311     
 312     # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
 313     # setting this here means it doesn't have to be peppered throughout the forest
 314     CFLAGS_JDK="$CFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
 315     CXXFLAGS_JDK="$CXXFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
 316     LDFLAGS_JDK="$LDFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
 317   fi
 318 
 319   # For solaris we really need solaris tools, and not the GNU equivalent.
 320   # The build tools on Solaris reside in /usr/ccs (C Compilation System),
 321   # so add that to path before starting to probe.
 322   # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.
 323   if test "x$OPENJDK_BUILD_OS" = xsolaris; then
 324     PATH="/usr/ccs/bin:$PATH"
 325   fi
 326 
 327   # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to 
 328   # override all other locations.
 329   if test "x$TOOLCHAIN_PATH" != x; then
 330     PATH=$TOOLCHAIN_PATH:$PATH
 331   fi
 332 ])
 333 
 334 # Restore path, etc
 335 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
 336 [
 337   # Restore old path.
 338   PATH="$OLD_PATH"
 339 
 340   # Restore the flags to the user specified values.
 341   # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
 342   CFLAGS="$ORG_CFLAGS"
 343   CXXFLAGS="$ORG_CXXFLAGS"
 344   OBJCFLAGS="$ORG_OBJCFLAGS"
 345 ])
 346 
 347 # Check if a compiler is of the toolchain type we expect, and save the version
 348 # information from it. If the compiler does not match the expected type,
 349 # this function will abort using AC_MSG_ERROR. If it matches, the version will
 350 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
 351 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
 352 #
 353 # $1 = compiler to test (CC or CXX)
 354 # $2 = human readable name of compiler (C or C++)
 355 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
 356 [
 357   COMPILER=[$]$1
 358   COMPILER_NAME=$2
 359 
 360   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 361     # cc -V output typically looks like
 362     #     cc: Sun C 5.12 Linux_i386 2011/11/16
 363     COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
 364     # Check that this is likely to be the Solaris Studio cc.
 365     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
 366     if test $? -ne 0; then
 367       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 368       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 369       AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
 370       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
 371       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 372     fi
 373     # Remove usage instructions (if present), and
 374     # collapse compiler output into a single line
 375     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
 376         $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
 377     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 378         $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
 379   elif test  "x$TOOLCHAIN_TYPE" = xxlc; then
 380     # xlc -qversion output typically looks like
 381     #     IBM XL C/C++ for AIX, V11.1 (5724-X13)
 382     #     Version: 11.01.0000.0015
 383     COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
 384     # Check that this is likely to be the IBM XL C compiler.
 385     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
 386     if test $? -ne 0; then
 387       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 388       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 389       AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
 390       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
 391       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 392     fi
 393     # Collapse compiler output into a single line
 394     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 395     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 396         $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
 397   elif test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 398     # There is no specific version flag, but all output starts with a version string.
 399     # First line typically looks something like:
 400     # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
 401     COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
 402     # Check that this is likely to be Microsoft CL.EXE.
 403     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
 404     if test $? -ne 0; then
 405       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 406       AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
 407       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 408     fi
 409     # Collapse compiler output into a single line
 410     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 411     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 412         $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
 413   elif test  "x$TOOLCHAIN_TYPE" = xgcc; then
 414     # gcc --version output typically looks like
 415     #     gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
 416     #     Copyright (C) 2013 Free Software Foundation, Inc.
 417     #     This is free software; see the source for copying conditions.  There is NO
 418     #     warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 419     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 420     # Check that this is likely to be GCC.
 421     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
 422     if test $? -ne 0; then
 423       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 424       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
 425       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 426     fi
 427     # Remove Copyright and legalese from version string, and
 428     # collapse into a single line
 429     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
 430         $SED -e 's/ *Copyright .*//'`
 431     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 432         $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
 433   elif test  "x$TOOLCHAIN_TYPE" = xclang; then
 434     # clang --version output typically looks like
 435     #    Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
 436     #    clang version 3.3 (tags/RELEASE_33/final)
 437     # or
 438     #    Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
 439     #    Target: x86_64-pc-linux-gnu
 440     #    Thread model: posix
 441     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 442     # Check that this is likely to be clang
 443     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
 444     if test $? -ne 0; then
 445       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 446       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
 447       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 448     fi
 449     # Collapse compiler output into a single line
 450     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 451     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 452         $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
 453 
 454   else
 455       AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
 456   fi
 457   # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
 458   $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
 459   # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
 460   $1_VERSION_STRING="$COMPILER_VERSION_STRING"
 461 
 462   AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
 463 ])
 464 
 465 
 466 # Try to locate the given C or C++ compiler in the path, or otherwise.
 467 #
 468 # $1 = compiler to test (CC or CXX)
 469 # $2 = human readable name of compiler (C or C++)
 470 # $3 = list of compiler names to search for
 471 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
 472 [
 473   COMPILER_NAME=$2
 474   SEARCH_LIST="$3"
 475 
 476   if test "x[$]$1" != x; then
 477     # User has supplied compiler name already, always let that override.
 478     AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
 479     if test "x`basename [$]$1`" = "x[$]$1"; then
 480       # A command without a complete path is provided, search $PATH.
 481       
 482       AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
 483       if test "x$POTENTIAL_$1" != x; then
 484         $1=$POTENTIAL_$1
 485       else
 486         AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
 487       fi
 488     else
 489       # Otherwise it might already be a complete path
 490       if test ! -x "[$]$1"; then
 491         AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
 492       fi
 493     fi
 494   else
 495     # No user supplied value. Locate compiler ourselves.
 496 
 497     # If we are cross compiling, assume cross compilation tools follows the
 498     # cross compilation standard where they are prefixed with the autoconf
 499     # standard name for the target. For example the binary
 500     # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
 501     # If we are not cross compiling, then the default compiler name will be
 502     # used.
 503 
 504     $1=
 505     # If TOOLCHAIN_PATH is set, check for all compiler names in there first
 506     # before checking the rest of the PATH.
 507     # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
 508     # step, this should not be necessary.
 509     if test -n "$TOOLCHAIN_PATH"; then
 510       PATH_save="$PATH"
 511       PATH="$TOOLCHAIN_PATH"
 512       AC_PATH_PROGS(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
 513       $1=$TOOLCHAIN_PATH_$1
 514       PATH="$PATH_save"
 515     fi
 516 
 517     # AC_PATH_PROGS can't be run multiple times with the same variable,
 518     # so create a new name for this run.
 519     if test "x[$]$1" = x; then
 520       AC_PATH_PROGS(POTENTIAL_$1, $3)
 521       $1=$POTENTIAL_$1
 522     fi
 523 
 524     if test "x[$]$1" = x; then
 525       HELP_MSG_MISSING_DEPENDENCY([devkit])
 526       AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
 527     fi
 528   fi
 529 
 530   # Now we have a compiler binary in $1. Make sure it's okay.
 531   BASIC_FIXUP_EXECUTABLE($1)
 532   TEST_COMPILER="[$]$1"
 533   # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
 534   # to 'xlc' but it is crucial that we invoke the compiler with the right name!
 535   if test "x$OPENJDK_BUILD_OS" != xaix; then
 536     # FIXME: This test should not be needed anymore; we don't do that for any platform.
 537     AC_MSG_CHECKING([resolved symbolic links for $1])
 538     BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
 539     AC_MSG_RESULT([$TEST_COMPILER])
 540   fi
 541   AC_MSG_CHECKING([if $1 is disguised ccache])
 542 
 543   COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
 544   if test "x$COMPILER_BASENAME" = "xccache"; then
 545     AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
 546     # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
 547     # We want to control ccache invocation ourselves, so ignore this cc and try
 548     # searching again.
 549 
 550     # Remove the path to the fake ccache cc from the PATH
 551     RETRY_COMPILER_SAVED_PATH="$PATH"
 552     COMPILER_DIRNAME=`$DIRNAME [$]$1`
 553     PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
 554 
 555     # Try again looking for our compiler
 556     AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
 557     BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
 558     PATH="$RETRY_COMPILER_SAVED_PATH"
 559 
 560     AC_MSG_CHECKING([for resolved symbolic links for $1])
 561     BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
 562     AC_MSG_RESULT([$PROPER_COMPILER_$1])
 563     $1="$PROPER_COMPILER_$1"
 564   else
 565     AC_MSG_RESULT([no, keeping $1])
 566     $1="$TEST_COMPILER"
 567   fi
 568 
 569   TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
 570 ])
 571 
 572 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
 573 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
 574 # archiver (AR). Verify that the compilers are correct according to the
 575 # toolchain type.
 576 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
 577 [
 578   #
 579   # Setup the compilers (CC and CXX)
 580   #
 581   TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
 582   # Now that we have resolved CC ourself, let autoconf have its go at it
 583   AC_PROG_CC([$CC])
 584 
 585   TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
 586   # Now that we have resolved CXX ourself, let autoconf have its go at it
 587   AC_PROG_CXX([$CXX])
 588 
 589   # This is the compiler version number on the form X.Y[.Z]
 590   AC_SUBST(CC_VERSION_NUMBER)
 591   AC_SUBST(CXX_VERSION_NUMBER)
 592 
 593   TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
 594 
 595   #
 596   # Setup the preprocessor (CPP and CXXCPP)
 597   #
 598   AC_PROG_CPP
 599   BASIC_FIXUP_EXECUTABLE(CPP)
 600   AC_PROG_CXXCPP
 601   BASIC_FIXUP_EXECUTABLE(CXXCPP)
 602 
 603   #
 604   # Setup the linker (LD)
 605   #
 606   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 607     # In the Microsoft toolchain we have a separate LD command "link".
 608     # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
 609     # a cygwin program for something completely different.
 610     AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
 611     BASIC_FIXUP_EXECUTABLE(LD)
 612     # Verify that we indeed succeeded with this trick.
 613     AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
 614     "$LD" --version > /dev/null
 615     if test $? -eq 0 ; then
 616       AC_MSG_RESULT([no])
 617       AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
 618     else
 619       AC_MSG_RESULT([yes])
 620     fi
 621     LDCXX="$LD"
 622   else
 623     # All other toolchains use the compiler to link.
 624     LD="$CC"
 625     LDCXX="$CXX"
 626   fi
 627   AC_SUBST(LD)
 628   # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
 629   AC_SUBST(LDCXX)
 630 
 631   #
 632   # Setup the assembler (AS)
 633   #
 634   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 635     # FIXME: should this really be solaris, or solstudio?
 636     BASIC_PATH_PROGS(AS, as)
 637     BASIC_FIXUP_EXECUTABLE(AS)
 638   else
 639     # FIXME: is this correct for microsoft?
 640     AS="$CC -c"
 641   fi
 642   AC_SUBST(AS)
 643 
 644   #
 645   # Setup the archiver (AR)
 646   #
 647   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 648     # The corresponding ar tool is lib.exe (used to create static libraries)
 649     AC_CHECK_PROG([AR], [lib],[lib],,,)
 650   else
 651     BASIC_CHECK_TOOLS(AR, ar)
 652   fi
 653   BASIC_FIXUP_EXECUTABLE(AR)
 654 ])
 655 
 656 # Setup additional tools that is considered a part of the toolchain, but not the
 657 # core part. Many of these are highly platform-specific and do not exist,
 658 # and/or are not needed on all platforms.
 659 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
 660 [
 661   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 662     AC_PROG_OBJC
 663     BASIC_FIXUP_EXECUTABLE(OBJC)
 664     BASIC_PATH_PROGS(LIPO, lipo)
 665     BASIC_FIXUP_EXECUTABLE(LIPO)
 666   else
 667     OBJC=
 668   fi
 669 
 670   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 671     AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
 672     BASIC_FIXUP_EXECUTABLE(MT)
 673     # Setup the resource compiler (RC)
 674     AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
 675     BASIC_FIXUP_EXECUTABLE(RC)
 676     AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
 677     BASIC_FIXUP_EXECUTABLE(DUMPBIN)
 678     # We need to check for 'msbuild.exe' because at the place where we expect to
 679     # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
 680     # won't find the 'msbuild.exe' executable in that case (and the
 681     # 'ac_executable_extensions' is unusable due to performance reasons).
 682     # Notice that we intentionally don't fix up the path to MSBUILD because we
 683     # will call it in a DOS shell during freetype detection on Windows (see
 684     # 'LIB_SETUP_FREETYPE' in "libraries.m4"
 685     AC_CHECK_PROG([MSBUILD], [msbuild.exe], [msbuild.exe],,,)
 686   fi
 687 
 688   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 689     BASIC_PATH_PROGS(STRIP, strip)
 690     BASIC_FIXUP_EXECUTABLE(STRIP)
 691     BASIC_PATH_PROGS(NM, nm)
 692     BASIC_FIXUP_EXECUTABLE(NM)
 693     BASIC_PATH_PROGS(GNM, gnm)
 694     BASIC_FIXUP_EXECUTABLE(GNM)
 695 
 696     BASIC_PATH_PROGS(MCS, mcs)
 697     BASIC_FIXUP_EXECUTABLE(MCS)
 698   elif test "x$OPENJDK_TARGET_OS" != xwindows; then
 699     # FIXME: we should unify this with the solaris case above.
 700     BASIC_CHECK_TOOLS(STRIP, strip)
 701     BASIC_FIXUP_EXECUTABLE(STRIP)
 702     AC_PATH_PROG(OTOOL, otool)
 703     if test "x$OTOOL" = "x"; then
 704       OTOOL="true"
 705     fi
 706     BASIC_CHECK_TOOLS(NM, nm)
 707     BASIC_FIXUP_EXECUTABLE(NM)
 708     GNM="$NM"
 709     AC_SUBST(GNM)
 710   fi
 711 
 712   # objcopy is used for moving debug symbols to separate files when
 713   # full debug symbols are enabled.
 714   if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 715     BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
 716     # Only call fixup if objcopy was found.
 717     if test -n "$OBJCOPY"; then
 718       BASIC_FIXUP_EXECUTABLE(OBJCOPY)
 719     fi
 720   fi
 721 
 722   BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
 723   if test "x$OBJDUMP" != x; then
 724     # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
 725     # bails if argument is missing.
 726     BASIC_FIXUP_EXECUTABLE(OBJDUMP)
 727   fi
 728 ])
 729 
 730 # Setup the build tools (i.e, the compiler and linker used to build programs
 731 # that should be run on the build platform, not the target platform, as a build
 732 # helper). Since the non-cross-compile case uses the normal, target compilers
 733 # for this, we can only do this after these have been setup.
 734 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
 735 [
 736   if test "x$COMPILE_TYPE" = "xcross"; then
 737     # Now we need to find a C/C++ compiler that can build executables for the
 738     # build platform. We can't use the AC_PROG_CC macro, since it can only be
 739     # used once. Also, we need to do this without adding a tools dir to the
 740     # path, otherwise we might pick up cross-compilers which don't use standard
 741     # naming.
 742 
 743     # FIXME: we should list the discovered compilers as an exclude pattern!
 744     # If we do that, we can do this detection before POST_DETECTION, and still
 745     # find the build compilers in the tools dir, if needed.
 746     BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
 747     BASIC_FIXUP_EXECUTABLE(BUILD_CC)
 748     BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
 749     BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
 750     BASIC_PATH_PROGS(BUILD_LD, ld)
 751     BASIC_FIXUP_EXECUTABLE(BUILD_LD)
 752   else
 753     # If we are not cross compiling, use the normal target compilers for
 754     # building the build platform executables.
 755     BUILD_CC="$CC"
 756     BUILD_CXX="$CXX"
 757     BUILD_LD="$LD"
 758   fi
 759 ])
 760 
 761 # Setup legacy variables that are still needed as alternative ways to refer to
 762 # parts of the toolchain.
 763 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
 764 [
 765   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 766     # For hotspot, we need these in Windows mixed path,
 767     # so rewrite them all. Need added .exe suffix.
 768     HOTSPOT_CXX="$CXX.exe"
 769     HOTSPOT_LD="$LD.exe"
 770     HOTSPOT_MT="$MT.exe"
 771     HOTSPOT_RC="$RC.exe"
 772     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
 773     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
 774     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
 775     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
 776     AC_SUBST(HOTSPOT_MT)
 777     AC_SUBST(HOTSPOT_RC)
 778   else
 779     HOTSPOT_CXX="$CXX"
 780     HOTSPOT_LD="$LD"
 781   fi
 782   AC_SUBST(HOTSPOT_CXX)
 783   AC_SUBST(HOTSPOT_LD)
 784 
 785   if test  "x$TOOLCHAIN_TYPE" = xclang; then
 786     USE_CLANG=true
 787   fi
 788   AC_SUBST(USE_CLANG)
 789 
 790   # LDEXE is the linker to use, when creating executables. Not really used.
 791   # FIXME: These should just be removed!
 792   LDEXE="$LD"
 793   LDEXECXX="$LDCXX"
 794   AC_SUBST(LDEXE)
 795   AC_SUBST(LDEXECXX)
 796 ])
 797 
 798 # Do some additional checks on the detected tools.
 799 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
 800  [
 801   # The package path is used only on macosx?
 802   # FIXME: clean this up, and/or move it elsewhere.
 803   PACKAGE_PATH=/opt/local
 804   AC_SUBST(PACKAGE_PATH)
 805 
 806   # Check for extra potential brokenness.
 807   if test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 808     # On Windows, double-check that we got the right compiler.
 809     CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
 810     COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
 811     if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
 812       if test "x$COMPILER_CPU_TEST" != "x80x86" -a "x$COMPILER_CPU_TEST" != "xx86"; then
 813         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86" or "x86".])
 814       fi
 815     elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
 816       if test "x$COMPILER_CPU_TEST" != "xx64"; then
 817         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
 818       fi
 819     fi
 820   fi
 821 
 822   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 823     # If this is a --hash-style=gnu system, use --hash-style=both, why?
 824     HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
 825     # This is later checked when setting flags.
 826   fi
 827 
 828   # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
 829   # in executable.'
 830   USING_BROKEN_SUSE_LD=no
 831   if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
 832     AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
 833     echo "SUNWprivate_1.1 { local: *; };" > version-script.map
 834     echo "int main() { }" > main.c
 835     if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
 836       AC_MSG_RESULT(no)
 837       USING_BROKEN_SUSE_LD=no
 838     else
 839       AC_MSG_RESULT(yes)
 840       USING_BROKEN_SUSE_LD=yes
 841     fi
 842     rm -rf version-script.map main.c
 843   fi
 844   AC_SUBST(USING_BROKEN_SUSE_LD)
 845 ])
 846 
 847 # Setup the JTReg Regression Test Harness.
 848 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
 849 [
 850   AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
 851       [Regression Test Harness @<:@probed@:>@])],
 852       [],
 853       [with_jtreg=no])
 854 
 855   if test "x$with_jtreg" = xno; then
 856     # jtreg disabled
 857     AC_MSG_CHECKING([for jtreg])
 858     AC_MSG_RESULT(no)
 859   else
 860     if test "x$with_jtreg" != xyes; then
 861       # with path specified.
 862       JT_HOME="$with_jtreg"
 863     fi
 864 
 865     if test "x$JT_HOME" != x; then
 866       AC_MSG_CHECKING([for jtreg])
 867 
 868       # use JT_HOME enviroment var.
 869       BASIC_FIXUP_PATH([JT_HOME])
 870 
 871       # jtreg win32 script works for everybody
 872       JTREGEXE="$JT_HOME/bin/jtreg"
 873 
 874       if test ! -f "$JTREGEXE"; then
 875         AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
 876       fi
 877 
 878       AC_MSG_RESULT($JTREGEXE)
 879     else
 880       # try to find jtreg on path
 881       BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
 882       JT_HOME="`$DIRNAME $JTREGEXE`"
 883     fi
 884   fi
 885 
 886   AC_SUBST(JT_HOME)
 887   AC_SUBST(JTREGEXE)
 888 ])
 889