1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 #
  28 
  29 AC_DEFUN([FLAGS_SETUP_LDFLAGS],
  30 [
  31   FLAGS_SETUP_LDFLAGS_HELPER
  32 
  33   # Setup the target toolchain
  34 
  35   # On some platforms (mac) the linker warns about non existing -L dirs.
  36   # For any of the variants server, client or minimal, the dir matches the
  37   # variant name. The "main" variant should be used for linking. For the
  38   # rest, the dir is just server.
  39   if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
  40       || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
  41     TARGET_JVM_VARIANT_PATH=$JVM_VARIANT_MAIN
  42   else
  43     TARGET_JVM_VARIANT_PATH=server
  44   fi
  45   FLAGS_SETUP_LDFLAGS_CPU_DEP([TARGET])
  46 
  47   # Setup the build toolchain
  48 
  49   # When building a buildjdk, it's always only the server variant
  50   BUILD_JVM_VARIANT_PATH=server
  51 
  52   FLAGS_SETUP_LDFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
  53 
  54   LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
  55   LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE ${TARGET_LDFLAGS_JDK_LIBPATH}"
  56   AC_SUBST(LDFLAGS_TESTLIB)
  57   AC_SUBST(LDFLAGS_TESTEXE)
  58 ])
  59 
  60 ################################################################################
  61 
  62 # CPU independent LDFLAGS setup, used for both target and build toolchain.
  63 AC_DEFUN([FLAGS_SETUP_LDFLAGS_HELPER],
  64 [
  65   # Setup basic LDFLAGS
  66   if test "x$TOOLCHAIN_TYPE" = xgcc; then
  67     # If this is a --hash-style=gnu system, use --hash-style=both, why?
  68     # We have previously set HAS_GNU_HASH if this is the case
  69     if test -n "$HAS_GNU_HASH"; then
  70       BASIC_LDFLAGS="-Wl,--hash-style=both"
  71       LIBJSIG_HASHSTYLE_LDFLAGS="-Wl,--hash-style=both"
  72     fi
  73 
  74     # Add -z defs, to forbid undefined symbols in object files.
  75     BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,defs"
  76 
  77     BASIC_LDFLAGS_JVM_ONLY="-Wl,-O1 -Wl,-z,relro"
  78 
  79 
  80   elif test "x$TOOLCHAIN_TYPE" = xclang; then
  81     BASIC_LDFLAGS_JVM_ONLY="-mno-omit-leaf-frame-pointer -mstack-alignment=16 \
  82         -fPIC"
  83 
  84   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
  85     BASIC_LDFLAGS="-Wl,-z,defs"
  86     BASIC_LDFLAGS_ONLYCXX="-norunpath"
  87     BASIC_LDFLAGS_ONLYCXX_JDK_ONLY="-xnolib"
  88 
  89     BASIC_LDFLAGS_JDK_ONLY="-ztext"
  90     BASIC_LDFLAGS_JVM_ONLY="-library=%none -mt -z noversion"
  91 
  92   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
  93     BASIC_LDFLAGS="-b64 -brtl -bnolibpath -bexpall -bernotok -btextpsize:64K \
  94         -bdatapsize:64K -bstackpsize:64K"
  95     # libjvm.so has gotten too large for normal TOC size; compile with qpic=large and link with bigtoc
  96     BASIC_LDFLAGS_JVM_ONLY="-Wl,-lC_r -bbigtoc"
  97 
  98   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
  99     BASIC_LDFLAGS="-nologo -opt:ref"
 100     BASIC_LDFLAGS_JDK_ONLY="-incremental:no"
 101     BASIC_LDFLAGS_JVM_ONLY="-opt:icf,8 -subsystem:windows"
 102   fi
 103 
 104   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 105     if test -n "$HAS_NOEXECSTACK"; then
 106       BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,noexecstack"
 107     fi
 108   fi
 109 
 110   # Setup OS-dependent LDFLAGS
 111   if test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xgcc; then
 112     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 113       # Assume clang or gcc.
 114       # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
 115       OS_LDFLAGS_JVM_ONLY="-Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
 116       OS_LDFLAGS_JDK_ONLY="-mmacosx-version-min=$MACOSX_VERSION_MIN"
 117     fi
 118   fi
 119 
 120   # Setup debug level-dependent LDFLAGS
 121   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 122     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 123       if test x$DEBUG_LEVEL = xrelease; then
 124         DEBUGLEVEL_LDFLAGS_JDK_ONLY="$DEBUGLEVEL_LDFLAGS_JDK_ONLY -Wl,-O1"
 125       else
 126         # mark relocations read only on (fast/slow) debug builds
 127         DEBUGLEVEL_LDFLAGS_JDK_ONLY="-Wl,-z,relro"
 128       fi
 129       if test x$DEBUG_LEVEL = xslowdebug; then
 130         # do relocations at load
 131         DEBUGLEVEL_LDFLAGS="-Wl,-z,now"
 132       fi
 133     fi
 134 
 135   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 136     # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
 137     # Hotspot now overflows its 64K TOC (currently only for debug),
 138     # so we build with '-qpic=large -bbigtoc'.
 139     if test "x$DEBUG_LEVEL" != xrelease; then
 140       DEBUGLEVEL_LDFLAGS_JVM_ONLY="$DEBUGLEVEL_LDFLAGS_JVM_ONLY -bbigtoc"
 141     fi
 142   fi
 143 
 144   # Setup LDFLAGS for linking executables
 145   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 146     EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -Wl,--allow-shlib-undefined"
 147   fi
 148 
 149   # Export some intermediate variables for compatibility
 150   LDFLAGS_CXX_JDK="$BASIC_LDFLAGS_ONLYCXX $BASIC_LDFLAGS_ONLYCXX_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY"
 151   AC_SUBST(LDFLAGS_CXX_JDK)
 152   AC_SUBST(LIBJSIG_HASHSTYLE_LDFLAGS)
 153   AC_SUBST(LIBJSIG_NOEXECSTACK_LDFLAGS)
 154 ])
 155 
 156 ################################################################################
 157 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
 158 #      conditionals against.
 159 # $2 - Optional prefix for each variable defined.
 160 AC_DEFUN([FLAGS_SETUP_LDFLAGS_CPU_DEP],
 161 [
 162   # Setup CPU-dependent basic LDFLAGS. These can differ between the target and
 163   # build toolchain.
 164   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 165     if test "x${OPENJDK_$1_CPU}" = xx86; then
 166       $1_CPU_LDFLAGS_JVM_ONLY="-march=i586"
 167     elif test "x$OPENJDK_$1_CPU" = xarm; then
 168       $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
 169       $1_CPU_LDFLAGS="$ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
 170     elif test "x$FLAGS_CPU" = xaarch64; then
 171       if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 172         $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
 173       fi
 174     fi
 175 
 176   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 177     if test "x${OPENJDK_$1_CPU}" = "xsparcv9"; then
 178       $1_CPU_LDFLAGS_JVM_ONLY="-xarch=sparc"
 179     fi
 180 
 181   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 182     if test "x${OPENJDK_$1_CPU}" = "xx86"; then
 183       $1_CPU_LDFLAGS="-safeseh"
 184       # NOTE: Old build added -machine. Probably not needed.
 185       $1_CPU_LDFLAGS_JVM_ONLY="-machine:I386"
 186       $1_CPU_EXECUTABLE_LDFLAGS="-stack:327680"
 187     else
 188       $1_CPU_LDFLAGS_JVM_ONLY="-machine:AMD64"
 189       $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
 190     fi
 191   fi
 192 
 193   # JVM_VARIANT_PATH depends on if this is build or target...
 194   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 195     $1_LDFLAGS_JDK_LIBPATH="-libpath:${OUTPUTDIR}/support/modules_libs/java.base"
 196   else
 197     $1_LDFLAGS_JDK_LIBPATH="-L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base \
 198         -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/${$1_JVM_VARIANT_PATH}"
 199   fi
 200 
 201   # Export variables according to old definitions, prefix with $2 if present.
 202   LDFLAGS_JDK_COMMON="$BASIC_LDFLAGS $BASIC_LDFLAGS_JDK_ONLY \
 203       $OS_LDFLAGS_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY ${$2EXTRA_LDFLAGS}"
 204   $2LDFLAGS_JDKLIB="$LDFLAGS_JDK_COMMON $BASIC_LDFLAGS_JDK_LIB_ONLY \
 205       ${$1_LDFLAGS_JDK_LIBPATH} $SHARED_LIBRARY_FLAGS"
 206   $2LDFLAGS_JDKEXE="$LDFLAGS_JDK_COMMON $EXECUTABLE_LDFLAGS \
 207       ${$1_CPU_EXECUTABLE_LDFLAGS}"
 208 
 209   $2JVM_LDFLAGS="$BASIC_LDFLAGS $BASIC_LDFLAGS_JVM_ONLY $OS_LDFLAGS_JVM_ONLY \
 210       $DEBUGLEVEL_LDFLAGS $DEBUGLEVEL_LDFLAGS_JVM_ONLY $BASIC_LDFLAGS_ONLYCXX \
 211       ${$1_CPU_LDFLAGS} ${$1_CPU_LDFLAGS_JVM_ONLY} ${$2EXTRA_LDFLAGS}"
 212 
 213   AC_SUBST($2LDFLAGS_JDKLIB)
 214   AC_SUBST($2LDFLAGS_JDKEXE)
 215 
 216   AC_SUBST($2JVM_LDFLAGS)
 217 ])