1 #
2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
28 fprof vm-structs jni-check services management all-gcs nmt cds static-build aot"
29
30 # All valid JVM variants
31 VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
32
33 ###############################################################################
34 # Check if the specified JVM variant should be built. To be used in shell if
35 # constructs, like this:
36 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
37 #
38 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
39
40 # Definition kept in one line to allow inlining in if statements.
41 # Additional [] needed to keep m4 from mangling shell constructs.
42 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
43 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
44
45 ###############################################################################
46 # Check if the specified JVM features are explicitly enabled. To be used in
47 # shell if constructs, like this:
48 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
49 #
50 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
51
52 # Definition kept in one line to allow inlining in if statements.
53 # Additional [] needed to keep m4 from mangling shell constructs.
54 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
55 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
56
57 ###############################################################################
58 # Check which variants of the JVM that we want to build. Available variants are:
59 # server: normal interpreter, and a tiered C1/C2 compiler
60 # client: normal interpreter, and C1 (no C2 compiler)
61 # minimal: reduced form of client with optional features stripped out
62 # core: normal interpreter only, no compiler
63 # zero: C++ based interpreter only, no compiler
64 # zeroshark: C++ based interpreter, and a llvm-based compiler
65 # custom: baseline JVM with no default features
66 #
67 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
68 [
69 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
70 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
71
72 if test "x$with_jvm_variants" = x; then
73 with_jvm_variants="server"
74 fi
75 JVM_VARIANTS_OPT="$with_jvm_variants"
76
77 # Has the user listed more than one variant?
78 # Additional [] needed to keep m4 from mangling shell constructs.
79 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
80 BUILDING_MULTIPLE_JVM_VARIANTS=true
81 else
82 BUILDING_MULTIPLE_JVM_VARIANTS=false
83 fi
84 # Replace the commas with AND for use in the build directory name.
85 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
86
87 AC_MSG_CHECKING([which variants of the JVM to build])
88 # JVM_VARIANTS is a space-separated list.
89 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
90 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
91 AC_MSG_RESULT([$JVM_VARIANTS])
92
93 # Check that the selected variants are valid
94
95 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
96 # Notice that the original variant failes on SLES 10 and 11
97 NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
98 STACK=${JVM_VARIANTS// /$'\n'}
99 INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
100 if test "x$INVALID_VARIANTS" != x; then
101 AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
102 AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
103 fi
104
105 # All "special" variants share the same output directory ("server")
106 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
107 NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
108 STACK=${JVM_VARIANTS// /$'\n'}
109 INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
110 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
111 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
112 fi
113
114 AC_SUBST(JVM_VARIANTS)
115 AC_SUBST(VALID_JVM_VARIANTS)
116
117 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
118 # zero behaves as a platform and rewrites these values. This is really weird. :(
119 # We are guaranteed that we do not build any other variants when building zero.
120 HOTSPOT_TARGET_CPU=zero
121 HOTSPOT_TARGET_CPU_ARCH=zero
122 fi
123 ])
124
125 ###############################################################################
126 # Check if dtrace should be enabled and has all prerequisites present.
127 #
128 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
129 [
130 # Test for dtrace dependencies
131 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
132 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
133 are present.])])
134
135 DTRACE_DEP_MISSING=false
136
137 AC_MSG_CHECKING([for dtrace tool])
138 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
139 AC_MSG_RESULT([$DTRACE])
140 else
141 AC_MSG_RESULT([not found, cannot build dtrace])
142 DTRACE_DEP_MISSING=true
143 fi
144
145 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
146 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
147 DTRACE_DEP_MISSING=true
148 fi
149
150 AC_MSG_CHECKING([if dtrace should be built])
151 if test "x$enable_dtrace" = "xyes"; then
152 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
153 AC_MSG_RESULT([no, missing dependencies])
154 HELP_MSG_MISSING_DEPENDENCY([dtrace])
155 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
156 else
157 INCLUDE_DTRACE=true
158 AC_MSG_RESULT([yes, forced])
159 fi
160 elif test "x$enable_dtrace" = "xno"; then
161 INCLUDE_DTRACE=false
162 AC_MSG_RESULT([no, forced])
163 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
164 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
165 INCLUDE_DTRACE=false
166 AC_MSG_RESULT([no, missing dependencies])
167 else
168 INCLUDE_DTRACE=true
169 AC_MSG_RESULT([yes, dependencies present])
170 fi
171 else
172 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
173 fi
174 AC_SUBST(INCLUDE_DTRACE)
175 ])
176
177 ################################################################################
178 # Check if AOT should be enabled
179 #
180 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
181 [
182 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
183 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
184
185 AC_MSG_CHECKING([if aot src is present])
186 if test -d "$HOTSPOT_TOPDIR/src/jdk.aot"; then
187 AC_MSG_RESULT([yes])
188
189 ENABLE_AOT_DEFAULT="false"
190 # Only enable AOT on linux-X64.
191 if test "x$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU" = "xlinux-x86_64"; then
192 ENABLE_AOT_DEFAULT="true"
193 fi
194
195 AC_MSG_CHECKING([if aot should be enabled])
196 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
197 if test "x$ENABLE_AOT_DEFAULT" = "xtrue"; then
198 AC_MSG_RESULT([yes])
199 ENABLE_AOT="true"
200 else
201 AC_MSG_RESULT([no])
202 ENABLE_AOT="false"
203 fi
204 elif test "x$enable_aot" = "xyes"; then
205 AC_MSG_RESULT([yes, forced])
206 ENABLE_AOT="true"
207 elif test "x$enable_aot" = "xno"; then
208 AC_MSG_RESULT([no, forced])
209 ENABLE_AOT="false"
210 else
211 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
212 fi
213
214 else
215 AC_MSG_RESULT([no])
216 ENABLE_AOT="false"
217 fi
218
219 AC_SUBST(ENABLE_AOT)
220 ])
221
222 ###############################################################################
223 # Set up all JVM features for each JVM variant.
224 #
225 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
226 [
227 # The user can in some cases supply additional jvm features. For the custom
228 # variant, this defines the entire variant.
229 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
230 [additional JVM features to enable (separated by comma), use '--help' to show possible values @<:@none@:>@])])
231 if test "x$with_jvm_features" != x; then
232 AC_MSG_CHECKING([additional JVM features])
233 JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
234 AC_MSG_RESULT([$JVM_FEATURES])
235 fi
236
237 # Verify that dependencies are met for explicitly set features.
238 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
239 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
240 fi
241
242 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
243 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
244 fi
245
246 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
247 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
248 fi
249
250 if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
251 AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
252 fi
253
254 if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
255 AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
256 fi
257
258 # Turn on additional features based on other parts of configure
259 if test "x$INCLUDE_DTRACE" = "xtrue"; then
260 JVM_FEATURES="$JVM_FEATURES dtrace"
261 else
262 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
263 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
264 fi
265 fi
266
267 if test "x$STATIC_BUILD" = "xtrue"; then
268 JVM_FEATURES="$JVM_FEATURES static-build"
269 else
270 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
271 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
272 fi
273 fi
274
275 if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
276 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
277 AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
278 fi
279 fi
280
281 if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
282 if HOTSPOT_CHECK_JVM_FEATURE(shark); then
283 AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
284 fi
285 fi
286
287 # Only enable jvmci on x86_64, sparcv9 and aarch64.
288 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
289 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
290 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
291 JVM_FEATURES_jvmci="jvmci"
292 else
293 JVM_FEATURES_jvmci=""
294 fi
295
296 if test "x$ENABLE_AOT" = "xtrue"; then
297 JVM_FEATURES_aot="aot"
298 else
299 JVM_FEATURES_aot=""
300 fi
301
302 # All variants but minimal (and custom) get these features
303 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti fprof vm-structs jni-check services management all-gcs nmt cds"
304
305 # Enable features depending on variant.
306 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot"
307 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
308 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
309 JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES"
310 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
311 JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
312 JVM_FEATURES_custom="$JVM_FEATURES"
313
314 AC_SUBST(JVM_FEATURES_server)
315 AC_SUBST(JVM_FEATURES_client)
316 AC_SUBST(JVM_FEATURES_core)
317 AC_SUBST(JVM_FEATURES_minimal)
318 AC_SUBST(JVM_FEATURES_zero)
319 AC_SUBST(JVM_FEATURES_zeroshark)
320 AC_SUBST(JVM_FEATURES_custom)
321
322 # Used for verification of Makefiles by check-jvm-feature
323 AC_SUBST(VALID_JVM_FEATURES)
324
325 # We don't support --with-jvm-interpreter anymore, use zero instead.
326 BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
327 ])
328
329 ###############################################################################
330 # Validate JVM features once all setup is complete, including custom setup.
331 #
332 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
333 [
334 # Keep feature lists sorted and free of duplicates
335 JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
336 JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
337 JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
338 JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
339 JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
340 JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
341 JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
342
343 # Validate features
344 for variant in $JVM_VARIANTS; do
345 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
346 features_var_name=JVM_FEATURES_$variant
347 JVM_FEATURES_TO_TEST=${!features_var_name}
348 AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
349 NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
350 STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
351 INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
352 if test "x$INVALID_FEATURES" != x; then
353 AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
354 fi
355 done
356 ])
357
358 ################################################################################
359 # Check if gtest should be built
360 #
361 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
362 [
363 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
364 [Disables building of the Hotspot unit tests])])
365
366 if test -e "$HOTSPOT_TOPDIR/test/native"; then
367 GTEST_DIR_EXISTS="true"
368 else
369 GTEST_DIR_EXISTS="false"
370 fi
371
372 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
373 if test "x$enable_hotspot_gtest" = "xyes"; then
374 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
375 AC_MSG_RESULT([yes, forced])
376 BUILD_GTEST="true"
377 else
378 AC_MSG_ERROR([Cannot build gtest without the test source])
379 fi
380 elif test "x$enable_hotspot_gtest" = "xno"; then
381 AC_MSG_RESULT([no, forced])
382 BUILD_GTEST="false"
383 elif test "x$enable_hotspot_gtest" = "x"; then
384 if test "x$GTEST_DIR_EXISTS" = "xtrue" && test "x$OPENJDK_TARGET_OS" != "xaix"; then
385 AC_MSG_RESULT([yes])
386 BUILD_GTEST="true"
387 else
388 AC_MSG_RESULT([no])
389 BUILD_GTEST="false"
390 fi
391 else
392 AC_MSG_ERROR([--enable-gtest must be either yes or no])
393 fi
394
395 AC_SUBST(BUILD_GTEST)
396 ])