1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64*x32)
34 VAR_CPU=x32
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=32
37 VAR_CPU_ENDIAN=little
38 ;;
39 x86_64)
40 VAR_CPU=x86_64
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=64
43 VAR_CPU_ENDIAN=little
44 ;;
45 i?86)
46 VAR_CPU=x86
47 VAR_CPU_ARCH=x86
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 alpha*)
52 VAR_CPU=alpha
53 VAR_CPU_ARCH=alpha
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 arm*)
58 VAR_CPU=arm
59 VAR_CPU_ARCH=arm
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=little
62 ;;
63 aarch64)
64 VAR_CPU=aarch64
65 VAR_CPU_ARCH=aarch64
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=little
68 ;;
69 ia64)
70 VAR_CPU=ia64
71 VAR_CPU_ARCH=ia64
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 m68k)
76 VAR_CPU=m68k
77 VAR_CPU_ARCH=m68k
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 mips)
82 VAR_CPU=mips
83 VAR_CPU_ARCH=mips
84 VAR_CPU_BITS=32
85 VAR_CPU_ENDIAN=big
86 ;;
87 mipsel)
88 VAR_CPU=mipsel
89 VAR_CPU_ARCH=mipsel
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=little
92 ;;
93 mips64)
94 VAR_CPU=mips64
95 VAR_CPU_ARCH=mips64
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 mips64el)
100 VAR_CPU=mips64el
101 VAR_CPU_ARCH=mips64el
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=little
104 ;;
105 powerpc)
106 VAR_CPU=ppc
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=32
109 VAR_CPU_ENDIAN=big
110 ;;
111 powerpc64)
112 VAR_CPU=ppc64
113 VAR_CPU_ARCH=ppc
114 VAR_CPU_BITS=64
115 VAR_CPU_ENDIAN=big
116 ;;
117 powerpc64le)
118 VAR_CPU=ppc64le
119 VAR_CPU_ARCH=ppc
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=little
122 ;;
123 riscv64)
124 VAR_CPU=riscv64
125 VAR_CPU_ARCH=riscv
126 VAR_CPU_BITS=64
127 VAR_CPU_ENDIAN=little
128 ;;
129 s390)
130 VAR_CPU=s390
131 VAR_CPU_ARCH=s390
132 VAR_CPU_BITS=32
133 VAR_CPU_ENDIAN=big
134 ;;
135 s390x)
136 VAR_CPU=s390x
137 VAR_CPU_ARCH=s390
138 VAR_CPU_BITS=64
139 VAR_CPU_ENDIAN=big
140 ;;
141 sh*eb)
142 VAR_CPU=sh
143 VAR_CPU_ARCH=sh
144 VAR_CPU_BITS=32
145 VAR_CPU_ENDIAN=big
146 ;;
147 sh*)
148 VAR_CPU=sh
149 VAR_CPU_ARCH=sh
150 VAR_CPU_BITS=32
151 VAR_CPU_ENDIAN=little
152 ;;
153 sparc)
154 VAR_CPU=sparc
155 VAR_CPU_ARCH=sparc
156 VAR_CPU_BITS=32
157 VAR_CPU_ENDIAN=big
158 ;;
159 sparcv9|sparc64)
160 VAR_CPU=sparcv9
161 VAR_CPU_ARCH=sparc
162 VAR_CPU_BITS=64
163 VAR_CPU_ENDIAN=big
164 ;;
165 *)
166 AC_MSG_ERROR([unsupported cpu $1])
167 ;;
168 esac
169 ])
170
171 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
172 # Converts autoconf style OS name to OpenJDK style, into
173 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
174 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
175 [
176 case "$1" in
177 *linux*)
178 VAR_OS=linux
179 VAR_OS_TYPE=unix
180 ;;
181 *solaris*)
182 VAR_OS=solaris
183 VAR_OS_TYPE=unix
184 ;;
185 *darwin*)
186 VAR_OS=macosx
187 VAR_OS_TYPE=unix
188 ;;
189 *bsd*)
190 VAR_OS=bsd
191 VAR_OS_TYPE=unix
192 ;;
193 *cygwin*)
194 VAR_OS=windows
195 VAR_OS_ENV=windows.cygwin
196 ;;
197 *wsl*)
198 VAR_OS=windows
199 VAR_OS_ENV=windows.wsl
200 ;;
201 *mingw*)
202 VAR_OS=windows
203 VAR_OS_ENV=windows.msys
204 ;;
205 *aix*)
206 VAR_OS=aix
207 VAR_OS_TYPE=unix
208 ;;
209 *)
210 AC_MSG_ERROR([unsupported operating system $1])
211 ;;
212 esac
213 ])
214
215 # Expects $host_os $host_cpu $build_os and $build_cpu
216 # and $with_target_bits to have been setup!
217 #
218 # Translate the standard triplet(quadruplet) definition
219 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
220 # OPENJDK_BUILD_OS, etc.
221 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
222 [
223 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
224 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
225 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
226 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
227 OPENJDK_TARGET_AUTOCONF_NAME="$host"
228 OPENJDK_BUILD_AUTOCONF_NAME="$build"
229 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
230 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
231
232 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
233 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
234 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
235 # ..and setup our own variables. (Do this explicitly to facilitate searching)
236 OPENJDK_BUILD_OS="$VAR_OS"
237 if test "x$VAR_OS_TYPE" != x; then
238 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
239 else
240 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
241 fi
242 if test "x$VAR_OS_ENV" != x; then
243 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
244 else
245 OPENJDK_BUILD_OS_ENV="$VAR_OS"
246 fi
247 OPENJDK_BUILD_CPU="$VAR_CPU"
248 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
249 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
250 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
251 AC_SUBST(OPENJDK_BUILD_OS)
252 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
253 AC_SUBST(OPENJDK_BUILD_OS_ENV)
254 AC_SUBST(OPENJDK_BUILD_CPU)
255 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
256 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
257 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
258
259 AC_MSG_CHECKING([openjdk-build os-cpu])
260 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
261
262 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
263 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
264 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
265 # ... and setup our own variables. (Do this explicitly to facilitate searching)
266 OPENJDK_TARGET_OS="$VAR_OS"
267 if test "x$VAR_OS_TYPE" != x; then
268 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
269 else
270 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
271 fi
272 if test "x$VAR_OS_ENV" != x; then
273 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
274 else
275 OPENJDK_TARGET_OS_ENV="$VAR_OS"
276 fi
277 OPENJDK_TARGET_CPU="$VAR_CPU"
278 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
279 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
280 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
281 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
282
283 AC_SUBST(OPENJDK_TARGET_OS)
284 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
285 AC_SUBST(OPENJDK_TARGET_OS_ENV)
286 AC_SUBST(OPENJDK_TARGET_OS_UPPERCASE)
287 AC_SUBST(OPENJDK_TARGET_CPU)
288 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
289 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
290 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
291
292 AC_MSG_CHECKING([openjdk-target os-cpu])
293 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
294 ])
295
296 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
297 # accordingly. Must be done after setting up build and target system, but before
298 # doing anything else with these values.
299 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
300 [
301 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
302 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
303
304 # We have three types of compiles:
305 # native == normal compilation, target system == build system
306 # cross == traditional cross compilation, target system != build system; special toolchain needed
307 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
308 #
309 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
310 # We're doing a proper cross-compilation
311 COMPILE_TYPE="cross"
312 else
313 COMPILE_TYPE="native"
314 fi
315
316 if test "x$with_target_bits" != x; then
317 if test "x$COMPILE_TYPE" = "xcross"; then
318 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
319 fi
320
321 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
322 # A reduced build is requested
323 COMPILE_TYPE="reduced"
324 OPENJDK_TARGET_CPU_BITS=32
325 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
326 OPENJDK_TARGET_CPU=x86
327 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
328 OPENJDK_TARGET_CPU=sparc
329 else
330 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
331 fi
332 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
333 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
334 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
335 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
336 else
337 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
338 fi
339 fi
340 AC_SUBST(COMPILE_TYPE)
341
342 AC_MSG_CHECKING([compilation type])
343 AC_MSG_RESULT([$COMPILE_TYPE])
344 ])
345
346 # Setup the legacy variables, for controlling the old makefiles.
347 #
348 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
349 [
350 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
351 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
352 ])
353
354 # $1 - Either TARGET or BUILD to setup the variables for.
355 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
356 [
357 # Also store the legacy naming of the cpu.
358 # Ie i586 and amd64 instead of x86 and x86_64
359 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
360 if test "x$OPENJDK_$1_CPU" = xx86; then
361 OPENJDK_$1_CPU_LEGACY="i586"
362 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
363 # On all platforms except MacOSX replace x86_64 with amd64.
364 OPENJDK_$1_CPU_LEGACY="amd64"
365 elif test "x$OPENJDK_$1_CPU" = xalpha; then
366 # Avoid name collisions with variables named alpha
367 OPENJDK_$1_CPU_LEGACY="_alpha_"
368 elif test "x$OPENJDK_$1_CPU" = xsh; then
369 # Avoid name collisions with variables named sh
370 OPENJDK_$1_CPU_LEGACY="_sh_"
371 fi
372 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
373
374 # And the second legacy naming of the cpu.
375 # Ie i386 and amd64 instead of x86 and x86_64.
376 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
377 if test "x$OPENJDK_$1_CPU" = xx86; then
378 OPENJDK_$1_CPU_LEGACY_LIB="i386"
379 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
380 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
381 fi
382 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
383
384 # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
385 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
386 # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
387 OPENJDK_$1_CPU_ISADIR=""
388 if test "x$OPENJDK_$1_OS" = xsolaris; then
389 if test "x$OPENJDK_$1_CPU" = xx86_64; then
390 OPENJDK_$1_CPU_ISADIR="/amd64"
391 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
392 OPENJDK_$1_CPU_ISADIR="/sparcv9"
393 fi
394 fi
395 AC_SUBST(OPENJDK_$1_CPU_ISADIR)
396
397 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
398 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
399 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
400 # On linux only, we replace x86 with i386.
401 OPENJDK_$1_CPU_OSARCH="i386"
402 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
403 # On all platforms except macosx, we replace x86_64 with amd64.
404 OPENJDK_$1_CPU_OSARCH="amd64"
405 fi
406 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
407
408 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
409 if test "x$OPENJDK_$1_CPU" = xx86; then
410 OPENJDK_$1_CPU_JLI="i386"
411 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
412 # On all platforms except macosx, we replace x86_64 with amd64.
413 OPENJDK_$1_CPU_JLI="amd64"
414 fi
415
416 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
417 # Macosx is osx and x86_64 is x64
418 if test "x$OPENJDK_$1_OS" = xmacosx; then
419 OPENJDK_$1_OS_BUNDLE="osx"
420 else
421 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
422 fi
423 if test "x$OPENJDK_$1_CPU" = xx86_64; then
424 OPENJDK_$1_CPU_BUNDLE="x64"
425 else
426 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
427 fi
428 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
429 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
430
431 if test "x$COMPILE_TYPE" = "xcross"; then
432 # FIXME: ... or should this include reduced builds..?
433 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
434 else
435 DEFINE_CROSS_COMPILE_ARCH=""
436 fi
437 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
438
439 # Convert openjdk platform names to hotspot names
440
441 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
442 if test "x$OPENJDK_$1_OS" = xmacosx; then
443 HOTSPOT_$1_OS=bsd
444 fi
445 AC_SUBST(HOTSPOT_$1_OS)
446
447 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
448 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
449 HOTSPOT_$1_OS_TYPE=posix
450 fi
451 AC_SUBST(HOTSPOT_$1_OS_TYPE)
452
453 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
454 if test "x$OPENJDK_$1_CPU" = xx86; then
455 HOTSPOT_$1_CPU=x86_32
456 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
457 HOTSPOT_$1_CPU=sparc
458 elif test "x$OPENJDK_$1_CPU" = xppc64; then
459 HOTSPOT_$1_CPU=ppc_64
460 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
461 HOTSPOT_$1_CPU=ppc_64
462 fi
463 AC_SUBST(HOTSPOT_$1_CPU)
464
465 # This is identical with OPENJDK_*, but define anyway for consistency.
466 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
467 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
468
469 # Setup HOTSPOT_$1_CPU_DEFINE
470 if test "x$OPENJDK_$1_CPU" = xx86; then
471 HOTSPOT_$1_CPU_DEFINE=IA32
472 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
473 HOTSPOT_$1_CPU_DEFINE=AMD64
474 elif test "x$OPENJDK_$1_CPU" = xx32; then
475 HOTSPOT_$1_CPU_DEFINE=X32
476 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
477 HOTSPOT_$1_CPU_DEFINE=SPARC
478 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
479 HOTSPOT_$1_CPU_DEFINE=AARCH64
480 elif test "x$OPENJDK_$1_CPU" = xppc64; then
481 HOTSPOT_$1_CPU_DEFINE=PPC64
482 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
483 HOTSPOT_$1_CPU_DEFINE=PPC64
484
485 # The cpu defines below are for zero, we don't support them directly.
486 elif test "x$OPENJDK_$1_CPU" = xsparc; then
487 HOTSPOT_$1_CPU_DEFINE=SPARC
488 elif test "x$OPENJDK_$1_CPU" = xppc; then
489 HOTSPOT_$1_CPU_DEFINE=PPC32
490 elif test "x$OPENJDK_$1_CPU" = xs390; then
491 HOTSPOT_$1_CPU_DEFINE=S390
492 elif test "x$OPENJDK_$1_CPU" = xs390x; then
493 HOTSPOT_$1_CPU_DEFINE=S390
494 elif test "x$OPENJDK_$1_CPU" = xriscv64; then
495 HOTSPOT_$1_CPU_DEFINE=RISCV
496 elif test "x$OPENJDK_$1_CPU" != x; then
497 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
498 fi
499 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
500
501 # For historical reasons, the OS include directories have odd names.
502 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
503 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
504 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
505 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
506 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
507 fi
508 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
509 ])
510
511 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
512 [
513 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
514 RELEASE_FILE_OS_NAME=SunOS
515 fi
516 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
517 RELEASE_FILE_OS_NAME=Linux
518 fi
519 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
520 RELEASE_FILE_OS_NAME=Windows
521 fi
522 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
523 RELEASE_FILE_OS_NAME="Darwin"
524 fi
525 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
526 RELEASE_FILE_OS_NAME="AIX"
527 fi
528 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
529
530 AC_SUBST(RELEASE_FILE_OS_NAME)
531 AC_SUBST(RELEASE_FILE_OS_ARCH)
532 ])
533
534 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
535 [
536 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
537 OPENJDK_MODULE_TARGET_OS_NAME="macos"
538 else
539 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
540 fi
541
542 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
543 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
544 else
545 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
546 fi
547
548 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
549 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
550 ])
551
552 #%%% Build and target systems %%%
553 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
554 [
555 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
556 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
557 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
558 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
559 # to use the configure naming style.
560 AC_CANONICAL_BUILD
561 AC_CANONICAL_HOST
562 AC_CANONICAL_TARGET
563
564 PLATFORM_EXTRACT_TARGET_AND_BUILD
565 PLATFORM_SETUP_TARGET_CPU_BITS
566 PLATFORM_SET_MODULE_TARGET_OS_VALUES
567 PLATFORM_SET_RELEASE_FILE_OS_VALUES
568 PLATFORM_SETUP_LEGACY_VARS
569 PLATFORM_CHECK_DEPRECATION
570 ])
571
572 AC_DEFUN([PLATFORM_CHECK_DEPRECATION],
573 [
574 UTIL_ARG_ENABLE(NAME: deprecated-ports, DEFAULT: false,
575 RESULT: ENABLE_DEPRECATED_PORTS,
576 DESC: [suppress the error when configuring for a deprecated port])
577
578 if test "x$OPENJDK_TARGET_OS" = xsolaris || \
579 (test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc && \
580 test "x$with_jvm_variants" != xzero); then
581 if test "x$ENABLE_DEPRECATED_PORTS" = "xtrue"; then
582 AC_MSG_WARN([The Solaris and SPARC ports are deprecated and may be removed in a future release.])
583 else
584 AC_MSG_ERROR(m4_normalize([The Solaris and SPARC ports are deprecated and may be removed in a
585 future release. Use --enable-deprecated-ports=yes to suppress this error.]))
586 fi
587 fi
588 ])
589
590 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
591 [
592 ###############################################################################
593
594 # Note that this is the build platform OS version!
595
596 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
597 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
598 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
599 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
600 AC_SUBST(OS_VERSION_MAJOR)
601 AC_SUBST(OS_VERSION_MINOR)
602 AC_SUBST(OS_VERSION_MICRO)
603 ])
604
605 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
606 [
607 ###############################################################################
608 #
609 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
610 # (The JVM can use 32 or 64 bit Java pointers but that decision
611 # is made at runtime.)
612 #
613
614 # Make compilation sanity check
615 AC_CHECK_HEADERS([stdio.h], , [
616 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
617 if test "x$COMPILE_TYPE" = xreduced; then
618 HELP_MSG_MISSING_DEPENDENCY([reduced])
619 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
620 elif test "x$COMPILE_TYPE" = xcross; then
621 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
622 fi
623 AC_MSG_ERROR([Cannot continue.])
624 ])
625
626 AC_CHECK_SIZEOF([int *], [1111])
627
628 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
629 if test "x$ac_cv_sizeof_int_p" = x; then
630 # The test failed, lets stick to the assumed value.
631 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
632 else
633 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
634
635 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
636 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
637 if test "x$COMPILE_TYPE" = xreduced; then
638 HELP_MSG_MISSING_DEPENDENCY([reduced])
639 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
640 elif test "x$COMPILE_TYPE" = xcross; then
641 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
642 fi
643 AC_MSG_ERROR([Cannot continue.])
644 fi
645 fi
646
647 AC_MSG_CHECKING([for target address size])
648 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
649 ])
650
651 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
652 [
653 ###############################################################################
654 #
655 # Is the target little of big endian?
656 #
657 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
658
659 if test "x$ENDIAN" = xuniversal_endianness; then
660 AC_MSG_ERROR([Building with both big and little endianness is not supported])
661 fi
662 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
663 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
664 fi
665 ])