1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 #
  28 
  29 AC_DEFUN([FLAGS_SETUP_LDFLAGS],
  30 [
  31   FLAGS_SETUP_LDFLAGS_HELPER
  32 
  33   # Setup the target toolchain
  34 
  35   # On some platforms (mac) the linker warns about non existing -L dirs.
  36   # For any of the variants server, client or minimal, the dir matches the
  37   # variant name. The "main" variant should be used for linking. For the
  38   # rest, the dir is just server.
  39   if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
  40       || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
  41     TARGET_JVM_VARIANT_PATH=$JVM_VARIANT_MAIN
  42   else
  43     TARGET_JVM_VARIANT_PATH=server
  44   fi
  45   FLAGS_SETUP_LDFLAGS_CPU_DEP([TARGET])
  46 
  47   # Setup the build toolchain
  48 
  49   # When building a buildjdk, it's always only the server variant
  50   BUILD_JVM_VARIANT_PATH=server
  51 
  52   FLAGS_SETUP_LDFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
  53 
  54   LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
  55   LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE ${TARGET_LDFLAGS_JDK_LIBPATH}"
  56   AC_SUBST(LDFLAGS_TESTLIB)
  57   AC_SUBST(LDFLAGS_TESTEXE)
  58 ])
  59 
  60 ################################################################################
  61 
  62 # CPU independent LDFLAGS setup, used for both target and build toolchain.
  63 AC_DEFUN([FLAGS_SETUP_LDFLAGS_HELPER],
  64 [
  65   # Setup basic LDFLAGS
  66   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
  67     # If this is a --hash-style=gnu system, use --hash-style=both, why?
  68     # We have previously set HAS_GNU_HASH if this is the case
  69     if test -n "$HAS_GNU_HASH"; then
  70       BASIC_LDFLAGS="-Wl,--hash-style=both"
  71       LIBJSIG_HASHSTYLE_LDFLAGS="-Wl,--hash-style=both"
  72     fi
  73 
  74     # Add -z defs, to forbid undefined symbols in object files.
  75     BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,defs"
  76 
  77     BASIC_LDFLAGS_JVM_ONLY="-Wl,-z,noexecstack -Wl,-O1 -Wl,-z,relro"
  78 
  79     BASIC_LDFLAGS_JDK_LIB_ONLY="-Wl,-z,noexecstack"
  80     LIBJSIG_NOEXECSTACK_LDFLAGS="-Wl,-z,noexecstack"
  81 
  82   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
  83     BASIC_LDFLAGS="-Wl,-z,defs"
  84     BASIC_LDFLAGS_ONLYCXX="-norunpath"
  85     BASIC_LDFLAGS_ONLYCXX_JDK_ONLY="-xnolib"
  86 
  87     BASIC_LDFLAGS_JDK_ONLY="-ztext"
  88     BASIC_LDFLAGS_JVM_ONLY="-library=%none -mt -z noversion"
  89 
  90   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
  91     BASIC_LDFLAGS="-b64 -brtl -bnolibpath -bexpall -bernotok -btextpsize:64K \
  92         -bdatapsize:64K -bstackpsize:64K"
  93     # libjvm.so has gotten too large for normal TOC size; compile with qpic=large and link with bigtoc
  94     BASIC_LDFLAGS_JVM_ONLY="-Wl,-lC_r -bbigtoc"
  95 
  96   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
  97     BASIC_LDFLAGS="-nologo -opt:ref"
  98     BASIC_LDFLAGS_JDK_ONLY="-incremental:no"
  99     BASIC_LDFLAGS_JVM_ONLY="-opt:icf,8 -subsystem:windows"
 100   fi
 101 
 102   # Setup OS-dependent LDFLAGS
 103   if test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xgcc; then
 104     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 105       # Assume clang or gcc.
 106       # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
 107       OS_LDFLAGS_JVM_ONLY="-Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
 108       OS_LDFLAGS_JDK_ONLY="-mmacosx-version-min=$MACOSX_VERSION_MIN"
 109     fi
 110   fi
 111 
 112   # Setup debug level-dependent LDFLAGS
 113   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 114     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 115       if test x$DEBUG_LEVEL = xrelease; then
 116         DEBUGLEVEL_LDFLAGS_JDK_ONLY="$DEBUGLEVEL_LDFLAGS_JDK_ONLY -Wl,-O1"
 117       else
 118         # mark relocations read only on (fast/slow) debug builds
 119         DEBUGLEVEL_LDFLAGS_JDK_ONLY="-Wl,-z,relro"
 120       fi
 121       if test x$DEBUG_LEVEL = xslowdebug; then
 122         # do relocations at load
 123         DEBUGLEVEL_LDFLAGS="-Wl,-z,now"
 124       fi
 125     fi
 126 
 127   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 128     # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
 129     # Hotspot now overflows its 64K TOC (currently only for debug),
 130     # so we build with '-qpic=large -bbigtoc'.
 131     if test "x$DEBUG_LEVEL" != xrelease; then
 132       DEBUGLEVEL_LDFLAGS_JVM_ONLY="$DEBUGLEVEL_LDFLAGS_JVM_ONLY -bbigtoc"
 133     fi
 134   fi
 135 
 136   # Setup LDFLAGS for linking executables
 137   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 138     EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -Wl,--allow-shlib-undefined"
 139   fi
 140 
 141   # Export some intermediate variables for compatibility
 142   LDFLAGS_CXX_JDK="$BASIC_LDFLAGS_ONLYCXX $BASIC_LDFLAGS_ONLYCXX_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY"
 143   AC_SUBST(LDFLAGS_CXX_JDK)
 144   AC_SUBST(LIBJSIG_HASHSTYLE_LDFLAGS)
 145   AC_SUBST(LIBJSIG_NOEXECSTACK_LDFLAGS)
 146 ])
 147 
 148 ################################################################################
 149 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
 150 #      conditionals against.
 151 # $2 - Optional prefix for each variable defined.
 152 AC_DEFUN([FLAGS_SETUP_LDFLAGS_CPU_DEP],
 153 [
 154   # Setup CPU-dependent basic LDFLAGS. These can differ between the target and
 155   # build toolchain.
 156   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 157     if test "x${OPENJDK_$1_CPU}" = xx86; then
 158       $1_CPU_LDFLAGS_JVM_ONLY="-march=i586"
 159     elif test "x$OPENJDK_$1_CPU" = xarm; then
 160       $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
 161       $1_CPU_LDFLAGS="$ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
 162     elif test "x$FLAGS_CPU" = xaarch64; then
 163       if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 164         $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
 165       fi
 166     fi
 167 
 168   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 169     if test "x${OPENJDK_$1_CPU}" = "xsparcv9"; then
 170       $1_CPU_LDFLAGS_JVM_ONLY="-xarch=sparc"
 171     fi
 172 
 173   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 174     if test "x${OPENJDK_$1_CPU}" = "xx86"; then
 175       $1_CPU_LDFLAGS="-safeseh"
 176       # NOTE: Old build added -machine. Probably not needed.
 177       $1_CPU_LDFLAGS_JVM_ONLY="-machine:I386"
 178       $1_CPU_EXECUTABLE_LDFLAGS="-stack:327680"
 179     else
 180       $1_CPU_LDFLAGS_JVM_ONLY="-machine:AMD64"
 181       $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
 182     fi
 183   fi
 184 
 185   # JVM_VARIANT_PATH depends on if this is build or target...
 186   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 187     $1_LDFLAGS_JDK_LIBPATH="-libpath:${OUTPUTDIR}/support/modules_libs/java.base"
 188   else
 189     $1_LDFLAGS_JDK_LIBPATH="-L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base \
 190         -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/${$1_JVM_VARIANT_PATH}"
 191   fi
 192 
 193   # Export variables according to old definitions, prefix with $2 if present.
 194   LDFLAGS_JDK_COMMON="$BASIC_LDFLAGS $BASIC_LDFLAGS_JDK_ONLY \
 195       $OS_LDFLAGS_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY ${$2EXTRA_LDFLAGS}"
 196   $2LDFLAGS_JDKLIB="$LDFLAGS_JDK_COMMON $BASIC_LDFLAGS_JDK_LIB_ONLY \
 197       ${$1_LDFLAGS_JDK_LIBPATH} $SHARED_LIBRARY_FLAGS"
 198   $2LDFLAGS_JDKEXE="$LDFLAGS_JDK_COMMON $EXECUTABLE_LDFLAGS \
 199       ${$1_CPU_EXECUTABLE_LDFLAGS}"
 200 
 201   $2JVM_LDFLAGS="$BASIC_LDFLAGS $BASIC_LDFLAGS_JVM_ONLY $OS_LDFLAGS_JVM_ONLY \
 202       $DEBUGLEVEL_LDFLAGS $DEBUGLEVEL_LDFLAGS_JVM_ONLY $BASIC_LDFLAGS_ONLYCXX \
 203       ${$1_CPU_LDFLAGS} ${$1_CPU_LDFLAGS_JVM_ONLY} ${$2EXTRA_LDFLAGS}"
 204 
 205   AC_SUBST($2LDFLAGS_JDKLIB)
 206   AC_SUBST($2LDFLAGS_JDKEXE)
 207 
 208   AC_SUBST($2JVM_LDFLAGS)
 209 ])