1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64*x32)
34 VAR_CPU=x32
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=32
37 VAR_CPU_ENDIAN=little
38 ;;
39 x86_64)
40 VAR_CPU=x86_64
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=64
43 VAR_CPU_ENDIAN=little
44 ;;
45 i?86)
46 VAR_CPU=x86
47 VAR_CPU_ARCH=x86
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 alpha*)
52 VAR_CPU=alpha
53 VAR_CPU_ARCH=alpha
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 arm*)
58 VAR_CPU=arm
59 VAR_CPU_ARCH=arm
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=little
62 ;;
63 aarch64)
64 VAR_CPU=aarch64
65 VAR_CPU_ARCH=aarch64
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=little
68 ;;
69 ia64)
70 VAR_CPU=ia64
71 VAR_CPU_ARCH=ia64
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 m68k)
76 VAR_CPU=m68k
77 VAR_CPU_ARCH=m68k
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 mips)
82 VAR_CPU=mips
83 VAR_CPU_ARCH=mips
84 VAR_CPU_BITS=32
85 VAR_CPU_ENDIAN=big
86 ;;
87 mipsel)
88 VAR_CPU=mipsel
89 VAR_CPU_ARCH=mipsel
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=little
92 ;;
93 mips64)
94 VAR_CPU=mips64
95 VAR_CPU_ARCH=mips64
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 mips64el)
100 VAR_CPU=mips64el
101 VAR_CPU_ARCH=mips64el
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=little
104 ;;
105 powerpc)
106 VAR_CPU=ppc
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=32
109 VAR_CPU_ENDIAN=big
110 ;;
111 powerpc64)
112 VAR_CPU=ppc64
113 VAR_CPU_ARCH=ppc
114 VAR_CPU_BITS=64
115 VAR_CPU_ENDIAN=big
116 ;;
117 powerpc64le)
118 VAR_CPU=ppc64le
119 VAR_CPU_ARCH=ppc
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=little
122 ;;
123 riscv64)
124 VAR_CPU=riscv64
125 VAR_CPU_ARCH=riscv
126 VAR_CPU_BITS=64
127 VAR_CPU_ENDIAN=little
128 ;;
129 s390)
130 VAR_CPU=s390
131 VAR_CPU_ARCH=s390
132 VAR_CPU_BITS=32
133 VAR_CPU_ENDIAN=big
134 ;;
135 s390x)
136 VAR_CPU=s390x
137 VAR_CPU_ARCH=s390
138 VAR_CPU_BITS=64
139 VAR_CPU_ENDIAN=big
140 ;;
141 sh*eb)
142 VAR_CPU=sh
143 VAR_CPU_ARCH=sh
144 VAR_CPU_BITS=32
145 VAR_CPU_ENDIAN=big
146 ;;
147 sh*)
148 VAR_CPU=sh
149 VAR_CPU_ARCH=sh
150 VAR_CPU_BITS=32
151 VAR_CPU_ENDIAN=little
152 ;;
153 *)
154 AC_MSG_ERROR([unsupported cpu $1])
155 ;;
156 esac
157 ])
158
159 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
160 # Converts autoconf style OS name to OpenJDK style, into
161 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
162 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
163 [
164 case "$1" in
165 *linux*)
166 VAR_OS=linux
167 VAR_OS_TYPE=unix
168 ;;
169 *darwin*)
170 VAR_OS=macosx
171 VAR_OS_TYPE=unix
172 ;;
173 *bsd*)
174 VAR_OS=bsd
175 VAR_OS_TYPE=unix
176 ;;
177 *cygwin*)
178 VAR_OS=windows
179 VAR_OS_ENV=windows.cygwin
180 ;;
181 *wsl*)
182 VAR_OS=windows
183 VAR_OS_ENV=windows.wsl
184 ;;
185 *mingw*)
186 VAR_OS=windows
187 VAR_OS_ENV=windows.msys
188 ;;
189 *aix*)
190 VAR_OS=aix
191 VAR_OS_TYPE=unix
192 ;;
193 *)
194 AC_MSG_ERROR([unsupported operating system $1])
195 ;;
196 esac
197 ])
198
199 # Expects $host_os $host_cpu $build_os and $build_cpu
200 # and $with_target_bits to have been setup!
201 #
202 # Translate the standard triplet(quadruplet) definition
203 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
204 # OPENJDK_BUILD_OS, etc.
205 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
206 [
207 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
208 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
209 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
210 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
211 OPENJDK_TARGET_AUTOCONF_NAME="$host"
212 OPENJDK_BUILD_AUTOCONF_NAME="$build"
213 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
214 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
215
216 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
217 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
218 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
219 # ..and setup our own variables. (Do this explicitly to facilitate searching)
220 OPENJDK_BUILD_OS="$VAR_OS"
221 if test "x$VAR_OS_TYPE" != x; then
222 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
223 else
224 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
225 fi
226 if test "x$VAR_OS_ENV" != x; then
227 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
228 else
229 OPENJDK_BUILD_OS_ENV="$VAR_OS"
230 fi
231 OPENJDK_BUILD_CPU="$VAR_CPU"
232 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
233 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
234 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
235 AC_SUBST(OPENJDK_BUILD_OS)
236 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
237 AC_SUBST(OPENJDK_BUILD_OS_ENV)
238 AC_SUBST(OPENJDK_BUILD_CPU)
239 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
240 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
241 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
242
243 AC_MSG_CHECKING([openjdk-build os-cpu])
244 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
245
246 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
247 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
248 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
249 # ... and setup our own variables. (Do this explicitly to facilitate searching)
250 OPENJDK_TARGET_OS="$VAR_OS"
251 if test "x$VAR_OS_TYPE" != x; then
252 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
253 else
254 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
255 fi
256 if test "x$VAR_OS_ENV" != x; then
257 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
258 else
259 OPENJDK_TARGET_OS_ENV="$VAR_OS"
260 fi
261 OPENJDK_TARGET_CPU="$VAR_CPU"
262 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
263 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
264 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
265 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
266
267 AC_SUBST(OPENJDK_TARGET_OS)
268 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
269 AC_SUBST(OPENJDK_TARGET_OS_ENV)
270 AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
271 AC_SUBST(OPENJDK_TARGET_CPU)
272 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
273 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
274 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
275
276 AC_MSG_CHECKING([openjdk-target os-cpu])
277 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
278 ])
279
280 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
281 # accordingly. Must be done after setting up build and target system, but before
282 # doing anything else with these values.
283 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
284 [
285 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
286 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
287
288 # We have three types of compiles:
289 # native == normal compilation, target system == build system
290 # cross == traditional cross compilation, target system != build system; special toolchain needed
291 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
292 #
293 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
294 # We're doing a proper cross-compilation
295 COMPILE_TYPE="cross"
296 else
297 COMPILE_TYPE="native"
298 fi
299
300 if test "x$with_target_bits" != x; then
301 if test "x$COMPILE_TYPE" = "xcross"; then
302 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
303 fi
304
305 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
306 # A reduced build is requested
307 COMPILE_TYPE="reduced"
308 OPENJDK_TARGET_CPU_BITS=32
309 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
310 OPENJDK_TARGET_CPU=x86
311 else
312 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64])
313 fi
314 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
315 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
316 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
317 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
318 else
319 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
320 fi
321 fi
322 AC_SUBST(COMPILE_TYPE)
323
324 AC_MSG_CHECKING([compilation type])
325 AC_MSG_RESULT([$COMPILE_TYPE])
326 ])
327
328 # Setup the legacy variables, for controlling the old makefiles.
329 #
330 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
331 [
332 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
333 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
334 ])
335
336 # $1 - Either TARGET or BUILD to setup the variables for.
337 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
338 [
339 # Also store the legacy naming of the cpu.
340 # Ie i586 and amd64 instead of x86 and x86_64
341 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
342 if test "x$OPENJDK_$1_CPU" = xx86; then
343 OPENJDK_$1_CPU_LEGACY="i586"
344 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
345 # On all platforms except MacOSX replace x86_64 with amd64.
346 OPENJDK_$1_CPU_LEGACY="amd64"
347 elif test "x$OPENJDK_$1_CPU" = xalpha; then
348 # Avoid name collisions with variables named alpha
349 OPENJDK_$1_CPU_LEGACY="_alpha_"
350 elif test "x$OPENJDK_$1_CPU" = xsh; then
351 # Avoid name collisions with variables named sh
352 OPENJDK_$1_CPU_LEGACY="_sh_"
353 fi
354 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
355
356 # And the second legacy naming of the cpu.
357 # Ie i386 and amd64 instead of x86 and x86_64.
358 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
359 if test "x$OPENJDK_$1_CPU" = xx86; then
360 OPENJDK_$1_CPU_LEGACY_LIB="i386"
361 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
362 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
363 fi
364 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
365
366 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
367 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
368 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
369 # On linux only, we replace x86 with i386.
370 OPENJDK_$1_CPU_OSARCH="i386"
371 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
372 # On all platforms except macosx, we replace x86_64 with amd64.
373 OPENJDK_$1_CPU_OSARCH="amd64"
374 fi
375 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
376
377 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
378 if test "x$OPENJDK_$1_CPU" = xx86; then
379 OPENJDK_$1_CPU_JLI="i386"
380 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
381 # On all platforms except macosx, we replace x86_64 with amd64.
382 OPENJDK_$1_CPU_JLI="amd64"
383 fi
384
385 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
386 # Macosx is osx and x86_64 is x64
387 if test "x$OPENJDK_$1_OS" = xmacosx; then
388 OPENJDK_$1_OS_BUNDLE="osx"
389 else
390 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
391 fi
392 if test "x$OPENJDK_$1_CPU" = xx86_64; then
393 OPENJDK_$1_CPU_BUNDLE="x64"
394 else
395 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
396 fi
397 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
398 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
399
400 if test "x$COMPILE_TYPE" = "xcross"; then
401 # FIXME: ... or should this include reduced builds..?
402 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
403 else
404 DEFINE_CROSS_COMPILE_ARCH=""
405 fi
406 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
407
408 # Convert openjdk platform names to hotspot names
409
410 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
411 if test "x$OPENJDK_$1_OS" = xmacosx; then
412 HOTSPOT_$1_OS=bsd
413 fi
414 AC_SUBST(HOTSPOT_$1_OS)
415
416 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
417 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
418 HOTSPOT_$1_OS_TYPE=posix
419 fi
420 AC_SUBST(HOTSPOT_$1_OS_TYPE)
421
422 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
423 if test "x$OPENJDK_$1_CPU" = xx86; then
424 HOTSPOT_$1_CPU=x86_32
425 elif test "x$OPENJDK_$1_CPU" = xppc64; then
426 HOTSPOT_$1_CPU=ppc_64
427 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
428 HOTSPOT_$1_CPU=ppc_64
429 fi
430 AC_SUBST(HOTSPOT_$1_CPU)
431
432 # This is identical with OPENJDK_*, but define anyway for consistency.
433 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
434 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
435
436 # Setup HOTSPOT_$1_CPU_DEFINE
437 if test "x$OPENJDK_$1_CPU" = xx86; then
438 HOTSPOT_$1_CPU_DEFINE=IA32
439 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
440 HOTSPOT_$1_CPU_DEFINE=AMD64
441 elif test "x$OPENJDK_$1_CPU" = xx32; then
442 HOTSPOT_$1_CPU_DEFINE=X32
443 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
444 HOTSPOT_$1_CPU_DEFINE=AARCH64
445 elif test "x$OPENJDK_$1_CPU" = xppc64; then
446 HOTSPOT_$1_CPU_DEFINE=PPC64
447 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
448 HOTSPOT_$1_CPU_DEFINE=PPC64
449
450 # The cpu defines below are for zero, we don't support them directly.
451 elif test "x$OPENJDK_$1_CPU" = xppc; then
452 HOTSPOT_$1_CPU_DEFINE=PPC32
453 elif test "x$OPENJDK_$1_CPU" = xs390; then
454 HOTSPOT_$1_CPU_DEFINE=S390
455 elif test "x$OPENJDK_$1_CPU" = xs390x; then
456 HOTSPOT_$1_CPU_DEFINE=S390
457 elif test "x$OPENJDK_$1_CPU" = xriscv64; then
458 HOTSPOT_$1_CPU_DEFINE=RISCV
459 elif test "x$OPENJDK_$1_CPU" != x; then
460 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
461 fi
462 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
463
464 # For historical reasons, the OS include directories have odd names.
465 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
466 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
467 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
468 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
469 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
470 fi
471 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
472 ])
473
474 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
475 [
476 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
477 RELEASE_FILE_OS_NAME=Linux
478 fi
479 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
480 RELEASE_FILE_OS_NAME=Windows
481 fi
482 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
483 RELEASE_FILE_OS_NAME="Darwin"
484 fi
485 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
486 RELEASE_FILE_OS_NAME="AIX"
487 fi
488 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
489
490 AC_SUBST(RELEASE_FILE_OS_NAME)
491 AC_SUBST(RELEASE_FILE_OS_ARCH)
492 ])
493
494 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
495 [
496 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
497 OPENJDK_MODULE_TARGET_OS_NAME="macos"
498 else
499 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
500 fi
501
502 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
503 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
504 else
505 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
506 fi
507
508 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
509 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
510 ])
511
512 #%%% Build and target systems %%%
513 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
514 [
515 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
516 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
517 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
518 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
519 # to use the configure naming style.
520 AC_CANONICAL_BUILD
521 AC_CANONICAL_HOST
522 AC_CANONICAL_TARGET
523
524 PLATFORM_EXTRACT_TARGET_AND_BUILD
525 PLATFORM_SETUP_TARGET_CPU_BITS
526 PLATFORM_SET_MODULE_TARGET_OS_VALUES
527 PLATFORM_SET_RELEASE_FILE_OS_VALUES
528 PLATFORM_SETUP_LEGACY_VARS
529 ])
530
531 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
532 [
533 ###############################################################################
534
535 # Note that this is the build platform OS version!
536
537 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
538 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
539 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
540 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
541 AC_SUBST(OS_VERSION_MAJOR)
542 AC_SUBST(OS_VERSION_MINOR)
543 AC_SUBST(OS_VERSION_MICRO)
544 ])
545
546 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
547 [
548 ###############################################################################
549 #
550 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
551 # (The JVM can use 32 or 64 bit Java pointers but that decision
552 # is made at runtime.)
553 #
554
555 # Make compilation sanity check
556 AC_CHECK_HEADERS([stdio.h], , [
557 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
558 if test "x$COMPILE_TYPE" = xreduced; then
559 HELP_MSG_MISSING_DEPENDENCY([reduced])
560 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
561 elif test "x$COMPILE_TYPE" = xcross; then
562 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
563 fi
564 AC_MSG_ERROR([Cannot continue.])
565 ])
566
567 AC_CHECK_SIZEOF([int *], [1111])
568
569 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
570 if test "x$ac_cv_sizeof_int_p" = x; then
571 # The test failed, lets stick to the assumed value.
572 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
573 else
574 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
575
576 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
577 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
578 if test "x$COMPILE_TYPE" = xreduced; then
579 HELP_MSG_MISSING_DEPENDENCY([reduced])
580 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
581 elif test "x$COMPILE_TYPE" = xcross; then
582 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
583 fi
584 AC_MSG_ERROR([Cannot continue.])
585 fi
586 fi
587
588 AC_MSG_CHECKING([for target address size])
589 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
590 ])
591
592 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
593 [
594 ###############################################################################
595 #
596 # Is the target little of big endian?
597 #
598 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
599
600 if test "x$ENDIAN" = xuniversal_endianness; then
601 AC_MSG_ERROR([Building with both big and little endianness is not supported])
602 fi
603 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
604 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
605 fi
606 ])