1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 # Default works for linux, might work on other platforms as well.
39 SHARED_LIBRARY_FLAGS='-shared'
40 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
41 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
42 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
43 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
44
45 elif test "x$TOOLCHAIN_TYPE" = xclang; then
46 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
47 # Linking is different on MacOSX
48 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
49 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
50 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
51 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
52 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
53
54 else
55 # Default works for linux, might work on other platforms as well.
56 SHARED_LIBRARY_FLAGS='-shared'
57 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
58 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
59 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
60
61 # arm specific settings
62 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
63 # '-Wl,-z,origin' isn't used on arm.
64 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
65 else
66 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
67 fi
68 fi
69
70 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
71 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
72 SET_EXECUTABLE_ORIGIN=""
73 SET_SHARED_LIBRARY_ORIGIN=''
74 SET_SHARED_LIBRARY_NAME=''
75 SET_SHARED_LIBRARY_MAPFILE=''
76
77 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
78 SHARED_LIBRARY_FLAGS="-dll"
79 SET_EXECUTABLE_ORIGIN=''
80 SET_SHARED_LIBRARY_ORIGIN=''
81 SET_SHARED_LIBRARY_NAME=''
82 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
83 fi
84
85 AC_SUBST(SET_EXECUTABLE_ORIGIN)
86 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
87 AC_SUBST(SET_SHARED_LIBRARY_NAME)
88 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
89 AC_SUBST(SHARED_LIBRARY_FLAGS)
90 ])
91
92 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
93 [
94 # By default don't set any specific assembler debug
95 # info flags for toolchains unless we know they work.
96 # See JDK-8207057.
97 ASFLAGS_DEBUG_SYMBOLS=""
98 # Debug symbols
99 if test "x$TOOLCHAIN_TYPE" = xgcc; then
100 CFLAGS_DEBUG_SYMBOLS="-g"
101 ASFLAGS_DEBUG_SYMBOLS="-g"
102 elif test "x$TOOLCHAIN_TYPE" = xclang; then
103 CFLAGS_DEBUG_SYMBOLS="-g"
104 ASFLAGS_DEBUG_SYMBOLS="-g"
105 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
106 CFLAGS_DEBUG_SYMBOLS="-g1"
107 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
108 CFLAGS_DEBUG_SYMBOLS="-Z7"
109 fi
110
111 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
112 AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
113 ])
114
115 AC_DEFUN([FLAGS_SETUP_WARNINGS],
116 [
117 # Set default value.
118 if test "x$TOOLCHAIN_TYPE" != xxlc; then
119 WARNINGS_AS_ERRORS_DEFAULT=true
120 else
121 WARNINGS_AS_ERRORS_DEFAULT=false
122 fi
123
124 UTIL_ARG_ENABLE(NAME: warnings-as-errors, DEFAULT: $WARNINGS_AS_ERRORS_DEFAULT,
125 RESULT: WARNINGS_AS_ERRORS,
126 DEFAULT_DESC: [auto],
127 DESC: [consider native warnings to be an error])
128 AC_SUBST(WARNINGS_AS_ERRORS)
129
130 case "${TOOLCHAIN_TYPE}" in
131 microsoft)
132 DISABLE_WARNING_PREFIX="-wd"
133 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
134
135 WARNINGS_ENABLE_ALL="-W3"
136 DISABLED_WARNINGS="4800"
137 ;;
138
139 gcc)
140 DISABLE_WARNING_PREFIX="-Wno-"
141 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
142
143 # Additional warnings that are not activated by -Wall and -Wextra
144 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare \
145 -Wunused-function -Wundef -Wunused-value -Wreturn-type \
146 -Wtrampolines"
147 WARNINGS_ENABLE_ADDITIONAL_CXX="-Woverloaded-virtual -Wreorder"
148 WARNINGS_ENABLE_ALL_CFLAGS="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
149 WARNINGS_ENABLE_ALL_CXXFLAGS="$WARNINGS_ENABLE_ALL_CFLAGS $WARNINGS_ENABLE_ADDITIONAL_CXX"
150
151 DISABLED_WARNINGS="unused-parameter unused"
152 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
153 ;;
154
155 clang)
156 DISABLE_WARNING_PREFIX="-Wno-"
157 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
158
159 # Additional warnings that are not activated by -Wall and -Wextra
160 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare -Wreorder \
161 -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual"
162 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
163
164 DISABLED_WARNINGS="unknown-warning-option unused-parameter unused"
165
166 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
167 # missing-method-return-type triggers in JavaNativeFoundation framework
168 DISABLED_WARNINGS="$DISABLED_WARNINGS missing-method-return-type"
169 fi
170
171 ;;
172
173 xlc)
174 DISABLE_WARNING_PREFIX="-Wno-"
175 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
176
177 # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
178 WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
179 DISABLED_WARNINGS=""
180 ;;
181 esac
182 AC_SUBST(DISABLE_WARNING_PREFIX)
183 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
184 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
185 AC_SUBST(DISABLED_WARNINGS)
186 AC_SUBST(DISABLED_WARNINGS_C)
187 AC_SUBST(DISABLED_WARNINGS_CXX)
188 ])
189
190 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
191 [
192 # bounds, memory and behavior checking options
193 if test "x$TOOLCHAIN_TYPE" = xgcc; then
194 case $DEBUG_LEVEL in
195 release )
196 # no adjustment
197 ;;
198 fastdebug )
199 # no adjustment
200 ;;
201 slowdebug )
202 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
203 # get's added conditionally on whether we produce debug symbols or not.
204 # This is most likely not really correct.
205
206 # Add runtime stack smashing and undefined behavior checks.
207 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
208 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
209
210 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
211 ;;
212 esac
213 fi
214 ])
215
216 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
217 [
218 if test "x$TOOLCHAIN_TYPE" = xgcc; then
219 C_O_FLAG_HIGHEST_JVM="-O3"
220 C_O_FLAG_HIGHEST="-O3"
221 C_O_FLAG_HI="-O3"
222 C_O_FLAG_NORM="-O2"
223 C_O_FLAG_SIZE="-Os"
224 C_O_FLAG_DEBUG="-O0"
225 C_O_FLAG_DEBUG_JVM="-O0"
226 C_O_FLAG_NONE="-O0"
227 # -D_FORTIFY_SOURCE=2 hardening option needs optimization (at least -O1) enabled
228 # set for lower O-levels -U_FORTIFY_SOURCE to overwrite previous settings
229 if test "x$OPENJDK_TARGET_OS" = xlinux -a "x$DEBUG_LEVEL" = "xfastdebug"; then
230 ENABLE_FORTIFY_CFLAGS="-D_FORTIFY_SOURCE=2"
231 DISABLE_FORTIFY_CFLAGS="-U_FORTIFY_SOURCE"
232 C_O_FLAG_HIGHEST_JVM="${C_O_FLAG_HIGHEST_JVM} ${ENABLE_FORTIFY_CFLAGS}"
233 C_O_FLAG_HIGHEST="${C_O_FLAG_HIGHEST} ${ENABLE_FORTIFY_CFLAGS}"
234 C_O_FLAG_HI="${C_O_FLAG_HI} ${ENABLE_FORTIFY_CFLAGS}"
235 C_O_FLAG_NORM="${C_O_FLAG_NORM} ${ENABLE_FORTIFY_CFLAGS}"
236 C_O_FLAG_SIZE="${C_O_FLAG_SIZE} ${DISABLE_FORTIFY_CFLAGS}"
237 C_O_FLAG_DEBUG="${C_O_FLAG_DEBUG} ${DISABLE_FORTIFY_CFLAGS}"
238 C_O_FLAG_DEBUG_JVM="${C_O_FLAG_DEBUG_JVM} ${DISABLE_FORTIFY_CFLAGS}"
239 C_O_FLAG_NONE="${C_O_FLAG_NONE} ${DISABLE_FORTIFY_CFLAGS}"
240 fi
241 elif test "x$TOOLCHAIN_TYPE" = xclang; then
242 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
243 # On MacOSX we optimize for size, something
244 # we should do for all platforms?
245 C_O_FLAG_HIGHEST_JVM="-Os"
246 C_O_FLAG_HIGHEST="-Os"
247 C_O_FLAG_HI="-Os"
248 C_O_FLAG_NORM="-Os"
249 C_O_FLAG_DEBUG_JVM=""
250 else
251 C_O_FLAG_HIGHEST_JVM="-O3"
252 C_O_FLAG_HIGHEST="-O3"
253 C_O_FLAG_HI="-O3"
254 C_O_FLAG_NORM="-O2"
255 C_O_FLAG_DEBUG_JVM="-O0"
256 fi
257 C_O_FLAG_SIZE="-Os"
258 C_O_FLAG_DEBUG="-O0"
259 C_O_FLAG_NONE="-O0"
260 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
261 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
262 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
263 C_O_FLAG_HI="-O3 -qinline -qinlglue"
264 C_O_FLAG_NORM="-O2"
265 C_O_FLAG_DEBUG="-qnoopt"
266 # FIXME: Value below not verified.
267 C_O_FLAG_DEBUG_JVM=""
268 C_O_FLAG_NONE="-qnoopt"
269 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
270 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
271 C_O_FLAG_HIGHEST="-O2"
272 C_O_FLAG_HI="-O1"
273 C_O_FLAG_NORM="-O1"
274 C_O_FLAG_DEBUG="-Od"
275 C_O_FLAG_DEBUG_JVM=""
276 C_O_FLAG_NONE="-Od"
277 C_O_FLAG_SIZE="-Os"
278 fi
279
280 # Now copy to C++ flags
281 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
282 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
283 CXX_O_FLAG_HI="$C_O_FLAG_HI"
284 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
285 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
286 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
287 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
288 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
289
290 # Adjust optimization flags according to debug level.
291 case $DEBUG_LEVEL in
292 release )
293 # no adjustment
294 ;;
295 fastdebug )
296 # Not quite so much optimization
297 C_O_FLAG_HI="$C_O_FLAG_NORM"
298 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
299 ;;
300 slowdebug )
301 # Disable optimization
302 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
303 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
304 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
305 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
306 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
307 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
308 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
309 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
310 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
311 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
312 ;;
313 esac
314
315 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
316 AC_SUBST(C_O_FLAG_HIGHEST)
317 AC_SUBST(C_O_FLAG_HI)
318 AC_SUBST(C_O_FLAG_NORM)
319 AC_SUBST(C_O_FLAG_NONE)
320 AC_SUBST(C_O_FLAG_SIZE)
321 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
322 AC_SUBST(CXX_O_FLAG_HIGHEST)
323 AC_SUBST(CXX_O_FLAG_HI)
324 AC_SUBST(CXX_O_FLAG_NORM)
325 AC_SUBST(CXX_O_FLAG_NONE)
326 AC_SUBST(CXX_O_FLAG_SIZE)
327 ])
328
329 AC_DEFUN([FLAGS_SETUP_CFLAGS],
330 [
331 ### CFLAGS
332
333 FLAGS_SETUP_CFLAGS_HELPER
334
335 FLAGS_OS=$OPENJDK_TARGET_OS
336 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
337 FLAGS_CPU=$OPENJDK_TARGET_CPU
338 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
339 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
340 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
341 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
342 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
343
344 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
345
346 # Repeat the check for the BUILD_CC and BUILD_CXX. Need to also reset CFLAGS
347 # since any target specific flags will likely not work with the build compiler.
348 CC_OLD="$CC"
349 CXX_OLD="$CXX"
350 CFLAGS_OLD="$CFLAGS"
351 CXXFLAGS_OLD="$CXXFLAGS"
352 CC="$BUILD_CC"
353 CXX="$BUILD_CXX"
354 CFLAGS=""
355 CXXFLAGS=""
356
357 FLAGS_OS=$OPENJDK_BUILD_OS
358 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
359 FLAGS_CPU=$OPENJDK_BUILD_CPU
360 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
361 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
362 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
363 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
364 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
365
366 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_], [BUILD_])
367
368 CC="$CC_OLD"
369 CXX="$CXX_OLD"
370 CFLAGS="$CFLAGS_OLD"
371 CXXFLAGS="$CXXFLAGS_OLD"
372 ])
373
374 ################################################################################
375 # platform independent
376 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
377 [
378 #### OS DEFINES, these should be independent on toolchain
379 if test "x$OPENJDK_TARGET_OS" = xlinux; then
380 CFLAGS_OS_DEF_JVM="-DLINUX"
381 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
382 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
383 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
384 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
385 elif test "x$OPENJDK_TARGET_OS" = xaix; then
386 CFLAGS_OS_DEF_JVM="-DAIX"
387 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
388 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
389 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
390 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
391 fi
392
393 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
394
395 #### GLOBAL DEFINES
396 # Set some common defines. These works for all compilers, but assume
397 # -D is universally accepted.
398
399 # Always enable optional macros for VM.
400 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
401
402 # Setup some hard coded includes
403 ALWAYS_CFLAGS_JDK=" \
404 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
405 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
406 -I${TOPDIR}/src/java.base/share/native/libjava \
407 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
408 -I${TOPDIR}/src/hotspot/share/include \
409 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
410
411 ###############################################################################
412
413 # Adjust flags according to debug level.
414 # Setup debug/release defines
415 if test "x$DEBUG_LEVEL" = xrelease; then
416 DEBUG_CFLAGS_JDK="-DNDEBUG"
417 else
418 DEBUG_CFLAGS_JDK="-DDEBUG"
419
420 if test "x$TOOLCHAIN_TYPE" = xxlc; then
421 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
422 # Hotspot now overflows its 64K TOC (currently only for debug),
423 # so for debug we build with '-qpic=large -bbigtoc'.
424 DEBUG_CFLAGS_JVM="-qpic=large"
425 fi
426 fi
427
428 if test "x$DEBUG_LEVEL" != xrelease; then
429 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
430 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
431 fi
432
433 #### TOOLCHAIN DEFINES
434
435 if test "x$TOOLCHAIN_TYPE" = xgcc; then
436 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
437 elif test "x$TOOLCHAIN_TYPE" = xclang; then
438 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
439 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
440 ALWAYS_DEFINES_JVM="-D_REENTRANT"
441 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
442 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
443 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
444 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
445 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
446 fi
447
448 ###############################################################################
449 #
450 #
451 # CFLAGS BASIC
452 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
453 # COMMON to gcc and clang
454 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
455 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
456 fi
457
458 if test "x$TOOLCHAIN_TYPE" = xgcc; then
459 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new -fstack-protector"
460 TOOLCHAIN_CFLAGS_JDK="-pipe -fstack-protector"
461 # reduce lib size on linux in link step, this needs also special compile flags
462 # do this on s390x also for libjvm (where serviceability agent is not supported)
463 if test "x$ENABLE_LINKTIME_GC" = xtrue; then
464 TOOLCHAIN_CFLAGS_JDK="$TOOLCHAIN_CFLAGS_JDK -ffunction-sections -fdata-sections"
465 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
466 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -ffunction-sections -fdata-sections"
467 fi
468 fi
469 # technically NOT for CXX (but since this gives *worse* performance, use
470 # no-strict-aliasing everywhere!)
471 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing"
472
473 elif test "x$TOOLCHAIN_TYPE" = xclang; then
474 # Restrict the debug information created by Clang to avoid
475 # too big object files and speed the build up a little bit
476 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
477 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
478
479 # In principle the stack alignment below is cpu- and ABI-dependent and
480 # should agree with values of StackAlignmentInBytes in various
481 # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
482 # works for all platforms.
483 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
484
485 if test "x$OPENJDK_TARGET_OS" = xlinux; then
486 if test "x$DEBUG_LEVEL" = xrelease; then
487 # Clang does not inline as much as GCC does for functions with "inline" keyword by default.
488 # This causes noticeable slowdown in pause time for G1, and possibly in other areas.
489 # Increasing the inline hint threshold avoids the slowdown for Clang-built JVM.
490 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mllvm -inlinehint-threshold=100000"
491 fi
492 TOOLCHAIN_CFLAGS_JDK="-pipe"
493 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
494 fi
495
496 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
497 # Suggested additions: -qsrcmsg to get improved error reporting
498 # set -qtbtable=full for a better traceback table/better stacks in hs_err when xlc16 is used
499 TOOLCHAIN_CFLAGS_JDK="-qtbtable=full -qchars=signed -qfullpath -qsaveopt -qstackprotect" # add on both CFLAGS
500 TOOLCHAIN_CFLAGS_JVM="-qtbtable=full -qtune=balanced \
501 -qalias=noansi -qstrict -qtls=default -qnortti -qnoeh -qignerrno -qstackprotect"
502 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
503 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
504 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
505 fi
506
507 # CFLAGS C language level for JDK sources (hotspot only uses C++)
508 # Ideally we would have a common level across all toolchains so that all sources
509 # are sure to conform to the same standard. Unfortunately neither our sources nor
510 # our toolchains are in a condition to support that. But what we loosely aim for is
511 # C99 level.
512 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xxlc; then
513 # Explicitly set C99. clang and xlclang support the same flag.
514 LANGSTD_CFLAGS="-std=c99"
515 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
516 # MSVC doesn't support C99/C11 explicitly, unless you compile as C++:
517 # LANGSTD_CFLAGS="-TP"
518 # but that requires numerous changes to the sources files. So we are limited
519 # to C89/C90 plus whatever extensions Visual Studio has decided to implement.
520 # This is the lowest bar for shared code.
521 LANGSTD_CFLAGS=""
522 fi
523 TOOLCHAIN_CFLAGS_JDK_CONLY="$LANGSTD_CFLAGS $TOOLCHAIN_CFLAGS_JDK_CONLY"
524
525 # CFLAGS WARNINGS STUFF
526 # Set JVM_CFLAGS warning handling
527 if test "x$TOOLCHAIN_TYPE" = xgcc; then
528 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
529 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
530 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
531
532 elif test "x$TOOLCHAIN_TYPE" = xclang; then
533 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
534
535 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
536 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
537
538 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
539 WARNING_CFLAGS="" # currently left empty
540 fi
541
542 # Set some additional per-OS defines.
543
544 # Additional macosx handling
545 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
546 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
547 -mmacosx-version-min=$MACOSX_VERSION_MIN"
548
549 if test -n "$MACOSX_VERSION_MAX"; then
550 OS_CFLAGS="$OS_CFLAGS \
551 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
552 fi
553 fi
554
555 # Where does this really belong??
556 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
557 PICFLAG="-fPIC"
558 PIEFLAG="-fPIE"
559 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
560 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
561 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
562 # will have to patch this single instruction with a call to some out-of-order code which
563 # does the load from the TOC. This is of course slower, and we also would have
564 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
565 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
566 # can be patched directly by the linker and does not require a jump to out-of-order code.
567 #
568 # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
569 # for all libjvm variants (both gtest and normal) but no other binaries. So, build
570 # libjvm with -qpic=large and link with -bbigtoc.
571 JVM_PICFLAG="-qpic=large"
572 JDK_PICFLAG="-qpic"
573 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
574 PICFLAG=""
575 fi
576
577 if test "x$TOOLCHAIN_TYPE" != xxlc; then
578 JVM_PICFLAG="$PICFLAG"
579 JDK_PICFLAG="$PICFLAG"
580 fi
581
582 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
583 # Linking is different on MacOSX
584 JDK_PICFLAG=''
585 if test "x$STATIC_BUILD" = xtrue; then
586 JVM_PICFLAG=""
587 fi
588 fi
589
590 # Optional POSIX functionality needed by the JVM
591 #
592 # Check if clock_gettime is available and in which library. This indicates
593 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
594 # don't let it update LIBS.
595 save_LIBS="$LIBS"
596 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
597 if test "x$LIBS" = "x-lrt "; then
598 CLOCK_GETTIME_IN_LIBRT=true
599 fi
600 LIBS="$save_LIBS"
601
602 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
603 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
604 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
605 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
606 fi
607 fi
608
609 # Extra flags needed when building optional static versions of certain
610 # JDK libraries.
611 STATIC_LIBS_CFLAGS="-DSTATIC_BUILD=1"
612 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
613 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -ffunction-sections -fdata-sections \
614 -DJNIEXPORT='__attribute__((visibility(\"hidden\")))'"
615 else
616 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -DJNIEXPORT="
617 fi
618 if test "x$TOOLCHAIN_TYPE" = xgcc; then
619 # Disable relax-relocation to enable compatibility with older linkers
620 RELAX_RELOCATIONS_FLAG="-Xassembler -mrelax-relocations=no"
621 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${RELAX_RELOCATIONS_FLAG}],
622 IF_TRUE: [STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS ${RELAX_RELOCATIONS_FLAG}"])
623 fi
624 AC_SUBST(STATIC_LIBS_CFLAGS)
625 ])
626
627 ################################################################################
628 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
629 # conditionals against.
630 # $2 - Optional prefix for each variable defined.
631 # $3 - Optional prefix for compiler variables (either BUILD_ or nothing).
632 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
633 [
634 #### CPU DEFINES, these should (in theory) be independent on toolchain
635
636 # Setup target CPU
637 # Setup endianness
638 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
639 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
640 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
641 else
642 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
643 fi
644
645 # setup CPU bit size
646 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
647 -D$FLAGS_CPU_LEGACY"
648
649 if test "x$FLAGS_CPU_BITS" = x64; then
650 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
651 # unpack200.exe.
652 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
653 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
654 fi
655 if test "x$FLAGS_OS" != xaix; then
656 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
657 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
658 fi
659 fi
660
661 # toolchain dependend, per-cpu
662 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
663 if test "x$FLAGS_CPU" = xx86_64; then
664 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
665 else
666 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
667 fi
668 fi
669
670 # CFLAGS PER CPU
671 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
672 # COMMON to gcc and clang
673 if test "x$FLAGS_CPU" = xx86; then
674 # Force compatibility with i586 on 32 bit intel platforms.
675 $1_CFLAGS_CPU="-march=i586"
676 fi
677 fi
678
679 if test "x$TOOLCHAIN_TYPE" = xgcc; then
680 if test "x$FLAGS_CPU" = xaarch64; then
681 # -Wno-psabi to get rid of annoying "note: parameter passing for argument of type '<type> changed in GCC 9.1"
682 $1_CFLAGS_CPU="-Wno-psabi"
683 elif test "x$FLAGS_CPU" = xarm; then
684 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
685 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
686 $1_CFLAGS_CPU_JVM="-DARM"
687 elif test "x$FLAGS_CPU_ARCH" = xppc; then
688 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
689 if test "x$FLAGS_CPU" = xppc64; then
690 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
691 # Use ppc64 instructions, but schedule for power5
692 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
693 elif test "x$FLAGS_CPU" = xppc64le; then
694 # Little endian machine uses ELFv2 ABI.
695 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
696 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
697 fi
698 elif test "x$FLAGS_CPU" = xs390x; then
699 $1_CFLAGS_CPU="-mbackchain -march=z10"
700 fi
701
702 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
703 # for all archs except arm and ppc, prevent gcc to omit frame pointer
704 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
705 fi
706
707 $1_CXXSTD_CXXFLAG="-std=gnu++98"
708 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${$1_CXXSTD_CXXFLAG}],
709 PREFIX: $3, IF_FALSE: [$1_CXXSTD_CXXFLAG=""])
710 $1_TOOLCHAIN_CFLAGS_JDK_CXXONLY="${$1_CXXSTD_CXXFLAG}"
711 $1_TOOLCHAIN_CFLAGS_JVM="${$1_TOOLCHAIN_CFLAGS_JVM} ${$1_CXXSTD_CXXFLAG}"
712 $2ADLC_CXXFLAG="${$1_CXXSTD_CXXFLAG}"
713
714 elif test "x$TOOLCHAIN_TYPE" = xclang; then
715 if test "x$FLAGS_OS" = xlinux; then
716 # ppc test not really needed for clang
717 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
718 # for all archs except arm and ppc, prevent gcc to omit frame pointer
719 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
720 fi
721 fi
722
723 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
724 if test "x$FLAGS_CPU" = xppc64; then
725 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
726 fi
727
728 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
729 if test "x$FLAGS_CPU" = xx86; then
730 $1_CFLAGS_CPU_JVM="-arch:IA32"
731 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
732 if test "x$DEBUG_LEVEL" != xrelease; then
733 # NOTE: This is probably redundant; -homeparams is default on
734 # non-release builds.
735 $1_CFLAGS_CPU_JVM="-homeparams"
736 fi
737 fi
738 fi
739
740 if test "x$TOOLCHAIN_TYPE" = xgcc; then
741 FLAGS_SETUP_GCC6_COMPILER_FLAGS($1, $3)
742 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
743
744 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
745 fi
746
747 # Prevent the __FILE__ macro from generating absolute paths into the built
748 # binaries. Depending on toolchain, different mitigations are possible.
749 # * GCC and Clang of new enough versions have -fmacro-prefix-map.
750 # * For most other toolchains, supplying all source files and -I flags as
751 # relative paths fixes the issue.
752 FILE_MACRO_CFLAGS=
753 if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
754 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
755 # Check if compiler supports -fmacro-prefix-map. If so, use that to make
756 # the __FILE__ macro resolve to paths relative to the workspace root.
757 workspace_root_trailing_slash="${WORKSPACE_ROOT%/}/"
758 FILE_MACRO_CFLAGS="-fmacro-prefix-map=${workspace_root_trailing_slash}="
759 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${FILE_MACRO_CFLAGS}],
760 PREFIX: $3,
761 IF_FALSE: [
762 FILE_MACRO_CFLAGS=
763 ]
764 )
765 fi
766 fi
767 AC_SUBST(FILE_MACRO_CFLAGS)
768
769 # EXPORT to API
770 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM \
771 $TOOLCHAIN_CFLAGS_JVM ${$1_TOOLCHAIN_CFLAGS_JVM} \
772 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
773 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG $FILE_MACRO_CFLAGS"
774
775 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
776 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
777 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK \
778 $FILE_MACRO_CFLAGS"
779
780 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
781 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
782 # change in the future.)
783
784 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
785 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
786 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY \
787 $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
788 ${$1_TOOLCHAIN_CFLAGS_JDK_CXXONLY} \
789 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
790
791 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
792 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
793
794 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
795
796 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} $PIEFLAG"
797 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} $PIEFLAG"
798 $2CFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} \
799 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
800 $2CXXFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} \
801 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
802
803 AC_SUBST($2JVM_CFLAGS)
804 AC_SUBST($2CFLAGS_JDKLIB)
805 AC_SUBST($2CFLAGS_JDKEXE)
806 AC_SUBST($2CXXFLAGS_JDKLIB)
807 AC_SUBST($2CXXFLAGS_JDKEXE)
808 AC_SUBST($2ADLC_CXXFLAG)
809
810 COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
811 # Check that the compiler supports -ffp-contract=off flag
812 # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
813 # otherwise.
814 # These flags are required for GCC-based builds of
815 # fdlibm with optimization without losing precision.
816 # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
817 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
818 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
819 PREFIX: $3,
820 IF_TRUE: [$2FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
821 IF_FALSE: [$2FDLIBM_CFLAGS=""])
822 fi
823 AC_SUBST($2FDLIBM_CFLAGS)
824 ])
825
826 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
827 # Arguments:
828 # $1 - Prefix for each variable defined.
829 # $2 - Prefix for compiler variables (either BUILD_ or nothing).
830 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
831 [
832 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
833 # runs afoul of the more aggressive versions of these optimisations.
834 # Notably, value range propagation now assumes that the this pointer of C++
835 # member functions is non-null.
836 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
837 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG],
838 PREFIX: $2, IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
839 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
840 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG],
841 PREFIX: $2, IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
842 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
843 ])