1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 C_FLAG_REORDER=''
39
40 # Default works for linux, might work on other platforms as well.
41 SHARED_LIBRARY_FLAGS='-shared'
42 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
43 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
44 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
45 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
46
47 elif test "x$TOOLCHAIN_TYPE" = xclang; then
48 C_FLAG_REORDER=''
49
50 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
51 # Linking is different on MacOSX
52 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
53 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
54 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
55 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
56 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
57
58 else
59 # Default works for linux, might work on other platforms as well.
60 SHARED_LIBRARY_FLAGS='-shared'
61 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
62 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
63 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
64
65 # arm specific settings
66 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
67 # '-Wl,-z,origin' isn't used on arm.
68 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
69 else
70 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
71 fi
72 fi
73
74 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
75 C_FLAG_REORDER='-xF'
76 SHARED_LIBRARY_FLAGS="-G"
77 SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
78 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
79 SET_SHARED_LIBRARY_NAME='-h [$]1'
80 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
81
82 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
83 C_FLAG_REORDER=''
84 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
85 SET_EXECUTABLE_ORIGIN=""
86 SET_SHARED_LIBRARY_ORIGIN=''
87 SET_SHARED_LIBRARY_NAME=''
88 SET_SHARED_LIBRARY_MAPFILE=''
89
90 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
91 C_FLAG_REORDER=''
92 SHARED_LIBRARY_FLAGS="-dll"
93 SET_EXECUTABLE_ORIGIN=''
94 SET_SHARED_LIBRARY_ORIGIN=''
95 SET_SHARED_LIBRARY_NAME=''
96 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
97 fi
98
99 AC_SUBST(C_FLAG_REORDER)
100 AC_SUBST(SET_EXECUTABLE_ORIGIN)
101 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
102 AC_SUBST(SET_SHARED_LIBRARY_NAME)
103 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
104 AC_SUBST(SHARED_LIBRARY_FLAGS)
105 ])
106
107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
108 [
109 # By default don't set any specific assembler debug
110 # info flags for toolchains unless we know they work.
111 # See JDK-8207057.
112 ASFLAGS_DEBUG_SYMBOLS=""
113 # Debug symbols
114 if test "x$TOOLCHAIN_TYPE" = xgcc; then
115 CFLAGS_DEBUG_SYMBOLS="-g"
116 ASFLAGS_DEBUG_SYMBOLS="-g"
117 elif test "x$TOOLCHAIN_TYPE" = xclang; then
118 CFLAGS_DEBUG_SYMBOLS="-g"
119 ASFLAGS_DEBUG_SYMBOLS="-g"
120 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
121 # -g0 enables debug symbols without disabling inlining.
122 CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
123 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
124 CFLAGS_DEBUG_SYMBOLS="-g1"
125 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
126 CFLAGS_DEBUG_SYMBOLS="-Z7"
127 fi
128
129 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
130 AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
131 ])
132
133 AC_DEFUN([FLAGS_SETUP_WARNINGS],
134 [
135 # Set default value.
136 if test "x$TOOLCHAIN_TYPE" != xxlc; then
137 WARNINGS_AS_ERRORS_DEFAULT=true
138 else
139 WARNINGS_AS_ERRORS_DEFAULT=false
140 fi
141
142 UTIL_ARG_ENABLE(NAME: warnings-as-errors, DEFAULT: $WARNINGS_AS_ERRORS_DEFAULT,
143 RESULT: WARNINGS_AS_ERRORS,
144 DEFAULT_DESC: [auto],
145 DESC: [consider native warnings to be an error])
146 AC_SUBST(WARNINGS_AS_ERRORS)
147
148 case "${TOOLCHAIN_TYPE}" in
149 microsoft)
150 DISABLE_WARNING_PREFIX="-wd"
151 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
152
153 WARNINGS_ENABLE_ALL="-W3"
154 DISABLED_WARNINGS="4800"
155 ;;
156
157 solstudio)
158 DISABLE_WARNING_PREFIX="-erroff="
159 CFLAGS_WARNINGS_ARE_ERRORS="-errwarn=%all"
160
161 WARNINGS_ENABLE_ALL_CFLAGS="-v -fd -xtransition"
162 WARNINGS_ENABLE_ALL_CXXFLAGS="+w +w2"
163
164 DISABLED_WARNINGS_C="E_OLD_STYLE_FUNC_DECL E_OLD_STYLE_FUNC_DEF E_SEMANTICS_OF_OP_CHG_IN_ANSI_C E_NO_REPLACEMENT_IN_STRING E_DECLARATION_IN_CODE"
165 DISABLED_WARNINGS_CXX="inllargeuse inllargeint notused wemptydecl notemsource"
166 ;;
167
168 gcc)
169 DISABLE_WARNING_PREFIX="-Wno-"
170 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
171
172 # Additional warnings that are not activated by -Wall and -Wextra
173 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare \
174 -Wunused-function -Wundef -Wunused-value -Wreturn-type \
175 -Wtrampolines"
176 WARNINGS_ENABLE_ADDITIONAL_CXX="-Woverloaded-virtual -Wreorder"
177 WARNINGS_ENABLE_ALL_CFLAGS="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
178 WARNINGS_ENABLE_ALL_CXXFLAGS="$WARNINGS_ENABLE_ALL_CFLAGS $WARNINGS_ENABLE_ADDITIONAL_CXX"
179
180 DISABLED_WARNINGS="unused-parameter unused"
181 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
182 ;;
183
184 clang)
185 DISABLE_WARNING_PREFIX="-Wno-"
186 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
187
188 # Additional warnings that are not activated by -Wall and -Wextra
189 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare -Wreorder \
190 -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual"
191 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
192
193 DISABLED_WARNINGS="unknown-warning-option unused-parameter unused"
194
195 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
196 # missing-method-return-type triggers in JavaNativeFoundation framework
197 DISABLED_WARNINGS="$DISABLED_WARNINGS missing-method-return-type"
198 fi
199
200 ;;
201
202 xlc)
203 DISABLE_WARNING_PREFIX="-Wno-"
204 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
205
206 # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
207 WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
208 DISABLED_WARNINGS=""
209 ;;
210 esac
211 AC_SUBST(DISABLE_WARNING_PREFIX)
212 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
213 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
214 AC_SUBST(DISABLED_WARNINGS)
215 AC_SUBST(DISABLED_WARNINGS_C)
216 AC_SUBST(DISABLED_WARNINGS_CXX)
217 ])
218
219 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
220 [
221 # bounds, memory and behavior checking options
222 if test "x$TOOLCHAIN_TYPE" = xgcc; then
223 case $DEBUG_LEVEL in
224 release )
225 # no adjustment
226 ;;
227 fastdebug )
228 # no adjustment
229 ;;
230 slowdebug )
231 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
232 # get's added conditionally on whether we produce debug symbols or not.
233 # This is most likely not really correct.
234
235 # Add runtime stack smashing and undefined behavior checks.
236 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
237 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
238
239 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
240 ;;
241 esac
242 fi
243 ])
244
245 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
246 [
247 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
248 CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
249
250 C_O_FLAG_HIGHEST_JVM="-xO4"
251 C_O_FLAG_DEBUG_JVM=""
252 C_O_FLAG_SIZE=""
253 C_O_FLAG_DEBUG=""
254 C_O_FLAG_NONE=""
255 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
256 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
257 C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
258 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
259 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
260 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
261 -xprefetch=auto,explicit $CC_HIGHEST"
262 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
263 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
264 fi
265 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
266 C_O_FLAG_HIGHEST_JVM="-O3"
267 C_O_FLAG_HIGHEST="-O3"
268 C_O_FLAG_HI="-O3"
269 C_O_FLAG_NORM="-O2"
270 C_O_FLAG_SIZE="-Os"
271 C_O_FLAG_DEBUG="-O0"
272 C_O_FLAG_DEBUG_JVM="-O0"
273 C_O_FLAG_NONE="-O0"
274 # -D_FORTIFY_SOURCE=2 hardening option needs optimization (at least -O1) enabled
275 # set for lower O-levels -U_FORTIFY_SOURCE to overwrite previous settings
276 if test "x$OPENJDK_TARGET_OS" = xlinux -a "x$DEBUG_LEVEL" = "xfastdebug"; then
277 ENABLE_FORTIFY_CFLAGS="-D_FORTIFY_SOURCE=2"
278 DISABLE_FORTIFY_CFLAGS="-U_FORTIFY_SOURCE"
279 C_O_FLAG_HIGHEST_JVM="${C_O_FLAG_HIGHEST_JVM} ${ENABLE_FORTIFY_CFLAGS}"
280 C_O_FLAG_HIGHEST="${C_O_FLAG_HIGHEST} ${ENABLE_FORTIFY_CFLAGS}"
281 C_O_FLAG_HI="${C_O_FLAG_HI} ${ENABLE_FORTIFY_CFLAGS}"
282 C_O_FLAG_NORM="${C_O_FLAG_NORM} ${ENABLE_FORTIFY_CFLAGS}"
283 C_O_FLAG_SIZE="${C_O_FLAG_SIZE} ${DISABLE_FORTIFY_CFLAGS}"
284 C_O_FLAG_DEBUG="${C_O_FLAG_DEBUG} ${DISABLE_FORTIFY_CFLAGS}"
285 C_O_FLAG_DEBUG_JVM="${C_O_FLAG_DEBUG_JVM} ${DISABLE_FORTIFY_CFLAGS}"
286 C_O_FLAG_NONE="${C_O_FLAG_NONE} ${DISABLE_FORTIFY_CFLAGS}"
287 fi
288 elif test "x$TOOLCHAIN_TYPE" = xclang; then
289 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
290 # On MacOSX we optimize for size, something
291 # we should do for all platforms?
292 C_O_FLAG_HIGHEST_JVM="-Os"
293 C_O_FLAG_HIGHEST="-Os"
294 C_O_FLAG_HI="-Os"
295 C_O_FLAG_NORM="-Os"
296 C_O_FLAG_DEBUG_JVM=""
297 else
298 C_O_FLAG_HIGHEST_JVM="-O3"
299 C_O_FLAG_HIGHEST="-O3"
300 C_O_FLAG_HI="-O3"
301 C_O_FLAG_NORM="-O2"
302 C_O_FLAG_DEBUG_JVM="-O0"
303 fi
304 C_O_FLAG_SIZE="-Os"
305 C_O_FLAG_DEBUG="-O0"
306 C_O_FLAG_NONE="-O0"
307 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
308 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
309 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
310 C_O_FLAG_HI="-O3 -qinline -qinlglue"
311 C_O_FLAG_NORM="-O2"
312 C_O_FLAG_DEBUG="-qnoopt"
313 # FIXME: Value below not verified.
314 C_O_FLAG_DEBUG_JVM=""
315 C_O_FLAG_NONE="-qnoopt"
316 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
317 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
318 C_O_FLAG_HIGHEST="-O2"
319 C_O_FLAG_HI="-O1"
320 C_O_FLAG_NORM="-O1"
321 C_O_FLAG_DEBUG="-Od"
322 C_O_FLAG_DEBUG_JVM=""
323 C_O_FLAG_NONE="-Od"
324 C_O_FLAG_SIZE="-Os"
325 fi
326
327 # Now copy to C++ flags
328 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
329 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
330 CXX_O_FLAG_HI="$C_O_FLAG_HI"
331 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
332 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
333 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
334 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
335 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
336
337 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
338 # In solstudio, also add this to C (but not C++) flags...
339 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
340 fi
341
342 # Adjust optimization flags according to debug level.
343 case $DEBUG_LEVEL in
344 release )
345 # no adjustment
346 ;;
347 fastdebug )
348 # Not quite so much optimization
349 C_O_FLAG_HI="$C_O_FLAG_NORM"
350 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
351 ;;
352 slowdebug )
353 # Disable optimization
354 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
355 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
356 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
357 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
358 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
359 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
360 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
361 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
362 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
363 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
364 ;;
365 esac
366
367 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
368 AC_SUBST(C_O_FLAG_HIGHEST)
369 AC_SUBST(C_O_FLAG_HI)
370 AC_SUBST(C_O_FLAG_NORM)
371 AC_SUBST(C_O_FLAG_NONE)
372 AC_SUBST(C_O_FLAG_SIZE)
373 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
374 AC_SUBST(CXX_O_FLAG_HIGHEST)
375 AC_SUBST(CXX_O_FLAG_HI)
376 AC_SUBST(CXX_O_FLAG_NORM)
377 AC_SUBST(CXX_O_FLAG_NONE)
378 AC_SUBST(CXX_O_FLAG_SIZE)
379 ])
380
381 AC_DEFUN([FLAGS_SETUP_CFLAGS],
382 [
383 ### CFLAGS
384
385 FLAGS_SETUP_CFLAGS_HELPER
386
387 FLAGS_OS=$OPENJDK_TARGET_OS
388 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
389 FLAGS_CPU=$OPENJDK_TARGET_CPU
390 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
391 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
392 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
393 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
394 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
395
396 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
397
398 # Repeat the check for the BUILD_CC and BUILD_CXX. Need to also reset CFLAGS
399 # since any target specific flags will likely not work with the build compiler.
400 CC_OLD="$CC"
401 CXX_OLD="$CXX"
402 CFLAGS_OLD="$CFLAGS"
403 CXXFLAGS_OLD="$CXXFLAGS"
404 CC="$BUILD_CC"
405 CXX="$BUILD_CXX"
406 CFLAGS=""
407 CXXFLAGS=""
408
409 FLAGS_OS=$OPENJDK_BUILD_OS
410 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
411 FLAGS_CPU=$OPENJDK_BUILD_CPU
412 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
413 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
414 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
415 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
416 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
417
418 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_], [BUILD_])
419
420 CC="$CC_OLD"
421 CXX="$CXX_OLD"
422 CFLAGS="$CFLAGS_OLD"
423 CXXFLAGS="$CXXFLAGS_OLD"
424 ])
425
426 ################################################################################
427 # platform independent
428 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
429 [
430 #### OS DEFINES, these should be independent on toolchain
431 if test "x$OPENJDK_TARGET_OS" = xlinux; then
432 CFLAGS_OS_DEF_JVM="-DLINUX"
433 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
434 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
435 CFLAGS_OS_DEF_JVM="-DSOLARIS"
436 CFLAGS_OS_DEF_JDK="-D__solaris__"
437 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
438 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
439 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
440 elif test "x$OPENJDK_TARGET_OS" = xaix; then
441 CFLAGS_OS_DEF_JVM="-DAIX"
442 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
443 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
444 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
445 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
446 fi
447
448 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
449
450 #### GLOBAL DEFINES
451 # Set some common defines. These works for all compilers, but assume
452 # -D is universally accepted.
453
454 # Always enable optional macros for VM.
455 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
456
457 # Setup some hard coded includes
458 ALWAYS_CFLAGS_JDK=" \
459 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
460 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
461 -I${TOPDIR}/src/java.base/share/native/libjava \
462 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
463 -I${TOPDIR}/src/hotspot/share/include \
464 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
465
466 ###############################################################################
467
468 # Adjust flags according to debug level.
469 # Setup debug/release defines
470 if test "x$DEBUG_LEVEL" = xrelease; then
471 DEBUG_CFLAGS_JDK="-DNDEBUG"
472 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
473 DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
474 fi
475 else
476 DEBUG_CFLAGS_JDK="-DDEBUG"
477
478 if test "x$TOOLCHAIN_TYPE" = xxlc; then
479 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
480 # Hotspot now overflows its 64K TOC (currently only for debug),
481 # so for debug we build with '-qpic=large -bbigtoc'.
482 DEBUG_CFLAGS_JVM="-qpic=large"
483 fi
484 fi
485
486 if test "x$DEBUG_LEVEL" != xrelease; then
487 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
488 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
489 fi
490
491 #### TOOLCHAIN DEFINES
492
493 if test "x$TOOLCHAIN_TYPE" = xgcc; then
494 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
495 elif test "x$TOOLCHAIN_TYPE" = xclang; then
496 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
497 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
498 ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
499 ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
500 ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
501 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
502 ALWAYS_DEFINES_JVM="-D_REENTRANT"
503 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
504 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
505 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
506 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
507 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
508 fi
509
510 ###############################################################################
511 #
512 #
513 # CFLAGS BASIC
514 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
515 # COMMON to gcc and clang
516 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
517 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
518 fi
519
520 if test "x$TOOLCHAIN_TYPE" = xgcc; then
521 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new -fstack-protector"
522 TOOLCHAIN_CFLAGS_JDK="-pipe -fstack-protector"
523 # reduce lib size on linux in link step, this needs also special compile flags
524 # do this on s390x also for libjvm (where serviceability agent is not supported)
525 if test "x$ENABLE_LINKTIME_GC" = xtrue; then
526 TOOLCHAIN_CFLAGS_JDK="$TOOLCHAIN_CFLAGS_JDK -ffunction-sections -fdata-sections"
527 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
528 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -ffunction-sections -fdata-sections"
529 fi
530 fi
531 # technically NOT for CXX (but since this gives *worse* performance, use
532 # no-strict-aliasing everywhere!)
533 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing"
534
535 elif test "x$TOOLCHAIN_TYPE" = xclang; then
536 # Restrict the debug information created by Clang to avoid
537 # too big object files and speed the build up a little bit
538 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
539 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
540
541 # In principle the stack alignment below is cpu- and ABI-dependent and
542 # should agree with values of StackAlignmentInBytes in various
543 # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
544 # works for all platforms.
545 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
546
547 if test "x$OPENJDK_TARGET_OS" = xlinux; then
548 if test "x$DEBUG_LEVEL" = xrelease; then
549 # Clang does not inline as much as GCC does for functions with "inline" keyword by default.
550 # This causes noticeable slowdown in pause time for G1, and possibly in other areas.
551 # Increasing the inline hint threshold avoids the slowdown for Clang-built JVM.
552 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mllvm -inlinehint-threshold=100000"
553 fi
554 TOOLCHAIN_CFLAGS_JDK="-pipe"
555 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
556 fi
557 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
558 TOOLCHAIN_FLAGS="-errtags -errfmt"
559 TOOLCHAIN_CFLAGS="-errshort=tags"
560
561 TOOLCHAIN_CFLAGS_JDK="-mt $TOOLCHAIN_FLAGS"
562 TOOLCHAIN_CFLAGS_JDK_CONLY="-W0,-noglobal $TOOLCHAIN_CFLAGS" # C only
563 TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
564 TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
565 -library=stlport4 -mt -features=no%except $TOOLCHAIN_FLAGS"
566 if test "x$DEBUG_LEVEL" = xslowdebug; then
567 # Previously -g was used instead of -g0 for slowdebug; this is equivalent
568 # to setting +d.
569 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
570 fi
571
572 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
573 # Suggested additions: -qsrcmsg to get improved error reporting
574 # set -qtbtable=full for a better traceback table/better stacks in hs_err when xlc16 is used
575 TOOLCHAIN_CFLAGS_JDK="-qtbtable=full -qchars=signed -qfullpath -qsaveopt -qstackprotect" # add on both CFLAGS
576 TOOLCHAIN_CFLAGS_JVM="-qtbtable=full -qtune=balanced \
577 -qalias=noansi -qstrict -qtls=default -qnortti -qnoeh -qignerrno -qstackprotect"
578 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
579 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
580 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
581 fi
582
583 # CFLAGS C language level for JDK sources (hotspot only uses C++)
584 # Ideally we would have a common level across all toolchains so that all sources
585 # are sure to conform to the same standard. Unfortunately neither our sources nor
586 # our toolchains are in a condition to support that. But what we loosely aim for is
587 # C99 level.
588 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xxlc; then
589 # Explicitly set C99. clang and xlclang support the same flag.
590 LANGSTD_CFLAGS="-std=c99"
591 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
592 # We can't turn on -std=c99 without breaking compilation of the splashscreen/png
593 # utilities. But we can enable c99 as below (previously achieved by using -Xa).
594 # It is the no_lib that makes the difference.
595 LANGSTD_CFLAGS="-xc99=all,no_lib"
596 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
597 # MSVC doesn't support C99/C11 explicitly, unless you compile as C++:
598 # LANGSTD_CFLAGS="-TP"
599 # but that requires numerous changes to the sources files. So we are limited
600 # to C89/C90 plus whatever extensions Visual Studio has decided to implement.
601 # This is the lowest bar for shared code.
602 LANGSTD_CFLAGS=""
603 fi
604 TOOLCHAIN_CFLAGS_JDK_CONLY="$LANGSTD_CFLAGS $TOOLCHAIN_CFLAGS_JDK_CONLY"
605
606 # CFLAGS WARNINGS STUFF
607 # Set JVM_CFLAGS warning handling
608 if test "x$TOOLCHAIN_TYPE" = xgcc; then
609 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
610 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
611 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
612
613 elif test "x$TOOLCHAIN_TYPE" = xclang; then
614 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
615
616 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
617 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
618 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
619 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
620
621 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
622 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
623
624 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
625 WARNING_CFLAGS="" # currently left empty
626 fi
627
628 # Set some additional per-OS defines.
629
630 # Additional macosx handling
631 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
632 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
633 -mmacosx-version-min=$MACOSX_VERSION_MIN"
634
635 if test -n "$MACOSX_VERSION_MAX"; then
636 OS_CFLAGS="$OS_CFLAGS \
637 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
638 fi
639 fi
640
641 # Where does this really belong??
642 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
643 PICFLAG="-fPIC"
644 PIEFLAG="-fPIE"
645 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
646 PICFLAG="-KPIC"
647 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
648 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
649 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
650 # will have to patch this single instruction with a call to some out-of-order code which
651 # does the load from the TOC. This is of course slower, and we also would have
652 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
653 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
654 # can be patched directly by the linker and does not require a jump to out-of-order code.
655 #
656 # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
657 # for all libjvm variants (both gtest and normal) but no other binaries. So, build
658 # libjvm with -qpic=large and link with -bbigtoc.
659 JVM_PICFLAG="-qpic=large"
660 JDK_PICFLAG="-qpic"
661 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
662 PICFLAG=""
663 fi
664
665 if test "x$TOOLCHAIN_TYPE" != xxlc; then
666 JVM_PICFLAG="$PICFLAG"
667 JDK_PICFLAG="$PICFLAG"
668 fi
669
670 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
671 # Linking is different on MacOSX
672 JDK_PICFLAG=''
673 if test "x$STATIC_BUILD" = xtrue; then
674 JVM_PICFLAG=""
675 fi
676 fi
677
678 # Optional POSIX functionality needed by the JVM
679 #
680 # Check if clock_gettime is available and in which library. This indicates
681 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
682 # don't let it update LIBS.
683 save_LIBS="$LIBS"
684 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
685 if test "x$LIBS" = "x-lrt "; then
686 CLOCK_GETTIME_IN_LIBRT=true
687 fi
688 LIBS="$save_LIBS"
689
690 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
691 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
692 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
693 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
694 fi
695 fi
696
697 # Extra flags needed when building optional static versions of certain
698 # JDK libraries.
699 STATIC_LIBS_CFLAGS="-DSTATIC_BUILD=1"
700 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
701 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -ffunction-sections -fdata-sections \
702 -DJNIEXPORT='__attribute__((visibility(\"hidden\")))'"
703 else
704 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -DJNIEXPORT="
705 fi
706 if test "x$TOOLCHAIN_TYPE" = xgcc; then
707 # Disable relax-relocation to enable compatibility with older linkers
708 RELAX_RELOCATIONS_FLAG="-Xassembler -mrelax-relocations=no"
709 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${RELAX_RELOCATIONS_FLAG}],
710 IF_TRUE: [STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS ${RELAX_RELOCATIONS_FLAG}"])
711 fi
712 AC_SUBST(STATIC_LIBS_CFLAGS)
713 ])
714
715 ################################################################################
716 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
717 # conditionals against.
718 # $2 - Optional prefix for each variable defined.
719 # $3 - Optional prefix for compiler variables (either BUILD_ or nothing).
720 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
721 [
722 #### CPU DEFINES, these should (in theory) be independent on toolchain
723
724 # Setup target CPU
725 # Setup endianness
726 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
727 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
728 fi
729 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
730 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
731 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
732 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
733 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
734 else
735 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
736 fi
737 else
738 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
739 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
740 else
741 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
742 fi
743 fi
744
745 # setup CPU bit size
746 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
747 -D$FLAGS_CPU_LEGACY"
748
749 if test "x$FLAGS_CPU_BITS" = x64; then
750 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
751 # unpack200.exe.
752 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
753 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
754 fi
755 if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
756 # Solaris does not have _LP64=1 in the old build.
757 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
758 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
759 fi
760 fi
761
762 # toolchain dependend, per-cpu
763 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
764 if test "x$FLAGS_CPU_ARCH" = xx86; then
765 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
766 fi
767 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
768 if test "x$FLAGS_CPU" = xx86_64; then
769 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
770 else
771 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
772 fi
773 fi
774
775 # CFLAGS PER CPU
776 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
777 # COMMON to gcc and clang
778 if test "x$FLAGS_CPU" = xx86; then
779 # Force compatibility with i586 on 32 bit intel platforms.
780 $1_CFLAGS_CPU="-march=i586"
781 fi
782 fi
783
784 if test "x$TOOLCHAIN_TYPE" = xgcc; then
785 if test "x$FLAGS_CPU" = xaarch64; then
786 # -Wno-psabi to get rid of annoying "note: parameter passing for argument of type '<type> changed in GCC 9.1"
787 $1_CFLAGS_CPU="-Wno-psabi"
788 elif test "x$FLAGS_CPU" = xarm; then
789 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
790 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
791 $1_CFLAGS_CPU_JVM="-DARM"
792 elif test "x$FLAGS_CPU_ARCH" = xppc; then
793 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
794 if test "x$FLAGS_CPU" = xppc64; then
795 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
796 # Use ppc64 instructions, but schedule for power5
797 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
798 elif test "x$FLAGS_CPU" = xppc64le; then
799 # Little endian machine uses ELFv2 ABI.
800 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
801 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
802 fi
803 elif test "x$FLAGS_CPU" = xs390x; then
804 $1_CFLAGS_CPU="-mbackchain -march=z10"
805 fi
806
807 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
808 # for all archs except arm and ppc, prevent gcc to omit frame pointer
809 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
810 fi
811
812 $1_CXXSTD_CXXFLAG="-std=gnu++98"
813 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${$1_CXXSTD_CXXFLAG}],
814 PREFIX: $3, IF_FALSE: [$1_CXXSTD_CXXFLAG=""])
815 $1_TOOLCHAIN_CFLAGS_JDK_CXXONLY="${$1_CXXSTD_CXXFLAG}"
816 $1_TOOLCHAIN_CFLAGS_JVM="${$1_TOOLCHAIN_CFLAGS_JVM} ${$1_CXXSTD_CXXFLAG}"
817 $2ADLC_CXXFLAG="${$1_CXXSTD_CXXFLAG}"
818
819 elif test "x$TOOLCHAIN_TYPE" = xclang; then
820 if test "x$FLAGS_OS" = xlinux; then
821 # ppc test not really needed for clang
822 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
823 # for all archs except arm and ppc, prevent gcc to omit frame pointer
824 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
825 fi
826 fi
827
828 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
829 if test "x$FLAGS_CPU" = xx86_64; then
830 # NOTE: -xregs=no%frameptr is supposed to be default on x64
831 $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
832 elif test "x$FLAGS_CPU" = xsparcv9; then
833 $1_CFLAGS_CPU_JVM="-xarch=sparc"
834 $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
835 fi
836
837 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
838 if test "x$FLAGS_CPU" = xppc64; then
839 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
840 fi
841
842 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
843 if test "x$FLAGS_CPU" = xx86; then
844 $1_CFLAGS_CPU_JVM="-arch:IA32"
845 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
846 if test "x$DEBUG_LEVEL" != xrelease; then
847 # NOTE: This is probably redundant; -homeparams is default on
848 # non-release builds.
849 $1_CFLAGS_CPU_JVM="-homeparams"
850 fi
851 fi
852 fi
853
854 if test "x$TOOLCHAIN_TYPE" = xgcc; then
855 FLAGS_SETUP_GCC6_COMPILER_FLAGS($1, $3)
856 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
857
858 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
859 fi
860
861 # Prevent the __FILE__ macro from generating absolute paths into the built
862 # binaries. Depending on toolchain, different mitigations are possible.
863 # * GCC and Clang of new enough versions have -fmacro-prefix-map.
864 # * For most other toolchains, supplying all source files and -I flags as
865 # relative paths fixes the issue.
866 FILE_MACRO_CFLAGS=
867 if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
868 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
869 # Check if compiler supports -fmacro-prefix-map. If so, use that to make
870 # the __FILE__ macro resolve to paths relative to the workspace root.
871 workspace_root_trailing_slash="${WORKSPACE_ROOT%/}/"
872 FILE_MACRO_CFLAGS="-fmacro-prefix-map=${workspace_root_trailing_slash}="
873 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${FILE_MACRO_CFLAGS}],
874 PREFIX: $3,
875 IF_FALSE: [
876 FILE_MACRO_CFLAGS=
877 ]
878 )
879 fi
880 fi
881 AC_SUBST(FILE_MACRO_CFLAGS)
882
883 # EXPORT to API
884 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM \
885 $TOOLCHAIN_CFLAGS_JVM ${$1_TOOLCHAIN_CFLAGS_JVM} \
886 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
887 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG $FILE_MACRO_CFLAGS"
888
889 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
890 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
891 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK \
892 $FILE_MACRO_CFLAGS"
893
894 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
895 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
896 # change in the future.)
897
898 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
899 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
900 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY \
901 $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
902 ${$1_TOOLCHAIN_CFLAGS_JDK_CXXONLY} \
903 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
904
905 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
906 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
907
908 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
909
910 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} $PIEFLAG"
911 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} $PIEFLAG"
912 $2CFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} \
913 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
914 $2CXXFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} \
915 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
916
917 AC_SUBST($2JVM_CFLAGS)
918 AC_SUBST($2CFLAGS_JDKLIB)
919 AC_SUBST($2CFLAGS_JDKEXE)
920 AC_SUBST($2CXXFLAGS_JDKLIB)
921 AC_SUBST($2CXXFLAGS_JDKEXE)
922 AC_SUBST($2ADLC_CXXFLAG)
923
924 COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
925 # Check that the compiler supports -ffp-contract=off flag
926 # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
927 # otherwise.
928 # These flags are required for GCC-based builds of
929 # fdlibm with optimization without losing precision.
930 # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
931 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
932 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
933 PREFIX: $3,
934 IF_TRUE: [$2FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
935 IF_FALSE: [$2FDLIBM_CFLAGS=""])
936 fi
937 AC_SUBST($2FDLIBM_CFLAGS)
938 ])
939
940 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
941 # Arguments:
942 # $1 - Prefix for each variable defined.
943 # $2 - Prefix for compiler variables (either BUILD_ or nothing).
944 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
945 [
946 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
947 # runs afoul of the more aggressive versions of these optimisations.
948 # Notably, value range propagation now assumes that the this pointer of C++
949 # member functions is non-null.
950 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
951 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG],
952 PREFIX: $2, IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
953 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
954 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG],
955 PREFIX: $2, IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
956 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
957 ])
958
959 # Documentation on common flags used for solstudio in HIGHEST.
960 #
961 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
962 # done with care, there are some assumptions below that need to
963 # be understood about the use of pointers, and IEEE behavior.
964 #
965 # -fns: Use non-standard floating point mode (not IEEE 754)
966 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
967 # -fsingle: Use single precision floating point with 'float'
968 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
969 # (Source with excessing pointer casting and data access with mixed
970 # pointer types are not recommended)
971 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
972 # (If you expect perfect errno behavior, do not use this)
973 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
974 # -xrestrict: Pointer parameters to functions do not overlap
975 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
976 # If you pass in multiple pointers to the same data, do not use this)
977 # -xlibmil: Inline some library routines
978 # (If you expect perfect errno behavior, do not use this)
979 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
980 # (If you expect perfect errno behavior, do not use this)
981 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now