1 #
   2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # All valid JVM features, regardless of platform
  27 VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
  28     graal fprof vm-structs jni-check services management all-gcs nmt cds static-build"
  29 
  30 # All valid JVM variants
  31 VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
  32 
  33 ###############################################################################
  34 # Check if the specified JVM variant should be built. To be used in shell if
  35 # constructs, like this:
  36 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
  37 #
  38 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
  39 
  40 # Definition kept in one line to allow inlining in if statements.
  41 # Additional [] needed to keep m4 from mangling shell constructs.
  42 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
  43 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
  44 
  45 ###############################################################################
  46 # Check if the specified JVM features are explicitly enabled. To be used in
  47 # shell if constructs, like this:
  48 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
  49 #
  50 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
  51 
  52 # Definition kept in one line to allow inlining in if statements.
  53 # Additional [] needed to keep m4 from mangling shell constructs.
  54 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
  55 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
  56 
  57 ###############################################################################
  58 # Check which variants of the JVM that we want to build. Available variants are:
  59 #   server: normal interpreter, and a tiered C1/C2 compiler
  60 #   client: normal interpreter, and C1 (no C2 compiler)
  61 #   minimal: reduced form of client with optional features stripped out
  62 #   core: normal interpreter only, no compiler
  63 #   zero: C++ based interpreter only, no compiler
  64 #   zeroshark: C++ based interpreter, and a llvm-based compiler
  65 #   custom: baseline JVM with no default features
  66 #
  67 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
  68 [
  69   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  70       [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
  71 
  72   if test "x$with_jvm_variants" = x; then
  73     with_jvm_variants="server"
  74   fi
  75   JVM_VARIANTS_OPT="$with_jvm_variants"
  76 
  77   # Has the user listed more than one variant?
  78   # Additional [] needed to keep m4 from mangling shell constructs.
  79   if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
  80     BUILDING_MULTIPLE_JVM_VARIANTS=true
  81   else
  82     BUILDING_MULTIPLE_JVM_VARIANTS=false
  83   fi
  84   # Replace the commas with AND for use in the build directory name.
  85   JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
  86 
  87   AC_MSG_CHECKING([which variants of the JVM to build])
  88   # JVM_VARIANTS is a space-separated list.
  89   # Also use minimal, not minimal1 (which is kept for backwards compatibility).
  90   JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
  91   AC_MSG_RESULT([$JVM_VARIANTS])
  92 
  93   # Check that the selected variants are valid
  94 
  95   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
  96   # Notice that the original variant failes on SLES 10 and 11
  97   NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
  98   STACK=${JVM_VARIANTS// /$'\n'}
  99   INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 100   if test "x$INVALID_VARIANTS" != x; then
 101     AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
 102     AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
 103   fi
 104 
 105   # All "special" variants share the same output directory ("server")
 106   VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
 107   NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
 108   STACK=${JVM_VARIANTS// /$'\n'}
 109   INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 110   if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
 111     AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
 112   fi
 113 
 114   # The "main" variant is the one used by other libs to link against during the
 115   # build.
 116   if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
 117     MAIN_VARIANT_PRIO_ORDER="server client minimal"
 118     for variant in $MAIN_VARIANT_PRIO_ORDER; do
 119       if HOTSPOT_CHECK_JVM_VARIANT($variant); then
 120         JVM_VARIANT_MAIN="$variant"
 121         break
 122       fi
 123     done
 124   else
 125     JVM_VARIANT_MAIN="$JVM_VARIANTS"
 126   fi
 127 
 128   AC_SUBST(JVM_VARIANTS)
 129   AC_SUBST(VALID_JVM_VARIANTS)
 130   AC_SUBST(JVM_VARIANT_MAIN)
 131 
 132   if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
 133     # zero behaves as a platform and rewrites these values. This is really weird. :(
 134     # We are guaranteed that we do not build any other variants when building zero.
 135     HOTSPOT_TARGET_CPU=zero
 136     HOTSPOT_TARGET_CPU_ARCH=zero
 137   fi
 138 ])
 139 
 140 ###############################################################################
 141 # Check if dtrace should be enabled and has all prerequisites present.
 142 #
 143 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
 144 [
 145   # Test for dtrace dependencies
 146   AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
 147       [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
 148       are present.])])
 149 
 150   DTRACE_DEP_MISSING=false
 151 
 152   AC_MSG_CHECKING([for dtrace tool])
 153   if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
 154     AC_MSG_RESULT([$DTRACE])
 155   else
 156     AC_MSG_RESULT([not found, cannot build dtrace])
 157     DTRACE_DEP_MISSING=true
 158   fi
 159 
 160   AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
 161   if test "x$DTRACE_HEADERS_OK" != "xyes"; then
 162     DTRACE_DEP_MISSING=true
 163   fi
 164 
 165   AC_MSG_CHECKING([if dtrace should be built])
 166   if test "x$enable_dtrace" = "xyes"; then
 167     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 168       AC_MSG_RESULT([no, missing dependencies])
 169       HELP_MSG_MISSING_DEPENDENCY([dtrace])
 170       AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
 171     else
 172       INCLUDE_DTRACE=true
 173       AC_MSG_RESULT([yes, forced])
 174     fi
 175   elif test "x$enable_dtrace" = "xno"; then
 176     INCLUDE_DTRACE=false
 177     AC_MSG_RESULT([no, forced])
 178   elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
 179     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 180       INCLUDE_DTRACE=false
 181       AC_MSG_RESULT([no, missing dependencies])
 182     else
 183       INCLUDE_DTRACE=true
 184       AC_MSG_RESULT([yes, dependencies present])
 185     fi
 186   else
 187     AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
 188   fi
 189   AC_SUBST(INCLUDE_DTRACE)
 190 ])
 191 
 192 ###############################################################################
 193 # Set up all JVM features for each JVM variant.
 194 #
 195 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
 196 [
 197   # The user can in some cases supply additional jvm features. For the custom
 198   # variant, this defines the entire variant.
 199   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
 200       [additional JVM features to enable (separated by comma),  use '--help' to show possible values @<:@none@:>@])])
 201   if test "x$with_jvm_features" != x; then
 202     AC_MSG_CHECKING([additional JVM features])
 203     JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
 204     AC_MSG_RESULT([$JVM_FEATURES])
 205   fi
 206 
 207   # Verify that dependencies are met for explicitly set features.
 208   if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
 209     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
 210   fi
 211 
 212   if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
 213     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
 214   fi
 215 
 216   if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
 217     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
 218   fi
 219 
 220   if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
 221     AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
 222   fi
 223 
 224   if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
 225     AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
 226   fi
 227 
 228   # Turn on additional features based on other parts of configure
 229   if test "x$INCLUDE_DTRACE" = "xtrue"; then
 230     JVM_FEATURES="$JVM_FEATURES dtrace"
 231   else
 232     if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
 233       AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
 234     fi
 235   fi
 236 
 237   if test "x$STATIC_BUILD" = "xtrue"; then
 238     JVM_FEATURES="$JVM_FEATURES static-build"
 239   else
 240     if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
 241       AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
 242     fi
 243   fi
 244 
 245   if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
 246     if HOTSPOT_CHECK_JVM_FEATURE(zero); then
 247       AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
 248     fi
 249   fi
 250 
 251   if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
 252     if HOTSPOT_CHECK_JVM_FEATURE(shark); then
 253       AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
 254     fi
 255   fi
 256 
 257   # Only enable jvmci on x86_64, sparcv9 and aarch64.
 258   if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 259      test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
 260      test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 261     JVM_FEATURES_jvmci="jvmci"
 262   else
 263     JVM_FEATURES_jvmci=""
 264   fi
 265 
 266   AC_MSG_CHECKING([if jdk.vm.compiler should be built])
 267   if HOTSPOT_CHECK_JVM_FEATURE(graal); then
 268     if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
 269       AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
 270     fi
 271     AC_MSG_RESULT([yes, forced])
 272   else
 273     # By default enable graal build where JVMCI is available
 274     if test "x$JVM_FEATURES_jvmci" = "xjvmci"; then
 275       JVM_FEATURES_graal="graal"
 276       AC_MSG_RESULT([yes])
 277     else
 278       JVM_FEATURES_graal=""
 279       AC_MSG_RESULT([no])
 280     fi
 281   fi
 282 
 283   if test "x$JVM_FEATURES_graal" = "xgraal"; then
 284     INCLUDE_GRAAL="true"
 285   else
 286     INCLUDE_GRAAL="false"
 287   fi
 288   AC_SUBST(INCLUDE_GRAAL)
 289 
 290   # All variants but minimal (and custom) get these features
 291   NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti fprof vm-structs jni-check services management all-gcs nmt cds"
 292 
 293   # Enable features depending on variant.
 294   JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_graal"
 295   JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
 296   JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
 297   JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES"
 298   JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
 299   JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
 300   JVM_FEATURES_custom="$JVM_FEATURES"
 301 
 302   AC_SUBST(JVM_FEATURES_server)
 303   AC_SUBST(JVM_FEATURES_client)
 304   AC_SUBST(JVM_FEATURES_core)
 305   AC_SUBST(JVM_FEATURES_minimal)
 306   AC_SUBST(JVM_FEATURES_zero)
 307   AC_SUBST(JVM_FEATURES_zeroshark)
 308   AC_SUBST(JVM_FEATURES_custom)
 309 
 310   # Used for verification of Makefiles by check-jvm-feature
 311   AC_SUBST(VALID_JVM_FEATURES)
 312 
 313   # We don't support --with-jvm-interpreter anymore, use zero instead.
 314   BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
 315 ])
 316 
 317 ###############################################################################
 318 # Validate JVM features once all setup is complete, including custom setup.
 319 #
 320 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
 321 [
 322   # Keep feature lists sorted and free of duplicates
 323   JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
 324   JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
 325   JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
 326   JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
 327   JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
 328   JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
 329   JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
 330 
 331   # Validate features
 332   for variant in $JVM_VARIANTS; do
 333     AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
 334     features_var_name=JVM_FEATURES_$variant
 335     JVM_FEATURES_TO_TEST=${!features_var_name}
 336     AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
 337     NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
 338     STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
 339     INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
 340     if test "x$INVALID_FEATURES" != x; then
 341       AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
 342     fi
 343   done
 344 ])
 345 
 346 ################################################################################
 347 # Check if gtest should be built
 348 #
 349 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
 350 [
 351   AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
 352       [Disables building of the Hotspot unit tests])])
 353 
 354   if test -e "$HOTSPOT_TOPDIR/test/native"; then
 355     GTEST_DIR_EXISTS="true"
 356   else
 357     GTEST_DIR_EXISTS="false"
 358   fi
 359 
 360   AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
 361   if test "x$enable_hotspot_gtest" = "xyes"; then
 362     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 363       AC_MSG_RESULT([yes, forced])
 364       BUILD_GTEST="true"
 365     else
 366       AC_MSG_ERROR([Cannot build gtest without the test source])
 367     fi
 368   elif test "x$enable_hotspot_gtest" = "xno"; then
 369     AC_MSG_RESULT([no, forced])
 370     BUILD_GTEST="false"
 371   elif test "x$enable_hotspot_gtest" = "x"; then
 372     if test "x$GTEST_DIR_EXISTS" = "xtrue" && test "x$OPENJDK_TARGET_OS" != "xaix"; then
 373       AC_MSG_RESULT([yes])
 374       BUILD_GTEST="true"
 375     else
 376       AC_MSG_RESULT([no])
 377       BUILD_GTEST="false"
 378     fi
 379   else
 380     AC_MSG_ERROR([--enable-gtest must be either yes or no])
 381   fi
 382 
 383   AC_SUBST(BUILD_GTEST)
 384 ])