1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
34
35
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
38
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
45
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
52
53 # Minimum supported versions, empty means unspecified
54 TOOLCHAIN_MINIMUM_VERSION_clang="3.2"
55 TOOLCHAIN_MINIMUM_VERSION_gcc="4.8"
56 TOOLCHAIN_MINIMUM_VERSION_microsoft="16.00.30319.01" # VS2010
57 TOOLCHAIN_MINIMUM_VERSION_solstudio="5.13"
58 TOOLCHAIN_MINIMUM_VERSION_xlc=""
59
60 # Minimum supported linker versions, empty means unspecified
61 TOOLCHAIN_MINIMUM_LD_VERSION_gcc="2.18"
62
63 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
64 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
65 # $1 - optional variable prefix for compiler and version variables (BUILD_)
66 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
67 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
68 [
69 if test "x[$]$1CC_VERSION_NUMBER" != "x[$]$1CXX_VERSION_NUMBER"; then
70 AC_MSG_WARN([C and C++ compiler have different version numbers, [$]$1CC_VERSION_NUMBER vs [$]$1CXX_VERSION_NUMBER.])
71 AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
72 fi
73
74 # We only check CC_VERSION_NUMBER since we assume CXX_VERSION_NUMBER is equal.
75 if [ [[ "[$]$1CC_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
76 AC_MSG_WARN([C compiler version number has more than four parts (W.X.Y.Z): [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
77 fi
78
79 if [ [[ "[$]$1CC_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
80 AC_MSG_WARN([C compiler version number has a part larger than 99999: [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
81 fi
82
83 $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1CC_VERSION_NUMBER"`
84 ])
85
86 # Check if the configured compiler (C and C++) is of a specific version or
87 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
88 #
89 # Arguments:
90 # VERSION: The version string to check against the found version
91 # IF_AT_LEAST: block to run if the compiler is at least this version (>=)
92 # IF_OLDER_THAN: block to run if the compiler is older than this version (<)
93 # PREFIX: Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
94 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_COMPILER_VERSION],
95 [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
96 [
97 # Need to assign to a variable since m4 is blocked from modifying parts in [].
98 REFERENCE_VERSION=ARG_VERSION
99
100 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
101 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
102 fi
103
104 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
105 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
106 fi
107
108 # Version comparison method inspired by http://stackoverflow.com/a/24067243
109 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
110
111 if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
112 :
113 ARG_IF_AT_LEAST
114 else
115 :
116 ARG_IF_OLDER_THAN
117 fi
118 ])
119
120 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
121 # Must have LD_VERSION_NUMBER.
122 # $1 - optional variable prefix for compiler and version variables (BUILD_)
123 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
124 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS],
125 [
126 if [ [[ "[$]$1LD_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
127 AC_MSG_WARN([Linker version number has more than four parts (W.X.Y.Z): [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
128 fi
129
130 if [ [[ "[$]$1LD_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
131 AC_MSG_WARN([Linker version number has a part larger than 99999: [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
132 fi
133
134 $2COMPARABLE_ACTUAL_LD_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1LD_VERSION_NUMBER"`
135 ])
136
137 # Check if the configured linker is of a specific version or
138 # newer. TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS must have been called before.
139 #
140 # Arguments:
141 # VERSION: The version string to check against the found version
142 # IF_AT_LEAST: block to run if the compiler is at least this version (>=)
143 # IF_OLDER_THAN: block to run if the compiler is older than this version (<)
144 # PREFIX: Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
145 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_LINKER_VERSION],
146 [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
147 [
148 # Need to assign to a variable since m4 is blocked from modifying parts in [].
149 REFERENCE_VERSION=ARG_VERSION
150
151 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
152 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
153 fi
154
155 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
156 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
157 fi
158
159 # Version comparison method inspired by http://stackoverflow.com/a/24067243
160 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
161
162 if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_LD_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
163 :
164 ARG_IF_AT_LEAST
165 else
166 :
167 ARG_IF_OLDER_THAN
168 fi
169 ])
170
171 # Setup a number of variables describing how native output files are
172 # named on this platform/toolchain.
173 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
174 [
175 # Define filename patterns
176 if test "x$OPENJDK_TARGET_OS" = xwindows; then
177 LIBRARY_PREFIX=
178 SHARED_LIBRARY_SUFFIX='.dll'
179 STATIC_LIBRARY_SUFFIX='.lib'
180 SHARED_LIBRARY='[$]1.dll'
181 STATIC_LIBRARY='[$]1.lib'
182 OBJ_SUFFIX='.obj'
183 EXE_SUFFIX='.exe'
184 else
185 LIBRARY_PREFIX=lib
186 SHARED_LIBRARY_SUFFIX='.so'
187 STATIC_LIBRARY_SUFFIX='.a'
188 SHARED_LIBRARY='lib[$]1.so'
189 STATIC_LIBRARY='lib[$]1.a'
190 OBJ_SUFFIX='.o'
191 EXE_SUFFIX=''
192 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
193 # For full static builds, we're overloading the SHARED_LIBRARY
194 # variables in order to limit the amount of changes required.
195 # It would be better to remove SHARED and just use LIBRARY and
196 # LIBRARY_SUFFIX for libraries that can be built either
197 # shared or static and use STATIC_* for libraries that are
198 # always built statically.
199 if test "x$STATIC_BUILD" = xtrue; then
200 SHARED_LIBRARY='lib[$]1.a'
201 SHARED_LIBRARY_SUFFIX='.a'
202 else
203 SHARED_LIBRARY='lib[$]1.dylib'
204 SHARED_LIBRARY_SUFFIX='.dylib'
205 fi
206 fi
207 fi
208
209 AC_SUBST(LIBRARY_PREFIX)
210 AC_SUBST(SHARED_LIBRARY_SUFFIX)
211 AC_SUBST(STATIC_LIBRARY_SUFFIX)
212 AC_SUBST(SHARED_LIBRARY)
213 AC_SUBST(STATIC_LIBRARY)
214 AC_SUBST(OBJ_SUFFIX)
215 AC_SUBST(EXE_SUFFIX)
216 ])
217
218 # Determine which toolchain type to use, and make sure it is valid for this
219 # platform. Setup various information about the selected toolchain.
220 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
221 [
222 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
223 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
224
225 # Use indirect variable referencing
226 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
227 VALID_TOOLCHAINS=${!toolchain_var_name}
228
229 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
230 if test -n "$XCODEBUILD"; then
231 # On Mac OS X, default toolchain to clang after Xcode 5
232 XCODE_VERSION_OUTPUT=`"$XCODEBUILD" -version 2>&1 | $HEAD -n 1`
233 $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
234 if test $? -ne 0; then
235 AC_MSG_NOTICE([xcodebuild output: $XCODE_VERSION_OUTPUT])
236 AC_MSG_ERROR([Failed to determine Xcode version.])
237 fi
238 XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
239 $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
240 $CUT -f 1 -d .`
241 AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
242 if test $XCODE_MAJOR_VERSION -ge 5; then
243 DEFAULT_TOOLCHAIN="clang"
244 else
245 DEFAULT_TOOLCHAIN="gcc"
246 fi
247 else
248 # If Xcode is not installed, but the command line tools are
249 # then we can't run xcodebuild. On these systems we should
250 # default to clang
251 DEFAULT_TOOLCHAIN="clang"
252 fi
253 else
254 # First toolchain type in the list is the default
255 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
256 fi
257
258 if test "x$with_toolchain_type" = xlist; then
259 # List all toolchains
260 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
261 for toolchain in $VALID_TOOLCHAINS; do
262 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
263 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
264 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
265 done
266
267 exit 0
268 elif test "x$with_toolchain_type" != x; then
269 # User override; check that it is valid
270 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
271 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
272 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
273 AC_MSG_ERROR([Cannot continue.])
274 fi
275 TOOLCHAIN_TYPE=$with_toolchain_type
276 else
277 # No flag given, use default
278 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
279 fi
280 AC_SUBST(TOOLCHAIN_TYPE)
281
282 TOOLCHAIN_CC_BINARY_clang="clang"
283 TOOLCHAIN_CC_BINARY_gcc="gcc"
284 TOOLCHAIN_CC_BINARY_microsoft="cl"
285 TOOLCHAIN_CC_BINARY_solstudio="cc"
286 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
287
288 TOOLCHAIN_CXX_BINARY_clang="clang++"
289 TOOLCHAIN_CXX_BINARY_gcc="g++"
290 TOOLCHAIN_CXX_BINARY_microsoft="cl"
291 TOOLCHAIN_CXX_BINARY_solstudio="CC"
292 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
293
294 # Use indirect variable referencing
295 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
296 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
297 toolchain_var_name=TOOLCHAIN_MINIMUM_VERSION_$TOOLCHAIN_TYPE
298 TOOLCHAIN_MINIMUM_VERSION=${!toolchain_var_name}
299 toolchain_var_name=TOOLCHAIN_MINIMUM_LD_VERSION_$TOOLCHAIN_TYPE
300 TOOLCHAIN_MINIMUM_LD_VERSION=${!toolchain_var_name}
301 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
302 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
303 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
304 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
305
306 TOOLCHAIN_SETUP_FILENAME_PATTERNS
307
308 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
309 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
310 else
311 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
312 fi
313 ])
314
315 # Before we start detecting the toolchain executables, we might need some
316 # special setup, e.g. additional paths etc.
317 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
318 [
319 # FIXME: Is this needed?
320 AC_LANG(C++)
321
322 # Store the CFLAGS etc passed to the configure script.
323 ORG_CFLAGS="$CFLAGS"
324 ORG_CXXFLAGS="$CXXFLAGS"
325
326 # autoconf magic only relies on PATH, so update it if tools dir is specified
327 OLD_PATH="$PATH"
328
329 # On Windows, we need to detect the visual studio installation first.
330 # This will change the PATH, but we need to keep that new PATH even
331 # after toolchain detection is done, since the compiler (on x86) uses
332 # it for DLL resolution in runtime.
333 if test "x$OPENJDK_BUILD_OS" = "xwindows" \
334 && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
335 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
336 # Reset path to VS_PATH. It will include everything that was on PATH at the time we
337 # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
338 PATH="$VS_PATH"
339 # The microsoft toolchain also requires INCLUDE and LIB to be set.
340 export INCLUDE="$VS_INCLUDE"
341 export LIB="$VS_LIB"
342 else
343 if test "x$XCODE_VERSION_OUTPUT" != x; then
344 # For Xcode, we set the Xcode version as TOOLCHAIN_VERSION
345 TOOLCHAIN_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | $CUT -f 2 -d ' '`
346 TOOLCHAIN_DESCRIPTION="$TOOLCHAIN_DESCRIPTION from Xcode $TOOLCHAIN_VERSION"
347 else
348 # Currently we do not define this for other toolchains. This might change as the need arise.
349 TOOLCHAIN_VERSION=
350 fi
351 fi
352 AC_SUBST(TOOLCHAIN_VERSION)
353
354 # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
355 # override all other locations.
356 if test "x$TOOLCHAIN_PATH" != x; then
357 PATH=$TOOLCHAIN_PATH:$PATH
358 fi
359 ])
360
361 # Restore path, etc
362 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
363 [
364 # Restore old path, except for the microsoft toolchain, which requires VS_PATH
365 # to remain in place. Otherwise the compiler will not work in some siutations
366 # in later configure checks.
367 if test "x$TOOLCHAIN_TYPE" != "xmicrosoft"; then
368 PATH="$OLD_PATH"
369 fi
370
371 # Restore the flags to the user specified values.
372 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
373 CFLAGS="$ORG_CFLAGS"
374 CXXFLAGS="$ORG_CXXFLAGS"
375 ])
376
377 # Check if a compiler is of the toolchain type we expect, and save the version
378 # information from it. If the compiler does not match the expected type,
379 # this function will abort using AC_MSG_ERROR. If it matches, the version will
380 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
381 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
382 #
383 # $1 = compiler to test (CC or CXX)
384 # $2 = human readable name of compiler (C or C++)
385 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
386 [
387 COMPILER=[$]$1
388 COMPILER_NAME=$2
389
390 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
391 # cc -V output typically looks like
392 # cc: Sun C 5.12 Linux_i386 2011/11/16
393 # or
394 # cc: Studio 12.5 Sun C 5.14 SunOS_sparc 2016/05/31
395 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
396 # Check that this is likely to be the Solaris Studio cc.
397 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.* Sun $COMPILER_NAME" > /dev/null
398 if test $? -ne 0; then
399 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
400 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
401 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
402 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
403 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
404 fi
405 # Remove usage instructions (if present), and
406 # collapse compiler output into a single line
407 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
408 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
409 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
410 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
411 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
412 # xlc -qversion output typically looks like
413 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
414 # Version: 11.01.0000.0015
415 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
416 # Check that this is likely to be the IBM XL C compiler.
417 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
418 if test $? -ne 0; then
419 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
420 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
421 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
422 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
423 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
424 fi
425 # Collapse compiler output into a single line
426 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
427 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
428 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
429 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
430 # There is no specific version flag, but all output starts with a version string.
431 # First line typically looks something like:
432 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
433 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
434 # Check that this is likely to be Microsoft CL.EXE.
435 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
436 if test $? -ne 0; then
437 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
438 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
439 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
440 fi
441 # Collapse compiler output into a single line
442 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
443 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
444 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
445 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
446 # gcc --version output typically looks like
447 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
448 # Copyright (C) 2013 Free Software Foundation, Inc.
449 # This is free software; see the source for copying conditions. There is NO
450 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
451 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
452 # Check that this is likely to be GCC.
453 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
454 if test $? -ne 0; then
455 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
456 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
457 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
458 fi
459 # Remove Copyright and legalese from version string, and
460 # collapse into a single line
461 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
462 $SED -e 's/ *Copyright .*//'`
463 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
464 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\)@<:@^0-9.@:>@.*$/\1/'`
465 elif test "x$TOOLCHAIN_TYPE" = xclang; then
466 # clang --version output typically looks like
467 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
468 # clang version 3.3 (tags/RELEASE_33/final)
469 # or
470 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
471 # Target: x86_64-pc-linux-gnu
472 # Thread model: posix
473 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
474 # Check that this is likely to be clang
475 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
476 if test $? -ne 0; then
477 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
478 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
479 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
480 fi
481 # Collapse compiler output into a single line
482 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
483 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
484 $SED -e 's/^.* version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
485 else
486 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
487 fi
488 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
489 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
490 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
491 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
492
493 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
494 ])
495
496 # Try to locate the given C or C++ compiler in the path, or otherwise.
497 #
498 # $1 = compiler to test (CC or CXX)
499 # $2 = human readable name of compiler (C or C++)
500 # $3 = compiler name to search for
501 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
502 [
503 COMPILER_NAME=$2
504 SEARCH_LIST="$3"
505
506 if test "x[$]$1" != x; then
507 # User has supplied compiler name already, always let that override.
508 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
509 if test "x`basename [$]$1`" = "x[$]$1"; then
510 # A command without a complete path is provided, search $PATH.
511
512 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
513 if test "x$POTENTIAL_$1" != x; then
514 $1=$POTENTIAL_$1
515 else
516 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
517 fi
518 else
519 # Otherwise it might already be a complete path
520 if test ! -x "[$]$1"; then
521 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
522 fi
523 fi
524 else
525 # No user supplied value. Locate compiler ourselves.
526
527 # If we are cross compiling, assume cross compilation tools follows the
528 # cross compilation standard where they are prefixed with the autoconf
529 # standard name for the target. For example the binary
530 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
531 # If we are not cross compiling, then the default compiler name will be
532 # used.
533
534 $1=
535 # If TOOLCHAIN_PATH is set, check for all compiler names in there first
536 # before checking the rest of the PATH.
537 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
538 # step, this should not be necessary.
539 if test -n "$TOOLCHAIN_PATH"; then
540 PATH_save="$PATH"
541 PATH="$TOOLCHAIN_PATH"
542 AC_PATH_TOOL(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
543 $1=$TOOLCHAIN_PATH_$1
544 PATH="$PATH_save"
545 fi
546
547 # AC_PATH_TOOL can't be run multiple times with the same variable,
548 # so create a new name for this run.
549 if test "x[$]$1" = x; then
550 AC_PATH_TOOL(POTENTIAL_$1, $SEARCH_LIST)
551 $1=$POTENTIAL_$1
552 fi
553
554 if test "x[$]$1" = x; then
555 HELP_MSG_MISSING_DEPENDENCY([devkit])
556 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
557 fi
558 fi
559
560 # Now we have a compiler binary in $1. Make sure it's okay.
561 BASIC_FIXUP_EXECUTABLE($1)
562 TEST_COMPILER="[$]$1"
563
564 AC_MSG_CHECKING([resolved symbolic links for $1])
565 SYMLINK_ORIGINAL="$TEST_COMPILER"
566 BASIC_REMOVE_SYMBOLIC_LINKS(SYMLINK_ORIGINAL)
567 if test "x$TEST_COMPILER" = "x$SYMLINK_ORIGINAL"; then
568 AC_MSG_RESULT([no symlink])
569 else
570 AC_MSG_RESULT([$SYMLINK_ORIGINAL])
571
572 # We can't handle ccache by gcc wrappers, since we need to know if we're
573 # using ccache. Instead ccache usage must be controlled by a configure option.
574 COMPILER_BASENAME=`$BASENAME "$SYMLINK_ORIGINAL"`
575 if test "x$COMPILER_BASENAME" = "xccache"; then
576 AC_MSG_NOTICE([Please use --enable-ccache instead of providing a wrapped compiler.])
577 AC_MSG_ERROR([$TEST_COMPILER is a symbolic link to ccache. This is not supported.])
578 fi
579 fi
580
581 TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
582 ])
583
584 # Retrieve the linker version number and store it in LD_VERSION_NUMBER
585 # (as a dotted number), and
586 # the full version string in LD_VERSION_STRING.
587 #
588 # $1 = linker to test (LD or BUILD_LD)
589 # $2 = human readable name of linker (Linker or BuildLinker)
590 AC_DEFUN([TOOLCHAIN_EXTRACT_LD_VERSION],
591 [
592 LINKER=[$]$1
593 LINKER_NAME=$2
594
595 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
596 # cc -Wl,-V output typically looks like
597 # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.2329
598
599 # solstudio cc requires us to have an existing file to pass as argument,
600 # but it need not be a syntactically correct C file, so just use
601 # ourself. :) The intermediate 'cat' is needed to stop ld from leaving
602 # a lingering a.out (!).
603 LINKER_VERSION_STRING=`$LD -Wl,-V $TOPDIR/configure 2>&1 | $CAT | $HEAD -n 1 | $SED -e 's/ld: //'`
604 # Extract version number
605 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
606 $SED -e 's/.* \([0-9][0-9]*\.[0-9][0-9]*\)-\([0-9][0-9]*\.[0-9][0-9]*\)/\1.\2/'` ]
607 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
608 LINKER_VERSION_STRING="Unknown"
609 LINKER_VERSION_NUMBER="0.0"
610 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
611 # There is no specific version flag, but all output starts with a version string.
612 # First line typically looks something like:
613 # Microsoft (R) Incremental Linker Version 12.00.31101.0
614 LINKER_VERSION_STRING=`$LD 2>&1 | $HEAD -n 1 | $TR -d '\r'`
615 # Extract version number
616 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
617 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
618 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
619 # gcc -Wl,-version output typically looks like
620 # GNU ld (GNU Binutils for Ubuntu) 2.26.1
621 # Copyright (C) 2015 Free Software Foundation, Inc.
622 # This program is free software; [...]
623 LINKER_VERSION_STRING=`$LD -Wl,-version 2>&1 | $HEAD -n 1`
624 # Extract version number
625 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
626 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
627 elif test "x$TOOLCHAIN_TYPE" = xclang; then
628 # clang -Wl,-v output typically looks like
629 # @(#)PROGRAM:ld PROJECT:ld64-305
630 # configured to support archs: armv6 armv7 armv7s arm64 i386 x86_64 x86_64h armv6m armv7k armv7m armv7em (tvOS)
631 # Library search paths: [...]
632 # or
633 # GNU ld (GNU Binutils for Ubuntu) 2.26.1
634
635 LINKER_VERSION_STRING=`$LD -Wl,-v 2>&1 | $HEAD -n 1`
636 # Check if we're using the GNU ld
637 $ECHO "$LINKER_VERSION_STRING" | $GREP "GNU" > /dev/null
638 if test $? -eq 0; then
639 # Extract version number
640 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
641 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
642 else
643 # Extract version number
644 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
645 $SED -e 's/.*-\([0-9][0-9]*\)/\1/'` ]
646 fi
647 fi
648
649 $1_VERSION_NUMBER="$LINKER_VERSION_NUMBER"
650 $1_VERSION_STRING="$LINKER_VERSION_STRING"
651
652 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $LINKER_NAME version $LINKER_VERSION_NUMBER @<:@$LINKER_VERSION_STRING@:>@])
653 ])
654
655 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
656 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
657 # archiver (AR). Verify that the compilers are correct according to the
658 # toolchain type.
659 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
660 [
661 #
662 # Setup the compilers (CC and CXX)
663 #
664 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
665 # Now that we have resolved CC ourself, let autoconf have its go at it
666 AC_PROG_CC([$CC])
667
668 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
669 # Now that we have resolved CXX ourself, let autoconf have its go at it
670 AC_PROG_CXX([$CXX])
671
672 # This is the compiler version number on the form X.Y[.Z]
673 AC_SUBST(CC_VERSION_NUMBER)
674 AC_SUBST(CXX_VERSION_NUMBER)
675
676 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
677
678 if test "x$TOOLCHAIN_MINIMUM_VERSION" != x; then
679 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_VERSION,
680 IF_OLDER_THAN: [
681 AC_MSG_WARN([You are using $TOOLCHAIN_TYPE older than $TOOLCHAIN_MINIMUM_VERSION. This is not a supported configuration.])
682 ]
683 )
684 fi
685
686 #
687 # Setup the preprocessor (CPP and CXXCPP)
688 #
689 AC_PROG_CPP
690 BASIC_FIXUP_EXECUTABLE(CPP)
691 AC_PROG_CXXCPP
692 BASIC_FIXUP_EXECUTABLE(CXXCPP)
693
694 #
695 # Setup the linker (LD)
696 #
697 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
698 # In the Microsoft toolchain we have a separate LD command "link".
699 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
700 # a cygwin program for something completely different.
701 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
702 BASIC_FIXUP_EXECUTABLE(LD)
703 # Verify that we indeed succeeded with this trick.
704 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
705 "$LD" --version > /dev/null
706 if test $? -eq 0 ; then
707 AC_MSG_RESULT([no])
708 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
709 else
710 AC_MSG_RESULT([yes])
711 fi
712 LDCXX="$LD"
713 else
714 # All other toolchains use the compiler to link.
715 LD="$CC"
716 LDCXX="$CXX"
717 fi
718 AC_SUBST(LD)
719 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
720 AC_SUBST(LDCXX)
721
722 TOOLCHAIN_EXTRACT_LD_VERSION([LD], [linker])
723 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS
724
725 if test "x$TOOLCHAIN_MINIMUM_LD_VERSION" != x; then
726 TOOLCHAIN_CHECK_LINKER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_LD_VERSION,
727 IF_OLDER_THAN: [
728 AC_MSG_WARN([You are using a linker older than $TOOLCHAIN_MINIMUM_LD_VERSION. This is not a supported configuration.])
729 ]
730 )
731 fi
732
733 #
734 # Setup the assembler (AS)
735 #
736 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
737 BASIC_PATH_PROGS(AS, as)
738 BASIC_FIXUP_EXECUTABLE(AS)
739 if test "x$AS" = x; then
740 AC_MSG_ERROR([Solaris assembler (as) is required. Please install via "pkg install pkg:/developer/assembler".])
741 fi
742 else
743 # FIXME: is this correct for microsoft?
744 AS="$CC -c"
745 fi
746 AC_SUBST(AS)
747
748 #
749 # Setup the archiver (AR)
750 #
751 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
752 # The corresponding ar tool is lib.exe (used to create static libraries)
753 AC_CHECK_PROG([AR], [lib],[lib],,,)
754 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
755 BASIC_CHECK_TOOLS(AR, ar gcc-ar)
756 else
757 BASIC_CHECK_TOOLS(AR, ar)
758 fi
759 BASIC_FIXUP_EXECUTABLE(AR)
760 ])
761
762 # Setup additional tools that is considered a part of the toolchain, but not the
763 # core part. Many of these are highly platform-specific and do not exist,
764 # and/or are not needed on all platforms.
765 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
766 [
767 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
768 BASIC_PATH_PROGS(LIPO, lipo)
769 BASIC_FIXUP_EXECUTABLE(LIPO)
770 BASIC_REQUIRE_PROGS(OTOOL, otool)
771 BASIC_FIXUP_EXECUTABLE(OTOOL)
772 BASIC_REQUIRE_PROGS(INSTALL_NAME_TOOL, install_name_tool)
773 BASIC_FIXUP_EXECUTABLE(INSTALL_NAME_TOOL)
774 fi
775
776 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
777 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
778 BASIC_FIXUP_EXECUTABLE(MT)
779 # Setup the resource compiler (RC)
780 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
781 BASIC_FIXUP_EXECUTABLE(RC)
782 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
783 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
784 # We need to check for 'msbuild.exe' because at the place where we expect to
785 # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
786 # won't find the 'msbuild.exe' executable in that case (and the
787 # 'ac_executable_extensions' is unusable due to performance reasons).
788 # Notice that we intentionally don't fix up the path to MSBUILD because we
789 # will call it in a DOS shell during freetype detection on Windows (see
790 # 'LIB_SETUP_FREETYPE' in "libraries.m4"
791 AC_CHECK_PROG([MSBUILD], [msbuild.exe], [msbuild.exe],,,)
792 fi
793
794 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
795 BASIC_PATH_PROGS(STRIP, strip)
796 BASIC_FIXUP_EXECUTABLE(STRIP)
797 BASIC_PATH_PROGS(NM, nm)
798 BASIC_FIXUP_EXECUTABLE(NM)
799 BASIC_PATH_PROGS(GNM, gnm)
800 BASIC_FIXUP_EXECUTABLE(GNM)
801 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
802 # FIXME: we should unify this with the solaris case above.
803 BASIC_CHECK_TOOLS(STRIP, strip)
804 BASIC_FIXUP_EXECUTABLE(STRIP)
805 if test "x$TOOLCHAIN_TYPE" = xgcc; then
806 BASIC_CHECK_TOOLS(NM, nm gcc-nm)
807 else
808 BASIC_CHECK_TOOLS(NM, nm)
809 fi
810 BASIC_FIXUP_EXECUTABLE(NM)
811 GNM="$NM"
812 AC_SUBST(GNM)
813 fi
814
815 # objcopy is used for moving debug symbols to separate files when
816 # full debug symbols are enabled.
817 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
818 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
819 # Only call fixup if objcopy was found.
820 if test -n "$OBJCOPY"; then
821 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
822 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
823 # objcopy prior to 2.21.1 on solaris is broken and is not usable.
824 # Rewrite objcopy version output to VALID_VERSION or BAD_VERSION.
825 # - version number is last blank separate word on first line
826 # - version number formats that have been seen:
827 # - <major>.<minor>
828 # - <major>.<minor>.<micro>
829 OBJCOPY_VERSION=`$OBJCOPY --version | $HEAD -n 1`
830 # The outer [ ] is to prevent m4 from eating the [] in the sed expression.
831 [ OBJCOPY_VERSION_CHECK=`$ECHO $OBJCOPY_VERSION | $SED -n \
832 -e 's/.* //' \
833 -e '/^[01]\./b bad' \
834 -e '/^2\./{' \
835 -e ' s/^2\.//' \
836 -e ' /^[0-9]$/b bad' \
837 -e ' /^[0-9]\./b bad' \
838 -e ' /^1[0-9]$/b bad' \
839 -e ' /^1[0-9]\./b bad' \
840 -e ' /^20\./b bad' \
841 -e ' /^21\.0$/b bad' \
842 -e ' /^21\.0\./b bad' \
843 -e '}' \
844 -e ':good' \
845 -e 's/.*/VALID_VERSION/p' \
846 -e 'q' \
847 -e ':bad' \
848 -e 's/.*/BAD_VERSION/p' \
849 -e 'q'` ]
850 if test "x$OBJCOPY_VERSION_CHECK" = xBAD_VERSION; then
851 OBJCOPY=
852 AC_MSG_WARN([Ignoring found objcopy since it is broken (prior to 2.21.1). No debug symbols will be generated.])
853 AC_MSG_NOTICE([objcopy reports version $OBJCOPY_VERSION])
854 AC_MSG_NOTICE([Note: patch 149063-01 or newer contains the correct Solaris 10 SPARC version])
855 AC_MSG_NOTICE([Note: patch 149064-01 or newer contains the correct Solaris 10 X86 version])
856 AC_MSG_NOTICE([Note: Solaris 11 Update 1 contains the correct version])
857 fi
858 fi
859 fi
860 fi
861
862 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
863 if test "x$OBJDUMP" != x; then
864 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
865 # bails if argument is missing.
866 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
867 fi
868
869 case $TOOLCHAIN_TYPE in
870 gcc|clang|solstudio)
871 BASIC_CHECK_TOOLS(CXXFILT, [c++filt])
872 BASIC_CHECK_NONEMPTY(CXXFILT)
873 BASIC_FIXUP_EXECUTABLE(CXXFILT)
874 ;;
875 esac
876 ])
877
878 # Setup the build tools (i.e, the compiler and linker used to build programs
879 # that should be run on the build platform, not the target platform, as a build
880 # helper). Since the non-cross-compile case uses the normal, target compilers
881 # for this, we can only do this after these have been setup.
882 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
883 [
884 if test "x$COMPILE_TYPE" = "xcross"; then
885 # Now we need to find a C/C++ compiler that can build executables for the
886 # build platform. We can't use the AC_PROG_CC macro, since it can only be
887 # used once. Also, we need to do this without adding a tools dir to the
888 # path, otherwise we might pick up cross-compilers which don't use standard
889 # naming.
890
891 OLDPATH="$PATH"
892
893 AC_ARG_WITH(build-devkit, [AS_HELP_STRING([--with-build-devkit],
894 [Devkit to use for the build platform toolchain])])
895 if test "x$with_build_devkit" = "xyes"; then
896 AC_MSG_ERROR([--with-build-devkit must have a value])
897 elif test -n "$with_build_devkit"; then
898 if test ! -d "$with_build_devkit"; then
899 AC_MSG_ERROR([--with-build-devkit points to non existing dir: $with_build_devkit])
900 else
901 BASIC_FIXUP_PATH([with_build_devkit])
902 BUILD_DEVKIT_ROOT="$with_build_devkit"
903 # Check for a meta data info file in the root of the devkit
904 if test -f "$BUILD_DEVKIT_ROOT/devkit.info"; then
905 # Process devkit.info so that existing devkit variables are not
906 # modified by this
907 $SED -e "s/^DEVKIT_/BUILD_DEVKIT_/g" \
908 -e "s/\$DEVKIT_ROOT/\$BUILD_DEVKIT_ROOT/g" \
909 -e "s/\$host/\$build/g" \
910 $BUILD_DEVKIT_ROOT/devkit.info \
911 > $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
912 . $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
913 # This potentially sets the following:
914 # A descriptive name of the devkit
915 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_NAME])
916 # Corresponds to --with-extra-path
917 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_EXTRA_PATH])
918 # Corresponds to --with-toolchain-path
919 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_TOOLCHAIN_PATH])
920 # Corresponds to --with-sysroot
921 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_SYSROOT])
922 # Skip the Window specific parts
923 fi
924
925 AC_MSG_CHECKING([for build platform devkit])
926 if test "x$BUILD_DEVKIT_NAME" != x; then
927 AC_MSG_RESULT([$BUILD_DEVKIT_NAME in $BUILD_DEVKIT_ROOT])
928 else
929 AC_MSG_RESULT([$BUILD_DEVKIT_ROOT])
930 fi
931
932 BUILD_SYSROOT="$BUILD_DEVKIT_SYSROOT"
933
934 # Fallback default of just /bin if DEVKIT_PATH is not defined
935 if test "x$BUILD_DEVKIT_TOOLCHAIN_PATH" = x; then
936 BUILD_DEVKIT_TOOLCHAIN_PATH="$BUILD_DEVKIT_ROOT/bin"
937 fi
938 PATH="$BUILD_DEVKIT_TOOLCHAIN_PATH:$BUILD_DEVKIT_EXTRA_PATH"
939 fi
940 fi
941
942 # FIXME: we should list the discovered compilers as an exclude pattern!
943 # If we do that, we can do this detection before POST_DETECTION, and still
944 # find the build compilers in the tools dir, if needed.
945 BASIC_REQUIRE_PROGS(BUILD_CC, [cl cc gcc])
946 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
947 BASIC_REQUIRE_PROGS(BUILD_CXX, [cl CC g++])
948 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
949 BASIC_PATH_PROGS(BUILD_NM, nm gcc-nm)
950 BASIC_FIXUP_EXECUTABLE(BUILD_NM)
951 BASIC_PATH_PROGS(BUILD_AR, ar gcc-ar)
952 BASIC_FIXUP_EXECUTABLE(BUILD_AR)
953 BASIC_PATH_PROGS(BUILD_OBJCOPY, objcopy)
954 BASIC_FIXUP_EXECUTABLE(BUILD_OBJCOPY)
955 BASIC_PATH_PROGS(BUILD_STRIP, strip)
956 BASIC_FIXUP_EXECUTABLE(BUILD_STRIP)
957 # Assume the C compiler is the assembler
958 BUILD_AS="$BUILD_CC -c"
959 # Just like for the target compiler, use the compiler as linker
960 BUILD_LD="$BUILD_CC"
961 BUILD_LDCXX="$BUILD_CXX"
962
963 PATH="$OLDPATH"
964
965 TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CC, [BuildC])
966 TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CXX, [BuildC++])
967 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
968 TOOLCHAIN_EXTRACT_LD_VERSION(BUILD_LD, [build linker])
969 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
970 else
971 # If we are not cross compiling, use the normal target compilers for
972 # building the build platform executables.
973 BUILD_CC="$CC"
974 BUILD_CXX="$CXX"
975 BUILD_LD="$LD"
976 BUILD_LDCXX="$LDCXX"
977 BUILD_NM="$NM"
978 BUILD_AS="$AS"
979 BUILD_OBJCOPY="$OBJCOPY"
980 BUILD_STRIP="$STRIP"
981 BUILD_AR="$AR"
982
983 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([], [OPENJDK_BUILD_])
984 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
985 fi
986
987 AC_SUBST(BUILD_CC)
988 AC_SUBST(BUILD_CXX)
989 AC_SUBST(BUILD_LD)
990 AC_SUBST(BUILD_LDCXX)
991 AC_SUBST(BUILD_NM)
992 AC_SUBST(BUILD_AS)
993 AC_SUBST(BUILD_AR)
994 ])
995
996 # Do some additional checks on the detected tools.
997 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
998 [
999 # The package path is used only on macosx?
1000 # FIXME: clean this up, and/or move it elsewhere.
1001 PACKAGE_PATH=/opt/local
1002 AC_SUBST(PACKAGE_PATH)
1003
1004 # Check for extra potential brokenness.
1005 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1006 # On Windows, double-check that we got the right compiler.
1007 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
1008 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
1009 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
1010 if test "x$COMPILER_CPU_TEST" != "x80x86" -a "x$COMPILER_CPU_TEST" != "xx86"; then
1011 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86" or "x86".])
1012 fi
1013 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
1014 if test "x$COMPILER_CPU_TEST" != "xx64"; then
1015 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
1016 fi
1017 fi
1018 fi
1019
1020 if test "x$TOOLCHAIN_TYPE" = xgcc; then
1021 # If this is a --hash-style=gnu system, use --hash-style=both, why?
1022 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
1023 # This is later checked when setting flags.
1024 fi
1025
1026 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
1027 # Check if linker has -z noexecstack.
1028 HAS_NOEXECSTACK=`$CC -Wl,--help 2>/dev/null | $GREP 'z noexecstack'`
1029 # This is later checked when setting flags.
1030 fi
1031
1032 # Setup hotspot lecagy names for toolchains
1033 HOTSPOT_TOOLCHAIN_TYPE=$TOOLCHAIN_TYPE
1034 if test "x$TOOLCHAIN_TYPE" = xclang; then
1035 HOTSPOT_TOOLCHAIN_TYPE=gcc
1036 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1037 HOTSPOT_TOOLCHAIN_TYPE=visCPP
1038 fi
1039 AC_SUBST(HOTSPOT_TOOLCHAIN_TYPE)
1040 ])
1041
1042 # Setup the JTReg Regression Test Harness.
1043 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1044 [
1045 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1046 [Regression Test Harness @<:@probed@:>@])])
1047
1048 if test "x$with_jtreg" = xno; then
1049 # jtreg disabled
1050 AC_MSG_CHECKING([for jtreg test harness])
1051 AC_MSG_RESULT([no, disabled])
1052 elif test "x$with_jtreg" != xyes && test "x$with_jtreg" != x; then
1053 # An explicit path is specified, use it.
1054 JT_HOME="$with_jtreg"
1055 BASIC_FIXUP_PATH([JT_HOME])
1056 if test ! -d "$JT_HOME"; then
1057 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not exist])
1058 fi
1059
1060 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1061 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg is not a valid jtreg home])
1062 fi
1063
1064 JTREGEXE="$JT_HOME/bin/jtreg"
1065 if test ! -x "$JTREGEXE"; then
1066 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not contain valid jtreg executable])
1067 fi
1068
1069 AC_MSG_CHECKING([for jtreg test harness])
1070 AC_MSG_RESULT([$JT_HOME])
1071 else
1072 # Try to locate jtreg
1073 if test "x$JT_HOME" != x; then
1074 # JT_HOME set in environment, use it
1075 if test ! -d "$JT_HOME"; then
1076 AC_MSG_WARN([Ignoring JT_HOME pointing to invalid directory: $JT_HOME])
1077 JT_HOME=
1078 else
1079 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1080 AC_MSG_WARN([Ignoring JT_HOME which is not a valid jtreg home: $JT_HOME])
1081 JT_HOME=
1082 elif test ! -x "$JT_HOME/bin/jtreg"; then
1083 AC_MSG_WARN([Ignoring JT_HOME which does not contain valid jtreg executable: $JT_HOME])
1084 JT_HOME=
1085 else
1086 JTREGEXE="$JT_HOME/bin/jtreg"
1087 AC_MSG_NOTICE([Located jtreg using JT_HOME from environment])
1088 fi
1089 fi
1090 fi
1091
1092 if test "x$JT_HOME" = x; then
1093 # JT_HOME is not set in environment, or was deemed invalid.
1094 # Try to find jtreg on path
1095 BASIC_PATH_PROGS(JTREGEXE, jtreg)
1096 if test "x$JTREGEXE" != x; then
1097 # That's good, now try to derive JT_HOME
1098 JT_HOME=`(cd $($DIRNAME $JTREGEXE)/.. && pwd)`
1099 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1100 AC_MSG_WARN([Ignoring jtreg from path since a valid jtreg home cannot be found])
1101 JT_HOME=
1102 JTREGEXE=
1103 else
1104 AC_MSG_NOTICE([Located jtreg using jtreg executable in path])
1105 fi
1106 fi
1107 fi
1108
1109 AC_MSG_CHECKING([for jtreg test harness])
1110 if test "x$JT_HOME" != x; then
1111 AC_MSG_RESULT([$JT_HOME])
1112 else
1113 AC_MSG_RESULT([no, not found])
1114
1115 if test "x$with_jtreg" = xyes; then
1116 AC_MSG_ERROR([--with-jtreg was specified, but no jtreg found.])
1117 fi
1118 fi
1119 fi
1120
1121 BASIC_FIXUP_EXECUTABLE(JTREGEXE)
1122 BASIC_FIXUP_PATH(JT_HOME)
1123 AC_SUBST(JT_HOME)
1124 AC_SUBST(JTREGEXE)
1125 ])
1126
1127 # Setup the JIB dependency resolver
1128 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JIB],
1129 [
1130 AC_ARG_WITH(jib, [AS_HELP_STRING([--with-jib],
1131 [Jib dependency management tool @<:@not used@:>@])])
1132
1133 if test "x$with_jib" = xno || test "x$with_jib" = x; then
1134 # jib disabled
1135 AC_MSG_CHECKING([for jib])
1136 AC_MSG_RESULT(no)
1137 elif test "x$with_jib" = xyes; then
1138 AC_MSG_ERROR([Must supply a value to --with-jib])
1139 else
1140 JIB_HOME="${with_jib}"
1141 AC_MSG_CHECKING([for jib])
1142 AC_MSG_RESULT(${JIB_HOME})
1143 if test ! -d "${JIB_HOME}"; then
1144 AC_MSG_ERROR([--with-jib must be a directory])
1145 fi
1146 JIB_JAR=$(ls ${JIB_HOME}/lib/jib-*.jar)
1147 if test ! -f "${JIB_JAR}"; then
1148 AC_MSG_ERROR([Could not find jib jar file in ${JIB_HOME}])
1149 fi
1150 fi
1151
1152 AC_SUBST(JIB_JAR)
1153 ])