1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
31
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 if test "$NUM_CORES" -eq "0"; then
36 NUM_CORES=`cat /proc/cpuinfo | grep -c ^CPU`
37 fi
38 if test "$NUM_CORES" -ne "0"; then
39 FOUND_CORES=yes
40 fi
41 elif test -x /usr/sbin/psrinfo; then
42 # Looks like a Solaris system
43 NUM_CORES=`/usr/sbin/psrinfo -v | grep -c on-line`
44 FOUND_CORES=yes
45 elif test -x /usr/sbin/sysctl; then
46 # Looks like a MacOSX system
47 NUM_CORES=`/usr/sbin/sysctl -n hw.ncpu`
48 FOUND_CORES=yes
49 elif test "x$OPENJDK_BUILD_OS" = xaix ; then
50 NUM_LCPU=`lparstat -m 2> /dev/null | $GREP -o "lcpu=[[0-9]]*" | $CUT -d "=" -f 2`
51 if test -n "$NUM_LCPU"; then
52 NUM_CORES=$NUM_LCPU
53 FOUND_CORES=yes
54 fi
55 elif test -n "$NUMBER_OF_PROCESSORS"; then
56 # On windows, look in the env
57 NUM_CORES=$NUMBER_OF_PROCESSORS
58 FOUND_CORES=yes
59 fi
60
61 if test "x$FOUND_CORES" = xyes; then
62 AC_MSG_RESULT([$NUM_CORES])
63 else
64 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
65 AC_MSG_WARN([This will disable all parallelism from build!])
66 fi
67 ])
68
69 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
70 [
71 AC_MSG_CHECKING([for memory size])
72 # Default to 1024 MB
73 MEMORY_SIZE=1024
74 FOUND_MEM=no
75
76 if test -f /proc/meminfo; then
77 # Looks like a Linux (or cygwin) system
78 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
79 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
80 FOUND_MEM=yes
81 elif test -x /usr/sbin/prtconf; then
82 # Looks like a Solaris or AIX system
83 MEMORY_SIZE=`/usr/sbin/prtconf 2> /dev/null | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
84 FOUND_MEM=yes
85 elif test -x /usr/sbin/sysctl; then
86 # Looks like a MacOSX system
87 MEMORY_SIZE=`/usr/sbin/sysctl -n hw.memsize`
88 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
89 FOUND_MEM=yes
90 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
91 # Windows, but without cygwin
92 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
93 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
94 FOUND_MEM=yes
95 fi
96
97 if test "x$FOUND_MEM" = xyes; then
98 AC_MSG_RESULT([$MEMORY_SIZE MB])
99 else
100 AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
101 AC_MSG_WARN([This might seriously impact build performance!])
102 fi
103 ])
104
105 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
106 [
107 # How many cores do we have on this build system?
108 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
109 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
110 if test "x$with_num_cores" = x; then
111 # The number of cores were not specified, try to probe them.
112 BPERF_CHECK_CORES
113 else
114 NUM_CORES=$with_num_cores
115 fi
116 AC_SUBST(NUM_CORES)
117 ])
118
119 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
120 [
121 # How much memory do we have on this build system?
122 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
123 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
124 if test "x$with_memory_size" = x; then
125 # The memory size was not specified, try to probe it.
126 BPERF_CHECK_MEMORY_SIZE
127 else
128 MEMORY_SIZE=$with_memory_size
129 fi
130 AC_SUBST(MEMORY_SIZE)
131 ])
132
133 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
134 [
135 # Provide a decent default number of parallel jobs for make depending on
136 # number of cores, amount of memory and machine architecture.
137 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
138 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
139 if test "x$with_jobs" = x; then
140 # Number of jobs was not specified, calculate.
141 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
142 # Approximate memory in GB.
143 memory_gb=`expr $MEMORY_SIZE / 1024`
144 # Pick the lowest of memory in gb and number of cores.
145 if test "$memory_gb" -lt "$NUM_CORES"; then
146 JOBS="$memory_gb"
147 else
148 JOBS="$NUM_CORES"
149 fi
150 if test "$JOBS" -eq "0"; then
151 JOBS=1
152 fi
153 AC_MSG_RESULT([$JOBS])
154 else
155 JOBS=$with_jobs
156 fi
157 AC_SUBST(JOBS)
158 ])
159
160 AC_DEFUN_ONCE([BPERF_SETUP_TEST_JOBS],
161 [
162 # The number of test jobs will be chosen automatically if TEST_JOBS is 0
163 AC_ARG_WITH(test-jobs, [AS_HELP_STRING([--with-test-jobs],
164 [number of parallel tests jobs to run @<:@based on build jobs@:>@])])
165 if test "x$with_test_jobs" = x; then
166 TEST_JOBS=0
167 else
168 TEST_JOBS=$with_test_jobs
169 fi
170 AC_SUBST(TEST_JOBS)
171 ])
172
173 AC_DEFUN([BPERF_SETUP_CCACHE],
174 [
175 # Check if ccache is available
176 CCACHE_AVAILABLE=true
177
178 OLD_PATH="$PATH"
179 if test "x$TOOLCHAIN_PATH" != x; then
180 PATH=$TOOLCHAIN_PATH:$PATH
181 fi
182 UTIL_PATH_PROGS(CCACHE, ccache)
183 PATH="$OLD_PATH"
184
185 AC_MSG_CHECKING([if ccache is available])
186 if test "x$TOOLCHAIN_TYPE" != "xgcc" && test "x$TOOLCHAIN_TYPE" != "xclang"; then
187 AC_MSG_RESULT([no, not supported for toolchain type $TOOLCHAIN_TYPE])
188 CCACHE_AVAILABLE=false
189 elif test "x$CCACHE" = "x"; then
190 AC_MSG_RESULT([no, ccache binary missing or not executable])
191 CCACHE_AVAILABLE=false
192 else
193 AC_MSG_RESULT([yes])
194 fi
195
196 CCACHE_STATUS=""
197 UTIL_ARG_ENABLE(NAME: ccache, DEFAULT: false, AVAILABLE: $CCACHE_AVAILABLE,
198 DESC: [enable using ccache to speed up recompilations],
199 CHECKING_MSG: [if ccache is enabled],
200 IF_ENABLED: [
201 CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
202 CCACHE_STATUS="Active ($CCACHE_VERSION)"
203 ],
204 IF_DISABLED: [
205 CCACHE=""
206 ])
207 AC_SUBST(CCACHE)
208
209 AC_ARG_WITH([ccache-dir],
210 [AS_HELP_STRING([--with-ccache-dir],
211 [where to store ccache files @<:@~/.ccache@:>@])])
212
213 if test "x$with_ccache_dir" != x; then
214 # When using a non home ccache directory, assume the use is to share ccache files
215 # with other users. Thus change the umask.
216 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
217 if test "x$CCACHE" = x; then
218 AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
219 fi
220 fi
221
222 if test "x$CCACHE" != x; then
223 BPERF_SETUP_CCACHE_USAGE
224 fi
225 ])
226
227 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
228 [
229 if test "x$CCACHE" != x; then
230 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
231 HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
232 $GREP -e '^1\.' -e '^2\.' -e '^3\.0\.' -e '^3\.1\.'`]
233 if test "x$HAS_BAD_CCACHE" != "x"; then
234 AC_MSG_ERROR([On macosx, ccache 3.2 or later is required, found $CCACHE_VERSION])
235 fi
236 fi
237 if test "x$USE_PRECOMPILED_HEADER" = "xtrue"; then
238 HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
239 $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
240 if test "x$HAS_BAD_CCACHE" != "x"; then
241 AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
242 fi
243 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
244 CCACHE_PRECOMP_FLAG="-fpch-preprocess"
245 PUSHED_FLAGS="$CXXFLAGS"
246 CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
248 CXXFLAGS="$PUSHED_FLAGS"
249 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
250 AC_MSG_RESULT([yes])
251 CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
252 AC_SUBST(CFLAGS_CCACHE)
253 CCACHE_SLOPPINESS=pch_defines,time_macros
254 else
255 AC_MSG_RESULT([no])
256 AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
257 fi
258 fi
259
260 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
261 CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
262
263 if test "x$SET_CCACHE_DIR" != x; then
264 mkdir -p $CCACHE_DIR > /dev/null 2>&1
265 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
266 fi
267 fi
268 ])
269
270 ################################################################################
271 #
272 # Runs icecc-create-env once and prints the error if it fails
273 #
274 # $1: arguments to icecc-create-env
275 # $2: log file
276 #
277 AC_DEFUN([BPERF_RUN_ICECC_CREATE_ENV],
278 [
279 ( cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
280 && ${ICECC_CREATE_ENV} $1 > $2 2>&1 )
281 if test "$?" != "0"; then
282 AC_MSG_NOTICE([icecc-create-env output:])
283 cat $2
284 AC_MSG_ERROR([Failed to create icecc compiler environment])
285 fi
286 ])
287
288 ################################################################################
289 #
290 # Optionally enable distributed compilation of native code using icecc/icecream
291 #
292 AC_DEFUN([BPERF_SETUP_ICECC],
293 [
294 UTIL_ARG_ENABLE(NAME: icecc, DEFAULT: false, RESULT: ENABLE_ICECC,
295 DESC: [enable distributed compilation of native code using icecc/icecream])
296
297 if test "x$ENABLE_ICECC" = "xtrue"; then
298 UTIL_REQUIRE_PROGS(ICECC_CMD, icecc)
299 old_path="$PATH"
300
301 # Look for icecc-create-env in some known places
302 PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
303 UTIL_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
304 # Use icecc-create-env to create a minimal compilation environment that can
305 # be sent to the other hosts in the icecream cluster.
306 icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
307 ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
308 # Older versions of icecc does not have the --gcc parameter
309 if ${ICECC_CREATE_ENV} | $GREP -q -e --gcc; then
310 icecc_gcc_arg="--gcc"
311 fi
312 if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
313 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${CC} ${CXX}], \
314 ${icecc_create_env_log})
315 elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
316 # For clang, the icecc compilerwrapper is needed. It usually resides next
317 # to icecc-create-env.
318 UTIL_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
319 BPERF_RUN_ICECC_CREATE_ENV([--clang ${CC} ${ICECC_WRAPPER}], ${icecc_create_env_log})
320 else
321 AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
322 fi
323 PATH="$old_path"
324 # The bundle with the compiler gets a name based on checksums. Parse log file
325 # to find it.
326 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
327 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
328 if test ! -f ${ICECC_ENV_BUNDLE}; then
329 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
330 fi
331 AC_MSG_CHECKING([for icecc build environment for target compiler])
332 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
333 ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
334
335 if test "x${COMPILE_TYPE}" = "xcross"; then
336 # If cross compiling, create a separate env package for the build compiler
337 # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
338 icecc_create_env_log_build="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env_build.log"
339 if test "x${BUILD_CC##*/}" = "xgcc" || test "x${BUILD_CC##*/}" = "xcc"; then
340 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${BUILD_CC} ${BUILD_CXX}], \
341 ${icecc_create_env_log_build})
342 elif test "x${BUILD_CC##*/}" = "xclang"; then
343 BPERF_RUN_ICECC_CREATE_ENV([--clang ${BUILD_CC} ${ICECC_WRAPPER}], ${icecc_create_env_log_build})
344 else
345 AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
346 fi
347 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log_build}`"
348 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
349 if test ! -f ${ICECC_ENV_BUNDLE}; then
350 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
351 fi
352 AC_MSG_CHECKING([for icecc build environment for build compiler])
353 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
354 BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
355 ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
356 else
357 BUILD_ICECC="${ICECC}"
358 fi
359 fi
360
361 AC_SUBST(ICECC)
362 AC_SUBST(BUILD_ICECC)
363 ])
364
365 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
366 [
367 # Are precompiled headers available?
368 PRECOMPILED_HEADERS_AVAILABLE=true
369 AC_MSG_CHECKING([if precompiled headers are available])
370 if test "x$ICECC" != "x"; then
371 AC_MSG_RESULT([no, does not work effectively with icecc])
372 PRECOMPILED_HEADERS_AVAILABLE=false
373 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
374 AC_MSG_RESULT([no, does not work with Solaris Studio])
375 PRECOMPILED_HEADERS_AVAILABLE=false
376 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
377 AC_MSG_RESULT([no, does not work with xlc])
378 PRECOMPILED_HEADERS_AVAILABLE=false
379 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
380 # Check that the compiler actually supports precomp headers.
381 echo "int alfa();" > conftest.h
382 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
383 if test ! -f conftest.hpp.gch; then
384 PRECOMPILED_HEADERS_AVAILABLE=false
385 AC_MSG_RESULT([no, gcc fails to compile properly with -x c++-header])
386 else
387 AC_MSG_RESULT([yes])
388 fi
389 $RM conftest.h conftest.hpp.gch
390 else
391 AC_MSG_RESULT([yes])
392 fi
393
394 UTIL_ARG_ENABLE(NAME: precompiled-headers, DEFAULT: auto,
395 RESULT: USE_PRECOMPILED_HEADER, AVAILABLE: $PRECOMPILED_HEADERS_AVAILABLE,
396 DESC: [enable using precompiled headers when compiling C++])
397 AC_SUBST(USE_PRECOMPILED_HEADER)
398 ])
399
400
401 AC_DEFUN_ONCE([BPERF_SETUP_JAVAC_SERVER],
402 [
403 UTIL_ARG_ENABLE(NAME: javac-server, DEFAULT: true,
404 RESULT: ENABLE_JAVAC_SERVER,
405 DESC: [enable javac server],
406 CHECKING_MSG: [whether to use javac server])
407 AC_SUBST(ENABLE_JAVAC_SERVER)
408 ])