1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for other tools than C/C++ compiler
29 #
30
31 AC_DEFUN([FLAGS_SETUP_ARFLAGS],
32 [
33 # FIXME: figure out if we should select AR flags depending on OS or toolchain.
34 if test "x$OPENJDK_TARGET_OS" = xaix; then
35 ARFLAGS="-X64"
36 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
37 # lib.exe is used as AR to create static libraries.
38 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
39 else
40 ARFLAGS=""
41 fi
42
43 AC_SUBST(ARFLAGS)
44 ])
45
46 AC_DEFUN([FLAGS_SETUP_STRIPFLAGS],
47 [
48 ## Setup strip.
49 # FIXME: should this really be per platform, or should it be per toolchain type?
50 # strip is not provided by clang; so guessing platform makes most sense.
51 # FIXME: we should really only export STRIPFLAGS from here, not POST_STRIP_CMD.
52 if test "x$OPENJDK_TARGET_OS" = xlinux; then
53 STRIPFLAGS="-g"
54 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
55 STRIPFLAGS="-S"
56 elif test "x$OPENJDK_TARGET_OS" = xaix; then
57 STRIPFLAGS="-X32_64"
58 fi
59
60 AC_SUBST(STRIPFLAGS)
61 ])
62
63 AC_DEFUN([FLAGS_SETUP_RCFLAGS],
64 [
65 # On Windows, we need to set RC flags.
66 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
67 RC_FLAGS="-nologo -l0x409"
68 JVM_RCFLAGS="-nologo"
69 if test "x$DEBUG_LEVEL" = xrelease; then
70 RC_FLAGS="$RC_FLAGS -DNDEBUG"
71 JVM_RCFLAGS="$JVM_RCFLAGS -DNDEBUG"
72 fi
73
74 # The version variables used to create RC_FLAGS may be overridden
75 # in a custom configure script, or possibly the command line.
76 # Let those variables be expanded at make time in spec.gmk.
77 # The \$ are escaped to the shell, and the $(...) variables
78 # are evaluated by make.
79 RC_FLAGS="$RC_FLAGS \
80 -D\"JDK_VERSION_STRING=\$(VERSION_STRING)\" \
81 -D\"JDK_COMPANY=\$(COMPANY_NAME)\" \
82 -D\"JDK_FILEDESC=\$(JDK_RC_NAME) binary\" \
83 -D\"JDK_VER=\$(VERSION_NUMBER)\" \
84 -D\"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
85 -D\"JDK_NAME=\$(JDK_RC_NAME) \$(VERSION_FEATURE)\" \
86 -D\"JDK_FVER=\$(subst .,\$(COMMA),\$(VERSION_NUMBER_FOUR_POSITIONS))\""
87
88 JVM_RCFLAGS="$JVM_RCFLAGS \
89 -D\"HS_VERSION_STRING=\$(VERSION_STRING)\" \
90 -D\"HS_COMPANY=\$(COMPANY_NAME)\" \
91 -D\"HS_VER=\$(VERSION_NUMBER_FOUR_POSITIONS)\" \
92 -D\"HS_INTERNAL_NAME=jvm\" \
93 -D\"HS_COPYRIGHT=Copyright $COPYRIGHT_YEAR\" \
94 -D\"HS_FNAME=jvm.dll\" \
95 -D\"HS_NAME=\$(PRODUCT_NAME) \$(VERSION_SHORT)\" \
96 -D\"HS_FVER=\$(subst .,\$(COMMA),\$(VERSION_NUMBER_FOUR_POSITIONS))\""
97 fi
98 AC_SUBST(RC_FLAGS)
99 AC_SUBST(JVM_RCFLAGS)
100 ])
101
102 ################################################################################
103 # platform independent
104 AC_DEFUN([FLAGS_SETUP_ASFLAGS],
105 [
106 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
107 JVM_BASIC_ASFLAGS="-x assembler-with-cpp -mno-omit-leaf-frame-pointer -mstack-alignment=16"
108 fi
109 ])
110
111 ################################################################################
112 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
113 # conditionals against.
114 # $2 - Optional prefix for each variable defined.
115 AC_DEFUN([FLAGS_SETUP_ASFLAGS_CPU_DEP],
116 [
117 # Misuse EXTRA_CFLAGS to mimic old behavior
118 $2JVM_ASFLAGS="$JVM_BASIC_ASFLAGS ${$2EXTRA_CFLAGS}"
119
120 if test "x$1" = "xTARGET" && \
121 test "x$TOOLCHAIN_TYPE" = xgcc && \
122 test "x$OPENJDK_TARGET_CPU" = xarm; then
123 $2JVM_ASFLAGS="${$2JVM_ASFLAGS} $ARM_ARCH_TYPE_ASFLAGS $ARM_FLOAT_TYPE_ASFLAGS"
124 fi
125
126 AC_SUBST($2JVM_ASFLAGS)
127 ])
128